186cff5379f9da49712c39ae2c46c39a27458395
[BackupPC.git] / makeDist
1 #!/bin/perl
2 #
3 # makeDist: Build a BackupPC distribution
4 #
5 # DESCRIPTION
6 #
7 #   This script should be run with no arguments to build a
8 #   distribution.  The $Version and $ReleaseDate should be
9 #   edited below to specify the version name and the release
10 #   date.  The distribution is createede in the sub-directory
11 #   dist.  The dsitribution is in the file name:
12 #
13 #           dist/BackupPC-$Version.tar.gz.
14 #
15 # AUTHOR
16 #   Craig Barratt <cbarratt@users.sourceforge.net>
17 #
18 # COPYRIGHT
19 #   Copyright (C) 2001-2004  Craig Barratt
20 #
21 #   This program is free software; you can redistribute it and/or modify
22 #   it under the terms of the GNU General Public License as published by
23 #   the Free Software Foundation; either version 2 of the License, or
24 #   (at your option) any later version.
25 #
26 #   This program is distributed in the hope that it will be useful,
27 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
28 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
29 #   GNU General Public License for more details.
30 #
31 #   You should have received a copy of the GNU General Public License
32 #   along with this program; if not, write to the Free Software
33 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
34 #
35 #========================================================================
36 #
37
38 use strict;
39 use File::Path;
40 use File::Copy;
41 use Getopt::Std;
42
43 umask(0022);
44
45 my $Version     = "2.1.0beta2";
46 my $ReleaseDate = "23 May 2004";
47 my $DistDir     = "dist/BackupPC-$Version";
48
49 my @PerlSrc = qw(
50     bin/BackupPC
51     bin/BackupPC_archive
52     bin/BackupPC_archiveHost
53     bin/BackupPC_dump
54     bin/BackupPC_link
55     bin/BackupPC_nightly
56     bin/BackupPC_restore
57     bin/BackupPC_sendEmail
58     bin/BackupPC_serverMesg
59     bin/BackupPC_trashClean
60     bin/BackupPC_tarExtract
61     bin/BackupPC_tarCreate
62     bin/BackupPC_compressPool
63     bin/BackupPC_zipCreate
64     bin/BackupPC_zcat
65     lib/BackupPC/Attrib.pm
66     lib/BackupPC/FileZIO.pm
67     lib/BackupPC/Lib.pm
68     lib/BackupPC/PoolWrite.pm
69     lib/BackupPC/View.pm
70     lib/BackupPC/CGI/AdminOptions.pm
71     lib/BackupPC/CGI/Archive.pm
72     lib/BackupPC/CGI/ArchiveInfo.pm
73     lib/BackupPC/CGI/Browse.pm
74     lib/BackupPC/CGI/DirHistory.pm
75     lib/BackupPC/CGI/EmailSummary.pm
76     lib/BackupPC/CGI/GeneralInfo.pm
77     lib/BackupPC/CGI/HostInfo.pm
78     lib/BackupPC/CGI/Lib.pm
79     lib/BackupPC/CGI/LOGlist.pm
80     lib/BackupPC/CGI/Queue.pm
81     lib/BackupPC/CGI/ReloadServer.pm
82     lib/BackupPC/CGI/RestoreFile.pm
83     lib/BackupPC/CGI/RestoreInfo.pm
84     lib/BackupPC/CGI/Restore.pm
85     lib/BackupPC/CGI/StartServer.pm
86     lib/BackupPC/CGI/StartStopBackup.pm
87     lib/BackupPC/CGI/StopServer.pm
88     lib/BackupPC/CGI/Summary.pm
89     lib/BackupPC/CGI/View.pm
90     lib/BackupPC/Lang/de.pm
91     lib/BackupPC/Lang/en.pm
92     lib/BackupPC/Lang/es.pm
93     lib/BackupPC/Lang/fr.pm
94     lib/BackupPC/Lang/it.pm
95     lib/BackupPC/Xfer/Archive.pm
96     lib/BackupPC/Xfer/Smb.pm
97     lib/BackupPC/Xfer/Tar.pm
98     lib/BackupPC/Xfer/Rsync.pm
99     lib/BackupPC/Xfer/RsyncDigest.pm
100     lib/BackupPC/Xfer/RsyncFileIO.pm
101     lib/BackupPC/Zip/FileMember.pm
102     cgi-bin/BackupPC_Admin
103 );
104
105 my %opts;
106 if ( !getopts("l", \%opts) || @ARGV != 0 ) {
107     print("usage: $0 [-l]\n");
108     exit(1);
109 }
110
111 #
112 # Check config parameters
113 #
114 my $ConfVars = {};
115 my $errCnt;
116
117 $errCnt += CheckConfigParams("conf/config.pl", $ConfVars, 0);
118
119 $errCnt += CheckConfigParams("doc-src/BackupPC.pod", $ConfVars, 1);
120
121 #
122 # These config parameters are not used in the code, so ignore them.
123 #
124 $ConfVars->{BackupPCUser} = 2;
125 $ConfVars->{CgiDir}       = 2;
126 $ConfVars->{InstallDir}   = 2;
127 $ConfVars->{CgiImageDir}  = 2;
128
129 #
130 # These config parameters are used in the code to be backward compatible,
131 # but are not present in the current config file, so ignore them.
132 #
133 $ConfVars->{BlackoutHourBegin} = 2;
134 $ConfVars->{BlackoutHourEnd}   = 2;
135 $ConfVars->{BlackoutWeekDays}  = 2;
136 $ConfVars->{RsyncLogLevel}     = 2;
137
138 foreach my $file ( @PerlSrc ) {
139     $errCnt += CheckConfigParams($file, $ConfVars, 1);
140 }
141 if ( !$opts{l} ) {
142     $errCnt += CheckLangUsage();
143     $errCnt += CheckLangTags();
144 }
145 if ( $errCnt ) {
146     print("Exiting because of errors\n");
147     exit(1)
148 }
149
150 $errCnt = 0;
151 foreach my $var ( sort(keys(%$ConfVars) ) ) {
152     next if ( $ConfVars->{$var} >= 2 || $var =~ /^\$/ );
153     printf("Unused config parameter $var\n");
154     $errCnt++;
155 }
156 if ( $errCnt ) {
157     print("Exiting because of errors\n");
158     exit(1)
159 }
160
161 rmtree($DistDir, 0, 0);
162 mkpath($DistDir, 0, 0777);
163
164 foreach my $dir ( qw(bin doc conf images init.d/src cgi-bin
165                      lib/BackupPC/CGI
166                      lib/BackupPC/Lang
167                      lib/BackupPC/Xfer
168                      lib/BackupPC/Zip
169                 ) ) {
170     mkpath("$DistDir/$dir", 0, 0777);
171 }
172
173 my %ConfName;
174 my $ConfPod = config2pod();
175 rmtree("doc", 0, 0);
176 mkpath("doc", 0, 0777);
177 InstallFile("doc-src/BackupPC.pod", "doc/BackupPC.pod");
178
179 use Pod::Html;
180 pod2html("doc/BackupPC.pod",
181         "--backlink=Back to Top",
182         "--header",
183         "--title=BackupPC",
184         "--outfile=doc/BackupPC.html");
185
186 foreach my $file ( (@PerlSrc,
187             <images/*>,
188             qw(
189                 conf/config.pl
190                 conf/hosts
191                 conf/BackupPC_stnd.css
192                 init.d/README
193                 init.d/src/debian-backuppc
194                 init.d/src/gentoo-backuppc
195                 init.d/src/gentoo-backuppc.conf
196                 init.d/src/linux-backuppc
197                 init.d/src/solaris-backuppc
198                 init.d/src/suse-backuppc
199                 doc/BackupPC.pod
200                 doc/BackupPC.html
201                 README
202                 LICENSE
203                 ChangeLog
204                 configure.pl
205         )) ) {
206     InstallFile("$file", "$DistDir/$file");
207 }
208 rmtree("doc", 0, 0);
209 system("cd dist ; tar zcf BackupPC-$Version.tar.gz BackupPC-$Version");
210 print("Distribution written to dist/BackupPC-$Version.tar.gz\n");
211 unlink("pod2htmd.x~~");
212 unlink("pod2htmi.x~~");
213 unlink("pod2htmd.tmp");
214 unlink("pod2htmi.tmp");
215
216 ###########################################################################
217 # Subroutines
218 ###########################################################################
219
220 sub InstallFile
221 {
222     my($file, $dest) = @_;
223
224     unlink($dest) if ( -d $dest );
225     if ( $file =~ /\.gif/ ) {
226         die("can't copy($file, $dest)\n") unless copy($file, $dest);
227     } else {
228         open(FILE, $file)   || die("can't open $file for reading\n");
229         open(OUT, ">$dest") || die("can't open $dest for writing\n");
230         binmode(FILE);
231         binmode(OUT);
232         while ( <FILE> ) {
233             s/^([#*\s]+)Version \d+\.\d+[\.\w]*, released \d+ \w+ \d{4}\.?/$1Version __VERSION__, released __RELEASEDATE__./;
234             s/__VERSION__/$Version/g;
235             s/__RELEASEDATE__/$ReleaseDate/g;
236             if ( $file =~ /BackupPC\.html$/ ) {
237                 #
238                 # fixup for perl 5.6.x
239                 #
240                 if ( !/A NAME="item_(%|_)24Conf/i ) {
241                     s/\$Conf{([^}]*)}/
242                         defined($ConfName{$1})
243                             ? "\L<A HREF=\"#$ConfName{$1}\">\E\$Conf{$1}<\/A>"
244                             : "\$Conf{$1}"/eg;
245                 }
246                 s/<(A NAME="item_(%|_)24Conf(%|_)7B(.*?)(%|_)7D).*?">/\L<A NAME="item_%24Conf%7b$4%7d">/ig;
247                 s/^<DD>/<DD><P>/;
248                 #
249                 # fixup for perl 5.8.x
250                 #
251                 if ( /^<\/dt>/ ) {
252                     $_ .= <FILE>;
253                     s/^(<\/dt>\n<dd>)/$1<p>/s;
254                 }
255                 s/^<li><\/li>/<li>/;
256             }
257             if ( /__CONFIGPOD__/ ) {
258                 print OUT $ConfPod;
259             } elsif ( /^use lib ".*BackupPC\/lib";/
260                     || /^use lib "\/home\/pcbackup\/install\/lib";/ ) {
261                 print OUT "use lib \"__INSTALLDIR__/lib\";\n";
262             } elsif ( $file =~ /Lib.pm/ && /(.*TopDir *=> .*)'.*',/ ) {
263                 print OUT "$1'__TOPDIR__',\n";
264             } elsif ( $file =~ /Lib.pm/ && /(.*Version *=> .*)'[\w\d\.]+',/ ) {
265                 print OUT "$1'$Version',\n";
266             } elsif ( $file =~ /Lib.pm/ && /(.*BinDir *=> .*)'.*',/ ) {
267                 print OUT "$1'__INSTALLDIR__',\n";
268             } elsif ( $file =~ /Lib.pm/ && /(.*LibDir *=> .*)'.*',/ ) {
269                 print OUT "$1'__INSTALLDIR__',\n";
270             } elsif ( $file =~ /BackupPC_Admin/ && /(my *\$installDir *= *)'.*'/ ) {
271                 print OUT "$1'__INSTALLDIR__/lib';\n";
272             } else {
273                 print OUT;
274             }
275         }
276         close(FILE);
277         close(OUT);
278     }
279     if ( -x $file ) {
280         chmod(0555, $dest);
281     } else {
282         chmod(0444, $dest);
283     }
284 }
285
286 sub config2pod
287 {
288     open(C, "conf/config.pl") || die("can't open conf/config.pl");
289     binmode(C);
290     my($str, $out, $getHdr, @conf);
291     my $first = 1;
292     while ( <C> ) {
293         chomp;
294         s/ +$//;
295         if ( /^#########################/ ) {
296             if ( $getHdr ) {
297                 $str =~ s/\n.*//sg;
298                 $out .= "=back\n\n" if ( !$first );
299                 $out .= "=head2 $str\n\n=over 4\n\n";
300                 $str = "";
301                 $first = 0;
302             }
303             $getHdr = !$getHdr;
304             next;
305         }
306         if ( /^#/ ) {
307             s/# ?//;
308             next if ( $str eq "" && /^$/ );
309             $str .= $_ . "\n";
310             $str .= "\n" if ( $str =~ /examples?:\n$/i );
311         } elsif ( /^\$Conf{([^}]*)/ ) {
312             my $var = $1;
313             s/  +/ /g;
314             s/;\s*#.*/;/;
315             if ( !s/\[$/[ ... ];/ && !s/<<'EOF'/.../ ) {
316                 s/([^;])\s*$/$1 .../;
317             }
318             push(@conf, $_);
319             my $text = "\$Conf{$var}";
320             $text =~ s/\s+/_/sg;
321             $text =~ s{(\W)}{sprintf("%%%02X", ord($1) )}gxe;
322             $text = substr($text, 0, 50);
323             $ConfName{$var} = "item_$text";
324         } elsif ( /^$/ ) {
325             if ( $str ne "" && @conf ) {
326                 $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
327                 $out .= $str;
328                 $out .= "\n" if ( $str !~ /\n$/ );
329             }
330             $str = "";
331             @conf = ();
332         }
333     }
334     if ( $str ne "" && @conf ) {
335         $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
336         $out .= $str;
337         $out .= "\n" if ( $str !~ /\n$/ );
338     }
339     $out .= "=back\n\n" if ( !$first );
340     return $out;
341 }
342
343 sub CheckConfigParams
344 {
345     my($file, $vars, $check) = @_;
346     my $errors;
347
348     open(F, $file) || die("can't open $file\n");
349     binmode(F);
350     if ( $check ) {
351         while ( <F> ) {
352             s/\$(self|bpc)->{Conf}{([^}\$]+)}/if ( !defined($vars->{$2}) ) {
353                     print("Unexpected Conf var $2 in $file\n");
354                     $errors++;
355                 } else {
356                     $vars->{$2}++;
357                 }/eg;
358             s/\$[Cc]onf(?:->)?{([^}\$]+)}/if ( !defined($vars->{$1}) ) {
359                     print("Unexpected Conf var $1 in $file\n");
360                     $errors++;
361                 } else {
362                     $vars->{$1}++;
363                 }/eg;
364             s/UserCommandRun\("([^"]*)"\)/if ( !defined($vars->{$1}) ) {
365                     print("Unexpected Conf var $1 in $file\n");
366                     $errors++;
367                 } else {
368                     $vars->{$1}++;
369                 }/eg;
370         }
371     } else {
372         while ( <F> ) {
373             s/^[^#]*\$self->{Conf}{([^}]*)/$vars->{$1} = 1;/eg;
374             s/^[^#]*\$Conf{([^}]*)/$vars->{$1} = 1;/eg;
375         }
376     }
377     close(F);
378     return $errors;
379 }
380
381 #
382 # Make sure that every lang variable in cgi-bin/BackupPC_Admin matches
383 # the strings in each lib/BackupPC/Lang/*.pm file.  This makes sure
384 # we didn't miss any translations in any of the languages.
385 #
386 sub CheckLangUsage
387 {
388     my $errors;
389     my $vars = {};
390
391     foreach my $file ( (
392                 qw(cgi-bin/BackupPC_Admin bin/BackupPC_sendEmail),
393                 <lib/BackupPC/CGI/*pm>
394             ) ) {
395         open(F, $file) || die("can't open $file");
396         binmode(F);
397         while ( <F> ) {
398             s/\$Lang->{([^}]*)}/$vars->{$1} = 1;/eg;
399         }
400         close(F);
401     }
402
403     foreach my $f ( <lib/BackupPC/Lang/*.pm> ) {
404         my $done = {};
405         open(F, $f) || die("can't open $f\n");
406         binmode(F);
407         while ( <F> ) {
408             s/#.*//g;
409             s/\$Lang{([^}]*)}/
410                     my $var = $1;
411                     next if ( $var =~ m{^(Reason_|Status_|backupType_)} );
412                     next if ( $var eq "Documentation" );
413                     if ( !defined($vars->{$var}) ) {
414                         print("Unexpected Lang var $var in $f\n");
415                         $errors++;
416                     } else {
417                         $done->{$var} = 1;
418                     }/eg;
419         }
420         close(F);
421         foreach my $v ( keys(%$vars) ) {
422             #
423             # skip "variables" with "$", since they are like expressions
424             #
425             next if ( $v =~ /\$/ );
426             if ( !defined($done->{$v}) ) {
427                 print("Lang var $v missing from $f\n");
428                 $errors++;
429             }
430         }
431     }
432     return $errors;
433 }
434
435 #
436 # Pedantically check that all the html tags in each language file
437 # match.
438 #
439 sub CheckLangTags
440 {
441     my($en, $enVars) = LangParse("lib/BackupPC/Lang/en.pm");
442     my($errors);
443
444     foreach my $lang ( qw(fr.pm de.pm es.pm it.pm) ) {
445         my($d, $dVars) = LangParse("lib/BackupPC/Lang/$lang");
446         foreach my $v1 ( @$en ) {
447             my $v2 = shift(@$d);
448             if ( $v1->{var} ne $v2->{var} ) {
449                 print("Botch: got $lang var $v2->{var} vs en.pm $v1->{var}\n");
450                 exit;
451             }
452             my $t1 = LangTextStrip($v1->{val});
453             my $t2 = LangTextStrip($v2->{val});
454             if ( $t1 ne $t2 ) {
455                 print("$v1->{var}: got en.pm $t1\nvs $lang $t2\n\n");
456                 $errors++;
457             }
458         }
459     }
460     return $errors;
461 }
462
463 sub LangTextStrip
464 {
465     my($t) = @_;
466
467     $t = "" if ( $t !~ /<.*>/ );
468     $t =~ s/^[^<]*</</s;
469     $t =~ s/([}>])[^<]*</$1</g;
470     $t =~ s/>[^<]*$/>/;
471     $t =~ s/(value=)"[^"]*"/$1""/sg;
472     $t =~ s/({h[12]\()"[^"]*"/$1""/g;
473     $t =~ s/ENG[\s\n]*//sg;
474     $t =~ s/^(<<EOF;\n)[^<]*/$1/g;
475     return $t;
476 }
477
478 sub LangParse
479 {
480     my($file) = @_;
481     open(C, $file) || die("can't open $file");
482     binmode(C);
483     my($out, @lang, $var);
484     my $comment = 1;
485     my $allVars = {};
486     my $endLine = undef;
487     while ( <C> ) {
488         if ( /^#/ && !defined($endLine) ) {
489             if ( $comment ) {
490                 $out .= $_;
491             } else {
492                 if ( $out ne "" ) {
493                     $allVars->{$var} = @lang if ( defined($var) );
494                     push(@lang, {
495                         text => $out,
496                         var => $var,
497                     });
498                 }
499                 $var = undef;
500                 $comment = 1;
501                 $out = $_;
502             }
503         } elsif ( /^\s*\$Lang\{([^}]*)/ ) {
504             $comment = 0;
505             if ( defined($var) ) {
506                 $allVars->{$var} = @lang if ( defined($var) );
507                 push(@lang, {
508                     text => $out,
509                     var => $var,
510                 });
511                 $out = $_;
512             } else {
513                 $out .= $_;
514             }
515             $var = $1;
516             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<(.*);/ );
517             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<'(.*)';/ );
518         } else {
519             $endLine = undef if ( defined($endLine) && /^\Q$endLine[\n\r]*$/ );
520             $out .= $_;
521         }
522     }
523     if ( $out ne "" ) {
524         $allVars->{$var} = @lang if ( defined($var) );
525         push(@lang, {
526             text => $out,
527             var  => $var,
528         });
529     }
530     close(C);
531     foreach my $v ( @lang ) {
532         if ( $v->{text} =~ /\$Lang{$v->{var}}\s*=\s*(.*)/s ) {
533             $v->{val} = $1;
534         }
535     }
536     return (\@lang, $allVars);
537 }