8a9ba26541bc71c77ff4df8b7b941de10120fcdd
[BackupPC.git] / lib / BackupPC / Xfer / Smb.pm
1 #============================================================= -*-perl-*-
2 #
3 # BackupPC::Xfer::Smb package
4 #
5 # DESCRIPTION
6 #
7 #   This library defines a BackupPC::Xfer::Smb class for managing
8 #   the SMB (smbclient) transport of backup data from the client.
9 #
10 # AUTHOR
11 #   Craig Barratt  <cbarratt@users.sourceforge.net>
12 #
13 # COPYRIGHT
14 #   Copyright (C) 2001-2003  Craig Barratt
15 #
16 #   This program is free software; you can redistribute it and/or modify
17 #   it under the terms of the GNU General Public License as published by
18 #   the Free Software Foundation; either version 2 of the License, or
19 #   (at your option) any later version.
20 #
21 #   This program is distributed in the hope that it will be useful,
22 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
23 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
24 #   GNU General Public License for more details.
25 #
26 #   You should have received a copy of the GNU General Public License
27 #   along with this program; if not, write to the Free Software
28 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
29 #
30 #========================================================================
31 #
32 # Version 2.1.0, released 20 Jun 2004.
33 #
34 # See http://backuppc.sourceforge.net.
35 #
36 #========================================================================
37
38 package BackupPC::Xfer::Smb;
39
40 use strict;
41
42 sub new
43 {
44     my($class, $bpc, $args) = @_;
45
46     $args ||= {};
47     my $t = bless {
48         bpc       => $bpc,
49         conf      => { $bpc->Conf },
50         host      => "",
51         hostIP    => "",
52         shareName => "",
53         pipeRH    => undef,
54         pipeWH    => undef,
55         badFiles  => [],
56         %$args,
57     }, $class;
58
59     return $t;
60 }
61
62 sub args
63 {
64     my($t, $args) = @_;
65
66     foreach my $arg ( keys(%$args) ) {
67         $t->{$arg} = $args->{$arg};
68     }
69 }
70
71 sub useTar
72 {
73     return 1;
74 }
75
76 sub start
77 {
78     my($t) = @_;
79     my $bpc = $t->{bpc};
80     my $conf = $t->{conf};
81     my $I_option = $t->{hostIP} eq $t->{host} ? [] : ['-I', $t->{hostIP}];
82     my(@fileList, $X_option, $smbClientCmd, $logMsg);
83     my($timeStampFile);
84     local(*SMB);
85
86     #
87     # First propagate the PASSWD setting 
88     #
89     $ENV{PASSWD} = $ENV{BPC_SMB_PASSWD} if ( defined($ENV{BPC_SMB_PASSWD}) );
90     $ENV{PASSWD} = $conf->{SmbSharePasswd}
91                                  if ( defined($conf->{SmbSharePasswd}) );
92     if ( !defined($ENV{PASSWD}) ) {
93         $t->{_errStr} = "passwd not set for smbclient";
94         return;
95     }
96     if ( !defined($conf->{SmbClientPath}) || !-x $conf->{SmbClientPath} ) {
97         $t->{_errStr} = '$Conf{SmbClientPath} is not a valid executable';
98         return;
99     }
100     if ( $t->{type} eq "restore" ) {
101         $smbClientCmd = $conf->{SmbClientRestoreCmd};
102         $logMsg = "restore started for share $t->{shareName}";
103     } else {
104         #
105         # Turn $conf->{BackupFilesOnly} and $conf->{BackupFilesExclude}
106         # into a hash of arrays of files, and $conf->{SmbShareName}
107         # to an array
108         #
109         $bpc->backupFileConfFix($conf, "SmbShareName");
110
111         $t->{fileIncludeHash} = {};
112         if ( defined($conf->{BackupFilesOnly}{$t->{shareName}}) ) {
113             foreach my $file ( @{$conf->{BackupFilesOnly}{$t->{shareName}}} ) {
114                 push(@fileList, $file);
115                 $t->{fileIncludeHash}{$file} = 1;
116             }
117         } elsif ( defined($conf->{BackupFilesExclude}{$t->{shareName}}) ) {
118             foreach my $file ( @{$conf->{BackupFilesExclude}{$t->{shareName}}} )
119             {
120                 push(@fileList, $file);
121             }
122             #
123             # Allow simple wildcards in exclude list by specifying "r" option.
124             #
125             $X_option = "rX";
126         }
127         if ( $t->{type} eq "full" ) {
128             $smbClientCmd = $conf->{SmbClientFullCmd};
129             $logMsg = "full backup started for share $t->{shareName}";
130         } else {
131             $timeStampFile = "$t->{outDir}/timeStamp.level0";
132             open(LEV0, ">", $timeStampFile) && close(LEV0);
133             utime($t->{lastFull} - 3600, $t->{lastFull} - 3600, $timeStampFile);
134             $smbClientCmd = $conf->{SmbClientIncrCmd};
135             $logMsg = "incr backup started back to "
136                         . $bpc->timeStamp($t->{lastFull} - 3600, 0)
137                         . "for share $t->{shareName}";
138         }
139     }
140     my $args = {
141         smbClientPath => $conf->{SmbClientPath},
142         host          => $t->{host},
143         hostIP        => $t->{hostIP},
144         client        => $t->{client},
145         shareName     => $t->{shareName},
146         userName      => $conf->{SmbShareUserName},
147         fileList      => \@fileList,
148         I_option      => $I_option,
149         X_option      => $X_option,
150         timeStampFile => $timeStampFile,
151     };
152     $smbClientCmd = $bpc->cmdVarSubstitute($smbClientCmd, $args);
153
154     if ( !defined($t->{xferPid} = open(SMB, "-|")) ) {
155         $t->{_errStr} = "Can't fork to run smbclient";
156         return;
157     }
158     $t->{pipeSMB} = *SMB;
159     if ( !$t->{xferPid} ) {
160         #
161         # This is the smbclient child.
162         #
163         setpgrp 0,0;
164         if ( $t->{type} eq "restore" ) {
165             #
166             # For restores close the write end of the pipe,
167             # clone STDIN from RH, and STDERR to STDOUT
168             #
169             close($t->{pipeWH});
170             close(STDERR);
171             open(STDERR, ">&STDOUT");
172             close(STDIN);
173             open(STDIN, "<&$t->{pipeRH}");
174         } else {
175             #
176             # For backups close the read end of the pipe,
177             # clone STDOUT to WH, STDERR to STDOUT
178             #
179             close($t->{pipeRH});
180             close(STDERR);
181             open(STDERR, ">&STDOUT");
182             open(STDOUT, ">&$t->{pipeWH}");
183         }
184         #
185         # Run smbclient.
186         #
187         alarm(0);
188         $bpc->cmdExecOrEval($smbClientCmd, $args);
189         # should not be reached, but just in case...
190         $t->{_errStr} = "Can't exec $conf->{SmbClientPath}";
191         return;
192     }
193     my $str = "Running: " . $bpc->execCmd2ShellCmd(@$smbClientCmd) . "\n";
194     $t->{XferLOG}->write(\$str);
195     alarm($conf->{ClientTimeout});
196     $t->{_errStr} = undef;
197     return $logMsg;
198 }
199
200 sub readOutput
201 {
202     my($t, $FDreadRef, $rout) = @_;
203     my $conf = $t->{conf};
204
205     if ( vec($rout, fileno($t->{pipeSMB}), 1) ) {
206         my $mesg;
207         if ( sysread($t->{pipeSMB}, $mesg, 8192) <= 0 ) {
208             vec($$FDreadRef, fileno($t->{pipeSMB}), 1) = 0;
209             close($t->{pipeSMB});
210         } else {
211             $t->{smbOut} .= $mesg;
212         }
213     }
214     while ( $t->{smbOut} =~ /(.*?)[\n\r]+(.*)/s ) {
215         $_ = $1;
216         $t->{smbOut} = $2;
217         #
218         # ignore the log file time stamps from smbclient introduced
219         # in version 3.0.0 - don't even write them to the log file.
220         #
221         if ( m{^\[\d+/\d+/\d+ +\d+:\d+:\d+.*\] +(client/cli|lib/util_unistr).*\(\d+\)} ) {
222             $t->{XferLOG}->write(\"$_\n") if ( $t->{logLevel} >= 5 );
223             next;
224         }
225         #
226         # refresh our inactivity alarm
227         #
228         alarm($conf->{ClientTimeout}) if ( !$t->{abort} );
229         $t->{lastOutputLine} = $_ if ( !/^$/ );
230         #
231         # This section is highly dependent on the version of smbclient.
232         # If you upgrade Samba, make sure that these regexp are still valid.
233         #
234         if ( /^\s*(-?\d+) \(\s*\d+[.,]\d kb\/s\) (.*)$/ ) {
235             my $sambaFileSize = $1;
236             my $pcFileName    = $2;
237             (my $fileName = $pcFileName) =~ s/\\/\//g;
238             $sambaFileSize += 1024 * 1024 * 4096 if ( $sambaFileSize < 0 );
239             $fileName =~ s/^\/*//;
240             $t->{byteCnt} += $sambaFileSize;
241             $t->{fileCnt}++;
242             $t->{XferLOG}->write(\"$_\n") if ( $t->{logLevel} >= 2 );
243         } elsif ( /restore tar file (.*) of size (\d+) bytes/ ) {
244             $t->{byteCnt} += $2;
245             $t->{fileCnt}++;
246             $t->{XferLOG}->write(\"$_\n") if ( $t->{logLevel} >= 1 );
247         } elsif ( /^\s*tar: dumped \d+ files/ ) {
248             $t->{xferOK} = 1;
249             $t->{XferLOG}->write(\"$_\n") if ( $t->{logLevel} >= 0 );
250         } elsif ( /^\s*tar: restored \d+ files/ ) {
251             $t->{xferOK} = 1;
252             $t->{XferLOG}->write(\"$_\n") if ( $t->{logLevel} >= 0 );
253         } elsif ( /^\s*read_socket_with_timeout: timeout read. /i ) {
254             $t->{hostAbort} = 1;
255             $t->{XferLOG}->write(\"$_\n") if ( $t->{logLevel} >= 0 );
256         } elsif ( /^code 0 listing /
257                     || /^\s*code 0 opening /
258                     || /^\s*abandoning restore/i
259                     || /^\s*Error: Looping in FIND_NEXT/i
260                     || /^\s*SUCCESS - 0/i
261                     || /^\s*Call timed out: server did not respond/i
262                     || /^\s*tree connect failed: ERRDOS - ERRnoaccess \(Access denied\.\)/
263                     || /^\s*tree connect failed: NT_STATUS_BAD_NETWORK_NAME/
264                  ) {
265             if ( $t->{hostError} eq "" ) {
266                 $t->{XferLOG}->write(\"This backup will fail because: $_\n");
267                 $t->{hostError} = $_;
268             }
269             $t->{XferLOG}->write(\"$_\n") if ( $t->{logLevel} >= 0 );
270         } elsif ( /^\s*NT_STATUS_ACCESS_DENIED listing (.*)/
271                || /^\s*ERRDOS - ERRnoaccess \(Access denied\.\) listing (.*)/ ) {
272             my $badDir = $1;
273             $badDir =~ s{\\}{/}g;
274             $badDir =~ s{/+}{/}g;
275             $badDir =~ s{/\*$}{};
276             if ( $t->{hostError} eq ""
277                     && ($badDir eq "" || $t->{fileIncludeHash}{$badDir}) ) {
278                 $t->{XferLOG}->write(\"This backup will fail because: $_\n");
279                 $t->{hostError} ||= $_;
280             }
281             $t->{XferLOG}->write(\"$_\n") if ( $t->{logLevel} >= 0 );
282         } elsif ( /^\s*directory \\/i ) {
283             $t->{XferLOG}->write(\"$_\n") if ( $t->{logLevel} >= 2 );
284         } elsif ( /smb: \\>/
285                 || /^\s*added interface/i
286                 || /^\s*tarmode is now/i
287                 || /^\s*Total bytes written/i
288                 || /^\s*Domain=/i
289                 || /^\([\d\.]* kb\/s\) \(average [\d\.]* kb\/s\)$/i
290                 || /^\s*Getting files newer than/i
291                 || /^\s*restore directory \\/i
292                 || /^\s*Output is \/dev\/null/i
293                 || /^\s*Timezone is/i
294                 || /^\s*tar_re_search set/i
295                 || /^\s*creating lame (up|low)case table/i
296             ) {
297             # ignore these messages
298             $t->{XferLOG}->write(\"$_\n") if ( $t->{logLevel} >= 1 );
299         } else {
300             $t->{xferErrCnt}++;
301             $t->{xferBadShareCnt}++ if ( /^ERRDOS - ERRbadshare/ );
302             $t->{xferBadFileCnt}++  if ( /^ERRDOS - ERRbadfile/ );
303             if ( $t->{xferErrCnt} > 50000 ) {
304                 $t->logMsg(
305                       "Too many smbtar errors ($t->{xferErrCnt})... giving up");
306                 $t->{hostError} = "Too many smbtar errors ($t->{xferErrCnt})";
307                 return;
308             }
309             if ( /^Error reading file (.*)\. Got 0 bytes/ ) {
310                 #
311                 # This happens when a Windoze application has
312                 # locked the file.  This is a particular problem
313                 # with MS-Outlook.  smbclient has already written
314                 # the tar header to stdout, so all it can do is to
315                 # write a dummy file with the correct size, but all
316                 # zeros. BackupPC_tarExtract stores these
317                 # zero-content files efficiently as a sparse file,
318                 # or if compression is on the file will be small
319                 # anyhow.  After the dump is done we simply delete
320                 # the file (it is no use) and try to link it to same
321                 # file in any recent backup.
322                 #
323                 my $badFile = $1;
324                 $badFile =~ s{\\}{/}g;
325                 $badFile =~ s{^/}{};
326                 push(@{$t->{badFiles}}, {
327                         share => $t->{shareName},
328                         file  => $badFile
329                     });
330             }
331             $t->{XferLOG}->write(\"$_\n") if ( $t->{logLevel} >= 1 );
332         }
333     }
334     return 1;
335 }
336
337 sub abort
338 {
339     my($t, $reason) = @_;
340
341     $t->{abort} = 1;
342     $t->{abortReason} = $reason;
343 }
344
345 sub setSelectMask
346 {
347     my($t, $FDreadRef) = @_;
348
349     vec($$FDreadRef, fileno($t->{pipeSMB}), 1) = 1;
350 }
351
352 sub errStr
353 {
354     my($t) = @_;
355
356     return $t->{_errStr};
357 }
358
359 sub xferPid
360 {
361     my($t) = @_;
362
363     return ($t->{xferPid});
364 }
365
366 sub logMsg
367 {
368     my($t, $msg) = @_;
369
370     push(@{$t->{_logMsg}}, $msg);
371 }
372
373 sub logMsgGet
374 {
375     my($t) = @_;
376
377     return shift(@{$t->{_logMsg}});
378 }
379
380 #
381 # Returns a hash ref giving various status information about
382 # the transfer.
383 #
384 sub getStats
385 {
386     my($t) = @_;
387
388     return { map { $_ => $t->{$_} }
389             qw(byteCnt fileCnt xferErrCnt xferBadShareCnt xferBadFileCnt
390                xferOK hostAbort hostError lastOutputLine)
391     };
392 }
393
394 sub getBadFiles
395 {
396     my($t) = @_;
397
398     return @{$t->{badFiles}};
399 }
400
401 1;