git.rot13.org Git - goodfet/blob - firmware/ldscripts/msp430.x

   1 /* Default linker script, for normal executables */
   2 OUTPUT_FORMAT("elf32-msp430")
   3 OUTPUT_ARCH("msp430")
   4 INCLUDE memory.x
   5 INCLUDE periph.x
   6 SECTIONS
   7 {
   8
   9   /* Leave two blank bytes in ram for calibration data */
  10   .hack.dco_choice (NOLOAD) : {
  11      SHORT(0)
  12   } >REGION_DATA
  13   /* Read-only sections, merged into text segment.  */
  14   .hash          : { *(.hash)             }
  15   .dynsym        : { *(.dynsym)           }
  16   .dynstr        : { *(.dynstr)           }
  17   .gnu.version   : { *(.gnu.version)      }
  18   .gnu.version_d   : { *(.gnu.version_d)  }
  19   .gnu.version_r   : { *(.gnu.version_r)  }
  20   .rel.init      : { *(.rel.init) }
  21   .rela.init     : { *(.rela.init) }
  22   .rel.text      :
  23     {
  24       *(.rel.text)
  25       *(.rel.text.*)
  26       *(.rel.gnu.linkonce.t*)
  27     }
  28   .rela.text     :
  29     {
  30       *(.rela.text)
  31       *(.rela.text.*)
  32       *(.rela.gnu.linkonce.t*)
  33     }
  34   .rel.fini      : { *(.rel.fini) }
  35   .rela.fini     : { *(.rela.fini) }
  36   .rel.rodata    :
  37     {
  38       *(.rel.rodata)
  39       *(.rel.rodata.*)
  40       *(.rel.gnu.linkonce.r*)
  41     }
  42   .rela.rodata   :
  43     {
  44       *(.rela.rodata)
  45       *(.rela.rodata.*)
  46       *(.rela.gnu.linkonce.r*)
  47     }
  48   .rel.data      :
  49     {
  50       *(.rel.data)
  51       *(.rel.data.*)
  52       *(.rel.gnu.linkonce.d*)
  53     }
  54   .rela.data     :
  55     {
  56       *(.rela.data)
  57       *(.rela.data.*)
  58       *(.rela.gnu.linkonce.d*)
  59     }
  60   .rel.ctors     : { *(.rel.ctors)        }
  61   .rela.ctors    : { *(.rela.ctors)       }
  62   .rel.dtors     : { *(.rel.dtors)        }
  63   .rela.dtors    : { *(.rela.dtors)       }
  64   .rel.got       : { *(.rel.got)          }
  65   .rela.got      : { *(.rela.got)         }
  66   .rel.bss       : { *(.rel.bss)          }
  67   .rela.bss      : { *(.rela.bss)         }
  68   .rel.plt       : { *(.rel.plt)          }
  69   .rela.plt      : { *(.rela.plt)         }
  70   /* Internal text space.  */
  71   .text :
  72   {
  73      . = ALIGN(2);
  74      KEEP(*(.init .init.*))
  75      KEEP(*(.init0))  /* Start here after reset.               */
  76      KEEP(*(.init1))  /* User definable.                       */
  77      KEEP(*(.init2))  /* Initialize stack.                     */
  78      KEEP(*(.init3))  /* Initialize hardware, user definable.  */
  79      KEEP(*(.init4))  /* Copy data to .data, clear bss.        */
  80      KEEP(*(.init5))  /* User definable.                       */
  81      KEEP(*(.init6))  /* C++ constructors.                     */
  82      KEEP(*(.init7))  /* User definable.                       */
  83      KEEP(*(.init8))  /* User definable.                       */
  84      KEEP(*(.init9))  /* Call main().                          */
  85      KEEP(*(.fini9))  /* Falls into here after main(). User definable.  */
  86      KEEP(*(.fini8))  /* User definable.                           */
  87      KEEP(*(.fini7))  /* User definable.                           */
  88      KEEP(*(.fini6))  /* C++ destructors.                          */
  89      KEEP(*(.fini5))  /* User definable.                           */
  90      KEEP(*(.fini4))  /* User definable.                           */
  91      KEEP(*(.fini3))  /* User definable.                           */
  92      KEEP(*(.fini2))  /* User definable.                           */
  93      KEEP(*(.fini1))  /* User definable.                           */
  94      KEEP(*(.fini0))  /* Infinite loop after program termination.  */
  95      KEEP(*(.fini .fini.*))
  96      . = ALIGN(2);
  97      __ctors_start = . ;
  98      KEEP(*(.ctors))
  99      __ctors_end = . ;
 100      __dtors_start = . ;
 101      KEEP(*(.dtors))
 102      __dtors_end = . ;
 103      . = ALIGN(2);
 104     *(.text .text.* .gnu.linkonce.t.*)
 105      . = ALIGN(2);
 106   }  > REGION_TEXT
 107   .rodata   :
 108   {
 109      . = ALIGN(2);
 110     *(.rodata .rodata.* .gnu.linkonce.r.*)
 111      . = ALIGN(2);
 112   }  > REGION_TEXT
 113    _etext = .;
 114   .data   :
 115   {
 116      . = ALIGN(2);
 117      PROVIDE (__data_start = .) ;
 118     *(.data)
 119     *(SORT_BY_ALIGNMENT(.data.*))
 120      . = ALIGN(2);
 121     *(.gnu.linkonce.d*)
 122      . = ALIGN(2);
 123      _edata = . ;
 124   }  > REGION_DATA AT > REGION_TEXT
 125     PROVIDE (__data_load_start = LOADADDR(.data) );
 126     PROVIDE (__data_size = SIZEOF(.data) );
 127   .bss   :
 128   {
 129      PROVIDE (__bss_start = .) ;
 130     *(.bss)
 131     *(SORT_BY_ALIGNMENT(.bss.*))
 132     *(COMMON)
 133      PROVIDE (__bss_end = .) ;
 134      _end = . ;
 135   }  > REGION_DATA
 136     PROVIDE (__bss_size = SIZEOF(.bss) );
 137   .noinit   :
 138   {
 139      PROVIDE (__noinit_start = .) ;
 140     *(.noinit)
 141     *(.noinit.*)
 142     *(COMMON)
 143      PROVIDE (__noinit_end = .) ;
 144      _end = . ;
 145   }  > REGION_DATA
 146   /* Information memory.  */
 147   .infomem   :
 148   {
 149     *(.infomem)
 150      . = ALIGN(2);
 151     *(.infomem.*)
 152   }  > infomem
 153   .vectors  :
 154   {
 155      PROVIDE (__vectors_start = .) ;
 156     KEEP(*(.vectors*))
 157      _vectors_end = . ;
 158   }  > vectors
 159   .fartext :
 160   {
 161      . = ALIGN(2);
 162     *(.fartext)
 163      . = ALIGN(2);
 164     *(.fartext.*)
 165      _efartext = .;
 166   }  > REGION_FAR_ROM
 167   /* Stabs for profiling information*/
 168   .profiler 0 : { *(.profiler) }
 169   /* Stabs debugging sections.  */
 170   .stab 0 : { *(.stab) }
 171   .stabstr 0 : { *(.stabstr) }
 172   .stab.excl 0 : { *(.stab.excl) }
 173   .stab.exclstr 0 : { *(.stab.exclstr) }
 174   .stab.index 0 : { *(.stab.index) }
 175   .stab.indexstr 0 : { *(.stab.indexstr) }
 176   .comment 0 : { *(.comment) }
 177   /* DWARF debug sections.
 178      Symbols in the DWARF debugging sections are relative to the beginning
 179      of the section so we begin them at 0.  */
 180   /* DWARF 1 */
 181   .debug          0 : { *(.debug) }
 182   .line           0 : { *(.line) }
 183   /* GNU DWARF 1 extensions */
 184   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 185   .debug_sfnames  0 : { *(.debug_sfnames) }
 186   /* DWARF 1.1 and DWARF 2 */
 187   .debug_aranges  0 : { *(.debug_aranges) }
 188   .debug_pubnames 0 : { *(.debug_pubnames) }
 189   /* DWARF 2 */
 190   .debug_info     0 : { *(.debug_info) *(.gnu.linkonce.wi.*) }
 191   .debug_abbrev   0 : { *(.debug_abbrev) }
 192   .debug_line     0 : { *(.debug_line) }
 193   .debug_frame    0 : { *(.debug_frame) }
 194   .debug_str      0 : { *(.debug_str) }
 195   .debug_loc      0 : { *(.debug_loc) }
 196   .debug_macinfo  0 : { *(.debug_macinfo) }
 197   /* DWARF 3 */
 198   .debug_pubtypes 0 : { *(.debug_pubtypes) }
 199   .debug_ranges   0 : { *(.debug_ranges) }
 200    PROVIDE (__stack = ORIGIN(ram) + LENGTH(ram));
 201    PROVIDE (__data_start_rom = _etext);
 202    PROVIDE (__data_end_rom   = _etext + SIZEOF (.data));
 203 }