lib/CWMP/Session.pm

   1 # Dobrica Pavlinusic, <dpavlin@rot13.org> 06/18/07 10:19:50 CEST
   2 package CWMP::Session;
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/Class::Accessor/;
   8 __PACKAGE__->mk_accessors( qw/
   9 debug
  10 create_dump
  11 session
  12
  13 sock
  14 state
  15 store
  16 / );
  17
  18 use HTTP::Daemon;
  19 use Data::Dump qw/dump/;
  20 use Carp qw/confess cluck croak/;
  21 use File::Slurp;
  22
  23 use CWMP::Request;
  24 use CWMP::Methods;
  25 use CWMP::Store;
  26
  27 =head1 NAME
  28
  29 CWMP::Session - implement logic of CWMP protocol
  30
  31 =head1 METHODS
  32
  33 =head2 new
  34
  35   my $server = CWMP::Session->new({
  36         sock => $io_socket_object,
  37         store => { ... },
  38         debug => 1,
  39         create_dump => 1,
  40   });
  41
  42 =cut
  43
  44 sub new {
  45         my $class = shift;
  46         my $self = $class->SUPER::new( @_ );
  47
  48         confess "need sock" unless $self->sock;
  49         confess "need store" unless $self->store;
  50         my $peerhost = $self->sock->peerhost || confess "can't get sock->peerhost";
  51
  52         $self->debug( 0 ) unless $self->debug;
  53
  54         warn "created ", __PACKAGE__, "(", dump( @_ ), ") for $peerhost\n" if $self->debug;
  55
  56         my $store_obj = CWMP::Store->new({
  57                 debug => $self->debug,
  58                 %{ $self->store },
  59         });
  60
  61         croak "can't open ", dump( $self->store ), ": $!" unless $store_obj;
  62
  63         # FIXME looks ugly. Should we have separate accessor for this?
  64         $self->store( $store_obj );
  65
  66         $self->create_dump( 1 ) if $self->debug > 2;
  67
  68         return $self;
  69 }
  70
  71 =head2 process_request
  72
  73 One request from client/response from server cycle. Call multiple times to
  74 facilitate brain-dead concept of adding state to stateless protocol like
  75 HTTP.
  76
  77 If used with debugging level of 3 or more, it will also create dumps of
  78 requests named C<< dump/nr.request >> where C<nr> is number from 0 to total number
  79 of requests in single session.
  80
  81 =cut
  82
  83 my $dump_nr = 0;
  84
  85 sub process_request {
  86         my $self = shift;
  87
  88         my $sock = $self->sock || die "no sock?";
  89
  90 #       die "not IO::Socket::INET but ", ref( $sock ) unless ( ref($sock) eq 'Net::Server::Proto::TCP' );
  91
  92         if ( ! $sock->connected ) {
  93                 warn "SOCKET NOT CONNECTED\n";
  94                 return 0;
  95         }
  96
  97         bless $sock, 'HTTP::Daemon::ClientConn';
  98
  99         # why do I have to do this?
 100         # solution from http://use.perl.org/~Matts/journal/12896
 101         ${*$sock}{'httpd_daemon'} = HTTP::Daemon->new;
 102
 103         my $r = $sock->get_request || confess "can't get_request";
 104
 105         my $xml = $r->content;
 106
 107         my $size = length( $xml );
 108
 109         warn "<<<< ", $sock->peerhost, " [" . localtime() . "] ", $r->method, " ", $r->uri, " $size bytes\n";
 110
 111         $dump_nr++;
 112         my $file = sprintf("dump/%04d-%s.request", $dump_nr, $sock->peerhost);
 113
 114         if ( $self->create_dump ) {
 115                 write_file( $file, $r->as_string );
 116                 warn "### request dumped to file: $file\n";
 117         }
 118
 119         my $state;
 120
 121         if ( $size > 0 ) {
 122
 123                 die "no SOAPAction header in ",dump($xml) unless defined ( $r->header('SOAPAction') );
 124
 125                 warn "## request payload: ",length($xml)," bytes\n$xml\n" if $self->debug;
 126
 127                 $state = CWMP::Request->parse( $xml );
 128
 129                 if ( defined( $state->{_dispatch} ) && $self->create_dump ) {
 130                         my $type = sprintf("dump/%04d-%s-%s", $dump_nr, $sock->peerhost, $state->{_dispatch});
 131                         symlink $file, $type || warn "can't symlink $file -> $type: $!";
 132                 }
 133
 134                 warn "## acquired state = ", dump( $state ), "\n";
 135
 136                 if ( ! defined( $state->{DeviceID} ) ) {
 137                         warn "## state with DeviceID, using old one...\n";
 138                         $state->{DeviceID} = $self->state->{DeviceID};
 139                 }
 140
 141                 $self->state( $state );
 142                 $self->store->update_state( $state );
 143
 144         } else {
 145
 146                 warn "## empty request, using last request state\n";
 147
 148                 $state = $self->state;
 149                 delete( $state->{_dispatch} );
 150                 #warn "last request state = ", dump( $state ), "\n" if $self->debug > 1;
 151         }
 152
 153
 154         $sock->send(join("\r\n",
 155                 'HTTP/1.1 200 OK',
 156                 'Content-Type: text/xml; charset="utf-8"',
 157                 'Server: AcmeCWMP/42',
 158                 'SOAPServer: AcmeCWMP/42'
 159         )."\r\n");
 160
 161         $sock->send( "Set-Cookie: ID=" . $state->{ID} . "; path=/\r\n" ) if ( $state->{ID} );
 162
 163         my $uid = $self->store->state_to_uid( $state );
 164
 165         my $queue = CWMP::Queue->new({
 166                 id => $uid,
 167                 debug => $self->debug,
 168         });
 169         my $job;
 170         $xml = '';
 171
 172         if ( my $dispatch = $state->{_dispatch} ) {
 173                 $xml = $self->dispatch( $dispatch );
 174         } elsif ( $job = $queue->dequeue ) {
 175                 $xml = $self->dispatch( $job->dispatch );
 176         } elsif ( $size == 0 ) {
 177                 warn ">>> no more queued commands, closing connection to $uid\n";
 178                 return 0;
 179         } else {
 180                 warn ">>> empty response to $uid\n";
 181                 $state->{NoMoreRequests} = 1;
 182                 $xml = $self->dispatch( 'xml', sub {} );
 183         }
 184
 185         $sock->send( "Content-Length: " . length( $xml ) . "\r\n\r\n" );
 186         $sock->send( $xml ) or die "can't send response";
 187
 188         warn ">>>> " . $sock->peerhost . " [" . localtime() . "] sent ", length( $xml )," bytes to $uid\n";
 189
 190         $job->finish if $job;
 191         warn "### request over for $uid\n" if $self->debug;
 192
 193         return 1;       # next request
 194 };
 195
 196 =head2 dispatch
 197
 198   $xml = $self->dispatch('Inform', $response_arguments );
 199
 200 If debugging level of 3 or more, it will create dumps of responses named C<< dump/nr.response >>
 201
 202 =cut
 203
 204 sub dispatch {
 205         my $self = shift;
 206
 207         my $dispatch = shift || die "no dispatch?";
 208         my $args = shift;
 209
 210         my $response = CWMP::Methods->new({ debug => $self->debug });
 211
 212         if ( $response->can( $dispatch ) ) {
 213                 warn ">>> dispatching to $dispatch with args ",dump( $args ),"\n";
 214                 my $xml = $response->$dispatch( $self->state, $args );
 215                 warn "## response payload: ",length($xml)," bytes\n$xml\n" if $self->debug;
 216                 if ( $self->create_dump ) {
 217                         my $file = sprintf("dump/%04d-%s.response", $dump_nr++, $self->sock->peerhost);
 218                         write_file( $file, $xml );
 219                         warn "### response dump: $file\n";
 220                 }
 221                 return $xml;
 222         } else {
 223                 confess "can't dispatch to $dispatch";
 224         }
 225 };
 226
 227
 228 =head2 error
 229
 230   return $self->error( 501, 'System error' );
 231
 232 =cut
 233
 234 sub error {
 235   my ($self, $number, $msg) = @_;
 236   $msg ||= 'ERROR';
 237   $self->sock->send( "HTTP/1.1 $number $msg\r\n" );
 238   warn "Error - $number - $msg\n";
 239   return 0;     # close connection
 240 }
 241
 242 1;