bin/BackupPC_zipCreate

   1 #!/bin/perl
   2 #============================================================= -*-perl-*-
   3 #
   4 # BackupPC_zipCreate: create a zip archive of an existing dump
   5 # for restore on a client.
   6 #
   7 # DESCRIPTION
   8 #
   9 #   Usage: BackupPC_zipCreate [options] files/directories...
  10 #
  11 #   Flags:
  12 #     Required options:
  13 #       -h host         host from which the zip archive is created
  14 #       -n dumpNum      dump number from which the zip archive is created
  15 #                       A negative number means relative to the end (eg -1
  16 #                       means the most recent dump, -2 2nd most recent etc).
  17 #       -s shareName    share name from which the zip archive is created
  18 #
  19 #     Other options:
  20 #       -t              print summary totals
  21 #       -r pathRemove   path prefix that will be replaced with pathAdd
  22 #       -p pathAdd      new path prefix
  23 #       -c level        compression level (default is 0, no compression)
  24 #       -e charset      charset for encoding file names (default: value of
  25 #                       $Conf{ClientCharset} when backup was done)
  26 #
  27 #     The -h, -n and -s options specify which dump is used to generate
  28 #     the zip archive.  The -r and -p options can be used to relocate
  29 #     the paths in the zip archive so extracted files can be placed
  30 #     in a location different from their original location.
  31 #
  32 # AUTHOR
  33 #   Guillaume Filion <gfk@users.sourceforge.net>
  34 #   Based on Backup_tarCreate by Craig Barratt <cbarratt@users.sourceforge.net>
  35 #
  36 # COPYRIGHT
  37 #   Copyright (C) 2002-2003  Craig Barratt and Guillaume Filion
  38 #
  39 #   This program is free software; you can redistribute it and/or modify
  40 #   it under the terms of the GNU General Public License as published by
  41 #   the Free Software Foundation; either version 2 of the License, or
  42 #   (at your option) any later version.
  43 #
  44 #   This program is distributed in the hope that it will be useful,
  45 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  46 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  47 #   GNU General Public License for more details.
  48 #
  49 #   You should have received a copy of the GNU General Public License
  50 #   along with this program; if not, write to the Free Software
  51 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  52 #
  53 #========================================================================
  54 #
  55 # Version 2.1.0, released 20 Jun 2004.
  56 #
  57 # See http://backuppc.sourceforge.net.
  58 #
  59 #========================================================================
  60
  61 use strict;
  62 no  utf8;
  63 use lib "/usr/local/BackupPC/lib";
  64 use Archive::Zip qw(:ERROR_CODES);
  65 use File::Path;
  66 use Getopt::Std;
  67 use Encode qw/from_to/;
  68 use IO::Handle;
  69 use BackupPC::Lib;
  70 use BackupPC::Attrib qw(:all);
  71 use BackupPC::FileZIO;
  72 use BackupPC::Zip::FileMember;
  73 use BackupPC::View;
  74
  75 die("BackupPC::Lib->new failed\n") if ( !(my $bpc = BackupPC::Lib->new) );
  76 my $TopDir = $bpc->TopDir();
  77 my $BinDir = $bpc->BinDir();
  78 my %Conf   = $bpc->Conf();
  79
  80 my %opts;
  81
  82 if ( !getopts("te:h:n:p:r:s:c:", \%opts) || @ARGV < 1 ) {
  83     print STDERR <<EOF;
  84 usage: $0 [options] files/directories...
  85   Required options:
  86      -h host         host from which the zip archive is created
  87      -n dumpNum      dump number from which the tar archive is created
  88                      A negative number means relative to the end (eg -1
  89                      means the most recent dump, -2 2nd most recent etc).
  90      -s shareName    share name from which the zip archive is created
  91
  92   Other options:
  93      -t              print summary totals
  94      -r pathRemove   path prefix that will be replaced with pathAdd
  95      -p pathAdd      new path prefix
  96      -c level        compression level (default is 0, no compression)
  97      -e charset      charset for encoding file names (default: value of
  98                      \$Conf{ClientCharset} when backup was done)
  99 EOF
 100     exit(1);
 101 }
 102
 103 if ( $opts{h} !~ /^([\w\.\s-]+)$/ ) {
 104     print(STDERR "$0: bad host name '$opts{h}'\n");
 105     exit(1);
 106 }
 107 my $Host = $opts{h};
 108
 109 if ( $opts{n} !~ /^(-?\d+)$/ ) {
 110     print(STDERR "$0: bad dump number '$opts{n}'\n");
 111     exit(1);
 112 }
 113 my $Num = $opts{n};
 114
 115 $opts{c} = 0 if ( $opts{c} eq "" );
 116 if ( $opts{c} !~ /^(\d+)$/ ) {
 117     print(STDERR "$0: invalid compression level '$opts{c}'. 0=none, 9=max\n");
 118     exit(1);
 119 }
 120 my $compLevel = $opts{c};
 121
 122 my @Backups = $bpc->BackupInfoRead($Host);
 123 my $FileCnt = 0;
 124 my $ByteCnt = 0;
 125 my $DirCnt = 0;
 126 my $SpecialCnt = 0;
 127 my $ErrorCnt = 0;
 128
 129 my $i;
 130 $Num = $Backups[@Backups + $Num]{num} if ( -@Backups <= $Num && $Num < 0 );
 131 for ( $i = 0 ; $i < @Backups ; $i++ ) {
 132     last if ( $Backups[$i]{num} == $Num );
 133 }
 134 if ( $i >= @Backups ) {
 135     print(STDERR "$0: bad backup number $Num for host $Host\n");
 136     exit(1);
 137 }
 138
 139 my $Charset = $Backups[$i]{charset};
 140 $Charset = $opts{e} if ( $opts{e} ne "" );
 141
 142 my $PathRemove = $1 if ( $opts{r} =~ /(.+)/ );
 143 my $PathAdd    = $1 if ( $opts{p} =~ /(.+)/ );
 144 if ( $opts{s} !~ /^([\w\s.\/$(){}[\]-]+)$/ ) {
 145     print(STDERR "$0: bad share name '$opts{s}'\n");
 146     exit(1);
 147 }
 148 my $ShareName = $opts{s};
 149
 150 my $BufSize    = 1048576;     # 1MB or 2^20
 151 my(%UidCache, %GidCache);
 152 #my $fh = *STDOUT;
 153 my $fh = new IO::Handle;
 154 $fh->fdopen(fileno(STDOUT),"w");
 155 my $zipfh = Archive::Zip->new();
 156
 157 binmode(STDOUT);
 158 foreach my $dir ( @ARGV ) {
 159     archiveWrite($zipfh, $dir);
 160 }
 161
 162 sub archiveWrite
 163 {
 164     my($zipfh, $dir, $zipPathOverride) = @_;
 165
 166     my $view = BackupPC::View->new($bpc, $Host, \@Backups);
 167
 168     if ( $dir =~ m{(^|/)\.\.(/|$)} || $dir !~ /^(.*)$/ ) {
 169         print(STDERR "$0: bad directory '$dir'\n");
 170         $ErrorCnt++;
 171         return;
 172     }
 173     $view->find($Num, $ShareName, $dir, 0, \&ZipWriteFile,
 174                 $zipfh, $zipPathOverride);
 175 }
 176
 177 # Create Zip file
 178 print STDERR "Can't write Zip file\n"
 179      unless $zipfh->writeToFileHandle($fh, 0) == Archive::Zip::AZ_OK;
 180
 181 #
 182 # print out totals if requested
 183 #
 184 if ( $opts{t} ) {
 185     print STDERR "Done: $FileCnt files, $ByteCnt bytes, $DirCnt dirs,",
 186                  " $SpecialCnt specials ignored, $ErrorCnt errors\n";
 187 }
 188 exit(0);
 189
 190 ###########################################################################
 191 # Subroutines
 192 ###########################################################################
 193
 194 sub UidLookup
 195 {
 196     my($uid) = @_;
 197
 198     $UidCache{$uid} = (getpwuid($uid))[0] if ( !exists($UidCache{$uid}) );
 199     return $UidCache{$uid};
 200 }
 201
 202 sub GidLookup
 203 {
 204     my($gid) = @_;
 205
 206     $GidCache{$gid} = (getgrgid($gid))[0] if ( !exists($GidCache{$gid}) );
 207     return $GidCache{$gid};
 208 }
 209
 210 my $Attr;
 211 my $AttrDir;
 212
 213 sub ZipWriteFile
 214 {
 215     my($hdr, $zipfh, $zipPathOverride) = @_;
 216
 217     my $tarPath = $hdr->{relPath};
 218     $tarPath = $zipPathOverride if ( defined($zipPathOverride) );
 219
 220     if ( defined($PathRemove)
 221             && substr($tarPath, 0, length($PathRemove)) eq $PathRemove ) {
 222         substr($tarPath, 0, length($PathRemove)) = $PathAdd;
 223     }
 224     $tarPath = $1 if ( $tarPath =~ m{^\.?/+(.*)} );
 225     $tarPath =~ s{//+}{/}g;
 226     $hdr->{name} = $tarPath;
 227     return if ( $tarPath eq "." || $tarPath eq "./" || $tarPath eq "" );
 228
 229     my $zipmember; # Container to hold the file/directory to zip.
 230
 231     if ( $hdr->{type} == BPC_FTYPE_DIR ) {
 232         #
 233         # Directory: just write the header
 234         #
 235         $hdr->{name} .= "/" if ( $hdr->{name} !~ m{/$} );
 236         from_to($hdr->{name}, "utf8", $Charset) if ( $Charset ne "" );
 237         $zipmember = Archive::Zip::Member->newDirectoryNamed($hdr->{name});
 238         $DirCnt++;
 239     } elsif ( $hdr->{type} == BPC_FTYPE_FILE ) {
 240         #
 241         # Regular file: write the header and file
 242         #
 243         from_to($hdr->{name}, "utf8", $Charset) if ( $Charset ne "" );
 244         $zipmember = BackupPC::Zip::FileMember->newFromFileNamed(
 245                                             $hdr->{fullPath},
 246                                             $hdr->{name},
 247                                             $hdr->{size},
 248                                             $hdr->{compress}
 249                                     );
 250         $FileCnt++;
 251         $ByteCnt += $hdr->{size};
 252     } elsif ( $hdr->{type} == BPC_FTYPE_HARDLINK ) {
 253         #
 254         # Hardlink file: not supported by Zip, so just make a copy
 255         # of the pointed-to file.
 256         #
 257         # Start by reading the contents of the link.
 258         #
 259         my $f = BackupPC::FileZIO->open($hdr->{fullPath}, 0, $hdr->{compress});
 260         if ( !defined($f) ) {
 261             print(STDERR "Unable to open file $hdr->{fullPath}\n");
 262             $ErrorCnt++;
 263             return;
 264         }
 265         my $data;
 266         while ( $f->read(\$data, $BufSize) > 0 ) {
 267             $hdr->{linkname} .= $data;
 268         }
 269         $f->close;
 270         #
 271         # Dump the original file.  Just call the top-level
 272         # routine, so that we save the hassle of dealing with
 273         # mangling, merging and attributes.
 274         #
 275         archiveWrite($zipfh, $hdr->{linkname}, $hdr->{name});
 276     } elsif ( $hdr->{type} == BPC_FTYPE_SYMLINK ) {
 277         #
 278         # Symlinks can't be Zipped. 8(
 279         # We could zip the pointed-to dir/file (just like hardlink), but we
 280         # have to avoid the infinite-loop case of a symlink pointed to a
 281         # directory above us.  Ignore for now.  Could be a comand-line
 282         # option later.
 283         #
 284         $SpecialCnt++;
 285     } elsif ( $hdr->{type} == BPC_FTYPE_CHARDEV
 286            || $hdr->{type} == BPC_FTYPE_BLOCKDEV
 287            || $hdr->{type} == BPC_FTYPE_FIFO ) {
 288         #
 289         # Special files can't be Zipped. 8(
 290         #
 291         $SpecialCnt++;
 292     } else {
 293         print(STDERR "Got unknown type $hdr->{type} for $hdr->{name}\n");
 294         $ErrorCnt++;
 295     }
 296     return if ( !$zipmember );
 297
 298     #
 299     # Set the attributes and permissions.  The standard zip file
 300     # header cannot handle dates prior to 1/1/1980, or 315561600
 301     # unix seconds, so we round up the mtime.
 302     #
 303     my $mtime = $hdr->{mtime};
 304     $mtime = 315561600 if ( $mtime < 315561600 );
 305     $zipmember->setLastModFileDateTimeFromUnix($mtime);
 306     $zipmember->unixFileAttributes($hdr->{mode});
 307     # Zip files don't accept uid and gid, so we put them in the comment field.
 308     $zipmember->fileComment("uid=".$hdr->{uid}." gid=".$hdr->{gid})
 309             if ( $hdr->{uid} || $hdr->{gid} );
 310
 311     # Specify the compression level for this member
 312     $zipmember->desiredCompressionLevel($compLevel) if ($compLevel =~ /[0-9]/);
 313
 314     # Finally Zip the member
 315     $zipfh->addMember($zipmember);
 316 }