55ae42c8e17f916c35553cfd68d9201f76bedb0d
[BackupPC.git] / makeDist
1 #!/bin/perl
2 #
3 # makeDist: Build a BackupPC distribution
4 #
5 # DESCRIPTION
6 #
7 #   This script should be run with no arguments to build a
8 #   distribution.  The $Version and $ReleaseDate should be
9 #   edited below to specify the version name and the release
10 #   date.  The distribution is createede in the sub-directory
11 #   dist.  The dsitribution is in the file name:
12 #
13 #           dist/BackupPC-$Version.tar.gz.
14 #
15 # AUTHOR
16 #   Craig Barratt <cbarratt@users.sourceforge.net>
17 #
18 # COPYRIGHT
19 #   Copyright (C) 2001-2004  Craig Barratt
20 #
21 #   This program is free software; you can redistribute it and/or modify
22 #   it under the terms of the GNU General Public License as published by
23 #   the Free Software Foundation; either version 2 of the License, or
24 #   (at your option) any later version.
25 #
26 #   This program is distributed in the hope that it will be useful,
27 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
28 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
29 #   GNU General Public License for more details.
30 #
31 #   You should have received a copy of the GNU General Public License
32 #   along with this program; if not, write to the Free Software
33 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
34 #
35 #========================================================================
36 #
37
38 use strict;
39 use File::Path;
40 use File::Copy;
41 use Getopt::Std;
42
43 umask(0022);
44
45 my $Version     = "2.1.0_CVS";
46 my $ReleaseDate = "13 Mar 2004";
47 my $DistDir     = "dist/BackupPC-$Version";
48
49 my @PerlSrc = qw(
50     bin/BackupPC
51     bin/BackupPC_archive
52     bin/BackupPC_archiveHost
53     bin/BackupPC_dump
54     bin/BackupPC_link
55     bin/BackupPC_nightly
56     bin/BackupPC_restore
57     bin/BackupPC_sendEmail
58     bin/BackupPC_serverMesg
59     bin/BackupPC_trashClean
60     bin/BackupPC_tarExtract
61     bin/BackupPC_tarCreate
62     bin/BackupPC_compressPool
63     bin/BackupPC_zipCreate
64     bin/BackupPC_zcat
65     lib/BackupPC/Attrib.pm
66     lib/BackupPC/FileZIO.pm
67     lib/BackupPC/Lib.pm
68     lib/BackupPC/PoolWrite.pm
69     lib/BackupPC/View.pm
70     lib/BackupPC/CGI/AdminOptions.pm
71     lib/BackupPC/CGI/Archive.pm
72     lib/BackupPC/CGI/ArchiveInfo.pm
73     lib/BackupPC/CGI/Browse.pm
74     lib/BackupPC/CGI/DirHistory.pm
75     lib/BackupPC/CGI/EmailSummary.pm
76     lib/BackupPC/CGI/GeneralInfo.pm
77     lib/BackupPC/CGI/HostInfo.pm
78     lib/BackupPC/CGI/Lib.pm
79     lib/BackupPC/CGI/LOGlist.pm
80     lib/BackupPC/CGI/Queue.pm
81     lib/BackupPC/CGI/ReloadServer.pm
82     lib/BackupPC/CGI/RestoreFile.pm
83     lib/BackupPC/CGI/RestoreInfo.pm
84     lib/BackupPC/CGI/Restore.pm
85     lib/BackupPC/CGI/StartServer.pm
86     lib/BackupPC/CGI/StartStopBackup.pm
87     lib/BackupPC/CGI/StopServer.pm
88     lib/BackupPC/CGI/Summary.pm
89     lib/BackupPC/CGI/View.pm
90     lib/BackupPC/Lang/de.pm
91     lib/BackupPC/Lang/en.pm
92     lib/BackupPC/Lang/es.pm
93     lib/BackupPC/Lang/fr.pm
94     lib/BackupPC/Lang/it.pm
95     lib/BackupPC/Xfer/Archive.pm
96     lib/BackupPC/Xfer/Smb.pm
97     lib/BackupPC/Xfer/Tar.pm
98     lib/BackupPC/Xfer/Rsync.pm
99     lib/BackupPC/Xfer/RsyncDigest.pm
100     lib/BackupPC/Xfer/RsyncFileIO.pm
101     lib/BackupPC/Zip/FileMember.pm
102     cgi-bin/BackupPC_Admin
103 );
104
105 my %opts;
106 if ( !getopts("l", \%opts) || @ARGV != 0 ) {
107     print("usage: $0 [-l]\n");
108     exit(1);
109 }
110
111 #
112 # Check config parameters
113 #
114 my $ConfVars = {};
115 my $errCnt;
116
117 $errCnt += CheckConfigParams("conf/config.pl", $ConfVars, 0);
118
119 $errCnt += CheckConfigParams("doc-src/BackupPC.pod", $ConfVars, 1);
120
121 #
122 # These config parameters are not used in the code, so ignore them.
123 #
124 $ConfVars->{BackupPCUser} = 2;
125 $ConfVars->{CgiDir}       = 2;
126 $ConfVars->{InstallDir}   = 2;
127 $ConfVars->{CgiImageDir}  = 2;
128
129 #
130 # These config parameters are used in the code to be backward compatible,
131 # but are not present in the current config file, so ignore them.
132 #
133 $ConfVars->{BlackoutHourBegin} = 2;
134 $ConfVars->{BlackoutHourEnd}   = 2;
135 $ConfVars->{BlackoutWeekDays}  = 2;
136 $ConfVars->{RsyncLogLevel}     = 2;
137
138 foreach my $file ( @PerlSrc ) {
139     $errCnt += CheckConfigParams($file, $ConfVars, 1);
140 }
141 if ( !$opts{l} ) {
142     $errCnt += CheckLangUsage();
143     $errCnt += CheckLangTags();
144 }
145 if ( $errCnt ) {
146     print("Exiting because of errors\n");
147     exit(1)
148 }
149
150 $errCnt = 0;
151 foreach my $var ( sort(keys(%$ConfVars) ) ) {
152     next if ( $ConfVars->{$var} >= 2 || $var =~ /^\$/ );
153     printf("Unused config parameter $var\n");
154     $errCnt++;
155 }
156 if ( $errCnt ) {
157     print("Exiting because of errors\n");
158     exit(1)
159 }
160
161 rmtree($DistDir, 0, 0);
162 mkpath($DistDir, 0, 0777);
163
164 foreach my $dir ( qw(bin doc conf images init.d/src cgi-bin
165                      lib/BackupPC/CGI
166                      lib/BackupPC/Lang
167                      lib/BackupPC/Xfer
168                      lib/BackupPC/Zip
169                 ) ) {
170     mkpath("$DistDir/$dir", 0, 0777);
171 }
172
173 my %ConfName;
174 my $ConfPod = config2pod();
175 rmtree("doc", 0, 0);
176 mkpath("doc", 0, 0777);
177 InstallFile("doc-src/BackupPC.pod", "doc/BackupPC.pod");
178
179 use Pod::Html;
180 pod2html("doc/BackupPC.pod",
181         "--backlink=Back to Top",
182         "--header",
183         "--title=BackupPC",
184         "--outfile=doc/BackupPC.html");
185
186 foreach my $file ( (@PerlSrc,
187             <images/*>,
188             qw(
189                 conf/config.pl
190                 conf/hosts
191                 init.d/README
192                 init.d/src/debian-backuppc
193                 init.d/src/gentoo-backuppc
194                 init.d/src/gentoo-backuppc.conf
195                 init.d/src/linux-backuppc
196                 init.d/src/solaris-backuppc
197                 init.d/src/suse-backuppc
198                 doc/BackupPC.pod
199                 doc/BackupPC.html
200                 README
201                 LICENSE
202                 ChangeLog
203                 configure.pl
204         )) ) {
205     InstallFile("$file", "$DistDir/$file");
206 }
207 rmtree("doc", 0, 0);
208 system("cd dist ; tar zcf BackupPC-$Version.tar.gz BackupPC-$Version");
209 print("Distribution written to dist/BackupPC-$Version.tar.gz\n");
210 unlink("pod2htmd.x~~");
211 unlink("pod2htmi.x~~");
212
213 ###########################################################################
214 # Subroutines
215 ###########################################################################
216
217 sub InstallFile
218 {
219     my($file, $dest) = @_;
220
221     unlink($dest) if ( -d $dest );
222     if ( $file =~ /\.gif/ ) {
223         die("can't copy($file, $dest)\n") unless copy($file, $dest);
224     } else {
225         open(FILE, $file)   || die("can't open $file for reading\n");
226         open(OUT, ">$dest") || die("can't open $dest for writing\n");
227         binmode(FILE);
228         binmode(OUT);
229         while ( <FILE> ) {
230             s/^# *Version \d+\.\d+[\.\w]*, released \d+ \w+ \d{4}\.?/# Version __VERSION__, released __RELEASEDATE__./;
231             s/__VERSION__/$Version/g;
232             s/__RELEASEDATE__/$ReleaseDate/g;
233             if ( $file =~ /BackupPC\.html$/ ) {
234                 #
235                 # fixup for perl 5.6.x
236                 #
237                 if ( !/A NAME="item_%24Conf/i ) {
238                     s/\$Conf{([^}]*)}/
239                         defined($ConfName{$1})
240                             ? "\L<A HREF=\"#$ConfName{$1}\">\E\$Conf{$1}<\/A>"
241                             : "\$Conf{$1}"/eg;
242                 }
243                 s/<(A NAME="item_%24Conf%7B.*?%7D).*?">/\L<$1">/ig;
244                 s/^<DD>/<DD><P>/;
245                 #
246                 # fixup for perl 5.8.x
247                 #
248                 if ( /^<\/dt>/ ) {
249                     $_ .= <FILE>;
250                     s/^(<\/dt>\n<dd>)/$1<p>/s;
251                 }
252                 s/^<li><\/li>/<li>/;
253             }
254             if ( /__CONFIGPOD__/ ) {
255                 print OUT $ConfPod;
256             } elsif ( /^use lib ".*BackupPC\/lib";/
257                     || /^use lib "\/home\/pcbackup\/install\/lib";/ ) {
258                 print OUT "use lib \"__INSTALLDIR__/lib\";\n";
259             } elsif ( $file =~ /Lib.pm/ && /(.*TopDir *=> .*)'.*',/ ) {
260                 print OUT "$1'__TOPDIR__',\n";
261             } elsif ( $file =~ /Lib.pm/ && /(.*Version *=> .*)'[\w\d\.]+',/ ) {
262                 print OUT "$1'$Version',\n";
263             } elsif ( $file =~ /Lib.pm/ && /(.*BinDir *=> .*)'.*',/ ) {
264                 print OUT "$1'__INSTALLDIR__',\n";
265             } elsif ( $file =~ /Lib.pm/ && /(.*LibDir *=> .*)'.*',/ ) {
266                 print OUT "$1'__INSTALLDIR__',\n";
267             } elsif ( $file =~ /BackupPC_Admin/ && /(my *\$installDir *= *)'.*'/ ) {
268                 print OUT "$1'__INSTALLDIR__/lib';\n";
269             } else {
270                 print OUT;
271             }
272         }
273         close(FILE);
274         close(OUT);
275     }
276     if ( -x $file ) {
277         chmod(0555, $dest);
278     } else {
279         chmod(0444, $dest);
280     }
281 }
282
283 sub config2pod
284 {
285     open(C, "conf/config.pl") || die("can't open conf/config.pl");
286     binmode(C);
287     my($str, $out, $getHdr, @conf);
288     my $first = 1;
289     while ( <C> ) {
290         chomp;
291         s/ +$//;
292         if ( /^#########################/ ) {
293             if ( $getHdr ) {
294                 $str =~ s/\n.*//sg;
295                 $out .= "=back\n\n" if ( !$first );
296                 $out .= "=head2 $str\n\n=over 4\n\n";
297                 $str = "";
298                 $first = 0;
299             }
300             $getHdr = !$getHdr;
301             next;
302         }
303         if ( /^#/ ) {
304             s/# ?//;
305             next if ( $str eq "" && /^$/ );
306             $str .= $_ . "\n";
307             $str .= "\n" if ( $str =~ /examples?:\n$/i );
308         } elsif ( /^\$Conf{([^}]*)/ ) {
309             my $var = $1;
310             s/  +/ /g;
311             s/;\s*#.*/;/;
312             if ( !s/\[$/[ ... ];/ && !s/<<'EOF'/.../ ) {
313                 s/([^;])\s*$/$1 .../;
314             }
315             push(@conf, $_);
316             my $text = "\$Conf{$var}";
317             $text =~ s/\s+/_/sg;
318             $text =~ s{(\W)}{sprintf("%%%02X", ord($1) )}gxe;
319             $text = substr($text, 0, 50);
320             $ConfName{$var} = "item_$text";
321         } elsif ( /^$/ ) {
322             if ( $str ne "" && @conf ) {
323                 $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
324                 $out .= $str;
325                 $out .= "\n" if ( $str !~ /\n$/ );
326             }
327             $str = "";
328             @conf = ();
329         }
330     }
331     if ( $str ne "" && @conf ) {
332         $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
333         $out .= $str;
334         $out .= "\n" if ( $str !~ /\n$/ );
335     }
336     $out .= "=back\n\n" if ( !$first );
337     return $out;
338 }
339
340 sub CheckConfigParams
341 {
342     my($file, $vars, $check) = @_;
343     my $errors;
344
345     open(F, $file) || die("can't open $file\n");
346     binmode(F);
347     if ( $check ) {
348         while ( <F> ) {
349             s/\$(self|bpc)->{Conf}{([^}\$]+)}/if ( !defined($vars->{$2}) ) {
350                     print("Unexpected Conf var $2 in $file\n");
351                     $errors++;
352                 } else {
353                     $vars->{$2}++;
354                 }/eg;
355             s/\$[Cc]onf(?:->)?{([^}\$]+)}/if ( !defined($vars->{$1}) ) {
356                     print("Unexpected Conf var $1 in $file\n");
357                     $errors++;
358                 } else {
359                     $vars->{$1}++;
360                 }/eg;
361             s/UserCommandRun\("([^"]*)"\)/if ( !defined($vars->{$1}) ) {
362                     print("Unexpected Conf var $1 in $file\n");
363                     $errors++;
364                 } else {
365                     $vars->{$1}++;
366                 }/eg;
367         }
368     } else {
369         while ( <F> ) {
370             s/^[^#]*\$self->{Conf}{([^}]*)/$vars->{$1} = 1;/eg;
371             s/^[^#]*\$Conf{([^}]*)/$vars->{$1} = 1;/eg;
372         }
373     }
374     close(F);
375     return $errors;
376 }
377
378 #
379 # Make sure that every lang variable in cgi-bin/BackupPC_Admin matches
380 # the strings in each lib/BackupPC/Lang/*.pm file.  This makes sure
381 # we didn't miss any translations in any of the languages.
382 #
383 sub CheckLangUsage
384 {
385     my $errors;
386     my $vars = {};
387
388     foreach my $file ( (
389                 qw(cgi-bin/BackupPC_Admin bin/BackupPC_sendEmail),
390                 <lib/BackupPC/CGI/*pm>
391             ) ) {
392         open(F, $file) || die("can't open $file");
393         binmode(F);
394         while ( <F> ) {
395             s/\$Lang->{([^}]*)}/$vars->{$1} = 1;/eg;
396         }
397         close(F);
398     }
399
400     foreach my $f ( <lib/BackupPC/Lang/*.pm> ) {
401         my $done = {};
402         open(F, $f) || die("can't open $f\n");
403         binmode(F);
404         while ( <F> ) {
405             s/#.*//g;
406             s/\$Lang{([^}]*)}/
407                     my $var = $1;
408                     next if ( $var =~ m{^(Reason_|Status_|backupType_)} );
409                     if ( !defined($vars->{$var}) ) {
410                         print("Unexpected Lang var $var in $f\n");
411                         $errors++;
412                     } else {
413                         $done->{$var} = 1;
414                     }/eg;
415         }
416         close(F);
417         foreach my $v ( keys(%$vars) ) {
418             #
419             # skip "variables" with "$", since they are like expressions
420             #
421             next if ( $v =~ /\$/ );
422             if ( !defined($done->{$v}) ) {
423                 print("Lang var $v missing from $f\n");
424                 $errors++;
425             }
426         }
427     }
428     return $errors;
429 }
430
431 #
432 # Pedantically check that all the html tags in each language file
433 # match.
434 #
435 sub CheckLangTags
436 {
437     my($en, $enVars) = LangParse("lib/BackupPC/Lang/en.pm");
438     my($errors);
439
440     foreach my $lang ( qw(fr.pm de.pm es.pm it.pm) ) {
441         my($d, $dVars) = LangParse("lib/BackupPC/Lang/$lang");
442         foreach my $v1 ( @$en ) {
443             my $v2 = shift(@$d);
444             if ( $v1->{var} ne $v2->{var} ) {
445                 print("Botch: got $lang var $v2->{var} vs en.pm $v1->{var}\n");
446                 exit;
447             }
448             my $t1 = LangTextStrip($v1->{val});
449             my $t2 = LangTextStrip($v2->{val});
450             if ( $t1 ne $t2 ) {
451                 print("$v1->{var}: got en.pm $t1\nvs $lang $t2\n\n");
452                 $errors++;
453             }
454         }
455     }
456     return $errors;
457 }
458
459 sub LangTextStrip
460 {
461     my($t) = @_;
462
463     $t = "" if ( $t !~ /<.*>/ );
464     $t =~ s/^[^<]*</</s;
465     $t =~ s/([}>])[^<]*</$1</g;
466     $t =~ s/>[^<]*$/>/;
467     $t =~ s/(value=)"[^"]*"/$1""/sg;
468     $t =~ s/({h[12]\()"[^"]*"/$1""/g;
469     $t =~ s/ENG[\s\n]*//sg;
470     $t =~ s/^(<<EOF;\n)[^<]*/$1/g;
471     return $t;
472 }
473
474 sub LangParse
475 {
476     my($file) = @_;
477     open(C, $file) || die("can't open $file");
478     binmode(C);
479     my($out, @lang, $var);
480     my $comment = 1;
481     my $allVars = {};
482     my $endLine = undef;
483     while ( <C> ) {
484         if ( /^#/ && !defined($endLine) ) {
485             if ( $comment ) {
486                 $out .= $_;
487             } else {
488                 if ( $out ne "" ) {
489                     $allVars->{$var} = @lang if ( defined($var) );
490                     push(@lang, {
491                         text => $out,
492                         var => $var,
493                     });
494                 }
495                 $var = undef;
496                 $comment = 1;
497                 $out = $_;
498             }
499         } elsif ( /^\s*\$Lang\{([^}]*)/ ) {
500             $comment = 0;
501             if ( defined($var) ) {
502                 $allVars->{$var} = @lang if ( defined($var) );
503                 push(@lang, {
504                     text => $out,
505                     var => $var,
506                 });
507                 $out = $_;
508             } else {
509                 $out .= $_;
510             }
511             $var = $1;
512             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<(.*);/ );
513             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<'(.*)';/ );
514         } else {
515             $endLine = undef if ( defined($endLine) && /^\Q$endLine[\n\r]*$/ );
516             $out .= $_;
517         }
518     }
519     if ( $out ne "" ) {
520         $allVars->{$var} = @lang if ( defined($var) );
521         push(@lang, {
522             text => $out,
523             var  => $var,
524         });
525     }
526     close(C);
527     foreach my $v ( @lang ) {
528         if ( $v->{text} =~ /\$Lang{$v->{var}}\s*=\s*(.*)/s ) {
529             $v->{val} = $1;
530         }
531     }
532     return (\@lang, $allVars);
533 }