kernel/linux/arch/arm/mm/abort-ev5tj.S

   1 #include <linux/linkage.h>
   2 #include <asm/assembler.h>
   3 /*
   4  * Function: v5tj_early_abort
   5  *
   6  * Params  : r2 = address of aborted instruction
   7  *         : r3 = saved SPSR
   8  *
   9  * Returns : r0 = address of abort
  10  *         : r1 = FSR, bit 11 = write
  11  *         : r2-r8 = corrupted
  12  *         : r9 = preserved
  13  *         : sp = pointer to registers
  14  *
  15  * Purpose : obtain information about current aborted instruction.
  16  * Note: we read user space.  This means we might cause a data
  17  * abort here if the I-TLB and D-TLB aren't seeing the same
  18  * picture.  Unfortunately, this does happen.  We live with it.
  19  */
  20         .align  5
  21 ENTRY(v5tj_early_abort)
  22         mrc     p15, 0, r1, c5, c0, 0           @ get FSR
  23         mrc     p15, 0, r0, c6, c0, 0           @ get FAR
  24         bic     r1, r1, #1 << 11 | 1 << 10      @ clear bits 11 and 10 of FSR
  25         tst     r3, #PSR_J_BIT                  @ Java?
  26         orrne   r1, r1, #1 << 11                @ always assume write
  27         movne   pc, lr
  28         tst     r3, #PSR_T_BIT                  @ Thumb?
  29         ldrneh  r3, [r2]                        @ read aborted thumb instruction
  30         ldreq   r3, [r2]                        @ read aborted ARM instruction
  31         movne   r3, r3, lsl #(21 - 12)          @ move thumb bit 11 to ARM bit 20
  32         tst     r3, #1 << 20                    @ L = 0 -> write
  33         orreq   r1, r1, #1 << 11                @ yes.
  34         mov     pc, lr
  35
  36