arch/mips/lib/strnlen_user.S

   1 /*
   2  * This file is subject to the terms and conditions of the GNU General Public
   3  * License.  See the file "COPYING" in the main directory of this archive
   4  * for more details.
   5  *
   6  * Copyright (c) 1996, 1998, 1999 by Ralf Baechle
   7  * Copyright (c) 1999 Silicon Graphics, Inc.
   8  */
   9 #include <asm/asm.h>
  10 #include <asm/offset.h>
  11 #include <asm/regdef.h>
  12 #include <asm/sgidefs.h>
  13
  14 #define EX(insn,reg,addr,handler)                       \
  15 9:      insn    reg, addr;                              \
  16         .section __ex_table,"a";                        \
  17         PTR     9b, handler;                            \
  18         .previous
  19
  20 /*
  21  * Return the size of a string (including the ending 0)
  22  *
  23  * Return 0 for error, len of string but at max a1 otherwise
  24  *
  25  * Note: for performance reasons we deliberately accept that a user may
  26  *       make strlen_user and strnlen_user access the first few KSEG0
  27  *       bytes.  There's nothing secret there ...
  28  */
  29 LEAF(__strnlen_user_asm)
  30         LONG_L          v0, THREAD_CURDS($28)   # pointer ok?
  31         and             v0, a0
  32         bltz            v0, fault
  33
  34 FEXPORT(__strnlen_user_nocheck_asm)
  35         move            v0, a0
  36         PTR_ADDU        a1, a0                  # stop pointer
  37         .set            noreorder
  38 1:      beq             v0, a1, 1f              # limit reached?
  39          PTR_ADDIU      v0, 1
  40         .set            reorder
  41         EX(lb, t0, -1(v0), fault)
  42         bnez            t0, 1b
  43 1:      PTR_SUBU        v0, a0
  44         jr              ra
  45         END(__strnlen_user_asm)
  46
  47 fault:  move            v0, zero
  48         jr              ra