9ebd8c45c831dca03ba6104261be4a849e2cfedc
[BackupPC.git] / bin / BackupPC_restore
1 #!/bin/perl
2 #============================================================= -*-perl-*-
3 #
4 # BackupPC_restore: Restore files to a client.
5 #
6 # DESCRIPTION
7 #
8 #   Usage: BackupPC_restore <hostIP> <client> <reqFileName>
9 #
10 # AUTHOR
11 #   Craig Barratt  <cbarratt@users.sourceforge.net>
12 #
13 # COPYRIGHT
14 #   Copyright (C) 2001-2003  Craig Barratt
15 #
16 #   This program is free software; you can redistribute it and/or modify
17 #   it under the terms of the GNU General Public License as published by
18 #   the Free Software Foundation; either version 2 of the License, or
19 #   (at your option) any later version.
20 #
21 #   This program is distributed in the hope that it will be useful,
22 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
23 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
24 #   GNU General Public License for more details.
25 #
26 #   You should have received a copy of the GNU General Public License
27 #   along with this program; if not, write to the Free Software
28 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
29 #
30 #========================================================================
31 #
32 # Version 2.1.0_CVS, released 8 Feb 2004.
33 #
34 # See http://backuppc.sourceforge.net.
35 #
36 #========================================================================
37
38 use strict;
39 no  utf8;
40 use lib "/usr/local/BackupPC/lib";
41 use BackupPC::Lib;
42 use BackupPC::FileZIO;
43 use BackupPC::Xfer::Smb;
44 use BackupPC::Xfer::Tar;
45 use BackupPC::Xfer::Rsync;
46 use Socket;
47
48 use File::Path;
49 use Getopt::Std;
50
51 use vars qw( %RestoreReq );
52
53 ###########################################################################
54 # Initialize
55 ###########################################################################
56
57 die("BackupPC::Lib->new failed\n") if ( !(my $bpc = BackupPC::Lib->new) );
58 my $TopDir = $bpc->TopDir();
59 my $BinDir = $bpc->BinDir();
60 my %Conf   = $bpc->Conf();
61 my $NeedPostCmd;
62
63 my($hostIP, $host, $client, $reqFileName, %stat);
64
65 $bpc->ChildInit();
66
67 if ( @ARGV != 3 ) {
68     print("usage: $0 <hostIP> <client> <reqFileName>\n");
69     exit(1);
70 }
71 $hostIP = $1 if ( $ARGV[0] =~ /(.+)/ );
72 $client = $1 if ( $ARGV[1] =~ /(.+)/ );
73 if ( $ARGV[2] !~ /^([\w.]+)$/ ) {
74     print("$0: bad reqFileName (arg #3): $ARGV[2]\n");
75     exit(1);
76 }
77 $reqFileName = $1;
78
79 my $startTime = time();
80
81 my $Hosts = $bpc->HostInfoRead($client);
82
83 my $Dir     = "$TopDir/pc/$client";
84 my @xferPid = ();
85 my $tarPid  = -1;
86
87 #
88 # Catch various signals
89 #
90 $SIG{INT}  = \&catch_signal;
91 $SIG{ALRM} = \&catch_signal;
92 $SIG{TERM} = \&catch_signal;
93 $SIG{PIPE} = \&catch_signal;
94 $SIG{STOP} = \&catch_signal;
95 $SIG{TSTP} = \&catch_signal;
96 $SIG{TTIN} = \&catch_signal;
97 my $Pid = $$;
98
99 mkpath($Dir, 0, 0777) if ( !-d $Dir );
100 if ( !-f "$Dir/LOCK" ) {
101     open(LOCK, ">", "$Dir/LOCK") && close(LOCK);
102 }
103 open(LOG, ">>", "$Dir/LOG");
104 select(LOG); $| = 1; select(STDOUT);
105
106
107 #
108 # Read the request file
109 #
110 if ( !(my $ret = do "$Dir/$reqFileName") ) {
111     my $err;
112     if ( $@ ) {
113         $err = "couldn't parse $Dir/$reqFileName: $@";
114     } elsif ( !defined($ret) ) {
115         $err = "couldn't do $Dir/$reqFileName: $!";
116     } else {
117         $err = "couldn't run $Dir/$reqFileName";
118     }
119     $stat{hostError} = $err;
120     exit(RestoreCleanup($client));
121 }
122
123 #
124 # Re-read config file, so we can include the PC-specific config
125 #
126 if ( defined(my $error = $bpc->ConfigRead($client)) ) {
127     $stat{hostError} = "Can't read PC's config file: $error";
128     exit(RestoreCleanup($client));
129 }
130 %Conf = $bpc->Conf();
131
132 #
133 # Make sure we eventually timeout if there is no activity from
134 # the data transport program.
135 #
136 alarm($Conf{ClientTimeout});
137
138 #
139 # See if the host name is aliased
140 #
141 if ( $Conf{ClientNameAlias} ne "" ) {
142     $host = $Conf{ClientNameAlias};
143 } else {
144     $host = $client;
145 }
146
147 #
148 # Find its IP address
149 #
150 if ( $hostIP !~ /\d+\.\d+\.\d+\.\d+/ ) {
151     if ( !defined(gethostbyname($host)) ) {
152         #
153         # Ok, NS doesn't know about it.  Maybe it is a NetBios name
154         # instead.
155         #
156         if ( !defined($hostIP = $bpc->NetBiosHostIPFind($host)) ) {
157             $stat{hostError} = "Can't find host $host";
158             exit(RestoreCleanup($client));
159         }
160     } else {
161         $hostIP = $host;
162     }
163 }
164
165 #
166 # Check if $host is alive
167 #
168 my $delay = $bpc->CheckHostAlive($hostIP);
169 if ( $delay < 0 ) {
170     $stat{hostError} = "no ping response from $host ($hostIP)";
171     exit(RestoreCleanup($client));
172 } elsif ( $delay > $Conf{PingMaxMsec} ) {
173     $stat{hostError} = sprintf("ping too slow: %.4gmsec (max is %gmsec)\n",
174                     $delay, $Conf{PingMaxMsec});
175     exit(RestoreCleanup($client));
176 }
177
178 #
179 # Make sure it is really the machine we expect
180 #
181 if ( (my $errMsg = CorrectHostCheck($hostIP, $host)) ) {
182     $stat{hostError} = $errMsg;
183     exit(RestoreCleanup($client));
184 }
185
186 #
187 # Setup file extension for compression and open RestoreLOG output file
188 #
189 $Conf{CompressLevel} = 0 if ( !BackupPC::FileZIO->compOk );
190 my $fileExt = $Conf{CompressLevel} > 0 ? ".z" : "";
191 my $RestoreLOG = BackupPC::FileZIO->open("$Dir/RestoreLOG$fileExt", 1,
192                                      $Conf{CompressLevel});
193 my $tarCreateFileCnt = 0;
194 my $tarCreateByteCnt = 0;
195 my $tarCreateErrCnt  = 1;       # assume not ok until we learn otherwise
196 my $tarCreateErr;
197 my($logMsg, $xfer);
198
199 $stat{xferOK} = $stat{hostAbort} = undef;
200 $stat{hostError} = $stat{lastOutputLine} = undef;
201 local(*RH, *WH);
202
203 #
204 # Run an optional pre-restore command
205 #
206 UserCommandRun("RestorePreUserCmd");
207 $NeedPostCmd = 1;
208
209 if ( $Conf{XferMethod} eq "tar" ) {
210     #
211     # Use tar (eg: tar/ssh) as the transport program.
212     #
213     $xfer = BackupPC::Xfer::Tar->new($bpc);
214 } elsif ( $Conf{XferMethod} eq "rsync" || $Conf{XferMethod} eq "rsyncd" ) {
215     #
216     # Use rsync as the transport program.
217     #
218     if ( !defined($xfer = BackupPC::Xfer::Rsync->new($bpc)) ) {
219         my $errStr = BackupPC::Xfer::Rsync->errStr;
220         UserCommandRun("RestorePostUserCmd") if ( $NeedPostCmd );
221         $stat{hostError} = $errStr;
222         exit(RestoreCleanup($client));
223     }
224 } else {
225     #
226     # Default is to use smbclient (smb) as the transport program.
227     #
228     $xfer = BackupPC::Xfer::Smb->new($bpc);
229 }
230 my $useTar = $xfer->useTar;
231
232 if ( $useTar ) {
233     #
234     # Create a socketpair to connect BackupPC_tarCreate to the transport
235     # program (smbclient, tar, etc).
236     # WH is the write handle for writing, provided to BackupPC_tarCreate
237     # and RH is the other end of the pipe for reading provided to the
238     # transport program.
239     #
240     if ( socketpair(RH, WH, AF_UNIX, SOCK_STREAM, PF_UNSPEC) ) {
241         shutdown(RH, 1);    # no writing to this socket
242         shutdown(WH, 0);    # no reading from this socket
243         setsockopt(RH, SOL_SOCKET, SO_RCVBUF, 8 * 65536);
244         setsockopt(WH, SOL_SOCKET, SO_SNDBUF, 8 * 65536);
245     } else {
246         #
247         # Default to pipe() if socketpair() doesn't work.
248         #
249         pipe(RH, WH);
250     }
251 }
252
253 #
254 # Run the transport program, which reads from RH and extracts the data.
255 #
256 my @Backups = $bpc->BackupInfoRead($RestoreReq{hostSrc});
257 my $xferArgs = {
258     client       => $client,
259     host         => $host,
260     hostIP       => $hostIP,
261     type         => "restore",
262     shareName    => $RestoreReq{shareDest},
263     pipeRH       => *RH,
264     pipeWH       => *WH,
265     XferLOG      => $RestoreLOG,
266     XferMethod   => $Conf{XferMethod},
267     bkupSrcHost  => $RestoreReq{hostSrc},
268     bkupSrcShare => $RestoreReq{shareSrc},
269     bkupSrcNum   => $RestoreReq{num},
270     backups      => \@Backups,
271     pathHdrSrc   => $RestoreReq{pathHdrSrc},
272     pathHdrDest  => $RestoreReq{pathHdrDest},
273     fileList     => $RestoreReq{fileList},
274     pidHandler   => \&pidHandler,
275 };
276
277 $xfer->args($xferArgs);
278
279 if ( !defined($logMsg = $xfer->start()) ) {
280     UserCommandRun("RestorePostUserCmd") if ( $NeedPostCmd );
281     $stat{hostError} = "xfer start failed: ", $xfer->errStr;
282     exit(RestoreCleanup($client));
283 }
284
285 if ( $useTar ) {
286     #
287     # Now do the restore by running BackupPC_tarCreate
288     #
289     # The parent must close the read handle since the transport program
290     # is using it.
291     #
292     close(RH);
293
294     #
295     # fork a child for BackupPC_tarCreate.  TAR is a file handle
296     # on which we (the parent) read the stderr from BackupPC_tarCreate.
297     #
298     my @tarPathOpts;
299     if ( defined($RestoreReq{pathHdrDest})
300                 && $RestoreReq{pathHdrDest} ne $RestoreReq{pathHdrSrc} ) {
301         @tarPathOpts = ("-r", $RestoreReq{pathHdrSrc},
302                         "-p", $RestoreReq{pathHdrDest}
303                 );
304     }
305     my @tarArgs = (
306              "-h", $RestoreReq{hostSrc},
307              "-n", $RestoreReq{num},
308              "-s", $RestoreReq{shareSrc},
309              "-t",
310              @tarPathOpts,
311              @{$RestoreReq{fileList}},
312     );
313     my $logMsg = "Running: "
314                . $bpc->execCmd2ShellCmd("$BinDir/BackupPC_tarCreate", @tarArgs)
315                . "\n";
316     $RestoreLOG->write(\$logMsg);
317     if ( !defined($tarPid = open(TAR, "-|")) ) {
318         close(WH);
319         # FIX: need to cleanup xfer
320         UserCommandRun("RestorePostUserCmd") if ( $NeedPostCmd );
321         $stat{hostError} = "Can't fork to run tar";
322         exit(RestoreCleanup($client));
323     }
324     binmode(TAR);
325     if ( !$tarPid ) {
326         #
327         # This is the tarCreate child.  Clone STDERR to STDOUT,
328         # STDOUT to WH, and then exec BackupPC_tarCreate.
329         #
330         setpgrp 0,0;
331         close(STDERR);
332         open(STDERR, ">&STDOUT");
333         close(STDOUT);
334         open(STDOUT, ">&WH");
335         alarm(0);
336         exec("$BinDir/BackupPC_tarCreate", @tarArgs);
337         print(LOG $bpc->timeStamp, "can't exec $BinDir/BackupPC_tarCreate\n");
338         # FIX: need to cleanup xfer
339         exit(0);
340     }
341     #
342     # The parent must close the write handle since BackupPC_tarCreate
343     # is using it.
344     #
345     close(WH);
346
347     @xferPid = $xfer->xferPid;
348
349     print(LOG $bpc->timeStamp, $logMsg, "\n");
350     print("started_restore\n");
351
352     pidHandler(@xferPid);
353
354     #
355     # Parse the output of the transfer program and BackupPC_tarCreate
356     # while they run.  Since we are reading from two or more children
357     # we use a select.
358     #
359     my($FDread, $tarOut, $mesg);
360     vec($FDread, fileno(TAR), 1) = 1;
361     $xfer->setSelectMask(\$FDread);
362
363     SCAN: while ( 1 ) {
364         my $ein = $FDread;
365         last if ( $FDread =~ /^\0*$/ );
366         alarm($Conf{ClientTimeout});
367         select(my $rout = $FDread, undef, $ein, undef);
368         if ( vec($rout, fileno(TAR), 1) ) {
369             if ( sysread(TAR, $mesg, 8192) <= 0 ) {
370                 vec($FDread, fileno(TAR), 1) = 0;
371                 if ( !close(TAR) ) {
372                     $tarCreateErrCnt  = 1;
373                     $tarCreateErr = "BackupPC_tarCreate failed";
374                 }
375             } else {
376                 $tarOut .= $mesg;
377             }
378         }
379         while ( $tarOut =~ /(.*?)[\n\r]+(.*)/s ) {
380             $_ = $1;
381             $tarOut = $2;
382             $RestoreLOG->write(\"tarCreate: $_\n");
383             if ( /^Done: (\d+) files, (\d+) bytes, (\d+) dirs, (\d+) specials, (\d+) errors/ ) {
384                 $tarCreateFileCnt = $1;
385                 $tarCreateByteCnt = $2;
386                 $tarCreateErrCnt  = $5;
387             }
388         }
389         last if ( !$xfer->readOutput(\$FDread, $rout) );
390         while ( my $str = $xfer->logMsgGet ) {
391             print(LOG $bpc->timeStamp, "xfer: $str\n");
392         }
393         if ( $xfer->getStats->{fileCnt} == 1 ) {
394             #
395             # Make sure it is still the machine we expect.  We do this while
396             # the transfer is running to avoid a potential race condition if
397             # the ip address was reassigned by dhcp just before we started
398             # the transfer.
399             #
400             if ( my $errMsg = CorrectHostCheck($hostIP, $host) ) {
401                 $stat{hostError} = $errMsg;
402                 last SCAN;
403             }
404         }
405     }
406 } else {
407     #
408     # otherwise the xfer module does everything for us
409     #
410     print(LOG $bpc->timeStamp, "Starting restore\n");
411     print("started_restore\n");
412     ($tarCreateFileCnt, $tarCreateByteCnt,
413         $tarCreateErrCnt, $tarCreateErr) = $xfer->run();
414 }
415 alarm(0);
416
417 #
418 # Merge the xfer status (need to accumulate counts)
419 #
420 my $newStat = $xfer->getStats;
421 foreach my $k ( (keys(%stat), keys(%$newStat)) ) {
422     next if ( !defined($newStat->{$k}) );
423     if ( $k =~ /Cnt$/ ) {
424         $stat{$k} += $newStat->{$k};
425         delete($newStat->{$k});
426         next;
427     }
428     if ( !defined($stat{$k}) ) {
429         $stat{$k} = $newStat->{$k};
430         delete($newStat->{$k});
431         next;
432     }
433 }
434
435 exit(RestoreCleanup($client));
436
437 ###########################################################################
438 # Subroutines
439 ###########################################################################
440
441 sub CorrectHostCheck
442 {
443     my($hostIP, $host) = @_;
444     return if ( $hostIP eq $host && !$Conf{FixedIPNetBiosNameCheck}
445                 || $Conf{NmbLookupCmd} eq "" );
446     my($netBiosHost, $netBiosUser) = $bpc->NetBiosInfoGet($hostIP);
447     return "host $host has mismatching netbios name $netBiosHost"
448             if ( $netBiosHost ne $host );
449     return;
450 }
451
452 sub catch_signal
453 {
454     my $signame = shift;
455
456     #
457     # Children quit quietly on ALRM
458     #
459     exit(1) if ( $Pid != $$ && $signame eq "ALRM" );
460
461     #
462     # Ignore signals in children
463     #
464     return if ( $Pid != $$ );
465
466     #
467     # Note: needs to be tested for each kind of XferMethod
468     #
469     print(LOG $bpc->timeStamp, "cleaning up after signal $signame\n");
470     $SIG{$signame} = 'IGNORE';
471     $RestoreLOG->write(\"exiting after signal $signame\n");
472     $stat{xferOK} = 0;
473     if ( $signame eq "INT" ) {
474         $stat{hostError} = "aborted by user (signal=$signame)";
475     } else {
476         $stat{hostError} = "aborted by signal=$signame";
477     }
478     exit(RestoreCleanup($client));
479 }
480
481 #
482 # Cleanup and update the restore status
483 #
484 sub RestoreCleanup
485 {
486     my($client) = @_;
487
488     $stat{xferOK} = 0 if ( $stat{hostError} || $stat{hostAbort}
489                         || $tarCreateErr );
490
491     if ( !$stat{xferOK} ) {
492         #
493         # kill off the tranfer program, first nicely then forcefully
494         #
495         if ( @xferPid ) {
496             kill(2, @xferPid);
497             sleep(1);
498             kill(9, @xferPid);
499         }
500         #
501         # kill off the tar process, first nicely then forcefully
502         #
503         if ( $tarPid > 0 ) {
504             kill(2, $tarPid);
505             sleep(1);
506             kill(9, $tarPid);
507         }
508     }
509
510     my $lastNum  = -1;
511     my @Restores;
512
513     #
514     # Do one last check to make sure it is still the machine we expect.
515     #
516     if ( $stat{xferOK} && (my $errMsg = CorrectHostCheck($hostIP, $host)) ) {
517         $stat{hostError} = $errMsg;
518         $stat{xferOK} = 0;
519     }
520     @Restores = $bpc->RestoreInfoRead($client);
521     for ( my $i = 0 ; $i < @Restores ; $i++ ) {
522         $lastNum = $Restores[$i]{num} if ( $lastNum < $Restores[$i]{num} );
523     }
524     $lastNum++;
525
526     #
527     # Run an optional post-restore command
528     #
529     UserCommandRun("RestorePostUserCmd") if ( $NeedPostCmd );
530
531     rename("$Dir/RestoreLOG$fileExt", "$Dir/RestoreLOG.$lastNum$fileExt");
532     rename("$Dir/$reqFileName", "$Dir/RestoreInfo.$lastNum");
533     my $endTime = time();
534
535     #
536     # If the restore failed, clean up
537     #
538     if ( !$stat{xferOK} ) {
539         #
540         # wait a short while and see if the system is still alive
541         #
542         $stat{hostError} ||= $tarCreateErr if ( $tarCreateErr ne "" );
543         $stat{hostError} = $stat{lastOutputLine} if ( $stat{hostError} eq "" );
544         sleep(2);
545         if ( $bpc->CheckHostAlive($hostIP) < 0 ) {
546             $stat{hostAbort} = 1;
547         }
548         if ( $stat{hostAbort} && $stat{hostError} eq "" ) {
549             $stat{hostError} = "lost network connection during restore";
550         }
551         $RestoreLOG->write(\"Restore failed: $stat{hostError}\n")
552                                             if ( defined($RestoreLOG) );
553     }
554
555     $RestoreLOG->close() if ( defined($RestoreLOG) );
556
557     #
558     # Add the new restore information to the restore file
559     #
560     @Restores = $bpc->RestoreInfoRead($client);
561     my $i = @Restores;
562     $Restores[$i]{num}           = $lastNum;
563     $Restores[$i]{startTime}     = $startTime;
564     $Restores[$i]{endTime}       = $endTime;
565     $Restores[$i]{result}        = $stat{xferOK} ? "ok" : "failed";
566     $Restores[$i]{errorMsg}      = $stat{hostError};
567     $Restores[$i]{nFiles}        = $tarCreateFileCnt;
568     $Restores[$i]{size}          = $tarCreateByteCnt;
569     $Restores[$i]{tarCreateErrs} = $tarCreateErrCnt;
570     $Restores[$i]{xferErrs}      = $stat{xferErrCnt} || 0;
571
572     while ( @Restores > $Conf{RestoreInfoKeepCnt} ) {
573         my $num = $Restores[0]{num};
574         unlink("$Dir/RestoreLOG.$num.z");
575         unlink("$Dir/RestoreLOG.$num");
576         unlink("$Dir/RestoreInfo.$num");
577         shift(@Restores);
578     }
579     $bpc->RestoreInfoWrite($client, @Restores);
580
581     if ( !$stat{xferOK} ) {
582         print(LOG $bpc->timeStamp, "Restore failed ($stat{hostError})\n");
583         print("restore failed: $stat{hostError}\n");
584         return 1;
585     } else {
586         print("restore complete\n");
587         return;
588     }
589 }
590
591 #
592 # The Xfer method might tell us from time to time about processes
593 # it forks.  We tell BackupPC about this (for status displays) and
594 # keep track of the pids in case we cancel the backup
595 #
596 sub pidHandler
597 {
598     @xferPid = @_;
599     @xferPid = grep(/./, @xferPid);
600     return if ( !@xferPid && $tarPid < 0 );
601     my @pids = @xferPid;
602     push(@pids, $tarPid) if ( $tarPid > 0 );
603     my $str = join(",", @pids);
604     $RestoreLOG->write(\"Xfer PIDs are now $str\n") if ( defined($RestoreLOG) );
605     print("xferPids $str\n");
606 }
607
608 #
609 # Run an optional pre- or post-dump command
610 #
611 sub UserCommandRun
612 {
613     my($type) = @_;
614
615     return if ( !defined($Conf{$type}) );
616     my $vars = {
617         xfer         => $xfer,
618         client       => $client,
619         host         => $host,
620         hostIP       => $hostIP,
621         share        => $RestoreReq{shareDest},
622         XferMethod   => $Conf{XferMethod},
623         sshPath      => $Conf{SshPath},
624         LOG          => *LOG,
625         user         => $Hosts->{$client}{user},
626         moreUsers    => $Hosts->{$client}{moreUsers},
627         XferLOG      => $RestoreLOG,
628         stat         => \%stat,
629         xferOK       => $stat{xferOK} || 0,
630         hostError    => $stat{hostError},
631         type         => $type,
632         bkupSrcHost  => $RestoreReq{hostSrc},
633         bkupSrcShare => $RestoreReq{shareSrc},
634         bkupSrcNum   => $RestoreReq{num},
635         backups      => \@Backups,
636         pathHdrSrc   => $RestoreReq{pathHdrSrc},
637         pathHdrDest  => $RestoreReq{pathHdrDest},
638         fileList     => $RestoreReq{fileList},
639     };
640     my $cmd = $bpc->cmdVarSubstitute($Conf{$type}, $vars);
641     $RestoreLOG->write(\"Executing $type: @$cmd\n");
642     #
643     # Run the user's command, dumping the stdout/stderr into the
644     # Xfer log file.  Also supply the optional $vars and %Conf in
645     # case the command is really perl code instead of a shell
646     # command.
647     #
648     $bpc->cmdSystemOrEval($cmd,
649             sub {
650                 $RestoreLOG->write(\$_[0]);
651             },
652             $vars, \%Conf);
653 }