- added $Conf{ClientNameAlias}, which allows the host name to be
[BackupPC.git] / lib / BackupPC / Xfer / Rsync.pm
1 #============================================================= -*-perl-*-
2 #
3 # BackupPC::Xfer::Rsync package
4 #
5 # DESCRIPTION
6 #
7 #   This library defines a BackupPC::Xfer::Rsync class for managing
8 #   the rsync-based transport of backup data from the client.
9 #
10 # AUTHOR
11 #   Craig Barratt  <cbarratt@users.sourceforge.net>
12 #
13 # COPYRIGHT
14 #   Copyright (C) 2002  Craig Barratt
15 #
16 #   This program is free software; you can redistribute it and/or modify
17 #   it under the terms of the GNU General Public License as published by
18 #   the Free Software Foundation; either version 2 of the License, or
19 #   (at your option) any later version.
20 #
21 #   This program is distributed in the hope that it will be useful,
22 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
23 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
24 #   GNU General Public License for more details.
25 #
26 #   You should have received a copy of the GNU General Public License
27 #   along with this program; if not, write to the Free Software
28 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
29 #
30 #========================================================================
31 #
32 # Version 2.0.0_CVS, released 18 Jan 2003.
33 #
34 # See http://backuppc.sourceforge.net.
35 #
36 #========================================================================
37
38 package BackupPC::Xfer::Rsync;
39
40 use strict;
41 use BackupPC::View;
42 use BackupPC::Xfer::RsyncFileIO;
43
44 use vars qw( $RsyncLibOK $RsyncLibErr );
45
46 BEGIN {
47     eval "use File::RsyncP;";
48     if ( $@ ) {
49         #
50         # Rsync module doesn't exist.
51         #
52         $RsyncLibOK = 0;
53         $RsyncLibErr = "File::RsyncP module doesn't exist";
54     } else {
55         if ( $File::RsyncP::VERSION < 0.20 ) {
56             $RsyncLibOK = 0;
57             $RsyncLibErr = "File::RsyncP module version too old: need 0.20";
58         } else {
59             $RsyncLibOK = 1;
60         }
61     }
62 };
63
64 sub new
65 {
66     my($class, $bpc, $args) = @_;
67
68     return if ( !$RsyncLibOK );
69     $args ||= {};
70     my $t = bless {
71         bpc       => $bpc,
72         conf      => { $bpc->Conf },
73         host      => "",
74         hostIP    => "",
75         shareName => "",
76         badFiles  => [],
77
78         #
79         # Various stats
80         #
81         byteCnt         => 0,
82         fileCnt         => 0,
83         xferErrCnt      => 0,
84         xferBadShareCnt => 0,
85         xferBadFileCnt  => 0,
86         xferOK          => 0,
87
88         #
89         # User's args
90         #
91         %$args,
92     }, $class;
93
94     return $t;
95 }
96
97 sub args
98 {
99     my($t, $args) = @_;
100
101     foreach my $arg ( keys(%$args) ) {
102         $t->{$arg} = $args->{$arg};
103     }
104 }
105
106 sub useTar
107 {
108     return 0;
109 }
110
111 sub start
112 {
113     my($t) = @_;
114     my $bpc = $t->{bpc};
115     my $conf = $t->{conf};
116     my(@fileList, $rsyncClientCmd, $rsyncArgs, $logMsg,
117        $incrDate, $argList, $fioArgs);
118
119     #
120     # We add a slash to the share name we pass to rsync
121     #
122     ($t->{shareNameSlash} = "$t->{shareName}/") =~ s{//+$}{};
123
124     if ( $t->{type} eq "restore" ) {
125         $rsyncClientCmd = $conf->{RsyncClientRestoreCmd};
126         $rsyncArgs = $conf->{RsyncRestoreArgs};
127         my $remoteDir = "$t->{shareName}/$t->{pathHdrDest}";
128         $remoteDir    =~ s{//+}{/}g;
129         $argList = ['--server', @$rsyncArgs, '.', $remoteDir];
130         $fioArgs = {
131             client   => $t->{bkupSrcHost},
132             share    => $t->{bkupSrcShare},
133             viewNum  => $t->{bkupSrcNum},
134             fileList => $t->{fileList},
135         };
136         $logMsg = "restore started below directory $t->{shareName}"
137                 . " to host $t->{host}";
138     } else {
139         #
140         # Turn $conf->{BackupFilesOnly} and $conf->{BackupFilesExclude}
141         # into a hash of arrays of files.
142         #
143         $conf->{RsyncShareName} = [ $conf->{RsyncShareName} ]
144                         unless ref($conf->{RsyncShareName}) eq "ARRAY";
145         foreach my $param qw(BackupFilesOnly BackupFilesExclude) {
146             next if ( !defined($conf->{$param}) );
147             if ( ref($conf->{$param}) eq "ARRAY" ) {
148                 $conf->{$param} = {
149                         $conf->{RsyncShareName}[0] => $conf->{$param}
150                 };
151             } elsif ( ref($conf->{$param}) eq "HASH" ) {
152                 # do nothing
153             } else {
154                 $conf->{$param} = {
155                         $conf->{RsyncShareName}[0] => [ $conf->{$param} ]
156                 };
157             }
158         }
159         if ( defined($conf->{BackupFilesOnly}{$t->{shareName}}) ) {
160             my(@inc, @exc, %incDone, %excDone);
161             foreach my $file ( @{$conf->{BackupFilesOnly}{$t->{shareName}}} ) {
162                 #
163                 # If the user wants to just include /home/craig, then
164                 # we need to do create include/exclude pairs at
165                 # each level:
166                 #     --include /home --exclude /*
167                 #     --include /home/craig --exclude /home/*
168                 #
169                 # It's more complex if the user wants to include multiple
170                 # deep paths.  For example, if they want /home/craig and
171                 # /var/log, then we need this mouthfull:
172                 #     --include /home --include /var --exclude /*
173                 #     --include /home/craig --exclude /home/*
174                 #     --include /var/log --exclude /var/*
175                 #
176                 # To make this easier we do all the includes first and all
177                 # of the excludes at the end (hopefully they commute).
178                 #
179                 $file = "/$file";
180                 $file =~ s{//+}{/}g;
181                 my $f = "";
182                 while ( $file =~ m{^/([^/]*)(.*)} ) {
183                     my $elt = $1;
184                     $file = $2;
185                     if ( $file eq "/" ) {
186                         #
187                         # preserve a tailing slash
188                         #
189                         $file = "";
190                         $elt = "$elt/";
191                     }
192                     push(@exc, "$f/*") if ( !$excDone{"$f/*"} );
193                     $excDone{"$f/*"} = 1;
194                     $f = "$f/$elt";
195                     push(@inc, $f) if ( !$incDone{$f} );
196                     $incDone{$f} = 1;
197                 }
198             }
199             foreach my $file ( @inc ) {
200                 push(@fileList, "--include=$file");
201             }
202             foreach my $file ( @exc ) {
203                 push(@fileList, "--exclude=$file");
204             }
205         }
206         if ( defined($conf->{BackupFilesExclude}{$t->{shareName}}) ) {
207             foreach my $file ( @{$conf->{BackupFilesExclude}{$t->{shareName}}} )
208             {
209                 #
210                 # just append additional exclude lists onto the end
211                 #
212                 push(@fileList, "--exclude=$file");
213             }
214         }
215         if ( $t->{type} eq "full" ) {
216             $logMsg = "full backup started for directory $t->{shareName}";
217         } else {
218             $incrDate = $bpc->timeStampISO($t->{lastFull} - 3600, 1);
219             $logMsg = "incr backup started back to $incrDate for directory"
220                     . " $t->{shareName}";
221         }
222         
223         #
224         # A full dump is implemented with --ignore-times: this causes all
225         # files to be checksummed, even if the attributes are the same.
226         # That way all the file contents are checked, but you get all
227         # the efficiencies of rsync: only files deltas need to be
228         # transferred, even though it is a full dump.
229         #
230         $rsyncArgs = $conf->{RsyncArgs};
231         $rsyncArgs = [@$rsyncArgs, "--ignore-times"]
232                                     if ( $t->{type} eq "full" );
233         $rsyncClientCmd = $conf->{RsyncClientCmd};
234         $argList = ['--server', '--sender', @$rsyncArgs,
235                               '.', $t->{shareNameSlash}];
236         $fioArgs = {
237             client  => $t->{client},
238             share   => $t->{shareName},
239             viewNum => $t->{lastFullBkupNum},
240         };
241     }
242
243     #
244     # Merge variables into $rsyncClientCmd
245     #
246     my $args = {
247         host      => $t->{host},
248         hostIP    => $t->{hostIP},
249         client    => $t->{client},
250         shareName => $t->{shareName},
251         shareNameSlash => $t->{shareNameSlash},
252         rsyncPath => $conf->{RsyncClientPath},
253         sshPath   => $conf->{SshPath},
254         argList   => $argList,
255     };
256     $rsyncClientCmd = $bpc->cmdVarSubstitute($rsyncClientCmd, $args);
257
258     #
259     # Create the Rsync object, and tell it to use our own File::RsyncP::FileIO
260     # module, which handles all the special BackupPC file storage
261     # (compression, mangling, hardlinks, special files, attributes etc).
262     #
263     $t->{rsyncClientCmd} = $rsyncClientCmd;
264     $t->{rs} = File::RsyncP->new({
265         logLevel     => $conf->{RsyncLogLevel},
266         rsyncCmd     => sub {
267                             $bpc->cmdExecOrEval($rsyncClientCmd, $args);
268                         },
269         rsyncCmdType => "full",
270         rsyncArgs    => $rsyncArgs,
271         logHandler   => sub {
272                           my($str) = @_;
273                           $str .= "\n";
274                           $t->{XferLOG}->write(\$str);
275                         },
276         fio          => BackupPC::Xfer::RsyncFileIO->new({
277                             xfer       => $t,
278                             bpc        => $t->{bpc},
279                             conf       => $t->{conf},
280                             backups    => $t->{backups},
281                             logLevel   => $conf->{RsyncLogLevel},
282                             timeout    => $conf->{ClientTimeout},
283                             logHandler => sub {
284                                               my($str) = @_;
285                                               $str .= "\n";
286                                               $t->{XferLOG}->write(\$str);
287                                           },
288                             %$fioArgs,
289                       }),
290     });
291
292     delete($t->{_errStr});
293
294     return $logMsg;
295 }
296
297 sub run
298 {
299     my($t) = @_;
300     my $rs = $t->{rs};
301     my $conf = $t->{conf};
302     my($remoteSend, $remoteDir, $remoteDirDaemon);
303
304     alarm($conf->{ClientTimeout});
305     if ( $t->{type} eq "restore" ) {
306         $remoteSend       = 0;
307         ($remoteDir       = "$t->{shareName}/$t->{pathHdrDest}") =~ s{//+}{/}g;
308         ($remoteDirDaemon = "$t->{shareName}/$t->{pathHdrDest}") =~ s{//+}{/}g;
309         $remoteDirDaemon  = $t->{shareNameSlash}
310                                 if ( $t->{pathHdrDest} eq ""
311                                               || $t->{pathHdrDest} eq "/" );
312     } else {
313         $remoteSend      = 1;
314         $remoteDir       = $t->{shareNameSlash};
315         $remoteDirDaemon = ".";
316     }
317     if ( $t->{XferMethod} eq "rsync" ) {
318         #
319         # Run rsync command
320         #
321         my $str = "Running: "
322                 . $t->{bpc}->execCmd2ShellCmd(@{$t->{rsyncClientCmd}})
323                 . "\n";
324         $t->{XferLOG}->write(\$str);
325         $rs->remoteStart($remoteSend, $remoteDir);
326     } else {
327         #
328         # Connect to the rsync server
329         #
330         if ( defined(my $err = $rs->serverConnect($t->{hostIP},
331                                              $conf->{RsyncdClientPort})) ) {
332             $t->{hostError} = $err;
333             my $str = "Error connecting to rsync daemon at $t->{hostIP}"
334                     . ":$conf->{RsyncdClientPort}: $err\n";
335             $t->{XferLOG}->write(\$str);
336             return;
337         }
338         #
339         # Pass module name, and follow it with a slash if it already
340         # contains a slash; otherwise just keep the plain module name.
341         #
342         my $module = $t->{shareName};
343         $module = $t->{shareNameSlash} if ( $module =~ /\// );
344         if ( defined(my $err = $rs->serverService($module,
345                                              $conf->{RsyncdUserName},
346                                              $conf->{RsyncdPasswd},
347                                              $conf->{RsyncdAuthRequired})) ) {
348             my $str = "Error connecting to module $module at $t->{hostIP}"
349                     . ":$conf->{RsyncdClientPort}: $err\n";
350             $t->{XferLOG}->write(\$str);
351             $t->{hostError} = $err;
352             return;
353         }
354         $rs->serverStart($remoteSend, $remoteDirDaemon);
355     }
356     my $error = $rs->go($t->{shareNameSlash});
357     $rs->serverClose();
358
359     #
360     # TODO: generate sensible stats
361     # 
362     # $rs->{stats}{totalWritten}
363     # $rs->{stats}{totalSize}
364     #
365     my $stats = $rs->statsFinal;
366     if ( !defined($error) && defined($stats) ) {
367         $t->{xferOK}  = 1;
368     } else {
369         $t->{xferOK}  = 0;
370     }
371     $t->{byteCnt} = $stats->{childStats}{TotalFileSize}
372                   + $stats->{parentStats}{TotalFileSize};
373     $t->{fileCnt} = $stats->{childStats}{TotalFileCnt}
374                   + $stats->{parentStats}{TotalFileCnt};
375     #
376     # TODO: get error count, and call fio to get stats...
377     #
378     $t->{hostError} = $error if ( defined($error) );
379
380     if ( $t->{type} eq "restore" ) {
381         return (
382             $t->{fileCnt},
383             $t->{byteCnt},
384             0,
385             0
386         );
387     } else {
388         return (
389             0,
390             $stats->{childStats}{ExistFileCnt}
391                 + $stats->{parentStats}{ExistFileCnt},
392             $stats->{childStats}{ExistFileSize}
393                 + $stats->{parentStats}{ExistFileSize},
394             $stats->{childStats}{ExistFileCompSize}
395                 + $stats->{parentStats}{ExistFileCompSize},
396             $stats->{childStats}{TotalFileCnt}
397                 + $stats->{parentStats}{TotalFileCnt},
398             $stats->{childStats}{TotalFileSize}
399                 + $stats->{parentStats}{TotalFileSize},
400         );
401     }
402 }
403
404 sub setSelectMask
405 {
406     my($t, $FDreadRef) = @_;
407 }
408
409 sub errStr
410 {
411     my($t) = @_;
412
413     return $RsyncLibErr if ( !defined($t) || ref($t) ne "HASH" );
414     return $t->{_errStr};
415 }
416
417 sub xferPid
418 {
419     my($t) = @_;
420
421     return -1;
422 }
423
424 sub logMsg
425 {
426     my($t, $msg) = @_;
427
428     push(@{$t->{_logMsg}}, $msg);
429 }
430
431 sub logMsgGet
432 {
433     my($t) = @_;
434
435     return shift(@{$t->{_logMsg}});
436 }
437
438 #
439 # Returns a hash ref giving various status information about
440 # the transfer.
441 #
442 sub getStats
443 {
444     my($t) = @_;
445
446     return { map { $_ => $t->{$_} }
447             qw(byteCnt fileCnt xferErrCnt xferBadShareCnt xferBadFileCnt
448                xferOK hostAbort hostError lastOutputLine)
449     };
450 }
451
452 sub getBadFiles
453 {
454     my($t) = @_;
455
456     return @{$t->{badFiles}};
457 }
458
459 1;