lib/CWMP/Session.pm

   1 # Dobrica Pavlinusic, <dpavlin@rot13.org> 06/18/07 10:19:50 CEST
   2 package CWMP::Session;
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/Class::Accessor/;
   8 __PACKAGE__->mk_accessors( qw/
   9 debug
  10 create_dump
  11 session
  12
  13 sock
  14 state
  15 store
  16 / );
  17
  18 use HTTP::Daemon;
  19 use Data::Dump qw/dump/;
  20 use Carp qw/carp confess cluck croak/;
  21 use File::Slurp;
  22
  23 use CWMP::Request;
  24 use CWMP::Methods;
  25 use CWMP::Store;
  26
  27 #use Devel::LeakTrace::Fast;
  28
  29 =head1 NAME
  30
  31 CWMP::Session - implement logic of CWMP protocol
  32
  33 =head1 METHODS
  34
  35 =head2 new
  36
  37   my $server = CWMP::Session->new({
  38         sock => $io_socket_object,
  39         store => { ... },
  40         debug => 1,
  41         create_dump => 1,
  42   });
  43
  44 =cut
  45
  46 sub new {
  47         my $class = shift;
  48         my $self = $class->SUPER::new( @_ );
  49
  50         confess "need sock" unless $self->sock;
  51         confess "need store" unless $self->store;
  52         my $peerhost = $self->sock->peerhost || confess "can't get sock->peerhost";
  53
  54         $self->debug( 0 ) unless $self->debug;
  55
  56         warn "created ", __PACKAGE__, "(", dump( @_ ), ") for $peerhost\n" if $self->debug;
  57
  58         my $store_obj = CWMP::Store->new({
  59                 debug => $self->debug,
  60                 %{ $self->store },
  61         });
  62
  63         croak "can't open ", dump( $self->store ), ": $!" unless $store_obj;
  64
  65         # FIXME looks ugly. Should we have separate accessor for this?
  66         $self->store( $store_obj );
  67
  68         $self->create_dump( 1 ) if $self->debug > 2;
  69
  70         return $self;
  71 }
  72
  73 =head2 process_request
  74
  75 One request from client/response from server cycle. Call multiple times to
  76 facilitate brain-dead concept of adding state to stateless protocol like
  77 HTTP.
  78
  79 If used with debugging level of 3 or more, it will also create dumps of
  80 requests named C<< dump/nr.request >> where C<nr> is number from 0 to total number
  81 of requests in single session.
  82
  83 =cut
  84
  85 my $dump_nr = 0;
  86
  87 sub process_request {
  88         my $self = shift;
  89
  90         my $sock = $self->sock || die "no sock?";
  91
  92 #       die "not IO::Socket::INET but ", ref( $sock ) unless ( ref($sock) eq 'Net::Server::Proto::TCP' );
  93
  94         if ( ! $sock->connected ) {
  95                 warn "SOCKET NOT CONNECTED\n";
  96                 return 0;
  97         }
  98
  99         bless $sock, 'HTTP::Daemon::ClientConn';
 100
 101         # why do I have to do this?
 102         # solution from http://use.perl.org/~Matts/journal/12896
 103         ${*$sock}{'httpd_daemon'} = HTTP::Daemon->new;
 104
 105         my $r = $sock->get_request;
 106
 107         if ( ! $r ) {
 108                 carp "can't get_request";
 109                 return 0;
 110         }
 111
 112         my $xml = $r->content;
 113
 114         my $size = length( $xml );
 115
 116         warn "<<<< ", $sock->peerhost, " [" . localtime() . "] ", $r->method, " ", $r->uri, " $size bytes\n";
 117
 118         $dump_nr++;
 119         my $file = sprintf("dump/%04d-%s.request", $dump_nr, $sock->peerhost);
 120
 121         if ( $self->create_dump ) {
 122                 write_file( $file, $r->as_string );
 123                 warn "### request dumped to file: $file\n" if $self->debug;
 124         }
 125
 126         my $state;
 127
 128         if ( $size > 0 ) {
 129
 130                 die "no SOAPAction header in ",dump($xml) unless defined ( $r->header('SOAPAction') );
 131
 132                 warn "## request payload: ",length($xml)," bytes\n$xml\n" if $self->debug;
 133
 134                 $state = CWMP::Request->parse( $xml );
 135
 136                 if ( defined( $state->{_dispatch} ) && $self->create_dump ) {
 137                         my $type = sprintf("dump/%04d-%s-%s", $dump_nr, $sock->peerhost, $state->{_dispatch});
 138                         symlink $file, $type || warn "can't symlink $file -> $type: $!";
 139                 }
 140
 141                 warn "## acquired state = ", dump( $state ), "\n" if $self->debug;
 142
 143                 if ( ! defined( $state->{DeviceID} ) ) {
 144                         warn "## state with DeviceID, using old one...\n";
 145                         $state->{DeviceID} = $self->state->{DeviceID};
 146                 }
 147
 148                 $self->state( $state );
 149                 $self->store->update_state( $state );
 150
 151         } else {
 152
 153                 warn "## empty request, using last request state\n";
 154
 155                 $state = $self->state;
 156                 delete( $state->{_dispatch} );
 157                 #warn "last request state = ", dump( $state ), "\n" if $self->debug > 1;
 158         }
 159
 160         $sock->send(join("\r\n",
 161                 'HTTP/1.1 200 OK',
 162                 'Content-Type: text/xml; charset="utf-8"',
 163                 'Server: PerlCWMP/42',
 164                 'SOAPServer: PerlCWMP/42'
 165         )."\r\n");
 166
 167         $sock->send( "Set-Cookie: ID=" . $state->{ID} . "; path=/\r\n" ) if ( $state->{ID} );
 168
 169         my $uid = $self->store->state_to_uid( $state );
 170
 171         my $to_uid = join(" ", grep { defined($_) } "to $uid",
 172                         # board
 173                         $state->{Parameter}->{'InternetGatewayDevice.DeviceInfo.HardwareVersion'},
 174                         # version
 175                         $state->{Parameter}->{'InternetGatewayDevice.DeviceInfo.SoftwareVersion'},
 176                         # summary
 177 #                       $state->{Parameter}->{'InternetGatewayDevice.DeviceSummary'},
 178         ) . "\n";
 179
 180         my $queue = CWMP::Queue->new({
 181                 id => $uid,
 182                 debug => $self->debug,
 183         });
 184         my $job;
 185         $xml = '';
 186
 187         if ( my $dispatch = $state->{_dispatch} ) {
 188                 $xml = $self->dispatch( $dispatch );
 189         } elsif ( $job = $queue->dequeue ) {
 190                 $xml = $self->dispatch( $job->dispatch );
 191         } elsif ( $size == 0 ) {
 192                 warn ">>> over, closing connection $to_uid";
 193                 $sock->close;
 194                 return;
 195         } else {
 196                 warn ">>> empty response $to_uid";
 197                 $state->{NoMoreRequests} = 1;
 198                 $xml = $self->dispatch( 'xml', sub {} );
 199         }
 200
 201         $sock->send( "Content-Length: " . length( $xml ) . "\r\n\r\n" );
 202         $sock->send( $xml ) or die "can't send response";
 203
 204         warn ">>>> " . $sock->peerhost . " [" . localtime() . "] sent ", length( $xml )," bytes $to_uid";
 205
 206         $job->finish if $job;
 207         warn "### request over for $uid\n" if $self->debug;
 208
 209         return 1;       # next request
 210 };
 211
 212 =head2 dispatch
 213
 214   $xml = $self->dispatch('Inform', $response_arguments );
 215
 216 If debugging level of 3 or more, it will create dumps of responses named C<< dump/nr.response >>
 217
 218 =cut
 219
 220 sub dispatch {
 221         my $self = shift;
 222
 223         my $dispatch = shift || die "no dispatch?";
 224         my $args = shift;
 225
 226         my $response = CWMP::Methods->new({ debug => $self->debug });
 227
 228         if ( $response->can( $dispatch ) ) {
 229                 warn ">>> dispatching to $dispatch with args ",dump( $args ),"\n";
 230                 my $xml = $response->$dispatch( $self->state, $args );
 231                 warn "## response payload: ",length($xml)," bytes\n$xml\n" if $self->debug;
 232                 if ( $self->create_dump ) {
 233                         my $file = sprintf("dump/%04d-%s.response", $dump_nr++, $self->sock->peerhost);
 234                         write_file( $file, $xml );
 235                         warn "### response dump: $file\n" if $self->debug;
 236                 }
 237                 return $xml;
 238         } else {
 239                 confess "can't dispatch to $dispatch";
 240         }
 241 };
 242
 243
 244 =head2 error
 245
 246   return $self->error( 501, 'System error' );
 247
 248 =cut
 249
 250 sub error {
 251   my ($self, $number, $msg) = @_;
 252   $msg ||= 'ERROR';
 253   $self->sock->send( "HTTP/1.1 $number $msg\r\n" );
 254   warn "Error - $number - $msg\n";
 255   return 0;     # close connection
 256 }
 257
 258 1;