couchdb-trigger.pl

   1 #!/usr/bin/perl
   2
   3 # back-end trigger server for CouchDB monitoring changes feed:
   4 #
   5 # http://wiki.apache.org/couchdb/HTTP_database_API#Changes
   6 #
   7 # implements state machine using document which you cen put with:
   8 #
   9 # curl -X PUT http://localhost:5984/monitor/df -d '{"trigger":{"command":"df -P","format":"table"}}'
  10 #
  11 # DEFAULT TRIGGER EXECUTE SHELL COMMANDS. IT IS NOT SECURE IF YOUR COUCHDB ISN'T SECURE!
  12
  13 use warnings;
  14 use strict;
  15
  16 use lib 'common/mojo/lib';
  17
  18 use Mojo::Client;
  19 use Mojo::JSON;
  20 use Time::HiRes qw(time);
  21 use Data::Dump qw(dump);
  22
  23 my ( $url, $trigger_path ) = @ARGV;
  24
  25 $url          ||= 'http://localhost:5984/monitor';
  26 $trigger_path ||= 'trigger/shell.pm' ;
  27
  28 our $database = $1 if $url =~ m{/(\w+)/?$};
  29
  30 sub commit { warn "# commit ignored\n"; }
  31 require $trigger_path if -e $trigger_path;
  32
  33 my $seq = 0;
  34
  35 my $client = Mojo::Client->new;
  36 our $json   = Mojo::JSON->new;
  37 sub info { warn $_[0], " ",$json->encode($_[1]),$/ }
  38 sub debug { info "# $_[0]", $_[1] }
  39 my $error;
  40
  41 $client->keep_alive_timeout(90); # couchdb timeout is 60s
  42
  43 while( ! $error ) {
  44
  45         my $changes_feed = "$url/_changes?feed=continuous;include_docs=true;since=$seq";
  46         info 'GET' => $changes_feed;
  47         my $tx = $client->build_tx( GET => $changes_feed );
  48         $tx->res->body(sub{
  49                 my ( $content, $body ) = @_;
  50
  51                 return if length($body) == 0; # empty chunk, heartbeat?
  52
  53                 debug 'BODY' => $body;
  54
  55                 foreach ( split(/\r?\n/, $body) ) { # we can get multiple documents in one chunk
  56
  57                         my $change = $json->decode($_);
  58
  59                         if ( exists $change->{error} ) {
  60                                 $error = $change;
  61                         } elsif ( exists $change->{last_seq} ) {
  62                                 $seq = $change->{last_seq};
  63                         } elsif ( $change->{seq} <= $seq ) {
  64                                 info "ERROR: stale" => $change;
  65                         } elsif ( exists $change->{changes} ) {
  66
  67                                 my $id  = $change->{id} || warn "no id?";
  68                                 my $rev = $change->{changes}->[0]->{rev} || warn "no rev?";
  69                                    $seq = $change->{seq} || warn "no seq?";
  70
  71                                 debug 'change' => $change;
  72
  73                                 if ( filter($change) ) {
  74                                         if ( exists $change->{doc}->{trigger}->{active} ) {
  75                                                 debug 'trigger.active',  $change->{doc}->{trigger}->{active};
  76                                         } else {
  77                                                 $change->{doc}->{trigger}->{active} = [ time() ];
  78
  79                                                 debug 'TRIGGER start PUT ', $change->{doc};
  80                                                 $client->put( "$url/$id" => $json->encode( $change->{doc} ) => sub {
  81                                                         my ($client,$tx) = @_;
  82                                                         if ($tx->error) {
  83                                                                 if ( $tx->res->code == 409 ) {
  84                                                                         info "TRIGGER ABORTED started on another worker? ", $tx->error;
  85                                                                 } else {
  86                                                                         info "ERROR $url/$id ", $tx->error;
  87                                                                 }
  88                                                         } else {
  89                                                                 my $res = $tx->res->json;
  90                                                                 $change->{doc}->{_rev} = $res->{rev};
  91
  92                                                                 debug "TRIGGER execute ", $change->{doc};
  93                                                                 trigger( $change );
  94
  95                                                                 push @{ $change->{doc}->{trigger}->{active} }, time(), 0; # last timestamp
  96
  97                                                                 $client->put( "$url/$id" => $json->encode( $change->{doc} ) => sub {
  98                                                                         my ($client,$tx) = @_;
  99                                                                         if ($tx->error) {
 100                                                                                 info "ERROR $url/$id", $tx->error;
 101                                                                         } else {
 102                                                                                 my $res = $tx->res->json;
 103                                                                                 $change->{doc}->{_rev} = $res->{rev};
 104                                                                                 info "TRIGGER finish ", $change->{doc};
 105                                                                         }
 106                                                                 })->process;
 107                                                         }
 108                                                 })->process;
 109                                         }
 110                                 }
 111                         } else {
 112                                 warn "UNKNOWN", $json->encode($change);
 113                         }
 114
 115                 }
 116
 117                 commit;
 118
 119         });
 120         $client->start($tx);
 121
 122 }
 123
 124 die "ERROR ", $json->encode($error) if $error;