7cee1efc47201b702e748abfb61880eab4b7a21f
[BackupPC.git] / lib / BackupPC / Xfer / Smb.pm
1 #============================================================= -*-perl-*-
2 #
3 # BackupPC::Xfer::Smb package
4 #
5 # DESCRIPTION
6 #
7 #   This library defines a BackupPC::Xfer::Smb class for managing
8 #   the SMB (smbclient) transport of backup data from the client.
9 #
10 # AUTHOR
11 #   Craig Barratt  <cbarratt@users.sourceforge.net>
12 #
13 # COPYRIGHT
14 #   Copyright (C) 2001-2003  Craig Barratt
15 #
16 #   This program is free software; you can redistribute it and/or modify
17 #   it under the terms of the GNU General Public License as published by
18 #   the Free Software Foundation; either version 2 of the License, or
19 #   (at your option) any later version.
20 #
21 #   This program is distributed in the hope that it will be useful,
22 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
23 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
24 #   GNU General Public License for more details.
25 #
26 #   You should have received a copy of the GNU General Public License
27 #   along with this program; if not, write to the Free Software
28 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
29 #
30 #========================================================================
31 #
32 # Version 2.1.0_CVS, released 8 Feb 2004.
33 #
34 # See http://backuppc.sourceforge.net.
35 #
36 #========================================================================
37
38 package BackupPC::Xfer::Smb;
39
40 use strict;
41
42 sub new
43 {
44     my($class, $bpc, $args) = @_;
45
46     $args ||= {};
47     my $t = bless {
48         bpc       => $bpc,
49         conf      => { $bpc->Conf },
50         host      => "",
51         hostIP    => "",
52         shareName => "",
53         pipeRH    => undef,
54         pipeWH    => undef,
55         badFiles  => [],
56         %$args,
57     }, $class;
58
59     return $t;
60 }
61
62 sub args
63 {
64     my($t, $args) = @_;
65
66     foreach my $arg ( keys(%$args) ) {
67         $t->{$arg} = $args->{$arg};
68     }
69 }
70
71 sub useTar
72 {
73     return 1;
74 }
75
76 sub start
77 {
78     my($t) = @_;
79     my $bpc = $t->{bpc};
80     my $conf = $t->{conf};
81     my $I_option = $t->{hostIP} eq $t->{host} ? [] : ['-I', $t->{hostIP}];
82     my(@fileList, $X_option, $smbClientCmd, $logMsg);
83     my($timeStampFile);
84     local(*SMB);
85
86     #
87     # First propagate the PASSWD setting 
88     #
89     $ENV{PASSWD} = $ENV{BPC_SMB_PASSWD} if ( defined($ENV{BPC_SMB_PASSWD}) );
90     $ENV{PASSWD} = $conf->{SmbSharePasswd}
91                                  if ( defined($conf->{SmbSharePasswd}) );
92     if ( !defined($ENV{PASSWD}) ) {
93         $t->{_errStr} = "passwd not set for smbclient";
94         return;
95     }
96     if ( !defined($conf->{SmbClientPath}) || !-x $conf->{SmbClientPath} ) {
97         $t->{_errStr} = '$Conf{SmbClientPath} is not a valid executable';
98         return;
99     }
100     if ( $t->{type} eq "restore" ) {
101         $smbClientCmd = $conf->{SmbClientRestoreCmd};
102         $logMsg = "restore started for share $t->{shareName}";
103     } else {
104         #
105         # Turn $conf->{BackupFilesOnly} and $conf->{BackupFilesExclude}
106         # into a hash of arrays of files
107         #
108         $conf->{SmbShareName} = [ $conf->{SmbShareName} ]
109                         unless ref($conf->{SmbShareName}) eq "ARRAY";
110         foreach my $param qw(BackupFilesOnly BackupFilesExclude) {
111             next if ( !defined($conf->{$param}) );
112             if ( ref($conf->{$param}) eq "ARRAY" ) {
113                 $conf->{$param} = {
114                         $conf->{SmbShareName}[0] => $conf->{$param}
115                 };
116             } elsif ( ref($conf->{$param}) eq "HASH" ) {
117                 # do nothing
118             } else {
119                 $conf->{$param} = {
120                         $conf->{SmbShareName}[0] => [ $conf->{$param} ]
121                 };
122             }
123         }
124         $t->{fileIncludeHash} = {};
125         if ( defined($conf->{BackupFilesOnly}{$t->{shareName}}) ) {
126             foreach my $file ( @{$conf->{BackupFilesOnly}{$t->{shareName}}} ) {
127                 push(@fileList, $file);
128                 $t->{fileIncludeHash}{$file} = 1;
129             }
130         } elsif ( defined($conf->{BackupFilesExclude}{$t->{shareName}}) ) {
131             foreach my $file ( @{$conf->{BackupFilesExclude}{$t->{shareName}}} )
132             {
133                 push(@fileList, $file);
134             }
135             #
136             # Allow simple wildcards in exclude list by specifying "r" option.
137             #
138             $X_option = "rX";
139         }
140         if ( $t->{type} eq "full" ) {
141             $smbClientCmd = $conf->{SmbClientFullCmd};
142             $logMsg = "full backup started for share $t->{shareName}";
143         } else {
144             $timeStampFile = "$t->{outDir}/timeStamp.level0";
145             open(LEV0, ">", $timeStampFile) && close(LEV0);
146             utime($t->{lastFull} - 3600, $t->{lastFull} - 3600, $timeStampFile);
147             $smbClientCmd = $conf->{SmbClientIncrCmd};
148             $logMsg = "incr backup started back to "
149                         . $bpc->timeStamp($t->{lastFull} - 3600, 0)
150                         . "for share $t->{shareName}";
151         }
152     }
153     my $args = {
154         smbClientPath => $conf->{SmbClientPath},
155         host          => $t->{host},
156         hostIP        => $t->{hostIP},
157         client        => $t->{client},
158         shareName     => $t->{shareName},
159         userName      => $conf->{SmbShareUserName},
160         fileList      => \@fileList,
161         I_option      => $I_option,
162         X_option      => $X_option,
163         timeStampFile => $timeStampFile,
164     };
165     $smbClientCmd = $bpc->cmdVarSubstitute($smbClientCmd, $args);
166
167     if ( !defined($t->{xferPid} = open(SMB, "-|")) ) {
168         $t->{_errStr} = "Can't fork to run smbclient";
169         return;
170     }
171     $t->{pipeSMB} = *SMB;
172     if ( !$t->{xferPid} ) {
173         #
174         # This is the smbclient child.
175         #
176         setpgrp 0,0;
177         if ( $t->{type} eq "restore" ) {
178             #
179             # For restores close the write end of the pipe,
180             # clone STDIN from RH, and STDERR to STDOUT
181             #
182             close($t->{pipeWH});
183             close(STDERR);
184             open(STDERR, ">&STDOUT");
185             close(STDIN);
186             open(STDIN, "<&$t->{pipeRH}");
187         } else {
188             #
189             # For backups close the read end of the pipe,
190             # clone STDOUT to WH, STDERR to STDOUT
191             #
192             close($t->{pipeRH});
193             close(STDERR);
194             open(STDERR, ">&STDOUT");
195             open(STDOUT, ">&$t->{pipeWH}");
196         }
197         #
198         # Run smbclient.
199         #
200         alarm(0);
201         $bpc->cmdExecOrEval($smbClientCmd, $args);
202         # should not be reached, but just in case...
203         $t->{_errStr} = "Can't exec $conf->{SmbClientPath}";
204         return;
205     }
206     my $str = "Running: " . $bpc->execCmd2ShellCmd(@$smbClientCmd) . "\n";
207     $t->{XferLOG}->write(\$str);
208     alarm($conf->{ClientTimeout});
209     $t->{_errStr} = undef;
210     return $logMsg;
211 }
212
213 sub readOutput
214 {
215     my($t, $FDreadRef, $rout) = @_;
216     my $conf = $t->{conf};
217
218     if ( vec($rout, fileno($t->{pipeSMB}), 1) ) {
219         my $mesg;
220         if ( sysread($t->{pipeSMB}, $mesg, 8192) <= 0 ) {
221             vec($$FDreadRef, fileno($t->{pipeSMB}), 1) = 0;
222             close($t->{pipeSMB});
223         } else {
224             $t->{smbOut} .= $mesg;
225         }
226     }
227     while ( $t->{smbOut} =~ /(.*?)[\n\r]+(.*)/s ) {
228         $_ = $1;
229         $t->{smbOut} = $2;
230         #
231         # ignore the log file time stamps from smbclient introduced
232         # in version 3.0.0 - don't even write them to the log file.
233         #
234         next if ( m{^\[\d+/\d+/\d+ +\d+:\d+:\d+.*\] +(client/cli|lib/util_unistr).*\(\d+\)} );
235         $t->{XferLOG}->write(\"$_\n");
236         #
237         # refresh our inactivity alarm
238         #
239         alarm($conf->{ClientTimeout});
240         $t->{lastOutputLine} = $_ if ( !/^$/ );
241         #
242         # This section is highly dependent on the version of smbclient.
243         # If you upgrade Samba, make sure that these regexp are still valid.
244         #
245         if ( /^\s*(-?\d+) \(\s*\d+[.,]\d kb\/s\) (.*)$/ ) {
246             my $sambaFileSize = $1;
247             my $pcFileName    = $2;
248             (my $fileName = $pcFileName) =~ s/\\/\//g;
249             $sambaFileSize += 1024 * 1024 * 4096 if ( $sambaFileSize < 0 );
250             $fileName =~ s/^\/*//;
251             $t->{byteCnt} += $sambaFileSize;
252             $t->{fileCnt}++;
253         } elsif ( /restore tar file (.*) of size (\d+) bytes/ ) {
254             $t->{byteCnt} += $2;
255             $t->{fileCnt}++;
256         } elsif ( /^\s*tar: dumped \d+ files/ ) {
257             $t->{xferOK} = 1;
258         } elsif ( /^\s*tar: restored \d+ files/ ) {
259             $t->{xferOK} = 1;
260         } elsif ( /^\s*read_socket_with_timeout: timeout read. /i ) {
261             $t->{hostAbort} = 1;
262         } elsif ( /^code 0 listing /
263                     || /^\s*code 0 opening /
264                     || /^\s*abandoning restore/i
265                     || /^\s*Error: Looping in FIND_NEXT/i
266                     || /^\s*SUCCESS - 0/i
267                     || /^\s*Call timed out: server did not respond/i
268                     || /^\s*tree connect failed: ERRDOS - ERRnoaccess \(Access denied\.\)/
269                     || /^\s*tree connect failed: NT_STATUS_BAD_NETWORK_NAME/
270                  ) {
271             if ( $t->{hostError} eq "" ) {
272                 $t->{XferLOG}->write(\"This backup will fail because: $_\n");
273                 $t->{hostError} = $_;
274             }
275         } elsif ( /^\s*NT_STATUS_ACCESS_DENIED listing (.*)/
276                || /^\s*ERRDOS - ERRnoaccess \(Access denied\.\) listing (.*)/ ) {
277             my $badDir = $1;
278             $badDir =~ s{\\}{/}g;
279             $badDir =~ s{/+}{/}g;
280             $badDir =~ s{/\*$}{};
281             if ( $t->{hostError} eq ""
282                     && ($badDir eq "" || $t->{fileIncludeHash}{$badDir}) ) {
283                 $t->{XferLOG}->write(\"This backup will fail because: $_\n");
284                 $t->{hostError} ||= $_;
285             }
286         } elsif ( /smb: \\>/
287                 || /^\s*added interface/i
288                 || /^\s*tarmode is now/i
289                 || /^\s*Total bytes written/i
290                 || /^\s*Domain=/i
291                 || /^\([\d\.]* kb\/s\) \(average [\d\.]* kb\/s\)$/i
292                 || /^\s*Getting files newer than/i
293                 || /^\s*directory \\/i
294                 || /^\s*restore directory \\/i
295                 || /^\s*Output is \/dev\/null/i
296                 || /^\s*Timezone is/i
297                 || /^\s*creating lame (up|low)case table/i
298             ) {
299             # ignore these messages
300         } else {
301             $t->{xferErrCnt}++;
302             $t->{xferBadShareCnt}++ if ( /^ERRDOS - ERRbadshare/ );
303             $t->{xferBadFileCnt}++  if ( /^ERRDOS - ERRbadfile/ );
304             if ( $t->{xferErrCnt} > 50000 ) {
305                 $t->logMsg(
306                       "Too many smbtar errors ($t->{xferErrCnt})... giving up");
307                 $t->{hostError} = "Too many smbtar errors ($t->{xferErrCnt})";
308                 return;
309             }
310             if ( /^Error reading file (.*)\. Got 0 bytes/ ) {
311                 #
312                 # This happens when a Windoze application has
313                 # locked the file.  This is a particular problem
314                 # with MS-Outlook.  smbclient has already written
315                 # the tar header to stdout, so all it can do is to
316                 # write a dummy file with the correct size, but all
317                 # zeros. BackupPC_tarExtract stores these
318                 # zero-content files efficiently as a sparse file,
319                 # or if compression is on the file will be small
320                 # anyhow.  After the dump is done we simply delete
321                 # the file (it is no use) and try to link it to same
322                 # file in any recent backup.
323                 #
324                 my $badFile = $1;
325                 $badFile =~ s{\\}{/}g;
326                 $badFile =~ s{^/}{};
327                 push(@{$t->{badFiles}}, {
328                         share => $t->{shareName},
329                         file  => $badFile
330                     });
331             }
332         }
333     }
334     return 1;
335 }
336
337 sub setSelectMask
338 {
339     my($t, $FDreadRef) = @_;
340
341     vec($$FDreadRef, fileno($t->{pipeSMB}), 1) = 1;
342 }
343
344 sub errStr
345 {
346     my($t) = @_;
347
348     return $t->{_errStr};
349 }
350
351 sub xferPid
352 {
353     my($t) = @_;
354
355     return ($t->{xferPid});
356 }
357
358 sub logMsg
359 {
360     my($t, $msg) = @_;
361
362     push(@{$t->{_logMsg}}, $msg);
363 }
364
365 sub logMsgGet
366 {
367     my($t) = @_;
368
369     return shift(@{$t->{_logMsg}});
370 }
371
372 #
373 # Returns a hash ref giving various status information about
374 # the transfer.
375 #
376 sub getStats
377 {
378     my($t) = @_;
379
380     return { map { $_ => $t->{$_} }
381             qw(byteCnt fileCnt xferErrCnt xferBadShareCnt xferBadFileCnt
382                xferOK hostAbort hostError lastOutputLine)
383     };
384 }
385
386 sub getBadFiles
387 {
388     my($t) = @_;
389
390     return @{$t->{badFiles}};
391 }
392
393 1;