6c081e587d2b7297d5a8520cabfb2d10b1508709
[BackupPC.git] / makeDist
1 #!/bin/perl
2 #
3 # makeDist: Build a BackupPC distribution
4 #
5 # DESCRIPTION
6 #
7 #   This script should be run with no arguments to build a
8 #   distribution.  The $Version and $ReleaseDate should be
9 #   edited below to specify the version name and the release
10 #   date.  The distribution is createede in the sub-directory
11 #   dist.  The dsitribution is in the file name:
12 #
13 #           dist/BackupPC-$Version.tar.gz.
14 #
15 #   Often the language files are not up to date, and makeDist
16 #   exits after complaining about the lang files being inconsistent.
17 #   Use the -l option to turn off that behavior.
18 #
19 # AUTHOR
20 #   Craig Barratt <cbarratt@users.sourceforge.net>
21 #
22 # COPYRIGHT
23 #   Copyright (C) 2001-2006  Craig Barratt
24 #
25 #   This program is free software; you can redistribute it and/or modify
26 #   it under the terms of the GNU General Public License as published by
27 #   the Free Software Foundation; either version 2 of the License, or
28 #   (at your option) any later version.
29 #
30 #   This program is distributed in the hope that it will be useful,
31 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
32 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
33 #   GNU General Public License for more details.
34 #
35 #   You should have received a copy of the GNU General Public License
36 #   along with this program; if not, write to the Free Software
37 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
38 #
39 #========================================================================
40 #
41
42 use strict;
43 use File::Path;
44 use File::Copy;
45 use Getopt::Std;
46 use lib "./lib";
47 use BackupPC::Lib;
48 use BackupPC::Config::Meta qw(:all);
49
50 my $bpc;
51 die("BackupPC::Lib->new failed\n")
52         if ( !($bpc = BackupPC::Lib->new(".", ".", "./conf", 1)) );
53
54 umask(0022);
55
56 my $Version     = "3.0.0beta0";
57 my $ReleaseDate = "11 Jul 2006";
58 my $DistDir     = "dist/BackupPC-$Version";
59
60 my @PerlSrc = qw(
61     bin/BackupPC
62     bin/BackupPC_archive
63     bin/BackupPC_archiveHost
64     bin/BackupPC_attribPrint
65     bin/BackupPC_dump
66     bin/BackupPC_fixupBackupSummary
67     bin/BackupPC_link
68     bin/BackupPC_nightly
69     bin/BackupPC_restore
70     bin/BackupPC_sendEmail
71     bin/BackupPC_serverMesg
72     bin/BackupPC_trashClean
73     bin/BackupPC_tarExtract
74     bin/BackupPC_tarCreate
75     bin/BackupPC_tarPCCopy
76     bin/BackupPC_compressPool
77     bin/BackupPC_zipCreate
78     bin/BackupPC_zcat
79     lib/BackupPC/Attrib.pm
80     lib/BackupPC/Config.pm
81     lib/BackupPC/FileZIO.pm
82     lib/BackupPC/Lib.pm
83     lib/BackupPC/PoolWrite.pm
84     lib/BackupPC/Storage.pm
85     lib/BackupPC/View.pm
86     lib/BackupPC/CGI/AdminOptions.pm
87     lib/BackupPC/CGI/Archive.pm
88     lib/BackupPC/CGI/ArchiveInfo.pm
89     lib/BackupPC/CGI/Browse.pm
90     lib/BackupPC/CGI/DirHistory.pm
91     lib/BackupPC/CGI/EditConfig.pm
92     lib/BackupPC/CGI/EmailSummary.pm
93     lib/BackupPC/CGI/GeneralInfo.pm
94     lib/BackupPC/CGI/HostInfo.pm
95     lib/BackupPC/CGI/Lib.pm
96     lib/BackupPC/CGI/LOGlist.pm
97     lib/BackupPC/CGI/Queue.pm
98     lib/BackupPC/CGI/ReloadServer.pm
99     lib/BackupPC/CGI/RestoreFile.pm
100     lib/BackupPC/CGI/RestoreInfo.pm
101     lib/BackupPC/CGI/Restore.pm
102     lib/BackupPC/CGI/RSS.pm
103     lib/BackupPC/CGI/StartServer.pm
104     lib/BackupPC/CGI/StartStopBackup.pm
105     lib/BackupPC/CGI/StopServer.pm
106     lib/BackupPC/CGI/Summary.pm
107     lib/BackupPC/CGI/View.pm
108     lib/BackupPC/Config/Meta.pm
109     lib/BackupPC/Lang/de.pm
110     lib/BackupPC/Lang/en.pm
111     lib/BackupPC/Lang/es.pm
112     lib/BackupPC/Lang/fr.pm
113     lib/BackupPC/Lang/it.pm
114     lib/BackupPC/Lang/nl.pm
115     lib/BackupPC/Lang/pt_br.pm
116     lib/BackupPC/Storage/Text.pm
117     lib/BackupPC/Xfer/Archive.pm
118     lib/BackupPC/Xfer/BackupPCd.pm
119     lib/BackupPC/Xfer/Smb.pm
120     lib/BackupPC/Xfer/Tar.pm
121     lib/BackupPC/Xfer/Rsync.pm
122     lib/BackupPC/Xfer/RsyncDigest.pm
123     lib/BackupPC/Xfer/RsyncFileIO.pm
124     lib/BackupPC/Zip/FileMember.pm
125     cgi-bin/BackupPC_Admin
126 );
127
128 my %opts;
129 if ( !getopts("l", \%opts) || @ARGV != 0 ) {
130     print("usage: $0 [-l]\n");
131     exit(1);
132 }
133
134 #
135 # Check config parameters
136 #
137 my $ConfVars = {};
138 my $errCnt;
139
140 $errCnt += CheckConfigParams("conf/config.pl", $ConfVars, 0);
141
142 $errCnt += CheckConfigParams("doc-src/BackupPC.pod", $ConfVars, 1);
143
144 $errCnt += CheckMetaDataVsConfig($ConfVars, "lib/BackupPC/Config/Meta.pm");
145
146 $errCnt += CheckEditorVsConfig($ConfVars, "lib/BackupPC/CGI/EditConfig.pm");
147
148 #
149 # These config parameters are not used in the code, so ignore them.
150 #
151 $ConfVars->{BackupPCUser} = 2;
152 $ConfVars->{CgiDir}       = 2;
153 $ConfVars->{TopDir}       = 2;
154 $ConfVars->{LogDir}       = 2;
155 $ConfVars->{ConfDir}      = 2;
156 $ConfVars->{InstallDir}   = 2;
157 $ConfVars->{CgiImageDir}  = 2;
158
159 #
160 # These config parameters are used in the code to be backward compatible,
161 # but are not present in the current config file, so ignore them.
162 #
163 $ConfVars->{BlackoutHourBegin} = 2;
164 $ConfVars->{BlackoutHourEnd}   = 2;
165 $ConfVars->{BlackoutWeekDays}  = 2;
166 $ConfVars->{RsyncLogLevel}     = 2;
167
168 foreach my $file ( @PerlSrc ) {
169     $errCnt += CheckConfigParams($file, $ConfVars, 1);
170 }
171 if ( !$opts{l} ) {
172     $errCnt += CheckLangUsage();
173     $errCnt += CheckLangTags();
174 }
175 if ( $errCnt ) {
176     print("Exiting because of errors\n");
177     exit(1)
178 }
179
180 $errCnt = 0;
181 foreach my $var ( sort(keys(%$ConfVars) ) ) {
182     next if ( $ConfVars->{$var} >= 2 || $var =~ /^\$/ );
183     printf("Unused config parameter $var\n");
184     $errCnt++;
185 }
186 if ( $errCnt ) {
187     print("Exiting because of errors\n");
188     exit(1)
189 }
190
191 rmtree($DistDir, 0, 0);
192 mkpath($DistDir, 0, 0777);
193
194 foreach my $dir ( qw(bin doc conf images init.d/src cgi-bin
195                      lib/BackupPC/CGI
196                      lib/BackupPC/Config
197                      lib/BackupPC/Lang
198                      lib/BackupPC/Storage
199                      lib/BackupPC/Xfer
200                      lib/BackupPC/Zip
201                 ) ) {
202     mkpath("$DistDir/$dir", 0, 0777);
203 }
204
205 my %ConfName;
206 my $ConfPod = config2pod();
207 rmtree("doc", 0, 0);
208 mkpath("doc", 0, 0777);
209 InstallFile("doc-src/BackupPC.pod", "doc/BackupPC.pod");
210
211 use Pod::Html;
212 pod2html("doc/BackupPC.pod",
213         "--backlink=Back to Top",
214         "--header",
215         "--title=BackupPC",
216         "--outfile=doc/BackupPC.html");
217
218 foreach my $file ( (@PerlSrc,
219             <images/*>,
220             qw(
221                 conf/config.pl
222                 conf/hosts
223                 conf/BackupPC_stnd.css
224                 init.d/README
225                 init.d/src/debian-backuppc
226                 init.d/src/gentoo-backuppc
227                 init.d/src/gentoo-backuppc.conf
228                 init.d/src/linux-backuppc
229                 init.d/src/slackware-backuppc
230                 init.d/src/solaris-backuppc
231                 init.d/src/suse-backuppc
232                 doc/BackupPC.pod
233                 doc/BackupPC.html
234                 README
235                 LICENSE
236                 ChangeLog
237                 configure.pl
238         )) ) {
239     InstallFile("$file", "$DistDir/$file");
240 }
241 rmtree("doc", 0, 0);
242 system("cd dist ; tar zcf BackupPC-$Version.tar.gz BackupPC-$Version");
243 print("Distribution written to dist/BackupPC-$Version.tar.gz\n");
244 unlink("pod2htmd.x~~");
245 unlink("pod2htmi.x~~");
246 unlink("pod2htmd.tmp");
247 unlink("pod2htmi.tmp");
248
249 ###########################################################################
250 # Subroutines
251 ###########################################################################
252
253 sub InstallFile
254 {
255     my($file, $dest) = @_;
256
257     unlink($dest) if ( -d $dest );
258     if ( $file =~ /\.gif/ ) {
259         die("can't copy($file, $dest)\n") unless copy($file, $dest);
260     } else {
261         open(FILE, $file)   || die("can't open $file for reading\n");
262         open(OUT, ">$dest") || die("can't open $dest for writing\n");
263         binmode(FILE);
264         binmode(OUT);
265         while ( <FILE> ) {
266             s/^([#*\s]+)Version \d+\.\d+[\.\w]*, released \d+ \w+ \d{4}\.?/$1Version __VERSION__, released __RELEASEDATE__./;
267             s/__VERSION__/$Version/g;
268             s/__RELEASEDATE__/$ReleaseDate/g;
269             if ( $file =~ /BackupPC\.html$/ ) {
270                 #
271                 # fixup for perl 5.6.x
272                 #
273                 if ( !/A NAME="item_(%|_)24Conf/i ) {
274                     s/\$Conf{([^}]*)}/
275                         defined($ConfName{$1})
276                             ? "\L<A HREF=\"#$ConfName{$1}\">\E\$Conf{$1}<\/A>"
277                             : "\$Conf{$1}"/eg;
278                 }
279                 s/<(A NAME="item_(%|_)24Conf(%|_)7B(.*?)(%|_)7D).*?">/\L<A NAME="item_%24Conf%7b$4%7d">/ig;
280                 s/^<DD>/<DD><P>/;
281                 #
282                 # Fixup for perl 5.8.x first one no longer needed after
283                 # fix in CSS)
284                 #
285 #               if ( /^<\/dt>/ ) {
286 #                   $_ .= <FILE>;
287 #                   s/^(<\/dt>\n<dd>)/$1<p>/s;
288 #               }
289                 s/^<li><\/li>/<li>/;
290             }
291             if ( /__CONFIGPOD__/ ) {
292                 print OUT $ConfPod;
293             } elsif ( /^use lib ".*BackupPC\/lib";/
294                     || /^use lib "\/home\/pcbackup\/install\/lib";/ ) {
295                 print OUT "use lib \"__INSTALLDIR__/lib\";\n";
296             } elsif ( $file =~ /Lib.pm/ && /^(\s*\$topDir\s*=\s*)'.*'(\s*if\s.*)/ ) {
297                 print OUT "$1'__TOPDIR__'$2\n";
298             } elsif ( $file =~ /Lib.pm/ && /^(\s*\$installDir\s*=\s*)'.*'(\s*if\s.*)/ ) {
299                 print OUT "$1'__INSTALLDIR__'$2\n";
300             } elsif ( $file =~ /Lib.pm/ && /^(\s*my \$useFHS\s*=\s*)\d;/ ) {
301                 print OUT "${1}0;\n";
302             } elsif ( $file =~ /Lib.pm/ && /(.*Version *=> .*)'[\w\d\.]+',/ ) {
303                 print OUT "$1'$Version',\n";
304             } elsif ( $file =~ /configure.pl/ && /__CONFIGURE_BIN_LIST__/ ) {
305                 print OUT "        ", join("\n        ", grep(/^bin\//, @PerlSrc)), "\n";
306             } elsif ( $file =~ /configure.pl/ && /__CONFIGURE_LIB_LIST__/ ) {
307                 print OUT "        ", join("\n        ", grep(/^lib\//, @PerlSrc)), "\n";
308             } elsif ( $file =~ /BackupPC_Admin/ && /(my *\$installDir *= *)'.*'/ ) {
309                 print OUT "$1'__INSTALLDIR__/lib';\n";
310             } else {
311                 print OUT;
312             }
313         }
314         close(FILE);
315         close(OUT);
316     }
317     if ( -x $file ) {
318         chmod(0555, $dest);
319     } else {
320         chmod(0444, $dest);
321     }
322 }
323
324 sub config2pod
325 {
326     open(C, "conf/config.pl") || die("can't open conf/config.pl");
327     binmode(C);
328     my($str, $out, $getHdr, @conf);
329     my $first = 1;
330     while ( <C> ) {
331         chomp;
332         s/ +$//;
333         if ( /^#########################/ ) {
334             if ( $getHdr ) {
335                 $str =~ s/\n.*//sg;
336                 $out .= "=back\n\n" if ( !$first );
337                 $out .= "=head2 $str\n\n=over 4\n\n";
338                 $str = "";
339                 $first = 0;
340             }
341             $getHdr = !$getHdr;
342             next;
343         }
344         if ( /^#/ ) {
345             s/# ?//;
346             next if ( $str eq "" && /^$/ );
347             $str .= $_ . "\n";
348             $str .= "\n" if ( $str =~ /examples?:\n$/i );
349         } elsif ( /^\$Conf{([^}]*)/ ) {
350             my $var = $1;
351             s/  +/ /g;
352             s/;\s*#.*/;/;
353             if ( !s/\[$/[ ... ];/ && !s/<<'EOF'/.../ ) {
354                 s/([^;])\s*$/$1 .../;
355             }
356             push(@conf, $_);
357             my $text = "\$Conf{$var}";
358             $text =~ s/\s+/_/sg;
359             $text =~ s{(\W)}{sprintf("%%%02X", ord($1) )}gxe;
360             $text = substr($text, 0, 50);
361             $ConfName{$var} = "item_$text";
362         } elsif ( /^$/ ) {
363             if ( $str ne "" && @conf ) {
364                 $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
365                 $out .= $str;
366                 $out .= "\n" if ( $str !~ /\n$/ );
367             }
368             $str = "";
369             @conf = ();
370         }
371     }
372     if ( $str ne "" && @conf ) {
373         $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
374         $out .= $str;
375         $out .= "\n" if ( $str !~ /\n$/ );
376     }
377     $out .= "=back\n\n" if ( !$first );
378     return $out;
379 }
380
381 sub CheckConfigParams
382 {
383     my($file, $vars, $check) = @_;
384     my $errors;
385
386     open(F, $file) || die("can't open $file\n");
387     binmode(F);
388     if ( $check ) {
389         while ( <F> ) {
390             s/\$(self|bpc)->{Conf}{([^}\$]+)}/if ( !defined($vars->{$2}) ) {
391                     print("Unexpected Conf var $2 in $file\n");
392                     $errors++;
393                 } else {
394                     $vars->{$2}++;
395                 }/eg;
396             s/\$[Cc]onf(?:->)?{([^}\$]+)}/if ( !defined($vars->{$1}) ) {
397                     print("Unexpected Conf var $1 in $file\n");
398                     $errors++;
399                 } else {
400                     $vars->{$1}++;
401                 }/eg;
402             s/UserCommandRun\("([^"]*)"/if ( !defined($vars->{$1}) ) {
403                     print("Unexpected Conf var $1 in $file\n");
404                     $errors++;
405                 } else {
406                     $vars->{$1}++;
407                 }/eg;
408         }
409     } else {
410         while ( <F> ) {
411             s/^[^#]*\$self->{Conf}{([^}]*)/$vars->{$1} = 1;/eg;
412             s/^[^#]*\$Conf{([^}]*)/$vars->{$1} = 1;/eg;
413         }
414     }
415     close(F);
416     return $errors;
417 }
418
419 sub CheckMetaDataVsConfig
420 {
421     my($confVars, $file) = @_;
422     my $done = {};
423     my $errors;
424
425     #
426     # Check that the meta file mentions all the config
427     # parameters
428     #
429     open(F, $file) || die("can't open $file");
430
431     while ( <F> ) {
432         next if ( !/^\s{4}(\w+)\s+=>/ );
433         if ( $confVars->{$1} ) {
434             $done->{$1} = 1;
435             next;
436         }
437         next if ( $1 eq "Hosts" );
438         print("$file has $1 but missing from conf/config.pl\n");
439         $errors++;
440     }
441     close(F);
442     foreach my $v ( keys(%$confVars) ) {
443         next if ( $done->{$v} );
444         print("$file missing $v from conf/config.pl\n");
445         $errors++;
446     }
447
448     #
449     # Do extra checks that the CgiUserConfigEdit hash in the Meta
450     # file matches the config file
451     #
452     foreach my $p ( keys(%{$ConfigMeta{CgiUserConfigEdit}{child}}) ) {
453         if ( !defined($bpc->{Conf}{CgiUserConfigEdit}{$p}) ) {
454             print("lib/BackupPC/Config/Meta.pm has $p in CgiUserConfigEdit,"
455                 . " but conf/config.pl CgiUserConfigEdit does not\n");
456             $errors++;
457         }
458     }
459     foreach my $p ( keys(%{$bpc->{Conf}{CgiUserConfigEdit}}) ) {
460         if ( !defined($ConfigMeta{CgiUserConfigEdit}{child}{$p}) ) {
461             print("conf/config.pl CgiUserConfigEdit has $p, but"
462                 . " lib/BackupPC/Config/Meta.pm does not\n");
463             $errors++;
464         }
465     }
466     return $errors;
467 }
468
469 sub CheckEditorVsConfig
470 {
471     my($confVars, $file) = @_;
472     my $done = {};
473     my $errors;
474
475     #
476     # Check that the config editor file mentions all the config
477     # parameters
478     #
479     open(F, $file) || die("can't open $file");
480
481     while ( <F> ) {
482         next if ( !/name\s*=>\s*"(\w+)"/ );
483         if ( $confVars->{$1} ) {
484             $done->{$1} = 1;
485             next;
486         }
487         next if ( $1 eq "Hosts" );
488         print("$file has $1 but missing from conf/config.pl\n");
489         $errors++;
490     }
491     close(F);
492     foreach my $v ( keys(%$confVars) ) {
493         next if ( $done->{$v} );
494         print("$file missing $v from conf/config.pl\n");
495         $errors++;
496     }
497     return $errors;
498 }
499
500 #
501 # Make sure that every lang variable in cgi-bin/BackupPC_Admin matches
502 # the strings in each lib/BackupPC/Lang/*.pm file.  This makes sure
503 # we didn't miss any translations in any of the languages.
504 #
505 sub CheckLangUsage
506 {
507     my $errors;
508     my $vars = {};
509
510     foreach my $file ( (
511                 qw(cgi-bin/BackupPC_Admin bin/BackupPC_sendEmail),
512                 <lib/BackupPC/CGI/*pm>,
513                 <lib/BackupPC/Lang/en.pm>,
514             ) ) {
515         open(F, $file) || die("can't open $file");
516         binmode(F);
517         while ( <F> ) {
518             next if ( /^\s*#/ );
519             s/\$Lang->{([^}]*)}/$vars->{$1} = 1;/eg;
520             s/(text|comment)\s*=>\s*"(CfgEdit_.*)"/$vars->{$2} = 1;/eg;
521         }
522         close(F);
523     }
524
525     foreach my $f ( <lib/BackupPC/Lang/*.pm> ) {
526         my $done = {};
527         open(F, $f) || die("can't open $f\n");
528         binmode(F);
529         while ( <F> ) {
530             s/#.*//g;
531             s/\$Lang{([^}]*)}/
532                     my $var = $1;
533                     next if ( $var =~ m{^(Reason_|Status_|backupType_)} );
534                     next if ( $var eq "Documentation" );
535                     if ( !defined($vars->{$var}) ) {
536                         print("Unexpected Lang var $var in $f\n");
537                         $errors++;
538                     } else {
539                         $done->{$var} = 1;
540                     }/eg;
541         }
542         close(F);
543         foreach my $v ( keys(%$vars) ) {
544             #
545             # skip "variables" with "$", since they are like expressions
546             #
547             next if ( $v =~ /\$/ );
548             if ( !defined($done->{$v}) ) {
549                 print("Lang var $v missing from $f\n");
550                 $errors++;
551             }
552         }
553     }
554     return $errors;
555 }
556
557 #
558 # Pedantically check that all the html tags in each language file
559 # match.
560 #
561 sub CheckLangTags
562 {
563     my($en, $enVars) = LangParse("lib/BackupPC/Lang/en.pm");
564     my($errors);
565
566     foreach my $lang ( qw(fr.pm de.pm es.pm it.pm nl.pm) ) {
567         my($d, $dVars) = LangParse("lib/BackupPC/Lang/$lang");
568         foreach my $v1 ( @$en ) {
569             my $v2 = shift(@$d);
570             if ( $v1->{var} ne $v2->{var} ) {
571                 print("Botch: got $lang var $v2->{var} vs en.pm $v1->{var}\n");
572                 exit;
573             }
574             my $t1 = LangTextStrip($v1->{val});
575             my $t2 = LangTextStrip($v2->{val});
576             if ( $t1 ne $t2 ) {
577                 my $i;
578                 for ( $i = 0 ; $i < length($t1) ; $i++ ) {
579                     last if ( substr($t1, 0, $i) ne substr($t2, 0, $i) );
580                 }
581                 print("$v1->{var}: ($i) got en.pm $t1\nvs $lang $t2\n\n");
582                 $errors++;
583             }
584         }
585     }
586     return $errors;
587 }
588
589 sub LangTextStrip
590 {
591     my($t) = @_;
592
593     $t = "" if ( $t !~ /<.*>/ );
594     $t =~ s/^[^<]*</</s;
595     $t =~ s/([}>])[^<]*</$1</g;
596     $t =~ s/>[^<]*$/>/;
597     $t =~ s/(value=)"[^"]*"/$1""/sg;
598     $t =~ s/({h[12]\()"[^"]*"/$1""/g;
599     $t =~ s/ENG[\s\n]*//sg;
600     $t =~ s/^(<<EOF;\n)[^<]*/$1/g;
601     return $t;
602 }
603
604 sub LangParse
605 {
606     my($file) = @_;
607     open(C, $file) || die("can't open $file");
608     binmode(C);
609     my($out, @lang, $var);
610     my $comment = 1;
611     my $allVars = {};
612     my $endLine = undef;
613     while ( <C> ) {
614         if ( /^#/ && !defined($endLine) ) {
615             if ( $comment ) {
616                 $out .= $_;
617             } else {
618                 if ( $out ne "" ) {
619                     $allVars->{$var} = @lang if ( defined($var) );
620                     push(@lang, {
621                         text => $out,
622                         var => $var,
623                     });
624                 }
625                 $var = undef;
626                 $comment = 1;
627                 $out = $_;
628             }
629         } elsif ( /^\s*\$Lang\{([^}]*)/ ) {
630             $comment = 0;
631             if ( defined($var) ) {
632                 $allVars->{$var} = @lang if ( defined($var) );
633                 push(@lang, {
634                     text => $out,
635                     var => $var,
636                 });
637                 $out = $_;
638             } else {
639                 $out .= $_;
640             }
641             $var = $1;
642             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<(.*);/ );
643             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<'(.*)';/ );
644         } else {
645             $endLine = undef if ( defined($endLine) && /^\Q$endLine[\n\r]*$/ );
646             $out .= $_;
647         }
648     }
649     if ( $out ne "" ) {
650         $allVars->{$var} = @lang if ( defined($var) );
651         push(@lang, {
652             text => $out,
653             var  => $var,
654         });
655     }
656     close(C);
657     foreach my $v ( @lang ) {
658         if ( $v->{text} =~ /\$Lang{$v->{var}}\s*=\s*(.*)/s ) {
659             $v->{val} = $1;
660         }
661     }
662     return (\@lang, $allVars);
663 }