d4ec87147c9c0fd49d19379f35d4fe041b9dc154
[BackupPC.git] / configure.pl
1 #!/bin/perl
2 #============================================================= -*-perl-*-
3 #
4 # configure.pl: Configuration and installation program for BackupPC
5 #
6 # DESCRIPTION
7 #
8 #   This script should be run as root:
9 #
10 #        perl configure.pl
11 #
12 #   The installation steps are described as the script runs.
13 #
14 # AUTHOR
15 #   Craig Barratt <cbarratt@users.sourceforge.net>
16 #
17 # COPYRIGHT
18 #   Copyright (C) 2001  Craig Barratt
19 #
20 #   This program is free software; you can redistribute it and/or modify
21 #   it under the terms of the GNU General Public License as published by
22 #   the Free Software Foundation; either version 2 of the License, or
23 #   (at your option) any later version.
24 #
25 #   This program is distributed in the hope that it will be useful,
26 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
27 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
28 #   GNU General Public License for more details.
29 #
30 #   You should have received a copy of the GNU General Public License
31 #   along with this program; if not, write to the Free Software
32 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
33 #
34 #========================================================================
35 #
36 # Version __VERSION__, released __RELEASEDATE__.
37 #
38 # See http://backuppc.sourceforge.net.
39 #
40 #========================================================================
41
42 use strict;
43 use vars qw(%Conf %OrigConf);
44 use lib "./lib";
45
46 my @Packages = qw(ExtUtils::MakeMaker File::Path File::Spec File::Copy
47                   DirHandle Digest::MD5 Data::Dumper Getopt::Std
48                   BackupPC::Lib BackupPC::FileZIO);
49
50 foreach my $pkg ( @Packages ) {
51     eval "use $pkg";
52     next if ( !$@ );
53     die <<EOF;
54
55 BackupPC needs the package $pkg.  Please install $pkg
56 before installing BackupPC.
57
58 EOF
59 }
60
61 if ( $< != 0 ) {
62     print <<EOF;
63
64 This configure script should be run as root, rather than uid $<.
65 Provided uid $< has sufficient permissions to create the data and
66 install directories, then it should be ok to proceed.  Otherwise,
67 please quit and restart as root.
68
69 EOF
70     exit unless prompt("--> Do you want to continue?", "y") =~ /y/i;
71 }
72
73 print <<EOF;
74
75 Is this a new installation or upgrade for BackupPC?  If this is
76 an upgrade please tell me the full path of the existing BackupPC
77 configuration file (eg: /xxxx/conf/config.pl).  Otherwise, just
78 hit return.
79
80 EOF
81
82 #
83 # Check if this is an upgrade, in which case read the existing
84 # config file to get all the defaults.
85 #
86 my $ConfigPath = "";
87 while ( 1 ) {
88     $ConfigPath = prompt("--> Full path to existing conf/config.pl",
89                                     $ConfigPath);
90     last if ( $ConfigPath eq ""
91             || ($ConfigPath =~ /^\// && -r $ConfigPath && -w $ConfigPath) );
92     my $problem = "is not an absolute path";
93     $problem = "is no writable"  if ( !-w $ConfigPath );
94     $problem = "is not readable" if ( !-r $ConfigPath );
95     $problem = "doesn't exist"   if ( !-f $ConfigPath );
96     print("The file '$ConfigPath' $problem.\n");
97 }
98 my $bpc;
99 if ( $ConfigPath ne "" && -r $ConfigPath ) {
100     (my $topDir = $ConfigPath) =~ s{/[^/]+/[^/]+$}{};
101     die("BackupPC::Lib->new failed\n")
102             if ( !($bpc = BackupPC::Lib->new($topDir)) );
103     %Conf = $bpc->Conf();
104     %OrigConf = %Conf;
105     $Conf{TopDir} = $topDir;
106     my $err = $bpc->ServerConnect($Conf{ServerHost}, $Conf{ServerPort}, 1); 
107     if ( $err eq "" ) {
108         print <<EOF;
109
110 BackupPC is running on $Conf{ServerHost}.  You need to stop BackupPC
111 before you can upgrade the code.  Depending upon your installation,
112 you could run "/etc/init.d/backuppc stop".
113
114 EOF
115         exit(1);
116     }
117 }
118
119 #
120 # These are the programs whose paths we need to find
121 #
122 my %Programs = (
123     perl       => "PerlPath",
124     'gtar/tar' => "TarClientPath",
125     smbclient  => "SmbClientPath",
126     nmblookup  => "NmbLookupPath",
127     ping       => "PingPath",
128     df         => "DfPath",
129     'ssh2/ssh' => "SshPath",
130     sendmail   => "SendmailPath",
131     hostname   => "HostnamePath",
132 );
133
134 foreach my $prog ( sort(keys(%Programs)) ) {
135     my $path;
136     foreach my $subProg ( split(/\//, $prog) ) {
137         $path ||= FindProgram("$ENV{PATH}:/bin:/usr/bin:/sbin:/usr/sbin",
138                               $subProg);
139     }
140     $Conf{$Programs{$prog}} ||= $path;
141 }
142
143 while ( 1 ) {
144     print <<EOF;
145
146 I found the following locations for these programs:
147
148 EOF
149     foreach my $prog ( sort(keys(%Programs)) ) {
150         printf("    %-11s => %s\n", $prog, $Conf{$Programs{$prog}});
151     }
152     print "\n";
153     last if (prompt('--> Are these paths correct?', 'y') =~ /^y/i);
154     foreach my $prog ( sort(keys(%Programs)) ) {
155         $Conf{$Programs{$prog}} = prompt("--> $prog path",
156                                          $Conf{$Programs{$prog}});
157     }
158 }
159
160 my $Perl56 = system($Conf{PerlPath}
161                         . q{ -e 'exit($^V && $^V ge v5.6.0 ? 1 : 0);'});
162
163 if ( !$Perl56 ) {
164     print <<EOF;
165
166 BackupPC needs perl version 5.6.0 or later.  $Conf{PerlPath} appears
167 to be an older version.  Please upgrade to a newer version of perl
168 and re-run this configure script.
169
170 EOF
171     exit(1);
172 }
173
174 print <<EOF;
175
176 Please tell me the hostname of the machine that BackupPC will run on.
177
178 EOF
179 chomp($Conf{ServerHost} = `$Conf{HostnamePath}`)
180         if ( defined($Conf{HostnamePath}) && !defined($Conf{ServerHost}) );
181 $Conf{ServerHost} = prompt("--> BackupPC will run on host", $Conf{ServerHost});
182
183 print <<EOF;
184
185 BackupPC should run as a dedicated user with limited privileges.  You
186 need to create a user.  This user will need read/write permission on
187 the main data directory and read/execute permission on the install
188 directory (these directories will be setup shortly).
189
190 The primary group for this user should also be chosen carefully.
191 By default the install directories will have group write permission.
192 The data directories and files will have group read permission but
193 no other permission.
194
195 EOF
196 my($name, $passwd, $Uid, $Gid);
197 while ( 1 ) {
198     $Conf{BackupPCUser} = prompt("--> BackupPC should run as user",
199                                  $Conf{BackupPCUser} || "backuppc");
200     ($name, $passwd, $Uid, $Gid) = getpwnam($Conf{BackupPCUser});
201     last if ( $name ne "" );
202     print <<EOF;
203
204 getpwnam() says that user $Conf{BackupPCUser} doesn't exist.  Please check the
205 name and verify that this user is in the passwd file.
206
207 EOF
208 }
209
210 print <<EOF;
211
212 Please specify an install directory for BackupPC.  This is where the
213 BackupPC scripts, library and documentation will be installed.
214
215 EOF
216
217 while ( 1 ) {
218     $Conf{InstallDir} = prompt("--> Install directory (full path)",
219                                $Conf{InstallDir});
220     last if ( $Conf{InstallDir} =~ /^\// );
221 }
222
223 print <<EOF;
224
225 Please specify a data directory for BackupPC.  This is where the
226 configuration files, LOG files and all the PC backups are stored.
227 This file system needs to be big enough to accommodate all the
228 PCs you expect to backup (eg: at least 1-2GB per machine).
229
230 EOF
231
232 while ( 1 ) {
233     $Conf{TopDir} = prompt("--> Data directory (full path)", $Conf{TopDir});
234     last if ( $Conf{TopDir} =~ /^\// );
235 }
236
237 if ( !defined($Conf{CompressLevel}) ) {
238     $Conf{CompressLevel} = BackupPC::FileZIO->compOk ? 3 : 0;
239     if ( $ConfigPath eq "" && $Conf{CompressLevel} ) {
240         print <<EOF;
241
242 BackupPC can compress pool files, providing around a 40% reduction in pool
243 size (your mileage may vary). Specify the compression level (0 turns
244 off compression, and 1 to 9 represent good/fastest to best/slowest).
245 The recommended values are 0 (off) or 3 (reasonable compression and speed).
246 Increasing the compression level to 5 will use around 20% more cpu time
247 and give perhaps 2-3% more compression.
248
249 EOF
250     } elsif ( $ConfigPath eq "" ) {
251         print <<EOF;
252
253 BackupPC can compress pool files, but it needs the Compress::Zlib
254 package installed (see www.cpan.org). Compression will provide around a
255 40% reduction in pool size, at the expense of cpu time.  You can leave
256 compression off and run BackupPC without compression, in which case you
257 should leave the compression level at 0 (which means off).  You could
258 install Compress::Zlib and turn compression on later, but read the
259 documentation first about how to do this.  Or the better choice is
260 to quit, install Compress::Zlib, and re-run configure.pl.
261
262 EOF
263     } elsif ( $Conf{CompressLevel} ) {
264         $Conf{CompressLevel} = 0;
265         print <<EOF;
266
267 BackupPC now supports pool file compression.  Since you are upgrading
268 BackupPC you probably have existing uncompressed backups.  You have
269 several choices if you want to turn on compression.  You can run
270 the script BackupPC_compressPool to convert everything to compressed
271 form.  Or you can simply turn on compression, so that new backups
272 will be compressed.  This will increase the pool storage requirement,
273 since both uncompressed and compressed copies of files will be stored.
274 But eventually the old uncompressed backups will expire, recovering
275 the pool storage.  Please see the documentation for more details.
276
277 If you are not sure what to do, leave the Compression Level at 0,
278 which disables compression.  You can always read the documentation
279 and turn it on later.
280
281 EOF
282     } else {
283         $Conf{CompressLevel} = 0;
284         print <<EOF;
285
286 BackupPC now supports pool file compression, but it needs the
287 Compress::Zlib module (see www.cpan.org).  For now, leave
288 the compression level set at 0 to disable compression.  If you
289 want you can install Compress::Zlib and turn compression on.
290 Please see the documentation for more details about converting
291 old backups to compressed form.
292
293 EOF
294     }
295     while ( 1 ) {
296         $Conf{CompressLevel}
297                     = prompt("--> Compression level", $Conf{CompressLevel});
298         last if ( $Conf{CompressLevel} =~ /^\d+$/ );
299     }
300 }
301
302 print <<EOF;
303
304 BackupPC has a powerful CGI perl interface that runs under Apache.
305 A single executable needs to be installed in a cgi-bin directory.
306 This executable needs to run as set-uid $Conf{BackupPCUser}, or
307 it can be run under mod_perl with Apache running as user $Conf{BackupPCUser}.
308
309 Leave this path empty if you don't want to install the CGI interface.
310
311 EOF
312
313 while ( 1 ) {
314     $Conf{CgiDir} = prompt("--> CGI bin directory (full path)", $Conf{CgiDir});
315     last if ( $Conf{CgiDir} =~ /^\// || $Conf{CgiDir} eq "" );
316 }
317
318 if ( $Conf{CgiDir} ne "" ) {
319
320     print <<EOF;
321
322 BackupPC's CGI script needs to display various GIF images that
323 should be stored where Apache can serve them.  They should be
324 placed somewher under Apache's DocumentRoot.  BackupPC also
325 needs to know the URL to access these images.  Example:
326
327     Apache image directory:  /usr/local/apache/htdocs/BackupPC
328     URL for image directory: /BackupPC
329
330 EOF
331     while ( 1 ) {
332         $Conf{CgiImageDir} = prompt("--> Apache image directory (full path)",
333                                         $Conf{CgiImageDir});
334         last if ( $Conf{CgiImageDir} =~ /^\// );
335     }
336     while ( 1 ) {
337         $Conf{CgiImageDirURL} = prompt("--> URL for image directory (omit http://host)",
338                                         $Conf{CgiImageDirURL});
339         last if ( $Conf{CgiImageDirURL} ne "" );
340     }
341 }
342
343 print <<EOF;
344
345 Ok, we're about to:
346
347   - install the binaries, lib and docs in $Conf{InstallDir},
348   - create the data directory $Conf{TopDir},
349   - create/update the config.pl file $Conf{TopDir}/conf,
350   - optionally install the cgi-bin interface.
351
352 EOF
353
354 exit unless prompt("--> Do you want to continue?", "y") =~ /y/i;
355
356 #
357 # Create install directories
358 #
359 foreach my $dir ( qw(bin lib/BackupPC/Xfer lib/BackupPC/Zip doc) ) {
360     next if ( -d "$Conf{InstallDir}/$dir" );
361     mkpath("$Conf{InstallDir}/$dir", 0, 0775);
362     if ( !-d "$Conf{InstallDir}/$dir"
363             || !chown($Uid, $Gid, "$Conf{InstallDir}/$dir") ) {
364         die("Failed to create or chown $Conf{InstallDir}/$dir\n");
365     } else {
366         print("Created $Conf{InstallDir}/$dir\n");
367     }
368 }
369
370 #
371 # Create CGI image directory
372 #
373 foreach my $dir ( ($Conf{CgiImageDir}) ) {
374     next if ( $dir eq "" || -d $dir );
375     mkpath($dir, 0, 0775);
376     if ( !-d $dir || !chown($Uid, $Gid, $dir) ) {
377         die("Failed to create or chown $dir");
378     } else {
379         print("Created $dir\n");
380     }
381 }
382
383 #
384 # Create $TopDir's top-level directories
385 #
386 foreach my $dir ( qw(. conf pool cpool pc trash log) ) {
387     mkpath("$Conf{TopDir}/$dir", 0, 0750) if ( !-d "$Conf{TopDir}/$dir" );
388     if ( !-d "$Conf{TopDir}/$dir"
389             || !chown($Uid, $Gid, "$Conf{TopDir}/$dir") ) {
390         die("Failed to create or chown $Conf{TopDir}/$dir\n");
391     } else {
392         print("Created $Conf{TopDir}/$dir\n");
393     }
394 }
395
396 printf("Installing binaries in $Conf{InstallDir}/bin\n");
397 foreach my $prog ( qw(BackupPC BackupPC_dump BackupPC_link BackupPC_nightly
398         BackupPC_sendEmail BackupPC_tarCreate BackupPC_trashClean
399         BackupPC_tarExtract BackupPC_compressPool BackupPC_zcat
400         BackupPC_restore BackupPC_serverMesg BackupPC_zipCreate ) ) {
401     InstallFile("bin/$prog", "$Conf{InstallDir}/bin/$prog", 0555);
402 }
403
404 #
405 # Remove unused binaries from older versions
406 #
407 unlink("$Conf{InstallDir}/bin/BackupPC_queueAll");
408
409 printf("Installing library in $Conf{InstallDir}/lib\n");
410 foreach my $lib ( qw(BackupPC/Lib.pm BackupPC/FileZIO.pm BackupPC/Attrib.pm
411         BackupPC/PoolWrite.pm BackupPC/Xfer/Tar.pm BackupPC/Xfer/Smb.pm
412         BackupPC/Zip/FileMember.pm
413         BackupPC/Lang/en.pm BackupPC/Lang/fr.pm
414     ) ) {
415     InstallFile("lib/$lib", "$Conf{InstallDir}/lib/$lib", 0444);
416 }
417
418 if ( $Conf{CgiImageDir} ne "" ) {
419     printf("Installing images in $Conf{CgiImageDir}\n");
420     foreach my $img ( <images/*> ) {
421         (my $destImg = $img) =~ s{^images/}{};
422         InstallFile($img, "$Conf{CgiImageDir}/$destImg", 0444, 1);
423     }
424 }
425
426 printf("Making init.d scripts\n");
427 foreach my $init ( qw(linux-backuppc solaris-backuppc) ) {
428     InstallFile("init.d/src/$init", "init.d/$init", 0444);
429 }
430
431 printf("Installing docs in $Conf{InstallDir}/doc\n");
432 foreach my $doc ( qw(BackupPC.pod BackupPC.html) ) {
433     InstallFile("doc/$doc", "$Conf{InstallDir}/doc/$doc", 0444);
434 }
435
436 printf("Installing config.pl and hosts in $Conf{TopDir}/conf\n");
437 InstallFile("conf/hosts", "$Conf{TopDir}/conf/hosts", 0644)
438                     if ( !-f "$Conf{TopDir}/conf/hosts" );
439
440 #
441 # Now do the config file.  If there is an existing config file we
442 # merge in the new config file, adding any new configuration
443 # parameters and deleting ones that are no longer needed.
444 #
445 my $dest = "$Conf{TopDir}/conf/config.pl";
446 my ($newConf, $newVars) = ConfigParse("conf/config.pl");
447 my ($oldConf, $oldVars);
448 if ( -f $dest ) {
449     ($oldConf, $oldVars) = ConfigParse($dest);
450     $newConf = ConfigMerge($oldConf, $oldVars, $newConf, $newVars);
451 }
452 $Conf{EMailFromUserName}  ||= $Conf{BackupPCUser};
453 $Conf{EMailAdminUserName} ||= $Conf{BackupPCUser};
454 #
455 # IncrFill should now be off
456 #
457 $Conf{IncrFill} = 0;
458 #
459 # Figure out sensible arguments for the ping command
460 #
461 if ( $^O eq "solaris" || $^O eq "sunos" ) {
462     $Conf{PingArgs} ||= '-s $host 56 1';
463 } elsif ( $^O eq "linux" || $^O eq "openbsd" || $^O eq "netbsd" ) {
464     $Conf{PingArgs} ||= '-c 1 -w 3 $host';
465 } else {
466     $Conf{PingArgs} ||= '-c 1 $host';
467 }
468
469 my $confCopy = "$dest.pre-1.4.0.b1";
470 if ( -f $dest && !-f $confCopy ) {
471     #
472     # Make copy of config file, preserving ownership and modes
473     #
474     printf("Making backup copy of $dest -> $confCopy\n");
475     my @stat = stat($dest);
476     my $mode = $stat[2];
477     my $uid  = $stat[4];
478     my $gid  = $stat[5];
479     die("can't copy($dest, $confCopy)\n")  unless copy($dest, $confCopy);
480     die("can't chown $uid, $gid $confCopy\n")
481                                            unless chown($uid, $gid, $confCopy);
482     die("can't chmod $mode $confCopy\n")   unless chmod($mode, $confCopy);
483 }
484 open(OUT, ">$dest") || die("can't open $dest for writing\n");
485 my $blockComment;
486 foreach my $var ( @$newConf ) {
487     if ( length($blockComment)
488           && substr($var->{text}, 0, length($blockComment)) eq $blockComment ) {
489         $var->{text} = substr($var->{text}, length($blockComment));
490         $blockComment = undef;
491     }
492     $blockComment = $1 if ( $var->{text} =~ /^([\s\n]*#{70}.*#{70}[\s\n]+)/s );
493     $var->{text} =~ s/^\s*\$Conf\{(.*?)\}(\s*=\s*['"]?)(.*?)(['"]?\s*;)/
494                 defined($Conf{$1}) && ref($Conf{$1}) eq ""
495                                    && $Conf{$1} ne $OrigConf{$1}
496                                    ? "\$Conf{$1}$2$Conf{$1}$4"
497                                    : "\$Conf{$1}$2$3$4"/emg;
498     print OUT $var->{text};
499 }
500 close(OUT);
501 if ( !defined($oldConf) ) {
502     die("can't chmod 0640 mode $dest\n")  unless chmod(0640, $dest);
503     die("can't chown $Uid, $Gid $dest\n") unless chown($Uid, $Gid, $dest);
504 }
505
506 if ( $Conf{CgiDir} ne "" ) {
507     printf("Installing cgi script BackupPC_Admin in $Conf{CgiDir}\n");
508     mkpath("$Conf{CgiDir}", 0, 0755);
509     InstallFile("cgi-bin/BackupPC_Admin", "$Conf{CgiDir}/BackupPC_Admin",
510                 04554);
511 }
512
513 print <<EOF;
514
515 Ok, it looks we are finished.  There are several more things you
516 will need to do:
517
518   - Browse through the config file, $Conf{TopDir}/conf/config.pl,
519     and make sure all the settings are correct.  In particular, you
520     will need to set the smb share password and user name, backup
521     policies and check the email message headers and bodies.
522
523   - Edit the list of hosts to backup in $Conf{TopDir}/conf/hosts.
524
525   - Read the documentation in $Conf{InstallDir}/doc/BackupPC.html.
526     Please pay special attention to the security section.
527
528   - Verify that the CGI script BackupPC_Admin runs correctly.  You might
529     need to change the permissions or group ownership of BackupPC_Admin.
530
531   - BackupPC should be ready to start.  Don't forget to run it
532     as user $Conf{BackupPCUser}!  The installation also contains an
533     init.d/backuppc script that can be copied to /etc/init.d
534     so that BackupPC can auto-start on boot.  See init.d/README.
535
536 Enjoy!
537 EOF
538
539 ###########################################################################
540 # Subroutines
541 ###########################################################################
542
543 sub InstallFile
544 {
545     my($prog, $dest, $mode, $binary) = @_;
546     my $first = 1;
547     my($uid, $gid) = ($Uid, $Gid);
548
549     if ( -f $dest ) {
550         #
551         # preserve ownership and modes of files that already exist
552         #
553         my @stat = stat($dest);
554         $mode = $stat[2];
555         $uid  = $stat[4];
556         $gid  = $stat[5];
557     }
558     unlink($dest) if ( -f $dest );
559     if ( $binary ) {
560         die("can't copy($prog, $dest)\n") unless copy($prog, $dest);
561     } else {
562         open(PROG, $prog)   || die("can't open $prog for reading\n");
563         open(OUT, ">$dest") || die("can't open $dest for writing\n");
564         while ( <PROG> ) {
565             s/__INSTALLDIR__/$Conf{InstallDir}/g;
566             s/__TOPDIR__/$Conf{TopDir}/g;
567             s/__BACKUPPCUSER__/$Conf{BackupPCUser}/g;
568             s/__CGIDIR__/$Conf{CgiDir}/g;
569             if ( $first && /^#.*bin\/perl/ ) {
570                 if ( $Perl56 ) {
571                     #
572                     # perl56 and later is taint ok
573                     #
574                     print OUT "#!$Conf{PerlPath} -T\n";
575                 } else {
576                     #
577                     # prior to perl56, File::Find fails taint checks,
578                     # so we run without -T.  It's still safe.
579                     #
580                     print OUT "#!$Conf{PerlPath}\n";
581                 }
582             } else {
583                 print OUT;
584             }
585             $first = 0;
586         }
587         close(PROG);
588         close(OUT);
589     }
590     die("can't chown $uid, $gid $dest") unless chown($uid, $gid, $dest);
591     die("can't chmod $mode $dest")      unless chmod($mode, $dest);
592 }
593
594 sub FindProgram
595 {
596     my($path, $prog) = @_;
597     foreach my $dir ( split(/:/, $path) ) {
598         my $file = File::Spec->catfile($dir, $prog);
599         return $file if ( -x $file );
600     }
601 }
602
603 sub ConfigParse
604 {
605     my($file) = @_;
606     open(C, $file) || die("can't open $file");
607     my($out, @conf, $var);
608     my $comment = 1;
609     my $allVars = {};
610     while ( <C> ) {
611         if ( /^\s*#/ ) {
612             if ( $comment ) {
613                 $out .= $_;
614             } else {
615                 if ( $out ne "" ) {
616                     $allVars->{$var} = @conf if ( defined($var) );
617                     push(@conf, {
618                         text => $out,
619                         var => $var,
620                     });
621                 }
622                 $var = undef;
623                 $comment = 1;
624                 $out = $_;
625             }
626         } elsif ( /^\s*\$Conf\{([^}]*)/ ) {
627             $comment = 0;
628             if ( defined($var) ) {
629                 $allVars->{$var} = @conf if ( defined($var) );
630                 push(@conf, {
631                     text => $out,
632                 var => $var,
633                 });
634                 $out = $_;
635             } else {
636                 $out .= $_;
637             }
638             $var = $1;
639         } else {
640             $out .= $_;
641         }
642     }
643     if ( $out ne "" ) {
644         $allVars->{$var} = @conf if ( defined($var) );
645         push(@conf, {
646             text => $out,
647             var  => $var,
648         });
649     }
650     close(C);
651     return (\@conf, $allVars);
652 }
653
654 sub ConfigMerge
655 {
656     my($old, $oldVars, $new, $newVars) = @_;
657     my $posn = 0;
658     my $res;
659
660     #
661     # Find which config parameters are not needed any longer
662     #
663     foreach my $var ( @$old ) {
664         next if ( !defined($var->{var}) || defined($newVars->{$var->{var}}) );
665         #print(STDERR "Deleting old config parameter $var->{var}\n");
666         $var->{delete} = 1;
667     }
668     #
669     # Find which config parameters are new
670     #
671     foreach my $var ( @$new ) {
672         next if ( !defined($var->{var}) );
673         if ( defined($oldVars->{$var->{var}}) ) {
674             $posn = $oldVars->{$var->{var}};
675         } else {
676             #print(STDERR "New config parameter $var->{var}: $var->{text}\n");
677             push(@{$old->[$posn]{new}}, $var);
678         }
679     }
680     #
681     # Create merged config file
682     #
683     foreach my $var ( @$old ) {
684         next if ( $var->{delete} );
685         push(@$res, $var);
686         foreach my $new ( @{$var->{new}} ) {
687             push(@$res, $new);
688         }
689     }
690     return $res;
691 }