* Support for rsync and rsyncd. Changes to BackupPC_dump and new
[BackupPC.git] / lib / BackupPC / Lib.pm
1 #============================================================= -*-perl-*-
2 #
3 # BackupPC::Lib package
4 #
5 # DESCRIPTION
6 #
7 #   This library defines a BackupPC::Lib class and a variety of utility
8 #   functions used by BackupPC.
9 #
10 # AUTHOR
11 #   Craig Barratt  <cbarratt@users.sourceforge.net>
12 #
13 # COPYRIGHT
14 #   Copyright (C) 2001  Craig Barratt
15 #
16 #   This program is free software; you can redistribute it and/or modify
17 #   it under the terms of the GNU General Public License as published by
18 #   the Free Software Foundation; either version 2 of the License, or
19 #   (at your option) any later version.
20 #
21 #   This program is distributed in the hope that it will be useful,
22 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
23 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
24 #   GNU General Public License for more details.
25 #
26 #   You should have received a copy of the GNU General Public License
27 #   along with this program; if not, write to the Free Software
28 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
29 #
30 #========================================================================
31 #
32 # Version 1.6.0_CVS, released 10 Dec 2002.
33 #
34 # See http://backuppc.sourceforge.net.
35 #
36 #========================================================================
37
38 package BackupPC::Lib;
39
40 use strict;
41
42 use vars qw(%Conf %Lang);
43 use Fcntl qw/:flock/;
44 use Carp;
45 use DirHandle ();
46 use File::Path;
47 use File::Compare;
48 use Socket;
49 use Cwd;
50 use Digest::MD5;
51
52 sub new
53 {
54     my $class = shift;
55     my($topDir, $installDir) = @_;
56
57     my $self = bless {
58         TopDir  => $topDir || '/data/BackupPC',
59         BinDir  => $installDir || '/usr/local/BackupPC',
60         LibDir  => $installDir || '/usr/local/BackupPC',
61         Version => '1.6.0_CVS',
62         BackupFields => [qw(
63                     num type startTime endTime
64                     nFiles size nFilesExist sizeExist nFilesNew sizeNew
65                     xferErrs xferBadFile xferBadShare tarErrs
66                     compress sizeExistComp sizeNewComp
67                     noFill fillFromNum mangle xferMethod level
68                 )],
69         RestoreFields => [qw(
70                     num startTime endTime result errorMsg nFiles size
71                     tarCreateErrs xferErrs
72                 )],
73     }, $class;
74     $self->{BinDir} .= "/bin";
75     $self->{LibDir} .= "/lib";
76     #
77     # Clean up %ENV and setup other variables.
78     #
79     delete @ENV{qw(IFS CDPATH ENV BASH_ENV)};
80     $self->{PoolDir}  = "$self->{TopDir}/pool";
81     $self->{CPoolDir} = "$self->{TopDir}/cpool";
82     if ( defined(my $error = $self->ConfigRead()) ) {
83         print(STDERR $error, "\n");
84         return;
85     }
86     return $self;
87 }
88
89 sub TopDir
90 {
91     my($self) = @_;
92     return $self->{TopDir};
93 }
94
95 sub BinDir
96 {
97     my($self) = @_;
98     return $self->{BinDir};
99 }
100
101 sub Version
102 {
103     my($self) = @_;
104     return $self->{Version};
105 }
106
107 sub Conf
108 {
109     my($self) = @_;
110     return %{$self->{Conf}};
111 }
112
113 sub Lang
114 {
115     my($self) = @_;
116     return $self->{Lang};
117 }
118
119 sub adminJob
120 {
121     return " admin ";
122 }
123
124 sub trashJob
125 {
126     return " trashClean ";
127 }
128
129 sub timeStamp
130 {
131     my($self, $t, $noPad) = @_;
132     my($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst)
133               = localtime($t || time);
134     $year += 1900;
135     $mon++;
136     return "$year/$mon/$mday " . sprintf("%02d:%02d:%02d", $hour, $min, $sec)
137             . ($noPad ? "" : " ");
138 }
139
140 #
141 # An ISO 8601-compliant version of timeStamp.  Needed by the
142 # --newer-mtime argument to GNU tar in BackupPC::Xfer::Tar.
143 # Also see http://www.w3.org/TR/NOTE-datetime.
144 #
145 sub timeStampISO
146 {
147     my($self, $t, $noPad) = @_;
148     my($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst)
149               = localtime($t || time);
150     $year += 1900;
151     $mon++;
152     return sprintf("%04d-%02d-%02d ", $year, $mon, $mday)
153          . sprintf("%02d:%02d:%02d", $hour, $min, $sec)
154          . ($noPad ? "" : " ");
155 }
156
157 sub BackupInfoRead
158 {
159     my($self, $host) = @_;
160     local(*BK_INFO, *LOCK);
161     my(@Backups);
162
163     flock(LOCK, LOCK_EX) if open(LOCK, "$self->{TopDir}/pc/$host/LOCK");
164     if ( open(BK_INFO, "$self->{TopDir}/pc/$host/backups") ) {
165         while ( <BK_INFO> ) {
166             s/[\n\r]+//;
167             next if ( !/^(\d+\t(incr|full)[\d\t]*$)/ );
168             $_ = $1;
169             @{$Backups[@Backups]}{@{$self->{BackupFields}}} = split(/\t/);
170         }
171         close(BK_INFO);
172     }
173     close(LOCK);
174     return @Backups;
175 }
176
177 sub BackupInfoWrite
178 {
179     my($self, $host, @Backups) = @_;
180     local(*BK_INFO, *LOCK);
181     my($i);
182
183     flock(LOCK, LOCK_EX) if open(LOCK, "$self->{TopDir}/pc/$host/LOCK");
184     unlink("$self->{TopDir}/pc/$host/backups.old")
185                 if ( -f "$self->{TopDir}/pc/$host/backups.old" );
186     rename("$self->{TopDir}/pc/$host/backups",
187            "$self->{TopDir}/pc/$host/backups.old")
188                 if ( -f "$self->{TopDir}/pc/$host/backups" );
189     if ( open(BK_INFO, ">$self->{TopDir}/pc/$host/backups") ) {
190         for ( $i = 0 ; $i < @Backups ; $i++ ) {
191             my %b = %{$Backups[$i]};
192             printf(BK_INFO "%s\n", join("\t", @b{@{$self->{BackupFields}}}));
193         }
194         close(BK_INFO);
195     }
196     close(LOCK);
197 }
198
199 sub RestoreInfoRead
200 {
201     my($self, $host) = @_;
202     local(*RESTORE_INFO, *LOCK);
203     my(@Restores);
204
205     flock(LOCK, LOCK_EX) if open(LOCK, "$self->{TopDir}/pc/$host/LOCK");
206     if ( open(RESTORE_INFO, "$self->{TopDir}/pc/$host/restores") ) {
207         while ( <RESTORE_INFO> ) {
208             s/[\n\r]+//;
209             next if ( !/^(\d+.*)/ );
210             $_ = $1;
211             @{$Restores[@Restores]}{@{$self->{RestoreFields}}} = split(/\t/);
212         }
213         close(RESTORE_INFO);
214     }
215     close(LOCK);
216     return @Restores;
217 }
218
219 sub RestoreInfoWrite
220 {
221     my($self, $host, @Restores) = @_;
222     local(*RESTORE_INFO, *LOCK);
223     my($i);
224
225     flock(LOCK, LOCK_EX) if open(LOCK, "$self->{TopDir}/pc/$host/LOCK");
226     unlink("$self->{TopDir}/pc/$host/restores.old")
227                 if ( -f "$self->{TopDir}/pc/$host/restores.old" );
228     rename("$self->{TopDir}/pc/$host/restores",
229            "$self->{TopDir}/pc/$host/restores.old")
230                 if ( -f "$self->{TopDir}/pc/$host/restores" );
231     if ( open(RESTORE_INFO, ">$self->{TopDir}/pc/$host/restores") ) {
232         for ( $i = 0 ; $i < @Restores ; $i++ ) {
233             my %b = %{$Restores[$i]};
234             printf(RESTORE_INFO "%s\n",
235                         join("\t", @b{@{$self->{RestoreFields}}}));
236         }
237         close(RESTORE_INFO);
238     }
239     close(LOCK);
240 }
241
242 sub ConfigRead
243 {
244     my($self, $host) = @_;
245     my($ret, $mesg, $config, @configs);
246
247     $self->{Conf} = ();
248     push(@configs, "$self->{TopDir}/conf/config.pl");
249     push(@configs, "$self->{TopDir}/pc/$host/config.pl")
250             if ( defined($host) && -f "$self->{TopDir}/pc/$host/config.pl" );
251     foreach $config ( @configs ) {
252         %Conf = ();
253         if ( !defined($ret = do $config) && ($! || $@) ) {
254             $mesg = "Couldn't open $config: $!" if ( $! );
255             $mesg = "Couldn't execute $config: $@" if ( $@ );
256             $mesg =~ s/[\n\r]+//;
257             return $mesg;
258         }
259         %{$self->{Conf}} = ( %{$self->{Conf} || {}}, %Conf );
260     }
261     return if ( !defined($self->{Conf}{Language}) );
262     my $langFile = "$self->{LibDir}/BackupPC/Lang/$self->{Conf}{Language}.pm";
263     if ( !defined($ret = do $langFile) && ($! || $@) ) {
264         $mesg = "Couldn't open language file $langFile: $!" if ( $! );
265         $mesg = "Couldn't execute language file $langFile: $@" if ( $@ );
266         $mesg =~ s/[\n\r]+//;
267         return $mesg;
268     }
269     $self->{Lang} = \%Lang;
270     return;
271 }
272
273 #
274 # Return the mtime of the config file
275 #
276 sub ConfigMTime
277 {
278     my($self) = @_;
279     return (stat("$self->{TopDir}/conf/config.pl"))[9];
280 }
281
282 #
283 # Returns information from the host file in $self->{TopDir}/conf/hosts.
284 # With no argument a ref to a hash of hosts is returned.  Each
285 # hash contains fields as specified in the hosts file.  With an
286 # argument a ref to a single hash is returned with information
287 # for just that host.
288 #
289 sub HostInfoRead
290 {
291     my($self, $host) = @_;
292     my(%hosts, @hdr, @fld);
293     local(*HOST_INFO);
294
295     if ( !open(HOST_INFO, "$self->{TopDir}/conf/hosts") ) {
296         print(STDERR $self->timeStamp,
297                      "Can't open $self->{TopDir}/conf/hosts\n");
298         return {};
299     }
300     while ( <HOST_INFO> ) {
301         s/[\n\r]+//;
302         s/#.*//;
303         s/\s+$//;
304         next if ( /^\s*$/ || !/^([\w\.-]+\s+.*)/ );
305         @fld = split(/\s+/, $1);
306         if ( @hdr ) {
307             if ( defined($host) ) {
308                 next if ( lc($fld[0]) ne $host );
309                 @{$hosts{lc($fld[0])}}{@hdr} = @fld;
310                 close(HOST_INFO);
311                 return \%hosts;
312             } else {
313                 @{$hosts{lc($fld[0])}}{@hdr} = @fld;
314             }
315         } else {
316             @hdr = @fld;
317         }
318     }
319     close(HOST_INFO);
320     return \%hosts;
321 }
322
323 #
324 # Return the mtime of the hosts file
325 #
326 sub HostsMTime
327 {
328     my($self) = @_;
329     return (stat("$self->{TopDir}/conf/hosts"))[9];
330 }
331
332 #
333 # Stripped down from File::Path.  In particular we don't print
334 # many warnings and we try three times to delete each directory
335 # and file -- for some reason the original File::Path rmtree
336 # didn't always completely remove a directory tree on the NetApp.
337 #
338 # Warning: this routine changes the cwd.
339 #
340 sub RmTreeQuiet
341 {
342     my($self, $pwd, $roots) = @_;
343     my(@files, $root);
344
345     if ( defined($roots) && length($roots) ) {
346       $roots = [$roots] unless ref $roots;
347     } else {
348       print "RmTreeQuiet: No root path(s) specified\n";
349     }
350     chdir($pwd);
351     foreach $root (@{$roots}) {
352         $root = $1 if ( $root =~ m{(.*?)/*$} );
353         #
354         # Try first to simply unlink the file: this avoids an
355         # extra stat for every file.  If it fails (which it
356         # will for directories), check if it is a directory and
357         # then recurse.
358         #
359         if ( !unlink($root) ) {
360             if ( -d $root ) {
361                 my $d = DirHandle->new($root)
362                   or print "Can't read $pwd/$root: $!";
363                 @files = $d->read;
364                 $d->close;
365                 @files = grep $_!~/^\.{1,2}$/, @files;
366                 $self->RmTreeQuiet("$pwd/$root", \@files);
367                 chdir($pwd);
368                 rmdir($root) || rmdir($root);
369             } else {
370                 unlink($root) || unlink($root);
371             }
372         }
373     }
374 }
375
376 #
377 # Move a directory or file away for later deletion
378 #
379 sub RmTreeDefer
380 {
381     my($self, $trashDir, $file) = @_;
382     my($i, $f);
383
384     return if ( !-e $file );
385     mkpath($trashDir, 0, 0777) if ( !-d $trashDir );
386     for ( $i = 0 ; $i < 1000 ; $i++ ) {
387         $f = sprintf("%s/%d_%d_%d", $trashDir, time, $$, $i);
388         next if ( -e $f );
389         return if ( rename($file, $f) );
390     }
391     # shouldn't get here, but might if you tried to call this
392     # across file systems.... just remove the tree right now.
393     if ( $file =~ /(.*)\/([^\/]*)/ ) {
394         my($d) = $1;
395         my($f) = $2;
396         my($cwd) = Cwd::fastcwd();
397         $cwd = $1 if ( $cwd =~ /(.*)/ );
398         $self->RmTreeQuiet($d, $f);
399         chdir($cwd) if ( $cwd );
400     }
401 }
402
403 #
404 # Empty the trash directory.  Returns 0 if it did nothing.
405 #
406 sub RmTreeTrashEmpty
407 {
408     my($self, $trashDir) = @_;
409     my(@files);
410     my($cwd) = Cwd::fastcwd();
411
412     $cwd = $1 if ( $cwd =~ /(.*)/ );
413     return if ( !-d $trashDir );
414     my $d = DirHandle->new($trashDir)
415       or carp "Can't read $trashDir: $!";
416     @files = $d->read;
417     $d->close;
418     @files = grep $_!~/^\.{1,2}$/, @files;
419     return 0 if ( !@files );
420     $self->RmTreeQuiet($trashDir, \@files);
421     chdir($cwd) if ( $cwd );
422     return 1;
423 }
424
425 #
426 # Open a connection to the server.  Returns an error string on failure.
427 # Returns undef on success.
428 #
429 sub ServerConnect
430 {
431     my($self, $host, $port, $justConnect) = @_;
432     local(*FH);
433
434     return if ( defined($self->{ServerFD}) );
435     #
436     # First try the unix-domain socket
437     #
438     my $sockFile = "$self->{TopDir}/log/BackupPC.sock";
439     socket(*FH, PF_UNIX, SOCK_STREAM, 0)     || return "unix socket: $!";
440     if ( !connect(*FH, sockaddr_un($sockFile)) ) {
441         my $err = "unix connect: $!";
442         close(*FH);
443         if ( $port > 0 ) {
444             my $proto = getprotobyname('tcp');
445             my $iaddr = inet_aton($host)     || return "unknown host $host";
446             my $paddr = sockaddr_in($port, $iaddr);
447
448             socket(*FH, PF_INET, SOCK_STREAM, $proto)
449                                              || return "inet socket: $!";
450             connect(*FH, $paddr)             || return "inet connect: $!";
451         } else {
452             return $err;
453         }
454     }
455     my($oldFH) = select(*FH); $| = 1; select($oldFH);
456     $self->{ServerFD} = *FH;
457     return if ( $justConnect );
458     #
459     # Read the seed that we need for our MD5 message digest.  See
460     # ServerMesg below.
461     #
462     sysread($self->{ServerFD}, $self->{ServerSeed}, 1024);
463     $self->{ServerMesgCnt} = 0;
464     return;
465 }
466
467 #
468 # Check that the server connection is still ok
469 #
470 sub ServerOK
471 {
472     my($self) = @_;
473
474     return 0 if ( !defined($self->{ServerFD}) );
475     vec(my $FDread, fileno($self->{ServerFD}), 1) = 1;
476     my $ein = $FDread;
477     return 0 if ( select(my $rout = $FDread, undef, $ein, 0.0) < 0 );
478     return 1 if ( !vec($rout, fileno($self->{ServerFD}), 1) );
479 }
480
481 #
482 # Disconnect from the server
483 #
484 sub ServerDisconnect
485 {
486     my($self) = @_;
487     return if ( !defined($self->{ServerFD}) );
488     close($self->{ServerFD});
489     delete($self->{ServerFD});
490 }
491
492 #
493 # Sends a message to the server and returns with the reply.
494 #
495 # To avoid possible attacks via the TCP socket interface, every client
496 # message is protected by an MD5 digest. The MD5 digest includes four
497 # items:
498 #   - a seed that is sent to us when we first connect
499 #   - a sequence number that increments for each message
500 #   - a shared secret that is stored in $Conf{ServerMesgSecret}
501 #   - the message itself.
502 # The message is sent in plain text preceded by the MD5 digest. A
503 # snooper can see the plain-text seed sent by BackupPC and plain-text
504 # message, but cannot construct a valid MD5 digest since the secret in
505 # $Conf{ServerMesgSecret} is unknown. A replay attack is not possible
506 # since the seed changes on a per-connection and per-message basis.
507 #
508 sub ServerMesg
509 {
510     my($self, $mesg) = @_;
511     return if ( !defined(my $fh = $self->{ServerFD}) );
512     my $md5 = Digest::MD5->new;
513     $md5->add($self->{ServerSeed} . $self->{ServerMesgCnt}
514             . $self->{Conf}{ServerMesgSecret} . $mesg);
515     print($fh $md5->b64digest . " $mesg\n");
516     $self->{ServerMesgCnt}++;
517     return <$fh>;
518 }
519
520 #
521 # Do initialization for child processes
522 #
523 sub ChildInit
524 {
525     my($self) = @_;
526     close(STDERR);
527     open(STDERR, ">&STDOUT");
528     select(STDERR); $| = 1;
529     select(STDOUT); $| = 1;
530     $ENV{PATH} = $self->{Conf}{MyPath};
531 }
532
533 #
534 # Compute the MD5 digest of a file.  For efficiency we don't
535 # use the whole file for big files:
536 #   - for files <= 256K we use the file size and the whole file.
537 #   - for files <= 1M we use the file size, the first 128K and
538 #     the last 128K.
539 #   - for files > 1M, we use the file size, the first 128K and
540 #     the 8th 128K (ie: the 128K up to 1MB).
541 # See the documentation for a discussion of the tradeoffs in
542 # how much data we use and how many collisions we get.
543 #
544 # Returns the MD5 digest (a hex string) and the file size.
545 #
546 sub File2MD5
547 {
548     my($self, $md5, $name) = @_;
549     my($data, $fileSize);
550     local(*N);
551
552     $fileSize = (stat($name))[7];
553     return ("", -1) if ( !-f _ );
554     $name = $1 if ( $name =~ /(.*)/ );
555     return ("", 0) if ( $fileSize == 0 );
556     return ("", -1) if ( !open(N, $name) );
557     $md5->reset();
558     $md5->add($fileSize);
559     if ( $fileSize > 262144 ) {
560         #
561         # read the first and last 131072 bytes of the file,
562         # up to 1MB.
563         #
564         my $seekPosn = ($fileSize > 1048576 ? 1048576 : $fileSize) - 131072;
565         $md5->add($data) if ( sysread(N, $data, 131072) );
566         $md5->add($data) if ( sysseek(N, $seekPosn, 0)
567                                 && sysread(N, $data, 131072) );
568     } else {
569         #
570         # read the whole file
571         #
572         $md5->add($data) if ( sysread(N, $data, $fileSize) );
573     }
574     close(N);
575     return ($md5->hexdigest, $fileSize);
576 }
577
578 #
579 # Compute the MD5 digest of a buffer (string).  For efficiency we don't
580 # use the whole string for big strings:
581 #   - for files <= 256K we use the file size and the whole file.
582 #   - for files <= 1M we use the file size, the first 128K and
583 #     the last 128K.
584 #   - for files > 1M, we use the file size, the first 128K and
585 #     the 8th 128K (ie: the 128K up to 1MB).
586 # See the documentation for a discussion of the tradeoffs in
587 # how much data we use and how many collisions we get.
588 #
589 # Returns the MD5 digest (a hex string).
590 #
591 sub Buffer2MD5
592 {
593     my($self, $md5, $fileSize, $dataRef) = @_;
594
595     $md5->reset();
596     $md5->add($fileSize);
597     if ( $fileSize > 262144 ) {
598         #
599         # add the first and last 131072 bytes of the string,
600         # up to 1MB.
601         #
602         my $seekPosn = ($fileSize > 1048576 ? 1048576 : $fileSize) - 131072;
603         $md5->add(substr($$dataRef, 0, 131072));
604         $md5->add(substr($$dataRef, $seekPosn, 131072));
605     } else {
606         #
607         # add the whole string
608         #
609         $md5->add($$dataRef);
610     }
611     return $md5->hexdigest;
612 }
613
614 #
615 # Given an MD5 digest $d and a compress flag, return the full
616 # path in the pool.
617 #
618 sub MD52Path
619 {
620     my($self, $d, $compress, $poolDir) = @_;
621
622     return if ( $d !~ m{(.)(.)(.)(.*)} );
623     $poolDir = ($compress ? $self->{CPoolDir} : $self->{PoolDir})
624                     if ( !defined($poolDir) );
625     return "$poolDir/$1/$2/$3/$1$2$3$4";
626 }
627
628 #
629 # For each file, check if the file exists in $self->{TopDir}/pool.
630 # If so, remove the file and make a hardlink to the file in
631 # the pool.  Otherwise, if the newFile flag is set, make a
632 # hardlink in the pool to the new file.
633 #
634 # Returns 0 if a link should be made to a new file (ie: when the file
635 #    is a new file but the newFile flag is 0).
636 # Returns 1 if a link to an existing file is made,
637 # Returns 2 if a link to a new file is made (only if $newFile is set)
638 # Returns negative on error.
639 #
640 sub MakeFileLink
641 {
642     my($self, $name, $d, $newFile, $compress) = @_;
643     my($i, $rawFile);
644
645     return -1 if ( !-f $name );
646     for ( $i = -1 ; ; $i++ ) {
647         return -2 if ( !defined($rawFile = $self->MD52Path($d, $compress)) );
648         $rawFile .= "_$i" if ( $i >= 0 );
649         if ( -f $rawFile ) {
650             if ( !compare($name, $rawFile) ) {
651                 unlink($name);
652                 return -3 if ( !link($rawFile, $name) );
653                 return 1;
654             }
655         } elsif ( $newFile && -f $name && (stat($name))[3] == 1 ) {
656             my($newDir);
657             ($newDir = $rawFile) =~ s{(.*)/.*}{$1};
658             mkpath($newDir, 0, 0777) if ( !-d $newDir );
659             return -4 if ( !link($name, $rawFile) );
660             return 2;
661         } else {
662             return 0;
663         }
664     }
665 }
666
667 sub CheckHostAlive
668 {
669     my($self, $host) = @_;
670     my($s, $pingArgs);
671
672     $pingArgs = $self->{Conf}{PingArgs};
673     #
674     # Merge variables into $pingArgs
675     #
676     my $vars = {
677         host    => $host,
678     };
679     $pingArgs =~ s/\$(\w+)/defined($vars->{$1})
680                                  ? $self->shellEscape($vars->{$1})
681                                  : \$$1/eg;
682     #
683     # Do a first ping in case the PC needs to wakeup
684     #
685     $s = `$self->{Conf}{PingPath} $pingArgs 2>&1`;
686     return -1 if ( $? );
687     #
688     # Do a second ping and get the round-trip time in msec
689     #
690     $s = `$self->{Conf}{PingPath} $pingArgs 2>&1`;
691     return -1 if ( $? );
692     return $1 if ( $s !~ /time=([\d\.]+)\s*ms/ );
693     return $1/1000 if ( $s !~ /time=([\d\.]+)\s*usec/ );
694     return 0;
695 }
696
697 sub CheckFileSystemUsage
698 {
699     my($self) = @_;
700     my($topDir) = $self->{TopDir};
701     my($s);
702
703     if ( $^O eq "solaris" ) {
704         $s = `$self->{Conf}{DfPath} -k $topDir 2>&1`;
705         return 0 if ( $? || $s !~ /(\d+)%/s );
706         return $1;
707     } elsif ( $^O eq "sunos" ) {
708         $s = `$self->{Conf}{DfPath} $topDir 2>&1`;
709         return 0 if ( $? || $s !~ /(\d+)%/s );
710         return $1;
711     } elsif ( $^O eq "linux" ) {
712         $s = `$self->{Conf}{DfPath} $topDir 2>&1`;
713         return 0 if ( $? || $s !~ /(\d+)%/s );
714         return $1;
715     } else {
716         return 0;
717     }
718 }
719
720 sub NetBiosInfoGet
721 {
722     my($self, $host) = @_;
723     my($netBiosHostName, $netBiosUserName);
724
725     foreach ( split(/[\n\r]+/, `$self->{Conf}{NmbLookupPath} -A $host 2>&1`) ) {
726         next if ( !/([\w-]+)\s*<(\w{2})\> - .*<ACTIVE>/i );
727         $netBiosHostName ||= $1 if ( $2 eq "00" );  # host is first 00
728         $netBiosUserName   = $1 if ( $2 eq "03" );  # user is last 03
729     }
730     return if ( !defined($netBiosHostName) );
731     return (lc($netBiosHostName), lc($netBiosUserName));
732 }
733
734 sub fileNameEltMangle
735 {
736     my($self, $name) = @_;
737
738     return "" if ( $name eq "" );
739     $name =~ s{([%/\n\r])}{sprintf("%%%02x", ord($1))}eg;
740     return "f$name";
741 }
742
743 #
744 # We store files with every name preceded by "f".  This
745 # avoids possible name conflicts with other information
746 # we store in the same directories (eg: attribute info).
747 # The process of turning a normal path into one with each
748 # node prefixed with "f" is called mangling.
749 #
750 sub fileNameMangle
751 {
752     my($self, $name) = @_;
753
754     $name =~ s{/([^/]+)}{"/" . $self->fileNameEltMangle($1)}eg;
755     $name =~ s{^([^/]+)}{$self->fileNameEltMangle($1)}eg;
756     return $name;
757 }
758
759 #
760 # This undoes FileNameMangle
761 #
762 sub fileNameUnmangle
763 {
764     my($self, $name) = @_;
765
766     $name =~ s{/f}{/}g;
767     $name =~ s{^f}{};
768     $name =~ s{%(..)}{chr(hex($1))}eg;
769     return $name;
770 }
771
772 #
773 # Escape shell meta-characters with backslashes.
774 # This should be applied to each argument seperately, not an
775 # entire shell command.
776 #
777 sub shellEscape
778 {
779     my($self, $cmd) = @_;
780
781     $cmd =~ s/([][;&()<>{}|^\n\r\t *\$\\'"`?])/\\$1/g;
782     return $cmd;
783 }
784
785 1;