2234b5d24f727eff250d658fdc75283073948265
[BackupPC.git] / makeDist
1 #!/bin/perl
2 #
3 # makeDist: Build a BackupPC distribution
4 #
5 # DESCRIPTION
6 #
7 #   This script should be run with no arguments to build a
8 #   distribution.  The $Version and $ReleaseDate should be
9 #   edited below to specify the version name and the release
10 #   date.  The distribution is createede in the sub-directory
11 #   dist.  The dsitribution is in the file name:
12 #
13 #           dist/BackupPC-$Version.tar.gz.
14 #
15 #   Often the language files are not up to date, and makeDist
16 #   exits after complaining about the lang files being inconsistent.
17 #   Use the -l option to turn off that behavior.
18 #
19 # AUTHOR
20 #   Craig Barratt <cbarratt@users.sourceforge.net>
21 #
22 # COPYRIGHT
23 #   Copyright (C) 2001-2006  Craig Barratt
24 #
25 #   This program is free software; you can redistribute it and/or modify
26 #   it under the terms of the GNU General Public License as published by
27 #   the Free Software Foundation; either version 2 of the License, or
28 #   (at your option) any later version.
29 #
30 #   This program is distributed in the hope that it will be useful,
31 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
32 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
33 #   GNU General Public License for more details.
34 #
35 #   You should have received a copy of the GNU General Public License
36 #   along with this program; if not, write to the Free Software
37 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
38 #
39 #========================================================================
40 #
41
42 use strict;
43 use File::Path;
44 use File::Copy;
45 use Getopt::Std;
46 use lib "./lib";
47 use BackupPC::Lib;
48 use BackupPC::Config::Meta qw(:all);
49
50 my $bpc;
51 die("BackupPC::Lib->new failed\n")
52         if ( !($bpc = BackupPC::Lib->new(".", ".", "./conf", 1)) );
53
54 umask(0022);
55
56 my $Version     = "3.0.0beta2";
57 my $ReleaseDate = "11 Nov 2006";
58 my $DistDir     = "dist/BackupPC-$Version";
59
60 my @PerlSrc = qw(
61     bin/BackupPC
62     bin/BackupPC_archive
63     bin/BackupPC_archiveHost
64     bin/BackupPC_attribPrint
65     bin/BackupPC_dump
66     bin/BackupPC_fixupBackupSummary
67     bin/BackupPC_link
68     bin/BackupPC_nightly
69     bin/BackupPC_restore
70     bin/BackupPC_sendEmail
71     bin/BackupPC_serverMesg
72     bin/BackupPC_trashClean
73     bin/BackupPC_tarExtract
74     bin/BackupPC_tarCreate
75     bin/BackupPC_tarPCCopy
76     bin/BackupPC_compressPool
77     bin/BackupPC_zipCreate
78     bin/BackupPC_zcat
79     lib/BackupPC/Attrib.pm
80     lib/BackupPC/Config.pm
81     lib/BackupPC/FileZIO.pm
82     lib/BackupPC/Lib.pm
83     lib/BackupPC/PoolWrite.pm
84     lib/BackupPC/Storage.pm
85     lib/BackupPC/View.pm
86     lib/BackupPC/CGI/AdminOptions.pm
87     lib/BackupPC/CGI/Archive.pm
88     lib/BackupPC/CGI/ArchiveInfo.pm
89     lib/BackupPC/CGI/Browse.pm
90     lib/BackupPC/CGI/DirHistory.pm
91     lib/BackupPC/CGI/EditConfig.pm
92     lib/BackupPC/CGI/EmailSummary.pm
93     lib/BackupPC/CGI/GeneralInfo.pm
94     lib/BackupPC/CGI/HostInfo.pm
95     lib/BackupPC/CGI/Lib.pm
96     lib/BackupPC/CGI/LOGlist.pm
97     lib/BackupPC/CGI/Queue.pm
98     lib/BackupPC/CGI/ReloadServer.pm
99     lib/BackupPC/CGI/RestoreFile.pm
100     lib/BackupPC/CGI/RestoreInfo.pm
101     lib/BackupPC/CGI/Restore.pm
102     lib/BackupPC/CGI/RSS.pm
103     lib/BackupPC/CGI/StartServer.pm
104     lib/BackupPC/CGI/StartStopBackup.pm
105     lib/BackupPC/CGI/StopServer.pm
106     lib/BackupPC/CGI/Summary.pm
107     lib/BackupPC/CGI/View.pm
108     lib/BackupPC/Config/Meta.pm
109     lib/BackupPC/Lang/de.pm
110     lib/BackupPC/Lang/en.pm
111     lib/BackupPC/Lang/es.pm
112     lib/BackupPC/Lang/fr.pm
113     lib/BackupPC/Lang/it.pm
114     lib/BackupPC/Lang/nl.pm
115     lib/BackupPC/Lang/pt_br.pm
116     lib/BackupPC/Storage/Text.pm
117     lib/BackupPC/Xfer/Archive.pm
118     lib/BackupPC/Xfer/BackupPCd.pm
119     lib/BackupPC/Xfer/Smb.pm
120     lib/BackupPC/Xfer/Tar.pm
121     lib/BackupPC/Xfer/Rsync.pm
122     lib/BackupPC/Xfer/RsyncDigest.pm
123     lib/BackupPC/Xfer/RsyncFileIO.pm
124     lib/BackupPC/Zip/FileMember.pm
125     cgi-bin/BackupPC_Admin
126 );
127
128 my %opts;
129 if ( !getopts("l", \%opts) || @ARGV != 0 ) {
130     print("usage: $0 [-l]\n");
131     exit(1);
132 }
133
134 #
135 # Check config parameters
136 #
137 my $ConfVars = {};
138 my $errCnt;
139
140 $errCnt += CheckConfigParams("conf/config.pl", $ConfVars, 0);
141
142 $errCnt += CheckConfigParams("doc-src/BackupPC.pod", $ConfVars, 1);
143
144 $errCnt += CheckMetaDataVsConfig($ConfVars, "lib/BackupPC/Config/Meta.pm");
145
146 $errCnt += CheckEditorVsConfig($ConfVars, "lib/BackupPC/CGI/EditConfig.pm");
147
148 #
149 # These config parameters are not used in the code, so ignore them.
150 #
151 $ConfVars->{BackupPCUser} = 2;
152 $ConfVars->{CgiDir}       = 2;
153 $ConfVars->{TopDir}       = 2;
154 $ConfVars->{LogDir}       = 2;
155 $ConfVars->{ConfDir}      = 2;
156 $ConfVars->{InstallDir}   = 2;
157 $ConfVars->{CgiImageDir}  = 2;
158
159 #
160 # These config parameters are used in the code to be backward compatible,
161 # but are not present in the current config file, so ignore them.
162 #
163 $ConfVars->{BlackoutHourBegin} = 2;
164 $ConfVars->{BlackoutHourEnd}   = 2;
165 $ConfVars->{BlackoutWeekDays}  = 2;
166 $ConfVars->{RsyncLogLevel}     = 2;
167
168 foreach my $file ( @PerlSrc ) {
169     $errCnt += CheckConfigParams($file, $ConfVars, 1);
170 }
171 if ( !$opts{l} ) {
172     $errCnt += CheckLangUsage();
173     $errCnt += CheckLangTags();
174 }
175 if ( $errCnt ) {
176     print("Exiting because of errors\n");
177     exit(1)
178 }
179
180 $errCnt = 0;
181 foreach my $var ( sort(keys(%$ConfVars) ) ) {
182     next if ( $ConfVars->{$var} >= 2 || $var =~ /^\$/ );
183     printf("Unused config parameter $var\n");
184     $errCnt++;
185 }
186 if ( $errCnt ) {
187     print("Exiting because of errors\n");
188     exit(1)
189 }
190
191 rmtree($DistDir, 0, 0);
192 mkpath($DistDir, 0, 0777);
193
194 foreach my $dir ( qw(bin doc conf images init.d/src cgi-bin
195                      lib/BackupPC/CGI
196                      lib/BackupPC/Config
197                      lib/BackupPC/Lang
198                      lib/BackupPC/Storage
199                      lib/BackupPC/Xfer
200                      lib/BackupPC/Zip
201                 ) ) {
202     mkpath("$DistDir/$dir", 0, 0777);
203 }
204
205 my %ConfName;
206 my $ConfPod = config2pod();
207 rmtree("doc", 0, 0);
208 mkpath("doc", 0, 0777);
209 InstallFile("doc-src/BackupPC.pod", "doc/BackupPC.pod");
210
211 use Pod::Html;
212 pod2html("doc/BackupPC.pod",
213         "--backlink=Back to Top",
214         "--header",
215         "--title=BackupPC",
216         "--outfile=doc/BackupPC.html");
217
218 foreach my $file ( (@PerlSrc,
219             <images/*.gif>,
220             <images/*.png>,
221             qw(
222                 conf/config.pl
223                 conf/hosts
224                 conf/BackupPC_stnd.css
225                 conf/BackupPC_stnd_orig.css
226                 init.d/README
227                 init.d/src/debian-backuppc
228                 init.d/src/gentoo-backuppc
229                 init.d/src/gentoo-backuppc.conf
230                 init.d/src/linux-backuppc
231                 init.d/src/slackware-backuppc
232                 init.d/src/solaris-backuppc
233                 init.d/src/suse-backuppc
234                 doc/BackupPC.pod
235                 doc/BackupPC.html
236                 README
237                 LICENSE
238                 ChangeLog
239                 configure.pl
240         )) ) {
241     InstallFile("$file", "$DistDir/$file");
242 }
243 rmtree("doc", 0, 0);
244 system("cd dist ; tar zcf BackupPC-$Version.tar.gz BackupPC-$Version");
245 print("Distribution written to dist/BackupPC-$Version.tar.gz\n");
246 unlink("pod2htmd.x~~");
247 unlink("pod2htmi.x~~");
248 unlink("pod2htmd.tmp");
249 unlink("pod2htmi.tmp");
250
251 ###########################################################################
252 # Subroutines
253 ###########################################################################
254
255 sub InstallFile
256 {
257     my($file, $dest) = @_;
258
259     unlink($dest) if ( -d $dest );
260     if ( $file =~ /\.gif/ || $file =~ /\.png/ ) {
261         die("can't copy($file, $dest)\n") unless copy($file, $dest);
262     } else {
263         open(FILE, $file)   || die("can't open $file for reading\n");
264         open(OUT, ">$dest") || die("can't open $dest for writing\n");
265         binmode(FILE);
266         binmode(OUT);
267         while ( <FILE> ) {
268             s/^([#*\s]+)Version \d+\.\d+[\.\w]*, released \d+ \w+ \d{4}\.?/$1Version __VERSION__, released __RELEASEDATE__./;
269             s/__VERSION__/$Version/g;
270             s/__RELEASEDATE__/$ReleaseDate/g;
271             if ( $file =~ /BackupPC\.html$/ ) {
272                 #
273                 # fixup for perl 5.6.x
274                 #
275                 if ( !/A NAME="item_(%|_)24Conf/i ) {
276                     s/\$Conf{([^}]*)}/
277                         defined($ConfName{$1})
278                             ? "\L<A HREF=\"#$ConfName{$1}\">\E\$Conf{$1}<\/A>"
279                             : "\$Conf{$1}"/eg;
280                 }
281                 s/<(A NAME="item_(%|_)24Conf(%|_)7B(.*?)(%|_)7D).*?">/\L<A NAME="item_%24Conf%7b$4%7d">/ig;
282                 s/^<DD>/<DD><P>/;
283                 #
284                 # Fixup for perl 5.8.x first one no longer needed after
285                 # fix in CSS)
286                 #
287 #               if ( /^<\/dt>/ ) {
288 #                   $_ .= <FILE>;
289 #                   s/^(<\/dt>\n<dd>)/$1<p>/s;
290 #               }
291                 s/^<li><\/li>/<li>/;
292             }
293             if ( /__CONFIGPOD__/ ) {
294                 print OUT $ConfPod;
295             } elsif ( /^use lib ".*BackupPC\/lib";/
296                     || /^use lib "\/home\/pcbackup\/install\/lib";/ ) {
297                 print OUT "use lib \"__INSTALLDIR__/lib\";\n";
298             } elsif ( $file =~ /Lib.pm/ && /^(\s*\$topDir\s*=\s*)'.*'(\s*if\s.*)/ ) {
299                 print OUT "$1'__TOPDIR__'$2\n";
300             } elsif ( $file =~ /Lib.pm/ && /^(\s*\$installDir\s*=\s*)'.*'(\s*if\s.*)/ ) {
301                 print OUT "$1'__INSTALLDIR__'$2\n";
302             } elsif ( $file =~ /Lib.pm/ && /^(\s*my \$useFHS\s*=\s*)\d;/ ) {
303                 print OUT "${1}0;\n";
304             } elsif ( $file =~ /Lib.pm/ && /(.*Version *=> .*)'[\w\d\.]+',/ ) {
305                 print OUT "$1'$Version',\n";
306             } elsif ( $file =~ /configure.pl/ && /__CONFIGURE_BIN_LIST__/ ) {
307                 print OUT "        ", join("\n        ", grep(/^bin\//, @PerlSrc)), "\n";
308             } elsif ( $file =~ /configure.pl/ && /__CONFIGURE_LIB_LIST__/ ) {
309                 print OUT "        ", join("\n        ", grep(/^lib\//, @PerlSrc)), "\n";
310             } elsif ( $file =~ /BackupPC_Admin/ && /(my *\$installDir *= *)'.*'/ ) {
311                 print OUT "$1'__INSTALLDIR__/lib';\n";
312             } else {
313                 print OUT;
314             }
315         }
316         close(FILE);
317         close(OUT);
318     }
319     if ( -x $file ) {
320         chmod(0555, $dest);
321     } else {
322         chmod(0444, $dest);
323     }
324 }
325
326 sub config2pod
327 {
328     open(C, "conf/config.pl") || die("can't open conf/config.pl");
329     binmode(C);
330     my($str, $out, $getHdr, @conf);
331     my $first = 1;
332     while ( <C> ) {
333         chomp;
334         s/ +$//;
335         if ( /^#########################/ ) {
336             if ( $getHdr ) {
337                 $str =~ s/\n.*//sg;
338                 $out .= "=back\n\n" if ( !$first );
339                 $out .= "=head2 $str\n\n=over 4\n\n";
340                 $str = "";
341                 $first = 0;
342             }
343             $getHdr = !$getHdr;
344             next;
345         }
346         if ( /^#/ ) {
347             s/# ?//;
348             next if ( $str eq "" && /^$/ );
349             $str .= $_ . "\n";
350             $str .= "\n" if ( $str =~ /examples?:\n$/i );
351         } elsif ( /^\$Conf{([^}]*)/ ) {
352             my $var = $1;
353             s/  +/ /g;
354             s/;\s*#.*/;/;
355             if ( !s/\[$/[ ... ];/ && !s/<<'EOF'/.../ ) {
356                 s/([^;])\s*$/$1 .../;
357             }
358             push(@conf, $_);
359             my $text = "\$Conf{$var}";
360             $text =~ s/\s+/_/sg;
361             $text =~ s{(\W)}{sprintf("%%%02X", ord($1) )}gxe;
362             $text = substr($text, 0, 50);
363             $ConfName{$var} = "item_$text";
364         } elsif ( /^$/ ) {
365             if ( $str ne "" && @conf ) {
366                 $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
367                 $out .= $str;
368                 $out .= "\n" if ( $str !~ /\n$/ );
369             }
370             $str = "";
371             @conf = ();
372         }
373     }
374     if ( $str ne "" && @conf ) {
375         $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
376         $out .= $str;
377         $out .= "\n" if ( $str !~ /\n$/ );
378     }
379     $out .= "=back\n\n" if ( !$first );
380     return $out;
381 }
382
383 sub CheckConfigParams
384 {
385     my($file, $vars, $check) = @_;
386     my $errors;
387
388     open(F, $file) || die("can't open $file\n");
389     binmode(F);
390     if ( $check ) {
391         while ( <F> ) {
392             s/\$(self|bpc)->{Conf}{([^}\$]+)}/if ( !defined($vars->{$2}) ) {
393                     print("Unexpected Conf var $2 in $file\n");
394                     $errors++;
395                 } else {
396                     $vars->{$2}++;
397                 }/eg;
398             s/\$[Cc]onf(?:->)?{([^}\$]+)}/if ( !defined($vars->{$1}) ) {
399                     print("Unexpected Conf var $1 in $file\n");
400                     $errors++;
401                 } else {
402                     $vars->{$1}++;
403                 }/eg;
404             s/UserCommandRun\("([^"]*)"/if ( !defined($vars->{$1}) ) {
405                     print("Unexpected Conf var $1 in $file\n");
406                     $errors++;
407                 } else {
408                     $vars->{$1}++;
409                 }/eg;
410         }
411     } else {
412         while ( <F> ) {
413             s/^[^#]*\$self->{Conf}{([^}]*)/$vars->{$1} = 1;/eg;
414             s/^[^#]*\$Conf{([^}]*)/$vars->{$1} = 1;/eg;
415         }
416     }
417     close(F);
418     return $errors;
419 }
420
421 sub CheckMetaDataVsConfig
422 {
423     my($confVars, $file) = @_;
424     my $done = {};
425     my $errors;
426
427     #
428     # Check that the meta file mentions all the config
429     # parameters
430     #
431     open(F, $file) || die("can't open $file");
432
433     while ( <F> ) {
434         next if ( !/^\s{4}(\w+)\s+=>/ );
435         if ( $confVars->{$1} ) {
436             $done->{$1} = 1;
437             next;
438         }
439         next if ( $1 eq "Hosts" );
440         print("$file has $1 but missing from conf/config.pl\n");
441         $errors++;
442     }
443     close(F);
444     foreach my $v ( keys(%$confVars) ) {
445         next if ( $done->{$v} );
446         print("$file missing $v from conf/config.pl\n");
447         $errors++;
448     }
449
450     #
451     # Do extra checks that the CgiUserConfigEdit hash in the Meta
452     # file matches the config file
453     #
454     foreach my $p ( keys(%{$ConfigMeta{CgiUserConfigEdit}{child}}) ) {
455         if ( !defined($bpc->{Conf}{CgiUserConfigEdit}{$p}) ) {
456             print("lib/BackupPC/Config/Meta.pm has $p in CgiUserConfigEdit,"
457                 . " but conf/config.pl CgiUserConfigEdit does not\n");
458             $errors++;
459         }
460     }
461     foreach my $p ( keys(%{$bpc->{Conf}{CgiUserConfigEdit}}) ) {
462         if ( !defined($ConfigMeta{CgiUserConfigEdit}{child}{$p}) ) {
463             print("conf/config.pl CgiUserConfigEdit has $p, but"
464                 . " lib/BackupPC/Config/Meta.pm does not\n");
465             $errors++;
466         }
467     }
468     return $errors;
469 }
470
471 sub CheckEditorVsConfig
472 {
473     my($confVars, $file) = @_;
474     my $done = {};
475     my $errors;
476
477     #
478     # Check that the config editor file mentions all the config
479     # parameters
480     #
481     open(F, $file) || die("can't open $file");
482
483     while ( <F> ) {
484         next if ( !/name\s*=>\s*"(\w+)"/ );
485         if ( $confVars->{$1} ) {
486             $done->{$1} = 1;
487             next;
488         }
489         next if ( $1 eq "Hosts" );
490         print("$file has $1 but missing from conf/config.pl\n");
491         $errors++;
492     }
493     close(F);
494     foreach my $v ( keys(%$confVars) ) {
495         next if ( $done->{$v} );
496         print("$file missing $v from conf/config.pl\n");
497         $errors++;
498     }
499     return $errors;
500 }
501
502 #
503 # Make sure that every lang variable in cgi-bin/BackupPC_Admin matches
504 # the strings in each lib/BackupPC/Lang/*.pm file.  This makes sure
505 # we didn't miss any translations in any of the languages.
506 #
507 sub CheckLangUsage
508 {
509     my $errors;
510     my $vars = {};
511
512     foreach my $file ( (
513                 qw(cgi-bin/BackupPC_Admin bin/BackupPC_sendEmail),
514                 <lib/BackupPC/CGI/*pm>,
515                 <lib/BackupPC/Lang/en.pm>,
516             ) ) {
517         open(F, $file) || die("can't open $file");
518         binmode(F);
519         while ( <F> ) {
520             next if ( /^\s*#/ );
521             s/\$Lang->{([^}]*)}/$vars->{$1} = 1;/eg;
522             s/(text|comment)\s*=>\s*"(CfgEdit_.*)"/$vars->{$2} = 1;/eg;
523         }
524         close(F);
525     }
526
527     foreach my $f ( <lib/BackupPC/Lang/*.pm> ) {
528         my $done = {};
529         open(F, $f) || die("can't open $f\n");
530         binmode(F);
531         while ( <F> ) {
532             s/#.*//g;
533             s/\$Lang{([^}]*)}/
534                     my $var = $1;
535                     next if ( $var =~ m{^(Reason_|Status_|backupType_|Disabled_)} );
536                     next if ( $var eq "Documentation" );
537                     if ( !defined($vars->{$var}) ) {
538                         print("Unexpected Lang var $var in $f\n");
539                         $errors++;
540                     } else {
541                         $done->{$var} = 1;
542                     }/eg;
543         }
544         close(F);
545         foreach my $v ( keys(%$vars) ) {
546             #
547             # skip "variables" with "$", since they are like expressions
548             #
549             next if ( $v =~ /\$/ );
550             if ( !defined($done->{$v}) ) {
551                 print("Lang var $v missing from $f\n");
552                 $errors++;
553             }
554         }
555     }
556     return $errors;
557 }
558
559 #
560 # Pedantically check that all the html tags in each language file
561 # match.
562 #
563 sub CheckLangTags
564 {
565     my($en, $enVars) = LangParse("lib/BackupPC/Lang/en.pm");
566     my($errors);
567
568     foreach my $lang ( qw(fr.pm de.pm es.pm it.pm nl.pm) ) {
569         my($d, $dVars) = LangParse("lib/BackupPC/Lang/$lang");
570         foreach my $v1 ( @$en ) {
571             my $v2 = shift(@$d);
572             if ( $v1->{var} ne $v2->{var} ) {
573                 print("Botch: got $lang var $v2->{var} vs en.pm $v1->{var}\n");
574                 exit;
575             }
576             my $t1 = LangTextStrip($v1->{val});
577             my $t2 = LangTextStrip($v2->{val});
578             if ( $t1 ne $t2 ) {
579                 my $i;
580                 for ( $i = 0 ; $i < length($t1) ; $i++ ) {
581                     last if ( substr($t1, 0, $i) ne substr($t2, 0, $i) );
582                 }
583                 print("$v1->{var}: ($i) got en.pm $t1\nvs $lang $t2\n\n");
584                 $errors++;
585             }
586         }
587     }
588     return $errors;
589 }
590
591 sub LangTextStrip
592 {
593     my($t) = @_;
594
595     $t = "" if ( $t !~ /<.*>/ );
596     $t =~ s/^[^<]*</</s;
597     $t =~ s/([}>])[^<]*</$1</g;
598     $t =~ s/>[^<]*$/>/;
599     $t =~ s/(value=)"[^"]*"/$1""/sg;
600     $t =~ s/({h[12]\()"[^"]*"/$1""/g;
601     $t =~ s/ENG[\s\n]*//sg;
602     $t =~ s/^(<<EOF;\n)[^<]*/$1/g;
603     return $t;
604 }
605
606 sub LangParse
607 {
608     my($file) = @_;
609     open(C, $file) || die("can't open $file");
610     binmode(C);
611     my($out, @lang, $var);
612     my $comment = 1;
613     my $allVars = {};
614     my $endLine = undef;
615     while ( <C> ) {
616         if ( /^#/ && !defined($endLine) ) {
617             if ( $comment ) {
618                 $out .= $_;
619             } else {
620                 if ( $out ne "" ) {
621                     $allVars->{$var} = @lang if ( defined($var) );
622                     push(@lang, {
623                         text => $out,
624                         var => $var,
625                     });
626                 }
627                 $var = undef;
628                 $comment = 1;
629                 $out = $_;
630             }
631         } elsif ( /^\s*\$Lang\{([^}]*)/ ) {
632             $comment = 0;
633             if ( defined($var) ) {
634                 $allVars->{$var} = @lang if ( defined($var) );
635                 push(@lang, {
636                     text => $out,
637                     var => $var,
638                 });
639                 $out = $_;
640             } else {
641                 $out .= $_;
642             }
643             $var = $1;
644             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<(.*);/ );
645             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<'(.*)';/ );
646         } else {
647             $endLine = undef if ( defined($endLine) && /^\Q$endLine[\n\r]*$/ );
648             $out .= $_;
649         }
650     }
651     if ( $out ne "" ) {
652         $allVars->{$var} = @lang if ( defined($var) );
653         push(@lang, {
654             text => $out,
655             var  => $var,
656         });
657     }
658     close(C);
659     foreach my $v ( @lang ) {
660         if ( $v->{text} =~ /\$Lang{$v->{var}}\s*=\s*(.*)/s ) {
661             $v->{val} = $1;
662         }
663     }
664     return (\@lang, $allVars);
665 }