lib/CWMP/Session.pm

   1 # Dobrica Pavlinusic, <dpavlin@rot13.org> 06/18/07 10:19:50 CEST
   2 package CWMP::Session;
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/Class::Accessor/;
   8 __PACKAGE__->mk_accessors( qw/
   9 debug
  10 create_dump
  11 session
  12
  13 sock
  14 state
  15 store
  16 / );
  17
  18 use Data::Dump qw/dump/;
  19 use Carp qw/carp confess cluck croak/;
  20
  21 use CWMP::Parser;
  22 use CWMP::Methods;
  23 use CWMP::Store;
  24
  25 #use Devel::LeakTrace::Fast;
  26
  27 =head1 NAME
  28
  29 CWMP::Session - implement logic of CWMP protocol
  30
  31 =head1 METHODS
  32
  33 =head2 new
  34
  35   my $server = CWMP::Session->new({
  36         sock => $io_socket_object,
  37         store => { ... },
  38         debug => 1,
  39         create_dump => 1,
  40   });
  41
  42 =cut
  43
  44 sub new {
  45         my $class = shift;
  46         my $self = $class->SUPER::new( @_ );
  47
  48         confess "need store" unless $self->store;
  49
  50         $self->debug( 0 ) unless $self->debug;
  51
  52         my $store_obj = CWMP::Store->new({
  53                 debug => $self->debug,
  54                 %{ $self->store },
  55         });
  56
  57         croak "can't open ", dump( $self->store ), ": $!" unless $store_obj;
  58
  59         # FIXME looks ugly. Should we have separate accessor for this?
  60         $self->store( $store_obj );
  61
  62         $self->create_dump( 1 ) if $self->debug > 2;
  63
  64         return $self;
  65 }
  66
  67 my $vendor_data = {
  68  'InternetGatewayDevice.ManagementServer.PeriodicInformEnable' => 1,
  69  'InternetGatewayDevice.ManagementServer.PeriodicInformInterval' => 17,
  70  'InternetGatewayDevice.DeviceInfo.ProvisioningCode' => 'test provision',
  71 };
  72
  73 sub vendor_hook {
  74         my ( $self, $stored, $queue ) = @_;
  75         warn "# vendor_hook ",dump($stored) if $self->debug > 2;
  76
  77         my @refresh;
  78
  79         foreach my $n ( keys %$vendor_data ) {
  80                 if ( $vendor_data->{$n} ne $stored->{$n} ) {
  81                         push @refresh, $n;
  82                         $queue->enqueue( 'SetParameterValues', { $n => $vendor_data->{$n} } );
  83                 }
  84         }
  85
  86         if ( @refresh ) {
  87                 $queue->enqueue( 'GetParameterValues', [ @refresh ] );
  88                 warn "vendor_hook SetParameterValues ", dump( @refresh );
  89                 return $self->dispatch( 'GetParameterValues', [ @refresh ] );
  90         }
  91
  92         return;
  93 }
  94
  95 =head2 process_request
  96
  97 One request from client/response from server cycle. Call multiple times to
  98 facilitate brain-dead concept of adding state to stateless protocol like
  99 HTTP.
 100
 101 If used with debugging level of 3 or more, it will also create dumps of
 102 requests named C<< dump/nr.request >> where C<nr> is number from 0 to total number
 103 of requests in single session.
 104
 105 =cut
 106
 107
 108 sub process_request {
 109         my ( $self, $ip, $xml ) = @_;
 110
 111         my $size = length( $xml );
 112
 113         my $state;
 114
 115         if ( $size > 0 ) {
 116
 117                 warn "## request payload: ",length($xml)," bytes\n$xml\n" if $self->debug;
 118
 119                 $state = CWMP::Parser->parse( $xml );
 120
 121                 warn "## acquired state = ", dump( $state ), "\n" if $self->debug;
 122
 123                 if ( ! defined( $state->{DeviceId} ) ) {
 124                         if ( $self->state ) {
 125                                 warn "## state without DeviceId, using old one...\n";
 126                                 $state->{DeviceId} = $self->state->{DeviceId};
 127                         } else {
 128                                 warn "WARNING: state without DeviceId, and I don't have old one!\n";
 129                                 warn "## state = ",dump( $state );
 130                         }
 131                 }
 132
 133                 $self->state( $state );
 134                 $self->store->update_state( $state );
 135
 136         } else {
 137
 138                 warn "## empty request, using last request state\n";
 139
 140                 $state = $self->state;
 141                 delete( $state->{_dispatch} );
 142                 #warn "last request state = ", dump( $state ), "\n" if $self->debug > 1;
 143         }
 144
 145         my $uid = $self->store->state_to_uid( $state );
 146
 147         my $to_uid = join(" ", grep { defined($_) } "to $uid",
 148                         # board
 149                         $state->{Parameter}->{'InternetGatewayDevice.DeviceInfo.HardwareVersion'},
 150                         # version
 151                         $state->{Parameter}->{'InternetGatewayDevice.DeviceInfo.SoftwareVersion'},
 152                         # summary
 153 #                       $state->{Parameter}->{'InternetGatewayDevice.DeviceSummary'},
 154         ) . "\n";
 155
 156         my $queue = CWMP::Queue->new({
 157                 id => $uid,
 158                 debug => $self->debug,
 159         });
 160         $xml = '';
 161
 162         if ( my $dispatch = $state->{_dispatch} ) {
 163                 $xml = $self->dispatch( $dispatch );
 164         } elsif ( my $job = $queue->dequeue ) {
 165                 $xml = $self->dispatch( $job->dispatch );
 166                 $job->finish;
 167         } else {
 168                 my $stored = $self->store->get_state( $uid );
 169                 if ( ! defined $stored->{ParameterInfo} ) {
 170                         $xml = $self->dispatch( 'GetParameterNames', [ 'InternetGatewayDevice.', 1 ] );
 171                 } else {
 172                         my @params = grep { m/\.$/ } keys %{ $stored->{ParameterInfo} };
 173                         if ( @params ) {
 174                                 warn "# GetParameterNames ", dump( @params );
 175                                 my $first = shift @params;
 176                                 delete $stored->{ParameterInfo}->{$first};
 177                                 $xml = $self->dispatch( 'GetParameterNames', [ $first, 1 ] );
 178                                 foreach ( @params ) {
 179                                         $queue->enqueue( 'GetParameterNames', [ $_, 1 ] );
 180                                         delete $stored->{ParameterInfo}->{ $_ };
 181                                 }
 182                                 $self->store->set_state( $uid, $stored );
 183                         } else {
 184
 185                                 my @params = sort
 186                                         grep { ! exists $stored->{Parameter}->{$_} }
 187                                         grep { ! m/\.$/ && ! m/NumberOfEntries/ }
 188                                         keys %{ $stored->{ParameterInfo} }
 189                                 ;
 190                                 if ( @params ) {
 191                                         warn "# GetParameterValues ", dump( @params );
 192                                         my $first = shift @params;
 193                                         $xml = $self->dispatch( 'GetParameterValues', [ $first ] );
 194                                         while ( @params ) {
 195                                                 my @chunk = splice @params, 0, 16; # FIXME 16 seems to be max
 196                                                 $queue->enqueue( 'GetParameterValues', [ @chunk ] );
 197                                         }
 198
 199                                 } elsif ( $xml = $self->vendor_hook( $stored, $queue ) ) {
 200
 201                                         warn "vendor_hook triggered\n";
 202
 203                                 } else {
 204
 205                                         warn ">>> empty response $to_uid";
 206                                         $state->{NoMoreRequests} = 1;
 207                                         $xml = '';
 208
 209                                 }
 210                         }
 211                 }
 212         }
 213
 214         my $status = length($xml) ? 200 : 204;
 215
 216         my $out = join("\r\n",
 217                 "HTTP/1.1 $status OK",
 218                 'Content-Type: text/xml; charset="utf-8"',
 219                 'Server: Perl-CWMP/42',
 220                 'SOAPServer: Perl-CWMP/42'
 221         ) . "\r\n";
 222
 223         $out .= "Set-Cookie: ID=" . $state->{ID} . "; path=/\r\n" if $state->{ID};
 224
 225         $out .= "Content-Length: " . length( $xml ) . "\r\n\r\n";
 226         $out .= $xml if length($xml);
 227
 228         warn "### request over for $uid\n" if $self->debug;
 229
 230         return $out;    # next request
 231 };
 232
 233 =head2 dispatch
 234
 235   $xml = $self->dispatch('Inform', $response_arguments );
 236
 237 If debugging level of 3 or more, it will create dumps of responses named C<< dump/nr.response >>
 238
 239 =cut
 240
 241 sub dispatch {
 242         my $self = shift;
 243
 244         my $dispatch = shift || die "no dispatch?";
 245         my $args = shift;
 246
 247         my $response = CWMP::Methods->new({ debug => $self->debug });
 248
 249         if ( $response->can( $dispatch ) ) {
 250                 warn ">>> dispatching to $dispatch with args ",dump( $args ),"\n";
 251                 my $xml = $response->$dispatch( $self->state, $args );
 252                 warn "## response payload: ",length($xml)," bytes\n$xml\n" if $self->debug;
 253                 return $xml;
 254         } else {
 255                 confess "can't dispatch to $dispatch";
 256         }
 257 };
 258
 259
 260 =head2 error
 261
 262   return $self->error( 501, 'System error' );
 263
 264 =cut
 265
 266 sub error {
 267   my ($self, $number, $msg) = @_;
 268   $msg ||= 'ERROR';
 269   $self->sock->send( "HTTP/1.1 $number $msg\r\n" );
 270   warn "Error - $number - $msg\n";
 271   return 0;     # close connection
 272 }
 273
 274 1;