kernel/linux/arch/arm26/lib/getuser.S

   1 /*
   2  *  linux/arch/arm/lib/getuser.S
   3  *
   4  *  Copyright (C) 2001 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  Idea from x86 version, (C) Copyright 1998 Linus Torvalds
  11  *
  12  * These functions have a non-standard call interface to make them more
  13  * efficient, especially as they return an error value in addition to
  14  * the "real" return value.
  15  *
  16  * __get_user_X
  17  *
  18  * Inputs:      r0 contains the address
  19  * Outputs:     r0 is the error code
  20  *              r1, r2 contains the zero-extended value
  21  *              lr corrupted
  22  *
  23  * No other registers must be altered.  (see include/asm-arm/uaccess.h
  24  * for specific ASM register usage).
  25  *
  26  * Note that ADDR_LIMIT is either 0 or 0xc0000000.
  27  * Note also that it is intended that __get_user_bad is not global.
  28  */
  29 #include <asm/asm_offsets.h>
  30 #include <asm/thread_info.h>
  31
  32         .global __get_user_1
  33 __get_user_1:
  34         bic     r1, sp, #0x1f00
  35         bic     r1, r1, #0x00ff
  36         str     lr, [sp, #-4]!
  37         ldr     r1, [r1, #TI_ADDR_LIMIT]
  38         sub     r1, r1, #1
  39         cmp     r0, r1
  40         bge     __get_user_bad
  41         cmp     r0, #0x02000000
  42 1:      ldrlsbt r1, [r0]
  43         ldrgeb  r1, [r0]
  44         mov     r0, #0
  45         ldmfd   sp!, {pc}^
  46
  47         .global __get_user_2
  48 __get_user_2:
  49         bic     r2, sp, #0x1f00
  50         bic     r2, r2, #0x00ff
  51         str     lr, [sp, #-4]!
  52         ldr     r2, [r2, #TI_ADDR_LIMIT]
  53         sub     r2, r2, #2
  54         cmp     r0, r2
  55         bge     __get_user_bad
  56         cmp     r0, #0x02000000
  57 2:      ldrlsbt r1, [r0], #1
  58 3:      ldrlsbt r2, [r0]
  59         ldrgeb  r1, [r0], #1
  60         ldrgeb  r2, [r0]
  61         orr     r1, r1, r2, lsl #8
  62         mov     r0, #0
  63         ldmfd   sp!, {pc}^
  64
  65         .global __get_user_4
  66 __get_user_4:
  67         bic     r1, sp, #0x1f00
  68         bic     r1, r1, #0x00ff
  69         str     lr, [sp, #-4]!
  70         ldr     r1, [r1, #TI_ADDR_LIMIT]
  71         sub     r1, r1, #4
  72         cmp     r0, r1
  73         bge     __get_user_bad
  74         cmp     r0, #0x02000000
  75 4:      ldrlst  r1, [r0]
  76         ldrge   r1, [r0]
  77         mov     r0, #0
  78         ldmfd   sp!, {pc}^
  79
  80         .global __get_user_8
  81 __get_user_8:
  82         bic     r2, sp, #0x1f00
  83         bic     r2, r2, #0x00ff
  84         str     lr, [sp, #-4]!
  85         ldr     r2, [r2, #TI_ADDR_LIMIT]
  86         sub     r2, r2, #8
  87         cmp     r0, r2
  88         bge     __get_user_bad_8
  89         cmp     r0, #0x02000000
  90 5:      ldrlst  r1, [r0], #4
  91 6:      ldrlst  r2, [r0]
  92         ldrge   r1, [r0], #4
  93         ldrge   r2, [r0]
  94         mov     r0, #0
  95         ldmfd   sp!, {pc}^
  96
  97 __get_user_bad_8:
  98         mov     r2, #0
  99 __get_user_bad:
 100         mov     r1, #0
 101         mov     r0, #-14
 102         ldmfd   sp!, {pc}^
 103
 104 .section __ex_table, "a"
 105         .long   1b, __get_user_bad
 106         .long   2b, __get_user_bad
 107         .long   3b, __get_user_bad
 108         .long   4b, __get_user_bad
 109         .long   5b, __get_user_bad_8
 110         .long   6b, __get_user_bad_8
 111 .previous