506fb5d32edd73eae0c7c7f9d223df0ee0398e42
[BackupPC.git] / makeDist
1 #!/bin/perl
2 #
3 # makeDist: Build a BackupPC distribution
4 #
5 # DESCRIPTION
6 #
7 #   This script should be run with no arguments to build a
8 #   distribution.  The $Version and $ReleaseDate should be
9 #   edited below to specify the version name and the release
10 #   date.  The distribution is createede in the sub-directory
11 #   dist.  The dsitribution is in the file name:
12 #
13 #           dist/BackupPC-$Version.tar.gz.
14 #
15 #   Often the language files are not up to date, and makeDist
16 #   exits after complaining about the lang files being inconsistent.
17 #   Use the -l option to turn off that behavior.
18 #
19 # AUTHOR
20 #   Craig Barratt <cbarratt@users.sourceforge.net>
21 #
22 # COPYRIGHT
23 #   Copyright (C) 2001-2007  Craig Barratt
24 #
25 #   This program is free software; you can redistribute it and/or modify
26 #   it under the terms of the GNU General Public License as published by
27 #   the Free Software Foundation; either version 2 of the License, or
28 #   (at your option) any later version.
29 #
30 #   This program is distributed in the hope that it will be useful,
31 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
32 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
33 #   GNU General Public License for more details.
34 #
35 #   You should have received a copy of the GNU General Public License
36 #   along with this program; if not, write to the Free Software
37 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
38 #
39 #========================================================================
40 #
41
42 use strict;
43 use File::Path;
44 use File::Copy;
45 use Getopt::Std;
46 use lib "./lib";
47 use BackupPC::Lib;
48 use BackupPC::Config::Meta qw(:all);
49
50 my $bpc;
51 die("BackupPC::Lib->new failed\n")
52         if ( !($bpc = BackupPC::Lib->new(".", ".", "./conf", 1)) );
53
54 umask(0022);
55
56 my $Version     = "3.1.0";
57 my $ReleaseDate = "15 Apr 2007";
58 my $DistDir     = "dist/BackupPC-$Version";
59
60 my @PerlSrc = qw(
61     bin/BackupPC
62     bin/BackupPC_archive
63     bin/BackupPC_archiveHost
64     bin/BackupPC_attribPrint
65     bin/BackupPC_dump
66     bin/BackupPC_fixupBackupSummary
67     bin/BackupPC_link
68     bin/BackupPC_nightly
69     bin/BackupPC_restore
70     bin/BackupPC_sendEmail
71     bin/BackupPC_serverMesg
72     bin/BackupPC_trashClean
73     bin/BackupPC_tarExtract
74     bin/BackupPC_tarCreate
75     bin/BackupPC_tarPCCopy
76     bin/BackupPC_compressPool
77     bin/BackupPC_zipCreate
78     bin/BackupPC_zcat
79     lib/BackupPC/Attrib.pm
80     lib/BackupPC/Config.pm
81     lib/BackupPC/FileZIO.pm
82     lib/BackupPC/Lib.pm
83     lib/BackupPC/PoolWrite.pm
84     lib/BackupPC/Storage.pm
85     lib/BackupPC/View.pm
86     lib/BackupPC/CGI/AdminOptions.pm
87     lib/BackupPC/CGI/Archive.pm
88     lib/BackupPC/CGI/ArchiveInfo.pm
89     lib/BackupPC/CGI/Browse.pm
90     lib/BackupPC/CGI/DirHistory.pm
91     lib/BackupPC/CGI/EditConfig.pm
92     lib/BackupPC/CGI/EmailSummary.pm
93     lib/BackupPC/CGI/GeneralInfo.pm
94     lib/BackupPC/CGI/HostInfo.pm
95     lib/BackupPC/CGI/Lib.pm
96     lib/BackupPC/CGI/LOGlist.pm
97     lib/BackupPC/CGI/Queue.pm
98     lib/BackupPC/CGI/ReloadServer.pm
99     lib/BackupPC/CGI/RestoreFile.pm
100     lib/BackupPC/CGI/RestoreInfo.pm
101     lib/BackupPC/CGI/Restore.pm
102     lib/BackupPC/CGI/RSS.pm
103     lib/BackupPC/CGI/StartServer.pm
104     lib/BackupPC/CGI/StartStopBackup.pm
105     lib/BackupPC/CGI/StopServer.pm
106     lib/BackupPC/CGI/Summary.pm
107     lib/BackupPC/CGI/View.pm
108     lib/BackupPC/Config/Meta.pm
109     lib/BackupPC/Lang/de.pm
110     lib/BackupPC/Lang/en.pm
111     lib/BackupPC/Lang/es.pm
112     lib/BackupPC/Lang/fr.pm
113     lib/BackupPC/Lang/it.pm
114     lib/BackupPC/Lang/nl.pm
115     lib/BackupPC/Lang/pt_br.pm
116     lib/BackupPC/Storage/Text.pm
117     lib/BackupPC/Xfer/Archive.pm
118     lib/BackupPC/Xfer/BackupPCd.pm
119     lib/BackupPC/Xfer/Smb.pm
120     lib/BackupPC/Xfer/Tar.pm
121     lib/BackupPC/Xfer/Rsync.pm
122     lib/BackupPC/Xfer/RsyncDigest.pm
123     lib/BackupPC/Xfer/RsyncFileIO.pm
124     lib/BackupPC/Zip/FileMember.pm
125     cgi-bin/BackupPC_Admin
126 );
127
128 my %opts;
129 if ( !getopts("l", \%opts) || @ARGV != 0 ) {
130     print("usage: $0 [-l]\n");
131     exit(1);
132 }
133
134 #
135 # Check config parameters
136 #
137 my $ConfVars = {};
138 my $errCnt;
139
140 $errCnt += CheckConfigParams("conf/config.pl", $ConfVars, 0);
141
142 $errCnt += CheckConfigParams("doc-src/BackupPC.pod", $ConfVars, 1);
143
144 $errCnt += CheckMetaDataVsConfig($ConfVars, "lib/BackupPC/Config/Meta.pm");
145
146 $errCnt += CheckEditorVsConfig($ConfVars, "lib/BackupPC/CGI/EditConfig.pm");
147
148 #
149 # These config parameters are not used in the code, so ignore them.
150 #
151 $ConfVars->{BackupPCUser} = 2;
152 $ConfVars->{CgiDir}       = 2;
153 $ConfVars->{TopDir}       = 2;
154 $ConfVars->{LogDir}       = 2;
155 $ConfVars->{ConfDir}      = 2;
156 $ConfVars->{InstallDir}   = 2;
157 $ConfVars->{CgiImageDir}  = 2;
158
159 #
160 # These config parameters are used in the code to be backward compatible,
161 # but are not present in the current config file, so ignore them.
162 #
163 $ConfVars->{BlackoutHourBegin} = 2;
164 $ConfVars->{BlackoutHourEnd}   = 2;
165 $ConfVars->{BlackoutWeekDays}  = 2;
166 $ConfVars->{RsyncLogLevel}     = 2;
167
168 foreach my $file ( @PerlSrc ) {
169     $errCnt += CheckConfigParams($file, $ConfVars, 1);
170 }
171 if ( !$opts{l} ) {
172     $errCnt += CheckLangUsage();
173     $errCnt += CheckLangTags();
174 }
175 if ( $errCnt ) {
176     print("Exiting because of errors\n");
177     exit(1)
178 }
179
180 $errCnt = 0;
181 foreach my $var ( sort(keys(%$ConfVars) ) ) {
182     next if ( $ConfVars->{$var} >= 2 || $var =~ /^\$/ );
183     printf("Unused config parameter $var\n");
184     $errCnt++;
185 }
186 if ( $errCnt ) {
187     print("Exiting because of errors\n");
188     exit(1)
189 }
190
191 rmtree($DistDir, 0, 0);
192 mkpath($DistDir, 0, 0777);
193
194 foreach my $dir ( qw(bin doc conf images init.d/src cgi-bin
195                      lib/BackupPC/CGI
196                      lib/BackupPC/Config
197                      lib/BackupPC/Lang
198                      lib/BackupPC/Storage
199                      lib/BackupPC/Xfer
200                      lib/BackupPC/Zip
201                 ) ) {
202     mkpath("$DistDir/$dir", 0, 0777);
203 }
204
205 my %ConfName;
206 my $ConfPod = config2pod();
207 rmtree("doc", 0, 0);
208 mkpath("doc", 0, 0777);
209 InstallFile("doc-src/BackupPC.pod", "doc/BackupPC.pod");
210
211 use Pod::Html;
212 pod2html("doc/BackupPC.pod",
213         "--backlink=Back to Top",
214         "--header",
215         "--title=BackupPC",
216         "--outfile=doc/BackupPC.html");
217
218 foreach my $file ( (@PerlSrc,
219             <images/*.gif>,
220             <images/*.png>,
221             qw(
222                 conf/config.pl
223                 conf/hosts
224                 conf/BackupPC_stnd.css
225                 conf/BackupPC_stnd_orig.css
226                 conf/sorttable.js
227                 init.d/README
228                 init.d/src/debian-backuppc
229                 init.d/src/freebsd-backuppc
230                 init.d/src/gentoo-backuppc
231                 init.d/src/gentoo-backuppc.conf
232                 init.d/src/linux-backuppc
233                 init.d/src/slackware-backuppc
234                 init.d/src/solaris-backuppc
235                 init.d/src/suse-backuppc
236                 doc/BackupPC.pod
237                 doc/BackupPC.html
238                 README
239                 LICENSE
240                 ChangeLog
241                 configure.pl
242         )) ) {
243     InstallFile("$file", "$DistDir/$file");
244 }
245 rmtree("doc", 0, 0);
246 system("cd dist ; tar zcf BackupPC-$Version.tar.gz BackupPC-$Version");
247 print("Distribution written to dist/BackupPC-$Version.tar.gz\n");
248 unlink("pod2htmd.x~~");
249 unlink("pod2htmi.x~~");
250 unlink("pod2htmd.tmp");
251 unlink("pod2htmi.tmp");
252
253 ###########################################################################
254 # Subroutines
255 ###########################################################################
256
257 sub InstallFile
258 {
259     my($file, $dest) = @_;
260
261     unlink($dest) if ( -d $dest );
262     if ( $file =~ /\.gif/ || $file =~ /\.png/ ) {
263         die("can't copy($file, $dest)\n") unless copy($file, $dest);
264     } else {
265         open(FILE, $file)   || die("can't open $file for reading\n");
266         open(OUT, ">$dest") || die("can't open $dest for writing\n");
267         binmode(FILE);
268         binmode(OUT);
269         while ( <FILE> ) {
270             s/^([#*\s]+)Version \d+\.\d+[\.\w]*, released \d+ \w+ \d{4}\.?/$1Version __VERSION__, released __RELEASEDATE__./;
271             s/__VERSION__/$Version/g;
272             s/__RELEASEDATE__/$ReleaseDate/g;
273             if ( $file =~ /BackupPC\.html$/ ) {
274                 #
275                 # fixup for conf links
276                 #
277                 if ( !/A NAME="item_(%|_)conf/i ) {
278                     s/\$Conf{([^}]*)}/
279                         defined($ConfName{$1})
280                             ? "\L<a href=\"#$ConfName{$1}\">\E\$Conf{$1}<\/A>"
281                             : "\$Conf{$1}"/eg;
282                 }
283                 s/^<DD>/<DD><P>/;
284                 s/^<li><\/li>/<li>/;
285             }
286             if ( /__CONFIGPOD__/ ) {
287                 print OUT $ConfPod;
288             } elsif ( /^use lib ".*BackupPC\/lib";/
289                     || /^use lib "\/home\/pcbackup\/install\/lib";/ ) {
290                 print OUT "use lib \"__INSTALLDIR__/lib\";\n";
291             } elsif ( $file =~ /Lib.pm/ && /^(\s*\$topDir\s*=\s*)'.*'(\s*if\s.*)/ ) {
292                 print OUT "$1'__TOPDIR__'$2\n";
293             } elsif ( $file =~ /Lib.pm/ && /^(\s*\$installDir\s*=\s*)'.*'(\s*if\s.*)/ ) {
294                 print OUT "$1'__INSTALLDIR__'$2\n";
295             } elsif ( $file =~ /Lib.pm/ && /^(\s*ConfDir\s*=\>\s*\$confDir eq.*)'.*'(.*)/ ) {
296                 print OUT "$1'__CONFDIR__'$2\n";
297             } elsif ( $file =~ /Lib.pm/ && /^(\s*my \$useFHS\s*=\s*)\d;/ ) {
298                 print OUT "${1}0;\n";
299             } elsif ( $file =~ /Lib.pm/ && /(.*Version *=> .*)'[\w\d\.]+',/ ) {
300                 print OUT "$1'$Version',\n";
301             } elsif ( $file =~ /configure.pl/ && /__CONFIGURE_BIN_LIST__/ ) {
302                 print OUT "        ", join("\n        ", grep(/^bin\//, @PerlSrc)), "\n";
303             } elsif ( $file =~ /configure.pl/ && /__CONFIGURE_LIB_LIST__/ ) {
304                 print OUT "        ", join("\n        ", grep(/^lib\//, @PerlSrc)), "\n";
305             } elsif ( $file =~ /BackupPC_Admin/ && /(my *\$installDir *= *)'.*'/ ) {
306                 print OUT "$1'__INSTALLDIR__/lib';\n";
307             } else {
308                 print OUT;
309             }
310         }
311         close(FILE);
312         close(OUT);
313     }
314     if ( -x $file ) {
315         chmod(0555, $dest);
316     } else {
317         chmod(0444, $dest);
318     }
319 }
320
321 sub config2pod
322 {
323     open(C, "conf/config.pl") || die("can't open conf/config.pl");
324     binmode(C);
325     my($str, $out, $getHdr, @conf);
326     my $first = 1;
327     while ( <C> ) {
328         chomp;
329         s/ +$//;
330         if ( /^#########################/ ) {
331             if ( $getHdr ) {
332                 $str =~ s/\n.*//sg;
333                 $out .= "=back\n\n" if ( !$first );
334                 $out .= "=head2 $str\n\n=over 4\n\n";
335                 $str = "";
336                 $first = 0;
337             }
338             $getHdr = !$getHdr;
339             next;
340         }
341         if ( /^#/ ) {
342             s/# ?//;
343             next if ( $str eq "" && /^$/ );
344             $str .= $_ . "\n";
345             $str .= "\n" if ( $str =~ /examples?:\n$/i );
346         } elsif ( /^\$Conf{([^}]*)/ ) {
347             my $var = $1;
348             s/  +/ /g;
349             s/;\s*#.*/;/;
350             if ( !s/\[$/[ ... ];/ && !s/<<'EOF'/.../ ) {
351                 s/([^;])\s*$/$1 .../;
352             }
353             push(@conf, $_);
354             my $text = "_conf_${var}_";
355             $text =~ s{[\W\s]}{_}g;
356             $ConfName{$var} = "item_$text";
357         } elsif ( /^$/ ) {
358             if ( $str ne "" && @conf ) {
359                 $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
360                 $out .= $str;
361                 $out .= "\n" if ( $str !~ /\n$/ );
362             }
363             $str = "";
364             @conf = ();
365         }
366     }
367     if ( $str ne "" && @conf ) {
368         $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
369         $out .= $str;
370         $out .= "\n" if ( $str !~ /\n$/ );
371     }
372     $out .= "=back\n\n" if ( !$first );
373     return $out;
374 }
375
376 sub CheckConfigParams
377 {
378     my($file, $vars, $check) = @_;
379     my $errors;
380
381     open(F, $file) || die("can't open $file\n");
382     binmode(F);
383     if ( $check ) {
384         while ( <F> ) {
385             s/\$(self|bpc)->{Conf}{([^}\$]+)}/if ( !defined($vars->{$2}) ) {
386                     print("Unexpected Conf var $2 in $file\n");
387                     $errors++;
388                 } else {
389                     $vars->{$2}++;
390                 }/eg;
391             s/\$[Cc]onf(?:->)?{([^}\$]+)}/if ( !defined($vars->{$1}) ) {
392                     print("Unexpected Conf var $1 in $file\n");
393                     $errors++;
394                 } else {
395                     $vars->{$1}++;
396                 }/eg;
397             s/UserCommandRun\("([^"]*)"/if ( !defined($vars->{$1}) ) {
398                     print("Unexpected Conf var $1 in $file\n");
399                     $errors++;
400                 } else {
401                     $vars->{$1}++;
402                 }/eg;
403         }
404     } else {
405         while ( <F> ) {
406             s/^[^#]*\$self->{Conf}{([^}]*)/$vars->{$1} = 1;/eg;
407             s/^[^#]*\$Conf{([^}]*)/$vars->{$1} = 1;/eg;
408         }
409     }
410     close(F);
411     return $errors;
412 }
413
414 sub CheckMetaDataVsConfig
415 {
416     my($confVars, $file) = @_;
417     my $done = {};
418     my $errors;
419
420     #
421     # Check that the meta file mentions all the config
422     # parameters
423     #
424     open(F, $file) || die("can't open $file");
425
426     while ( <F> ) {
427         next if ( !/^\s{4}(\w+)\s+=>/ );
428         if ( $confVars->{$1} ) {
429             $done->{$1} = 1;
430             next;
431         }
432         next if ( $1 eq "Hosts" );
433         print("$file has $1 but missing from conf/config.pl\n");
434         $errors++;
435     }
436     close(F);
437     foreach my $v ( keys(%$confVars) ) {
438         next if ( $done->{$v} );
439         print("$file missing $v from conf/config.pl\n");
440         $errors++;
441     }
442
443     #
444     # Do extra checks that the CgiUserConfigEdit hash in the Meta
445     # file matches the config file
446     #
447     foreach my $p ( keys(%{$ConfigMeta{CgiUserConfigEdit}{child}}) ) {
448         if ( !defined($bpc->{Conf}{CgiUserConfigEdit}{$p}) ) {
449             print("lib/BackupPC/Config/Meta.pm has $p in CgiUserConfigEdit,"
450                 . " but conf/config.pl CgiUserConfigEdit does not\n");
451             $errors++;
452         }
453     }
454     foreach my $p ( keys(%{$bpc->{Conf}{CgiUserConfigEdit}}) ) {
455         if ( !defined($ConfigMeta{CgiUserConfigEdit}{child}{$p}) ) {
456             print("conf/config.pl CgiUserConfigEdit has $p, but"
457                 . " lib/BackupPC/Config/Meta.pm does not\n");
458             $errors++;
459         }
460     }
461     return $errors;
462 }
463
464 sub CheckEditorVsConfig
465 {
466     my($confVars, $file) = @_;
467     my $done = {};
468     my $errors;
469
470     #
471     # Check that the config editor file mentions all the config
472     # parameters
473     #
474     open(F, $file) || die("can't open $file");
475
476     while ( <F> ) {
477         next if ( !/name\s*=>\s*"(\w+)"/ );
478         if ( $confVars->{$1} ) {
479             $done->{$1} = 1;
480             next;
481         }
482         next if ( $1 eq "Hosts" );
483         print("$file has $1 but missing from conf/config.pl\n");
484         $errors++;
485     }
486     close(F);
487     foreach my $v ( keys(%$confVars) ) {
488         next if ( $done->{$v} );
489         print("$file missing $v from conf/config.pl\n");
490         $errors++;
491     }
492     return $errors;
493 }
494
495 #
496 # Make sure that every lang variable in cgi-bin/BackupPC_Admin matches
497 # the strings in each lib/BackupPC/Lang/*.pm file.  This makes sure
498 # we didn't miss any translations in any of the languages.
499 #
500 sub CheckLangUsage
501 {
502     my $errors;
503     my $vars = {};
504
505     foreach my $file ( (
506                 qw(cgi-bin/BackupPC_Admin bin/BackupPC_sendEmail),
507                 <lib/BackupPC/CGI/*pm>,
508                 <lib/BackupPC/Lang/en.pm>,
509             ) ) {
510         open(F, $file) || die("can't open $file");
511         binmode(F);
512         while ( <F> ) {
513             next if ( /^\s*#/ );
514             s/\$Lang->{([^}]*)}/$vars->{$1} = 1;/eg;
515             s/(text|comment)\s*=>\s*"(CfgEdit_.*)"/$vars->{$2} = 1;/eg;
516         }
517         close(F);
518     }
519
520     foreach my $f ( <lib/BackupPC/Lang/*.pm> ) {
521         my $done = {};
522         open(F, $f) || die("can't open $f\n");
523         binmode(F);
524         while ( <F> ) {
525             s/#.*//g;
526             s/\$Lang{([^}]*)}/
527                     my $var = $1;
528                     next if ( $var =~ m{^(Reason_|Status_|backupType_|Disabled_)} );
529                     next if ( $var eq "Documentation" );
530                     if ( !defined($vars->{$var}) ) {
531                         print("Unexpected Lang var $var in $f\n");
532                         $errors++;
533                     } else {
534                         $done->{$var} = 1;
535                     }/eg;
536         }
537         close(F);
538         foreach my $v ( keys(%$vars) ) {
539             #
540             # skip "variables" with "$", since they are like expressions
541             #
542             next if ( $v =~ /\$/ );
543             if ( !defined($done->{$v}) ) {
544                 print("Lang var $v missing from $f\n");
545                 $errors++;
546             }
547         }
548     }
549     return $errors;
550 }
551
552 #
553 # Pedantically check that all the html tags in each language file
554 # match.
555 #
556 sub CheckLangTags
557 {
558     my($en, $enVars) = LangParse("lib/BackupPC/Lang/en.pm");
559     my($errors);
560
561     foreach my $lang ( qw(fr.pm de.pm es.pm it.pm nl.pm pt_br.pm) ) {
562         my($d, $dVars) = LangParse("lib/BackupPC/Lang/$lang");
563         foreach my $v1 ( @$en ) {
564             my $v2 = shift(@$d);
565             if ( $v1->{var} ne $v2->{var} ) {
566                 print("Botch: got $lang var $v2->{var} vs en.pm $v1->{var}\n");
567                 exit;
568             }
569             my $t1 = LangTextStrip($v1->{val});
570             my $t2 = LangTextStrip($v2->{val});
571             if ( $t1 ne $t2 ) {
572                 my $i;
573                 for ( $i = 0 ; $i < length($t1) ; $i++ ) {
574                     last if ( substr($t1, 0, $i) ne substr($t2, 0, $i) );
575                 }
576                 print("$v1->{var}: ($i) got en.pm $t1\nvs $lang $t2\n\n");
577                 $errors++;
578             }
579         }
580     }
581     return $errors;
582 }
583
584 sub LangTextStrip
585 {
586     my($t) = @_;
587
588     $t = "" if ( $t !~ /<.*>/ );
589     $t =~ s/^[^<]*</</s;
590     $t =~ s/([}>])[^<]*</$1</g;
591     $t =~ s/>[^<]*$/>/;
592     $t =~ s/(value=)"[^"]*"/$1""/sg;
593     $t =~ s/({h[12]\()"[^"]*"/$1""/g;
594     $t =~ s/ENG[\s\n]*//sg;
595     $t =~ s/^(<<EOF;\n)[^<]*/$1/g;
596     return $t;
597 }
598
599 sub LangParse
600 {
601     my($file) = @_;
602     open(C, $file) || die("can't open $file");
603     binmode(C);
604     my($out, @lang, $var);
605     my $comment = 1;
606     my $allVars = {};
607     my $endLine = undef;
608     while ( <C> ) {
609         if ( /^#/ && !defined($endLine) ) {
610             if ( $comment ) {
611                 $out .= $_;
612             } else {
613                 if ( $out ne "" ) {
614                     $allVars->{$var} = @lang if ( defined($var) );
615                     push(@lang, {
616                         text => $out,
617                         var => $var,
618                     });
619                 }
620                 $var = undef;
621                 $comment = 1;
622                 $out = $_;
623             }
624         } elsif ( /^\s*\$Lang\{([^}]*)/ ) {
625             $comment = 0;
626             if ( defined($var) ) {
627                 $allVars->{$var} = @lang if ( defined($var) );
628                 push(@lang, {
629                     text => $out,
630                     var => $var,
631                 });
632                 $out = $_;
633             } else {
634                 $out .= $_;
635             }
636             $var = $1;
637             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<(.*);/ );
638             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<'(.*)';/ );
639         } else {
640             $endLine = undef if ( defined($endLine) && /^\Q$endLine[\n\r]*$/ );
641             $out .= $_;
642         }
643     }
644     if ( $out ne "" ) {
645         $allVars->{$var} = @lang if ( defined($var) );
646         push(@lang, {
647             text => $out,
648             var  => $var,
649         });
650     }
651     close(C);
652     foreach my $v ( @lang ) {
653         if ( $v->{text} =~ /\$Lang{$v->{var}}\s*=\s*(.*)/s ) {
654             $v->{val} = $1;
655         }
656     }
657     return (\@lang, $allVars);
658 }