bin/BackupPC_zipCreate

   1 #!/bin/perl
   2 #============================================================= -*-perl-*-
   3 #
   4 # BackupPC_zipCreate: create a zip archive of an existing dump
   5 # for restore on a client.
   6 #
   7 # DESCRIPTION
   8 #
   9 #   Usage: BackupPC_zipCreate [options] files/directories...
  10 #
  11 #   Flags:
  12 #     Required options:
  13 #       -h host         host from which the zip archive is created
  14 #       -n dumpNum      dump number from which the zip archive is created
  15 #                       A negative number means relative to the end (eg -1
  16 #                       means the most recent dump, -2 2nd most recent etc).
  17 #       -s shareName    share name from which the zip archive is created
  18 #
  19 #     Other options:
  20 #       -t              print summary totals
  21 #       -r pathRemove   path prefix that will be replaced with pathAdd
  22 #       -p pathAdd      new path prefix
  23 #       -c level        compression level (default is 0, no compression)
  24 #       -e charset      charset for encoding file names (default: value of
  25 #                       $Conf{ClientCharset} when backup was done)
  26 #
  27 #     The -h, -n and -s options specify which dump is used to generate
  28 #     the zip archive.  The -r and -p options can be used to relocate
  29 #     the paths in the zip archive so extracted files can be placed
  30 #     in a location different from their original location.
  31 #
  32 # AUTHOR
  33 #   Guillaume Filion <gfk@users.sourceforge.net>
  34 #   Based on Backup_tarCreate by Craig Barratt <cbarratt@users.sourceforge.net>
  35 #
  36 # COPYRIGHT
  37 #   Copyright (C) 2002-2003  Craig Barratt and Guillaume Filion
  38 #
  39 #   This program is free software; you can redistribute it and/or modify
  40 #   it under the terms of the GNU General Public License as published by
  41 #   the Free Software Foundation; either version 2 of the License, or
  42 #   (at your option) any later version.
  43 #
  44 #   This program is distributed in the hope that it will be useful,
  45 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  46 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  47 #   GNU General Public License for more details.
  48 #
  49 #   You should have received a copy of the GNU General Public License
  50 #   along with this program; if not, write to the Free Software
  51 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  52 #
  53 #========================================================================
  54 #
  55 # Version 3.0.0beta1, released 30 Jul 2006.
  56 #
  57 # See http://backuppc.sourceforge.net.
  58 #
  59 #========================================================================
  60
  61 use strict;
  62 no  utf8;
  63 use lib "/usr/local/BackupPC/lib";
  64 use Archive::Zip qw(:ERROR_CODES);
  65 use File::Path;
  66 use Getopt::Std;
  67 use Encode qw/from_to/;
  68 use IO::Handle;
  69 use BackupPC::Lib;
  70 use BackupPC::Attrib qw(:all);
  71 use BackupPC::FileZIO;
  72 use BackupPC::Zip::FileMember;
  73 use BackupPC::View;
  74
  75 die("BackupPC::Lib->new failed\n") if ( !(my $bpc = BackupPC::Lib->new) );
  76 my $TopDir = $bpc->TopDir();
  77 my $BinDir = $bpc->BinDir();
  78 my %Conf   = $bpc->Conf();
  79
  80 my %opts;
  81
  82 if ( !getopts("te:h:n:p:r:s:c:", \%opts) || @ARGV < 1 ) {
  83     print STDERR <<EOF;
  84 usage: $0 [options] files/directories...
  85   Required options:
  86      -h host         host from which the zip archive is created
  87      -n dumpNum      dump number from which the tar archive is created
  88                      A negative number means relative to the end (eg -1
  89                      means the most recent dump, -2 2nd most recent etc).
  90      -s shareName    share name from which the zip archive is created
  91
  92   Other options:
  93      -t              print summary totals
  94      -r pathRemove   path prefix that will be replaced with pathAdd
  95      -p pathAdd      new path prefix
  96      -c level        compression level (default is 0, no compression)
  97      -e charset      charset for encoding file names (default: value of
  98                      \$Conf{ClientCharset} when backup was done)
  99 EOF
 100     exit(1);
 101 }
 102
 103 if ( $opts{h} !~ /^([\w\.\s-]+)$/
 104         || $opts{h} =~ m{(^|/)\.\.(/|$)} ) {
 105     print(STDERR "$0: bad host name '$opts{h}'\n");
 106     exit(1);
 107 }
 108 my $Host = $opts{h};
 109
 110 if ( $opts{n} !~ /^(-?\d+)$/ ) {
 111     print(STDERR "$0: bad dump number '$opts{n}'\n");
 112     exit(1);
 113 }
 114 my $Num = $opts{n};
 115
 116 $opts{c} = 0 if ( $opts{c} eq "" );
 117 if ( $opts{c} !~ /^(\d+)$/ ) {
 118     print(STDERR "$0: invalid compression level '$opts{c}'. 0=none, 9=max\n");
 119     exit(1);
 120 }
 121 my $compLevel = $opts{c};
 122
 123 my @Backups = $bpc->BackupInfoRead($Host);
 124 my $FileCnt = 0;
 125 my $ByteCnt = 0;
 126 my $DirCnt = 0;
 127 my $SpecialCnt = 0;
 128 my $ErrorCnt = 0;
 129
 130 my $i;
 131 $Num = $Backups[@Backups + $Num]{num} if ( -@Backups <= $Num && $Num < 0 );
 132 for ( $i = 0 ; $i < @Backups ; $i++ ) {
 133     last if ( $Backups[$i]{num} == $Num );
 134 }
 135 if ( $i >= @Backups ) {
 136     print(STDERR "$0: bad backup number $Num for host $Host\n");
 137     exit(1);
 138 }
 139
 140 my $Charset = $Backups[$i]{charset};
 141 $Charset = $opts{e} if ( $opts{e} ne "" );
 142
 143 my $PathRemove = $1 if ( $opts{r} =~ /(.+)/ );
 144 my $PathAdd    = $1 if ( $opts{p} =~ /(.+)/ );
 145 if ( $opts{s} =~ m{(^|/)\.\.(/|$)} ) {
 146     print(STDERR "$0: bad share name '$opts{s}'\n");
 147     exit(1);
 148 }
 149 my $ShareName = $opts{s};
 150
 151 my $BufSize    = 1048576;     # 1MB or 2^20
 152 my(%UidCache, %GidCache);
 153 #my $fh = *STDOUT;
 154 my $fh = new IO::Handle;
 155 $fh->fdopen(fileno(STDOUT),"w");
 156 my $zipfh = Archive::Zip->new();
 157
 158 binmode(STDOUT);
 159 foreach my $dir ( @ARGV ) {
 160     archiveWrite($zipfh, $dir);
 161 }
 162
 163 sub archiveWrite
 164 {
 165     my($zipfh, $dir, $zipPathOverride) = @_;
 166
 167     my $view = BackupPC::View->new($bpc, $Host, \@Backups);
 168
 169     if ( $dir =~ m{(^|/)\.\.(/|$)} || $dir !~ /^(.*)$/ ) {
 170         print(STDERR "$0: bad directory '$dir'\n");
 171         $ErrorCnt++;
 172         return;
 173     }
 174     $dir = "/" if ( $dir eq "." );
 175     $view->find($Num, $ShareName, $dir, 0, \&ZipWriteFile,
 176                 $zipfh, $zipPathOverride);
 177 }
 178
 179 # Create Zip file
 180 print STDERR "Can't write Zip file\n"
 181      unless $zipfh->writeToFileHandle($fh, 0) == Archive::Zip::AZ_OK;
 182
 183 #
 184 # print out totals if requested
 185 #
 186 if ( $opts{t} ) {
 187     print STDERR "Done: $FileCnt files, $ByteCnt bytes, $DirCnt dirs,",
 188                  " $SpecialCnt specials ignored, $ErrorCnt errors\n";
 189 }
 190 exit(0);
 191
 192 ###########################################################################
 193 # Subroutines
 194 ###########################################################################
 195
 196 sub UidLookup
 197 {
 198     my($uid) = @_;
 199
 200     $UidCache{$uid} = (getpwuid($uid))[0] if ( !exists($UidCache{$uid}) );
 201     return $UidCache{$uid};
 202 }
 203
 204 sub GidLookup
 205 {
 206     my($gid) = @_;
 207
 208     $GidCache{$gid} = (getgrgid($gid))[0] if ( !exists($GidCache{$gid}) );
 209     return $GidCache{$gid};
 210 }
 211
 212 my $Attr;
 213 my $AttrDir;
 214
 215 sub ZipWriteFile
 216 {
 217     my($hdr, $zipfh, $zipPathOverride) = @_;
 218
 219     my $tarPath = $hdr->{relPath};
 220     $tarPath = $zipPathOverride if ( defined($zipPathOverride) );
 221
 222     if ( defined($PathRemove)
 223             && substr($tarPath, 0, length($PathRemove)) eq $PathRemove ) {
 224         substr($tarPath, 0, length($PathRemove)) = $PathAdd;
 225     }
 226     $tarPath = $1 if ( $tarPath =~ m{^\.?/+(.*)} );
 227     $tarPath =~ s{//+}{/}g;
 228     $hdr->{name} = $tarPath;
 229     return if ( $tarPath eq "." || $tarPath eq "./" || $tarPath eq "" );
 230
 231     my $zipmember; # Container to hold the file/directory to zip.
 232
 233     if ( $hdr->{type} == BPC_FTYPE_DIR ) {
 234         #
 235         # Directory: just write the header
 236         #
 237         $hdr->{name} .= "/" if ( $hdr->{name} !~ m{/$} );
 238         from_to($hdr->{name}, "utf8", $Charset) if ( $Charset ne "" );
 239         $zipmember = Archive::Zip::Member->newDirectoryNamed($hdr->{name});
 240         $DirCnt++;
 241     } elsif ( $hdr->{type} == BPC_FTYPE_FILE ) {
 242         #
 243         # Regular file: write the header and file
 244         #
 245         from_to($hdr->{name}, "utf8", $Charset) if ( $Charset ne "" );
 246         $zipmember = BackupPC::Zip::FileMember->newFromFileNamed(
 247                                             $hdr->{fullPath},
 248                                             $hdr->{name},
 249                                             $hdr->{size},
 250                                             $hdr->{compress}
 251                                     );
 252         $FileCnt++;
 253         $ByteCnt += $hdr->{size};
 254     } elsif ( $hdr->{type} == BPC_FTYPE_HARDLINK ) {
 255         #
 256         # Hardlink file: not supported by Zip, so just make a copy
 257         # of the pointed-to file.
 258         #
 259         # Start by reading the contents of the link.
 260         #
 261         my $f = BackupPC::FileZIO->open($hdr->{fullPath}, 0, $hdr->{compress});
 262         if ( !defined($f) ) {
 263             print(STDERR "Unable to open file $hdr->{fullPath}\n");
 264             $ErrorCnt++;
 265             return;
 266         }
 267         my $data;
 268         while ( $f->read(\$data, $BufSize) > 0 ) {
 269             $hdr->{linkname} .= $data;
 270         }
 271         $f->close;
 272         #
 273         # Dump the original file.  Just call the top-level
 274         # routine, so that we save the hassle of dealing with
 275         # mangling, merging and attributes.
 276         #
 277         archiveWrite($zipfh, $hdr->{linkname}, $hdr->{name});
 278     } elsif ( $hdr->{type} == BPC_FTYPE_SYMLINK ) {
 279         #
 280         # Symlinks can't be Zipped. 8(
 281         # We could zip the pointed-to dir/file (just like hardlink), but we
 282         # have to avoid the infinite-loop case of a symlink pointed to a
 283         # directory above us.  Ignore for now.  Could be a comand-line
 284         # option later.
 285         #
 286         $SpecialCnt++;
 287     } elsif ( $hdr->{type} == BPC_FTYPE_CHARDEV
 288            || $hdr->{type} == BPC_FTYPE_BLOCKDEV
 289            || $hdr->{type} == BPC_FTYPE_FIFO ) {
 290         #
 291         # Special files can't be Zipped. 8(
 292         #
 293         $SpecialCnt++;
 294     } else {
 295         print(STDERR "Got unknown type $hdr->{type} for $hdr->{name}\n");
 296         $ErrorCnt++;
 297     }
 298     return if ( !$zipmember );
 299
 300     #
 301     # Set the attributes and permissions.  The standard zip file
 302     # header cannot handle dates prior to 1/1/1980, or 315561600
 303     # unix seconds, so we round up the mtime.
 304     #
 305     my $mtime = $hdr->{mtime};
 306     $mtime = 315561600 if ( $mtime < 315561600 );
 307     $zipmember->setLastModFileDateTimeFromUnix($mtime);
 308     $zipmember->unixFileAttributes($hdr->{mode});
 309     # Zip files don't accept uid and gid, so we put them in the comment field.
 310     $zipmember->fileComment("uid=".$hdr->{uid}." gid=".$hdr->{gid})
 311             if ( $hdr->{uid} || $hdr->{gid} );
 312
 313     # Specify the compression level for this member
 314     $zipmember->desiredCompressionLevel($compLevel) if ($compLevel =~ /[0-9]/);
 315
 316     # Finally Zip the member
 317     $zipfh->addMember($zipmember);
 318 }