kernel/linux/arch/alpha/kernel/vmlinux.lds.S

   1 #include <linux/config.h>
   2 #include <asm-generic/vmlinux.lds.h>
   3
   4 OUTPUT_FORMAT("elf64-alpha")
   5 OUTPUT_ARCH(alpha)
   6 ENTRY(__start)
   7 PHDRS { kernel PT_LOAD ; }
   8 jiffies = jiffies_64;
   9 SECTIONS
  10 {
  11 #ifdef CONFIG_ALPHA_LEGACY_START_ADDRESS
  12   . = 0xfffffc0000310000;
  13 #else
  14   . = 0xfffffc0001010000;
  15 #endif
  16
  17   _text = .;                                    /* Text and read-only data */
  18   .text : {
  19         *(.text)
  20         SCHED_TEXT
  21         *(.fixup)
  22         *(.gnu.warning)
  23   } :kernel
  24   _etext = .;                                   /* End of text section */
  25
  26   . = ALIGN(16);
  27   __start___ex_table = .;                       /* Exception table */
  28   __ex_table : { *(__ex_table) }
  29   __stop___ex_table = .;
  30
  31   RODATA
  32
  33   /* Will be freed after init */
  34   . = ALIGN(8192);                              /* Init code and data */
  35   __init_begin = .;
  36   .init.text : {
  37         _sinittext = .;
  38         *(.init.text)
  39         _einittext = .;
  40   }
  41   .init.data : { *(.init.data) }
  42
  43   . = ALIGN(16);
  44   __setup_start = .;
  45   .init.setup : { *(.init.setup) }
  46   __setup_end = .;
  47
  48   . = ALIGN(8);
  49   __start___param = .;
  50   __param : { *(__param) }
  51   __stop___param = .;
  52
  53   . = ALIGN(8);
  54   __initcall_start = .;
  55   .initcall.init : {
  56         *(.initcall1.init)
  57         *(.initcall2.init)
  58         *(.initcall3.init)
  59         *(.initcall4.init)
  60         *(.initcall5.init)
  61         *(.initcall6.init)
  62         *(.initcall7.init)
  63   }
  64   __initcall_end = .;
  65
  66   . = ALIGN(8192);
  67   __initramfs_start = .;
  68   .init.ramfs : { *(.init.ramfs) }
  69   __initramfs_end = .;
  70
  71   . = ALIGN(8);
  72   .con_initcall.init : {
  73         __con_initcall_start = .;
  74         *(.con_initcall.init)
  75         __con_initcall_end = .;
  76   }
  77
  78   . = ALIGN(8);
  79   SECURITY_INIT
  80
  81   . = ALIGN(64);
  82   __per_cpu_start = .;
  83   .data.percpu : { *(.data.percpu) }
  84   __per_cpu_end = .;
  85
  86   . = ALIGN(2*8192);
  87   __init_end = .;
  88   /* Freed after init ends here */
  89
  90   /* Note 2 page alignment above.  */
  91   .data.init_thread : { *(.data.init_thread) }
  92
  93   . = ALIGN(8192);
  94   .data.page_aligned : { *(.data.page_aligned) }
  95
  96   . = ALIGN(64);
  97   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  98
  99   _data = .;
 100   .data : {                                     /* Data */
 101         *(.data)
 102         CONSTRUCTORS
 103   }
 104
 105   .got : { *(.got) }
 106   .sdata : { *(.sdata) }
 107
 108   _edata = .;                                   /* End of data section */
 109
 110   __bss_start = .;
 111   .sbss : { *(.sbss) *(.scommon) }
 112   .bss : { *(.bss) *(COMMON) }
 113   __bss_stop = .;
 114
 115   _end = .;
 116
 117   /* Sections to be discarded */
 118   /DISCARD/ : { *(.exit.text) *(.exit.data) *(.exitcall.exit) }
 119
 120   .mdebug 0 : { *(.mdebug) }
 121   .note 0 : { *(.note) }
 122   .comment 0 : { *(.comment) }
 123
 124   /* Stabs debugging sections */
 125   .stab 0 : { *(.stab) }
 126   .stabstr 0 : { *(.stabstr) }
 127   .stab.excl 0 : { *(.stab.excl) }
 128   .stab.exclstr 0 : { *(.stab.exclstr) }
 129   .stab.index 0 : { *(.stab.index) }
 130   .stab.indexstr 0 : { *(.stab.indexstr) }
 131   /* DWARF 1 */
 132   .debug          0 : { *(.debug) }
 133   .line           0 : { *(.line) }
 134   /* GNU DWARF 1 extensions */
 135   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 136   .debug_sfnames  0 : { *(.debug_sfnames) }
 137   /* DWARF 1.1 and DWARF 2 */
 138   .debug_aranges  0 : { *(.debug_aranges) }
 139   .debug_pubnames 0 : { *(.debug_pubnames) }
 140   /* DWARF 2 */
 141   .debug_info     0 : { *(.debug_info) }
 142   .debug_abbrev   0 : { *(.debug_abbrev) }
 143   .debug_line     0 : { *(.debug_line) }
 144   .debug_frame    0 : { *(.debug_frame) }
 145   .debug_str      0 : { *(.debug_str) }
 146   .debug_loc      0 : { *(.debug_loc) }
 147   .debug_macinfo  0 : { *(.debug_macinfo) }
 148   /* SGI/MIPS DWARF 2 extensions */
 149   .debug_weaknames 0 : { *(.debug_weaknames) }
 150   .debug_funcnames 0 : { *(.debug_funcnames) }
 151   .debug_typenames 0 : { *(.debug_typenames) }
 152   .debug_varnames  0 : { *(.debug_varnames) }
 153 }