lib/CWMP/Session.pm

   1 # Dobrica Pavlinusic, <dpavlin@rot13.org> 06/18/07 10:19:50 CEST
   2 package CWMP::Session;
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/Class::Accessor/;
   8 __PACKAGE__->mk_accessors( qw/
   9 debug
  10 store_path
  11
  12 sock
  13 state
  14 queue
  15 store
  16 / );
  17
  18 use HTTP::Daemon;
  19 use Data::Dump qw/dump/;
  20 use Carp qw/confess cluck croak/;
  21 use File::Slurp;
  22
  23 use CWMP::Request;
  24 use CWMP::Response;
  25 use CWMP::Store;
  26
  27 =head1 NAME
  28
  29 CWMP::Session - implement logic of CWMP protocol
  30
  31 =head1 METHODS
  32
  33 =head2 new
  34
  35   my $server = CWMP::Session->new({
  36         sock => $io_socket_object,
  37         store_path => 'state.db',
  38         queue => [ qw/GetRPCMethods GetParameterNames/ ],
  39         debug => 1,
  40   });
  41
  42 =cut
  43
  44 sub new {
  45         my $class = shift;
  46         my $self = $class->SUPER::new( @_ );
  47
  48         confess "need sock" unless $self->sock;
  49
  50         $self->debug( 0 ) unless $self->debug;
  51
  52         warn "created ", __PACKAGE__, "(", dump( @_ ), ") for ", $self->sock->peerhost, "\n" if $self->debug;
  53
  54         $self->store( CWMP::Store->new({
  55                 debug => $self->debug,
  56                 path => $self->store_path,
  57         }) );
  58
  59         croak "can't open ", $self->store_path, ": $!" unless $self->store;
  60
  61         return $self;
  62 }
  63
  64 =head2 process_request
  65
  66 One request from client/response from server cycle. Call multiple times to
  67 facilitate brain-dead concept of adding state to stateless protocol like
  68 HTTP.
  69
  70 If used with debugging level of 3 or more, it will also create dumps of
  71 requests named C<< nr.dump >> where C<nr> is number from 0 to total number
  72 of requests in single session.
  73
  74 =cut
  75
  76 my $dump_nr = 0;
  77
  78 sub process_request {
  79         my $self = shift;
  80
  81         my $sock = $self->sock || die "no sock?";
  82
  83 #       die "not IO::Socket::INET but ", ref( $sock ) unless ( ref($sock) eq 'Net::Server::Proto::TCP' );
  84
  85         if ( ! $sock->connected ) {
  86                 warn "SOCKET NOT CONNECTED\n";
  87                 return 0;
  88         }
  89
  90         bless $sock, 'HTTP::Daemon::ClientConn';
  91
  92         # why do I have to do this?
  93         # solution from http://use.perl.org/~Matts/journal/12896
  94         ${*$sock}{'httpd_daemon'} = HTTP::Daemon->new;
  95
  96         my $r = $sock->get_request || confess "can't get_request";
  97
  98         my $chunk = $r->content;
  99
 100         my $size = length( $chunk );
 101
 102         warn "<<<< ", $sock->peerhost, " [" . localtime() . "] ", $r->method, " ", $r->uri, " $size bytes\n";
 103
 104         if ( $self->debug > 2 ) {
 105                 my $file = $dump_nr++ . '.dump';
 106                 write_file( $file, $r->as_string );
 107                 warn "### request dump: $file\n";
 108         }
 109
 110         my $state;
 111
 112         if ( $size > 0 ) {
 113
 114                 die "no SOAPAction header in ",dump($chunk) unless defined ( $r->header('SOAPAction') );
 115
 116
 117                 if ( $chunk ) {
 118                         warn "## request chunk: ",length($chunk)," bytes\n$chunk\n" if $self->debug;
 119
 120                         $state = CWMP::Request->parse( $chunk );
 121
 122                         warn "## acquired state = ", dump( $state ), "\n";
 123
 124                         $self->state( $state );
 125                         $self->store->update_state( ID => $state->{ID}, $state );
 126
 127                 } else {
 128                         warn "## empty request\n";
 129                 }
 130
 131         } else {
 132                 $state = $self->state;
 133                 warn "last request state = ", dump( $state ), "\n" if $self->debug > 1;
 134         }
 135
 136
 137         $sock->send(join("\r\n",
 138                 'HTTP/1.1 200 OK',
 139                 'Content-Type: text/xml; charset="utf-8"',
 140                 'Server: AcmeCWMP/42',
 141                 'SOAPServer: AcmeCWMP/42'
 142         )."\r\n");
 143
 144         $sock->send( "Set-Cookie: ID=" . $state->{ID} . "; path=/\r\n" ) if ( $state->{ID} );
 145
 146         my $xml = '';
 147
 148         if ( my $dispatch = $state->{_dispatch} ) {
 149                 $xml = $self->dispatch( $dispatch );
 150         } elsif ( $dispatch = shift @{ $self->queue } ) {
 151                 $xml = $self->dispatch( $dispatch );
 152         } elsif ( $size == 0 ) {
 153                 warn ">>> closing connection\n";
 154                 return 0;
 155         } else {
 156                 warn ">>> empty response\n";
 157                 $state->{NoMoreRequests} = 1;
 158                 $xml = $self->dispatch( 'xml', sub {} );
 159         }
 160
 161         $sock->send( "Content-Length: " . length( $xml ) . "\r\n\r\n" );
 162         $sock->send( $xml ) or die "can't send response";
 163
 164         warn ">>>> " . $sock->peerhost . " [" . localtime() . "] sent ", length( $xml )," bytes\n";
 165
 166         warn "### request over\n" if $self->debug;
 167
 168         return 1;       # next request
 169 };
 170
 171 =head2 dispatch
 172
 173   $xml = $self->dispatch('Inform', $response_arguments );
 174
 175 =cut
 176
 177 sub dispatch {
 178         my $self = shift;
 179
 180         my $dispatch = shift || die "no dispatch?";
 181
 182         my $response = CWMP::Response->new({ debug => $self->debug });
 183
 184         if ( $response->can( $dispatch ) ) {
 185                 warn ">>> dispatching to $dispatch\n";
 186                 my $xml = $response->$dispatch( $self->state, @_ );
 187                 warn "## response payload: ",length($xml)," bytes\n$xml\n" if $self->debug;
 188                 return $xml;
 189         } else {
 190                 confess "can't dispatch to $dispatch";
 191         }
 192 };
 193
 194
 195 =head2 error
 196
 197   return $self->error( 501, 'System error' );
 198
 199 =cut
 200
 201 sub error {
 202   my ($self, $number, $msg) = @_;
 203   $msg ||= 'ERROR';
 204   $self->sock->send( "HTTP/1.1 $number $msg\r\n" );
 205   warn "Error - $number - $msg\n";
 206   return 0;     # close connection
 207 }
 208
 209 1;