kernel/linux/arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7
   8 OUTPUT_ARCH(arm)
   9 ENTRY(stext)
  10 #ifndef __ARMEB__
  11 jiffies = jiffies_64;
  12 #else
  13 jiffies = jiffies_64 + 4;
  14 #endif
  15 SECTIONS
  16 {
  17         . = TEXTADDR;
  18         .init : {                       /* Init code and data           */
  19                 _stext = .;
  20                 __init_begin = .;
  21                         _sinittext = .;
  22                         *(.init.text)
  23                         _einittext = .;
  24                 __proc_info_begin = .;
  25                         *(.proc.info)
  26                 __proc_info_end = .;
  27                 __arch_info_begin = .;
  28                         *(.arch.info)
  29                 __arch_info_end = .;
  30                 __tagtable_begin = .;
  31                         *(.taglist)
  32                 __tagtable_end = .;
  33                         *(.init.data)
  34                 . = ALIGN(16);
  35                 __setup_start = .;
  36                         *(.init.setup)
  37                 __setup_end = .;
  38                 __early_begin = .;
  39                         *(__early_param)
  40                 __early_end = .;
  41                 __start___param = .;
  42                         *(__param)
  43                 __stop___param = .;
  44                 __initcall_start = .;
  45                         *(.initcall1.init)
  46                         *(.initcall2.init)
  47                         *(.initcall3.init)
  48                         *(.initcall4.init)
  49                         *(.initcall5.init)
  50                         *(.initcall6.init)
  51                         *(.initcall7.init)
  52                 __initcall_end = .;
  53                 __con_initcall_start = .;
  54                         *(.con_initcall.init)
  55                 __con_initcall_end = .;
  56                 __security_initcall_start = .;
  57                         *(.security_initcall.init)
  58                 __security_initcall_end = .;
  59                 . = ALIGN(32);
  60                 __initramfs_start = .;
  61                         usr/built-in.o(.init.ramfs)
  62                 __initramfs_end = .;
  63                 . = ALIGN(4096);
  64                 __init_end = .;
  65         }
  66
  67         /DISCARD/ : {                   /* Exit code and data           */
  68                 *(.exit.text)
  69                 *(.exit.data)
  70                 *(.exitcall.exit)
  71         }
  72
  73         .text : {                       /* Real text segment            */
  74                 _text = .;              /* Text and read-only data      */
  75                         *(.text)
  76                         SCHED_TEXT
  77                         *(.fixup)
  78                         *(.gnu.warning)
  79                         *(.rodata)
  80                         *(.rodata.*)
  81                         *(.glue_7)
  82                         *(.glue_7t)
  83                 *(.got)                 /* Global offset table          */
  84
  85                 _etext = .;             /* End of text section          */
  86         }
  87
  88         . = ALIGN(16);
  89         __ex_table : {                  /* Exception table              */
  90                 __start___ex_table = .;
  91                         *(__ex_table)
  92                 __stop___ex_table = .;
  93         }
  94
  95         RODATA
  96
  97         . = ALIGN(8192);
  98
  99         .data : {
 100                 /*
 101                  * first, the init task union, aligned
 102                  * to an 8192 byte boundary.
 103                  */
 104                 *(.init.task)
 105
 106                 . = ALIGN(4096);
 107                 __nosave_begin = .;
 108                 *(.data.nosave)
 109                 . = ALIGN(4096);
 110                 __nosave_end = .;
 111
 112                 /*
 113                  * then the cacheline aligned data
 114                  */
 115                 . = ALIGN(32);
 116                 *(.data.cacheline_aligned)
 117
 118                 /*
 119                  * and the usual data section
 120                  */
 121                 *(.data)
 122                 CONSTRUCTORS
 123
 124                 _edata = .;
 125         }
 126
 127         .bss : {
 128                 __bss_start = .;        /* BSS                          */
 129                 *(.bss)
 130                 *(COMMON)
 131                 _end = . ;
 132         }
 133                                         /* Stabs debugging sections.    */
 134         .stab 0 : { *(.stab) }
 135         .stabstr 0 : { *(.stabstr) }
 136         .stab.excl 0 : { *(.stab.excl) }
 137         .stab.exclstr 0 : { *(.stab.exclstr) }
 138         .stab.index 0 : { *(.stab.index) }
 139         .stab.indexstr 0 : { *(.stab.indexstr) }
 140         .comment 0 : { *(.comment) }
 141 }