lib/CWMP/Session.pm

   1 # Dobrica Pavlinusic, <dpavlin@rot13.org> 06/18/07 10:19:50 CEST
   2 package CWMP::Session;
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/Class::Accessor/;
   8 __PACKAGE__->mk_accessors( qw/
   9 debug
  10 create_dump
  11 session
  12
  13 sock
  14 state
  15 store
  16 / );
  17
  18 use Data::Dump qw/dump/;
  19 use Carp qw/carp confess cluck croak/;
  20
  21 use CWMP::Request;
  22 use CWMP::Methods;
  23 use CWMP::Store;
  24
  25 #use Devel::LeakTrace::Fast;
  26
  27 =head1 NAME
  28
  29 CWMP::Session - implement logic of CWMP protocol
  30
  31 =head1 METHODS
  32
  33 =head2 new
  34
  35   my $server = CWMP::Session->new({
  36         sock => $io_socket_object,
  37         store => { ... },
  38         debug => 1,
  39         create_dump => 1,
  40   });
  41
  42 =cut
  43
  44 sub new {
  45         my $class = shift;
  46         my $self = $class->SUPER::new( @_ );
  47
  48         confess "need store" unless $self->store;
  49
  50         $self->debug( 0 ) unless $self->debug;
  51
  52         my $store_obj = CWMP::Store->new({
  53                 debug => $self->debug,
  54                 %{ $self->store },
  55         });
  56
  57         croak "can't open ", dump( $self->store ), ": $!" unless $store_obj;
  58
  59         # FIXME looks ugly. Should we have separate accessor for this?
  60         $self->store( $store_obj );
  61
  62         $self->create_dump( 1 ) if $self->debug > 2;
  63
  64         return $self;
  65 }
  66
  67 =head2 process_request
  68
  69 One request from client/response from server cycle. Call multiple times to
  70 facilitate brain-dead concept of adding state to stateless protocol like
  71 HTTP.
  72
  73 If used with debugging level of 3 or more, it will also create dumps of
  74 requests named C<< dump/nr.request >> where C<nr> is number from 0 to total number
  75 of requests in single session.
  76
  77 =cut
  78
  79
  80 sub process_request {
  81         my ( $self, $ip, $xml ) = @_;
  82
  83         my $size = length( $xml );
  84
  85         my $state;
  86
  87         if ( $size > 0 ) {
  88
  89                 warn "## request payload: ",length($xml)," bytes\n$xml\n" if $self->debug;
  90
  91                 $state = CWMP::Request->parse( $xml );
  92
  93                 warn "## acquired state = ", dump( $state ), "\n" if $self->debug;
  94
  95                 if ( ! defined( $state->{DeviceID} ) ) {
  96                         if ( $self->state ) {
  97                                 warn "## state without DeviceID, using old one...\n";
  98                                 $state->{DeviceID} = $self->state->{DeviceID};
  99                         } else {
 100                                 warn "WARNING: state without DeviceID, and I don't have old one!\n";
 101                                 warn "## state = ",dump( $state );
 102                         }
 103                 }
 104
 105                 $self->state( $state );
 106                 $self->store->update_state( $state );
 107
 108         } else {
 109
 110                 warn "## empty request, using last request state\n";
 111
 112                 $state = $self->state;
 113                 delete( $state->{_dispatch} );
 114                 #warn "last request state = ", dump( $state ), "\n" if $self->debug > 1;
 115         }
 116
 117         my $uid = $self->store->state_to_uid( $state );
 118
 119         my $to_uid = join(" ", grep { defined($_) } "to $uid",
 120                         # board
 121                         $state->{Parameter}->{'InternetGatewayDevice.DeviceInfo.HardwareVersion'},
 122                         # version
 123                         $state->{Parameter}->{'InternetGatewayDevice.DeviceInfo.SoftwareVersion'},
 124                         # summary
 125 #                       $state->{Parameter}->{'InternetGatewayDevice.DeviceSummary'},
 126         ) . "\n";
 127
 128         my $queue = CWMP::Queue->new({
 129                 id => $uid,
 130                 debug => $self->debug,
 131         });
 132         $xml = '';
 133
 134         if ( my $dispatch = $state->{_dispatch} ) {
 135                 $xml = $self->dispatch( $dispatch );
 136         } elsif ( my $job = $queue->dequeue ) {
 137                 $xml = $self->dispatch( $job->dispatch );
 138                 $job->finish;
 139         } else {
 140                 my $stored = $self->store->get_state( $uid );
 141                 if ( ! defined $stored->{ParameterInfo} ) {
 142                         $xml = $self->dispatch( 'GetParameterNames', [ 'InternetGatewayDevice.', 1 ] );
 143                 } else {
 144                         my @params = grep { m/\.$/ } keys %{ $stored->{ParameterInfo} };
 145                         if ( @params ) {
 146                                 warn "# GetParameterNames ", dump( @params );
 147                                 $xml = $self->dispatch( 'GetParameterNames', [ shift @params, 1 ] );
 148                                 foreach ( @params ) {
 149                                         $queue->enqueue( 'GetParameterNames', [ $_, 1 ] );
 150                                         delete( $stored->{ParameterInfo}->{ $_ } );
 151                                 }
 152                                 $self->store->set_state( $uid, $stored );
 153                         } else {
 154                                 warn ">>> empty response $to_uid";
 155                                 $state->{NoMoreRequests} = 1;
 156                                 $xml = '';
 157                         }
 158                 }
 159         }
 160
 161         my $status = length($xml) ? 200 : 204;
 162
 163         my $out = join("\r\n",
 164                 "HTTP/1.1 $status OK",
 165                 'Content-Type: text/xml; charset="utf-8"',
 166                 'Server: Perl-CWMP/42',
 167                 'SOAPServer: Perl-CWMP/42'
 168         ) . "\r\n";
 169
 170         $out .= "Set-Cookie: ID=" . $state->{ID} . "; path=/\r\n" if $state->{ID};
 171
 172         $out .= "Content-Length: " . length( $xml ) . "\r\n\r\n";
 173         $out .= $xml if length($xml);
 174
 175         warn "### request over for $uid\n" if $self->debug;
 176
 177         return $out;    # next request
 178 };
 179
 180 =head2 dispatch
 181
 182   $xml = $self->dispatch('Inform', $response_arguments );
 183
 184 If debugging level of 3 or more, it will create dumps of responses named C<< dump/nr.response >>
 185
 186 =cut
 187
 188 sub dispatch {
 189         my $self = shift;
 190
 191         my $dispatch = shift || die "no dispatch?";
 192         my $args = shift;
 193
 194         my $response = CWMP::Methods->new({ debug => $self->debug });
 195
 196         if ( $response->can( $dispatch ) ) {
 197                 warn ">>> dispatching to $dispatch with args ",dump( $args ),"\n";
 198                 my $xml = $response->$dispatch( $self->state, $args );
 199                 warn "## response payload: ",length($xml)," bytes\n$xml\n" if $self->debug;
 200                 return $xml;
 201         } else {
 202                 confess "can't dispatch to $dispatch";
 203         }
 204 };
 205
 206
 207 =head2 error
 208
 209   return $self->error( 501, 'System error' );
 210
 211 =cut
 212
 213 sub error {
 214   my ($self, $number, $msg) = @_;
 215   $msg ||= 'ERROR';
 216   $self->sock->send( "HTTP/1.1 $number $msg\r\n" );
 217   warn "Error - $number - $msg\n";
 218   return 0;     # close connection
 219 }
 220
 221 1;