Various changes, including changes in 2.1.1 and 2.1.2 releases.
[BackupPC.git] / bin / BackupPC_tarCreate
1 #!/bin/perl
2 #============================================================= -*-perl-*-
3 #
4 # BackupPC_tarCreate: create a tar archive of an existing dump
5 # for restore on a client.
6 #
7 # DESCRIPTION
8 #  
9 #   Usage: BackupPC_tarCreate [options] files/directories...
10 #
11 #   Flags:
12 #     Required options:
13 #
14 #       -h host         Host from which the tar archive is created.
15 #       -n dumpNum      Dump number from which the tar archive is created.
16 #                       A negative number means relative to the end (eg -1
17 #                       means the most recent dump, -2 2nd most recent etc).
18 #       -s shareName    Share name from which the tar archive is created.
19 #
20 #     Other options:
21 #       -t              print summary totals
22 #       -r pathRemove   path prefix that will be replaced with pathAdd
23 #       -p pathAdd      new path prefix
24 #       -b BLOCKS       BLOCKS x 512 bytes per record (default 20; same as tar)
25 #       -w writeBufSz   write buffer size (default 1MB)
26 #
27 #     The -h, -n and -s options specify which dump is used to generate
28 #     the tar archive.  The -r and -p options can be used to relocate
29 #     the paths in the tar archive so extracted files can be placed
30 #     in a location different from their original location.
31 #
32 # AUTHOR
33 #   Craig Barratt  <cbarratt@users.sourceforge.net>
34 #
35 # COPYRIGHT
36 #   Copyright (C) 2001-2003  Craig Barratt
37 #
38 #   This program is free software; you can redistribute it and/or modify
39 #   it under the terms of the GNU General Public License as published by
40 #   the Free Software Foundation; either version 2 of the License, or
41 #   (at your option) any later version.
42 #
43 #   This program is distributed in the hope that it will be useful,
44 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
45 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
46 #   GNU General Public License for more details.
47 #
48 #   You should have received a copy of the GNU General Public License
49 #   along with this program; if not, write to the Free Software
50 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
51 #
52 #========================================================================
53 #
54 # Version 2.1.0, released 20 Jun 2004.
55 #
56 # See http://backuppc.sourceforge.net.
57 #
58 #========================================================================
59
60 use strict;
61 no  utf8;
62 use lib "/usr/local/BackupPC/lib";
63 use File::Path;
64 use Getopt::Std;
65 use BackupPC::Lib;
66 use BackupPC::Attrib qw(:all);
67 use BackupPC::FileZIO;
68 use BackupPC::View;
69
70 die("BackupPC::Lib->new failed\n") if ( !(my $bpc = BackupPC::Lib->new) );
71 my $TopDir = $bpc->TopDir();
72 my $BinDir = $bpc->BinDir();
73 my %Conf   = $bpc->Conf();
74
75 my %opts;
76
77 if ( !getopts("th:n:p:r:s:b:w:", \%opts) || @ARGV < 1 ) {
78     print STDERR <<EOF;
79 usage: $0 [options] files/directories...
80   Required options:
81      -h host         host from which the tar archive is created
82      -n dumpNum      dump number from which the tar archive is created
83                      A negative number means relative to the end (eg -1
84                      means the most recent dump, -2 2nd most recent etc).
85      -s shareName    share name from which the tar archive is created
86
87   Other options:
88      -t              print summary totals
89      -r pathRemove   path prefix that will be replaced with pathAdd
90      -p pathAdd      new path prefix
91      -b BLOCKS       BLOCKS x 512 bytes per record (default 20; same as tar)
92      -w writeBufSz   write buffer size (default 1048576 = 1MB)
93 EOF
94     exit(1);
95 }
96
97 if ( $opts{h} !~ /^([\w\.\s-]+)$/ ) {
98     print(STDERR "$0: bad host name '$opts{h}'\n");
99     exit(1);
100 }
101 my $Host = $opts{h};
102
103 if ( $opts{n} !~ /^(-?\d+)$/ ) {
104     print(STDERR "$0: bad dump number '$opts{n}'\n");
105     exit(1);
106 }
107 my $Num = $opts{n};
108
109 my @Backups = $bpc->BackupInfoRead($Host);
110 my $FileCnt = 0;
111 my $ByteCnt = 0;
112 my $DirCnt = 0;
113 my $SpecialCnt = 0;
114 my $ErrorCnt = 0;
115
116 my $i;
117 $Num = $Backups[@Backups + $Num]{num} if ( -@Backups <= $Num && $Num < 0 );
118 for ( $i = 0 ; $i < @Backups ; $i++ ) {
119     last if ( $Backups[$i]{num} == $Num );
120 }
121 if ( $i >= @Backups ) {
122     print(STDERR "$0: bad backup number $Num for host $Host\n");
123     exit(1);
124 }
125
126 my $PathRemove = $1 if ( $opts{r} =~ /(.+)/ );
127 my $PathAdd    = $1 if ( $opts{p} =~ /(.+)/ );
128 if ( $opts{s} !~ /^([\w\s\.\/\$-]+)$/ && $opts{s} ne "*" ) {
129     print(STDERR "$0: bad share name '$opts{s}'\n");
130     exit(1);
131 }
132 our $ShareName = $opts{s};
133 our $view = BackupPC::View->new($bpc, $Host, \@Backups);
134
135 #
136 # This constant and the line of code below that uses it are borrowed
137 # from Archive::Tar.  Thanks to Calle Dybedahl and Stephen Zander.
138 # See www.cpan.org.
139 #
140 # Archive::Tar is Copyright 1997 Calle Dybedahl. All rights reserved.
141 #                 Copyright 1998 Stephen Zander. All rights reserved.
142 #
143 my $tar_pack_header
144     = 'a100 a8 a8 a8 a12 a12 A8 a1 a100 a6 a2 a32 a32 a8 a8 a155 x12';
145 my $tar_header_length = 512;
146
147 my $BufSize    = $opts{w} || 1048576;     # 1MB or 2^20
148 my $WriteBuf   = "";
149 my $WriteBufSz = ($opts{b} || 20) * $tar_header_length;
150
151 my(%UidCache, %GidCache);
152 my(%HardLinkExtraFiles, @HardLinks);
153
154 #
155 # Write out all the requested files/directories
156 #
157 binmode(STDOUT);
158 my $fh = *STDOUT;
159 if ( $ShareName eq "*" ) {
160     my $PathRemoveOrig = $PathRemove;
161     my $PathAddOrig    = $PathAdd;
162     foreach $ShareName ( $view->shareList($Num) ) {
163         #print(STDERR "Doing share ($ShareName)\n");
164         $PathRemove = "/" if ( !defined($PathRemoveOrig) );
165         ($PathAdd = "/$ShareName/$PathAddOrig") =~ s{//+}{/}g;
166         foreach my $dir ( @ARGV ) {
167             archiveWrite($fh, $dir);
168         }
169         archiveWriteHardLinks($fh);
170     }
171 } else {
172     foreach my $dir ( @ARGV ) {
173         archiveWrite($fh, $dir);
174     }
175     archiveWriteHardLinks($fh);
176 }
177
178 #
179 # Finish with two null 512 byte headers, and then round out a full
180 # block.
181
182 my $data = "\0" x ($tar_header_length * 2);
183 TarWrite($fh, \$data);
184 TarWrite($fh, undef);
185
186 #
187 # print out totals if requested
188 #
189 if ( $opts{t} ) {
190     print STDERR "Done: $FileCnt files, $ByteCnt bytes, $DirCnt dirs,",
191                  " $SpecialCnt specials, $ErrorCnt errors\n";
192 }
193 if ( $ErrorCnt && !$FileCnt && !$DirCnt ) {
194     #
195     # Got errors, with no files or directories; exit with non-zero
196     # status
197     #
198     exit(1);
199 }
200 exit(0);
201
202 ###########################################################################
203 # Subroutines
204 ###########################################################################
205
206 sub archiveWrite
207 {
208     my($fh, $dir, $tarPathOverride) = @_;
209
210     if ( $dir =~ m{(^|/)\.\.(/|$)} ) {
211         print(STDERR "$0: bad directory '$dir'\n");
212         $ErrorCnt++;
213         return;
214     }
215     $dir = "/" if ( $dir eq "." );
216     #print(STDERR "calling find with $Num, $ShareName, $dir\n");
217     if ( $view->find($Num, $ShareName, $dir, 0, \&TarWriteFile,
218                 $fh, $tarPathOverride) < 0 ) {
219         print(STDERR "$0: bad share or directory '$ShareName/$dir'\n");
220         $ErrorCnt++;
221         return;
222     }
223 }
224
225 #
226 # Write out any hardlinks (if any)
227 #
228 sub archiveWriteHardLinks
229 {
230     my($fh) = @_;
231     foreach my $hdr ( @HardLinks ) {
232         $hdr->{size} = 0;
233         my $name = $hdr->{linkname};
234         $name =~ s{^\./}{/};
235         if ( defined($HardLinkExtraFiles{$name}) ) {
236             $hdr->{linkname} = $HardLinkExtraFiles{$name};
237         }
238         if ( defined($PathRemove)
239               && substr($hdr->{linkname}, 0, length($PathRemove)+1)
240                         eq ".$PathRemove" ) {
241             substr($hdr->{linkname}, 0, length($PathRemove)+1) = ".$PathAdd";
242         }
243         TarWriteFileInfo($fh, $hdr);
244     }
245     @HardLinks = ();
246     %HardLinkExtraFiles = ();
247 }
248
249 sub UidLookup
250 {
251     my($uid) = @_;
252
253     $UidCache{$uid} = (getpwuid($uid))[0] if ( !exists($UidCache{$uid}) );
254     return $UidCache{$uid};
255 }
256
257 sub GidLookup
258 {
259     my($gid) = @_;
260
261     $GidCache{$gid} = (getgrgid($gid))[0] if ( !exists($GidCache{$gid}) );
262     return $GidCache{$gid};
263 }
264
265 sub TarWrite
266 {
267     my($fh, $dataRef) = @_;
268
269     if ( !defined($dataRef) ) {
270         #
271         # do flush by padding to a full $WriteBufSz
272         #
273         my $data = "\0" x ($WriteBufSz - length($WriteBuf));
274         $dataRef = \$data;
275     }
276     if ( length($WriteBuf) + length($$dataRef) < $WriteBufSz ) {
277         #
278         # just buffer and return
279         #
280         $WriteBuf .= $$dataRef;
281         return;
282     }
283     my $done = $WriteBufSz - length($WriteBuf);
284     if ( syswrite($fh, $WriteBuf . substr($$dataRef, 0, $done))
285                                 != $WriteBufSz ) {
286         print(STDERR "Unable to write to output file ($!)\n");
287         exit(1);
288     }
289     while ( $done + $WriteBufSz <= length($$dataRef) ) {
290         if ( syswrite($fh, substr($$dataRef, $done, $WriteBufSz))
291                             != $WriteBufSz ) {
292             print(STDERR "Unable to write to output file ($!)\n");
293             exit(1);
294         }
295         $done += $WriteBufSz;
296     }
297     $WriteBuf = substr($$dataRef, $done);
298 }
299
300 sub TarWritePad
301 {
302     my($fh, $size) = @_;
303
304     if ( $size % $tar_header_length ) {
305         my $data = "\0" x ($tar_header_length - ($size % $tar_header_length));
306         TarWrite($fh, \$data);
307     }
308 }
309
310 sub TarWriteHeader
311 {
312     my($fh, $hdr) = @_;
313
314     $hdr->{uname} = UidLookup($hdr->{uid}) if ( !defined($hdr->{uname}) );
315     $hdr->{gname} = GidLookup($hdr->{gid}) if ( !defined($hdr->{gname}) );
316     my $devmajor = defined($hdr->{devmajor}) ? sprintf("%07o", $hdr->{devmajor})
317                                              : "";
318     my $devminor = defined($hdr->{devminor}) ? sprintf("%07o", $hdr->{devminor})
319                                              : "";
320     my $sizeStr;
321     if ( $hdr->{size} >= 2 * 65536 * 65536 ) {
322         #
323         # GNU extension for files >= 8GB: send size in big-endian binary
324         #
325         $sizeStr = pack("c4 N N", 0x80, 0, 0, 0,
326                                   $hdr->{size} / (65536 * 65536),
327                                   $hdr->{size} % (65536 * 65536));
328     } elsif ( $hdr->{size} >= 1 * 65536 * 65536 ) {
329         #
330         # sprintf octal only handles up to 2^32 - 1
331         #
332         $sizeStr = sprintf("%03o", $hdr->{size} / (1 << 24))
333                  . sprintf("%08o", $hdr->{size} % (1 << 24));
334     } else {
335         $sizeStr = sprintf("%011o", $hdr->{size});
336     }
337     my $data = pack($tar_pack_header,
338                      substr($hdr->{name}, 0, 99),
339                      sprintf("%07o", $hdr->{mode}),
340                      sprintf("%07o", $hdr->{uid}),
341                      sprintf("%07o", $hdr->{gid}),
342                      $sizeStr,
343                      sprintf("%011o", $hdr->{mtime}),
344                      "",        #checksum field - space padded by pack("A8")
345                      $hdr->{type},
346                      substr($hdr->{linkname}, 0, 99),
347                      $hdr->{magic} || 'ustar ',
348                      $hdr->{version} || ' ',
349                      $hdr->{uname},
350                      $hdr->{gname},
351                      $devmajor,
352                      $devminor,
353                      ""         # prefix is empty
354                  );
355     substr($data, 148, 7) = sprintf("%06o\0", unpack("%16C*",$data));
356     TarWrite($fh, \$data);
357 }
358
359 sub TarWriteFileInfo
360 {
361     my($fh, $hdr) = @_;
362
363     #
364     # Handle long link names (symbolic links)
365     #
366     if ( length($hdr->{linkname}) > 99 ) {
367         my %h;
368         my $data = $hdr->{linkname} . "\0";
369         $h{name} = "././\@LongLink";
370         $h{type} = "K";
371         $h{size} = length($data);
372         TarWriteHeader($fh, \%h);
373         TarWrite($fh, \$data);
374         TarWritePad($fh, length($data));
375     }
376     #
377     # Handle long file names
378     #
379     if ( length($hdr->{name}) > 99 ) {
380         my %h;
381         my $data = $hdr->{name} . "\0";
382         $h{name} = "././\@LongLink";
383         $h{type} = "L";
384         $h{size} = length($data);
385         TarWriteHeader($fh, \%h);
386         TarWrite($fh, \$data);
387         TarWritePad($fh, length($data));
388     }
389     TarWriteHeader($fh, $hdr);
390 }
391
392 my $Attr;
393 my $AttrDir;
394
395 sub TarWriteFile
396 {
397     my($hdr, $fh, $tarPathOverride) = @_;
398
399     my $tarPath = $hdr->{relPath};
400     $tarPath = $tarPathOverride if ( defined($tarPathOverride) );
401
402     $tarPath =~ s{//+}{/}g;
403     if ( defined($PathRemove)
404             && substr($tarPath, 0, length($PathRemove)) eq $PathRemove ) {
405         substr($tarPath, 0, length($PathRemove)) = $PathAdd;
406     }
407     $tarPath = "./" . $tarPath if ( $tarPath !~ /^\.\// );
408     $tarPath =~ s{//+}{/}g;
409     $hdr->{name} = $tarPath;
410
411     if ( $hdr->{type} == BPC_FTYPE_DIR ) {
412         #
413         # Directory: just write the header
414         #
415         $hdr->{name} .= "/" if ( $hdr->{name} !~ m{/$} );
416         TarWriteFileInfo($fh, $hdr);
417         $DirCnt++;
418     } elsif ( $hdr->{type} == BPC_FTYPE_FILE ) {
419         #
420         # Regular file: write the header and file
421         #
422         my $f = BackupPC::FileZIO->open($hdr->{fullPath}, 0, $hdr->{compress});
423         if ( !defined($f) ) {
424             print(STDERR "Unable to open file $hdr->{fullPath}\n");
425             $ErrorCnt++;
426             return;
427         }
428         TarWriteFileInfo($fh, $hdr);
429         my($data, $size);
430         while ( $f->read(\$data, $BufSize) > 0 ) {
431             if ( $size + length($data) > $hdr->{size} ) {
432                 print(STDERR "Error: truncating $hdr->{fullPath} to"
433                            . " $hdr->{size} bytes\n");
434                 $data = substr($data, 0, $hdr->{size} - $size);
435                 $ErrorCnt++;
436             }
437             TarWrite($fh, \$data);
438             $size += length($data);
439         }
440         $f->close;
441         if ( $size != $hdr->{size} ) {
442             print(STDERR "Error: padding $hdr->{fullPath} to $hdr->{size}"
443                        . " bytes from $size bytes\n");
444             $ErrorCnt++;
445             while ( $size < $hdr->{size} ) {
446                 my $len = $hdr->{size} - $size;
447                 $len = $BufSize if ( $len > $BufSize );
448                 $data = "\0" x $len;
449                 TarWrite($fh, \$data);
450                 $size += $len;
451             }
452         }
453         TarWritePad($fh, $size);
454         $FileCnt++;
455         $ByteCnt += $size;
456     } elsif ( $hdr->{type} == BPC_FTYPE_HARDLINK ) {
457         #
458         # Hardlink file: either write a hardlink or the complete file
459         # depending upon whether the linked-to file will be written
460         # to the archive.
461         #
462         # Start by reading the contents of the link.
463         #
464         my $f = BackupPC::FileZIO->open($hdr->{fullPath}, 0, $hdr->{compress});
465         if ( !defined($f) ) {
466             print(STDERR "Unable to open file $hdr->{fullPath}\n");
467             $ErrorCnt++;
468             return;
469         }
470         my $data;
471         while ( $f->read(\$data, $BufSize) > 0 ) {
472             $hdr->{linkname} .= $data;
473         }
474         $f->close;
475         #
476         # Check @ARGV and the list of hardlinked files we have explicity
477         # dumped to see if we have dumped this file or not
478         #
479         my $done = 0;
480         my $name = $hdr->{linkname};
481         $name =~ s{^\./}{/};
482         if ( defined($HardLinkExtraFiles{$name}) ) {
483             $done = 1;
484         } else {
485             foreach my $arg ( @ARGV ) {
486                 $arg = "/" if ( $arg eq "." );
487                 $arg =~ s{^\./+}{/};
488                 $arg =~ s{/+$}{};
489                 $done = 1 if ( $name eq $arg || $name =~ /^\Q$arg\// );
490             }
491         }
492         if ( $done ) {
493             #
494             # Target file will be or was written, so just remember
495             # the hardlink so we can dump it later.
496             #
497             push(@HardLinks, $hdr);
498             $SpecialCnt++;
499         } else {
500             #
501             # Have to dump the original file.  Just call the top-level
502             # routine, so that we save the hassle of dealing with
503             # mangling, merging and attributes.
504             #
505             my $name = $hdr->{linkname};
506             $name =~ s{^\./}{/};
507             $HardLinkExtraFiles{$name} = $hdr->{name};
508             archiveWrite($fh, $name, $hdr->{name});
509         }
510     } elsif ( $hdr->{type} == BPC_FTYPE_SYMLINK ) {
511         #
512         # Symbolic link: read the symbolic link contents into the header
513         # and write the header.
514         #
515         my $f = BackupPC::FileZIO->open($hdr->{fullPath}, 0, $hdr->{compress});
516         if ( !defined($f) ) {
517             print(STDERR "Unable to open symlink file $hdr->{fullPath}\n");
518             $ErrorCnt++;
519             return;
520         }
521         my $data;
522         while ( $f->read(\$data, $BufSize) > 0 ) {
523             $hdr->{linkname} .= $data;
524         }
525         $f->close;
526         $hdr->{size} = 0;
527         TarWriteFileInfo($fh, $hdr);
528         $SpecialCnt++;
529     } elsif ( $hdr->{type} == BPC_FTYPE_CHARDEV
530            || $hdr->{type} == BPC_FTYPE_BLOCKDEV
531            || $hdr->{type} == BPC_FTYPE_FIFO ) {
532         #
533         # Special files: for char and block special we read the
534         # major and minor numbers from a plain file.
535         #
536         if ( $hdr->{type} != BPC_FTYPE_FIFO ) {
537             my $f = BackupPC::FileZIO->open($hdr->{fullPath}, 0,
538                                                 $hdr->{compress});
539             my $data;
540             if ( !defined($f) || $f->read(\$data, $BufSize) < 0 ) {
541                 print(STDERR "Unable to open/read char/block special file"
542                            . " $hdr->{fullPath}\n");
543                 $f->close if ( defined($f) );
544                 $ErrorCnt++;
545                 return;
546             }
547             $f->close;
548             if ( $data =~ /(\d+),(\d+)/ ) {
549                 $hdr->{devmajor} = $1;
550                 $hdr->{devminor} = $2;
551             }
552         }
553         $hdr->{size} = 0;
554         TarWriteFileInfo($fh, $hdr);
555         $SpecialCnt++;
556     } else {
557         print(STDERR "Got unknown type $hdr->{type} for $hdr->{name}\n");
558         $ErrorCnt++;
559     }
560 }