package config;

use warnings;
use strict;
use autodie;

use server;
use pxelinux;
use client;
use File::Slurp;

sub available { qw/debian_live webconverger debirf tinycore nfsroot/ };

sub debian_live {
	my ($ip) = @_;

	upstream::files( qw{
		http://cdimage.debian.org/cdimage/release/current-live/i386/web/
		vmlinuz1
		initrd1.img
		debian-live-501-i386-standard.squashfs
	});

	my $hostname = client::conf( $ip => 'hostname' ) || 'debian-live';

	pxelinux::config_for_ip( $ip, qq{

default debian_live
label debian_live
	kernel vmlinuz1
	append initrd=initrd1.img fetch=http://${server::ip}:7777/debian_live/debian-live-501-i386-standard.squashfs boot=live nopersistent hostname=$hostname union=aufs
	});

}

use upstream;

=head1 webconverger

Webconverger - the opensource Web Kiosk

L<http://webconverger.org/>

=cut

sub webconverger {
	my ($ip) = @_;

	upstream::iso( 'http://download.webconverger.com/webc-5.2.iso' );

	my $homepage = client::conf( $ip => 'homepage', default => "http://${server::ip}:7777/client" );
	my $hostname = client::conf( $ip => 'hostname' ) || 'webconverger';

	pxelinux::config_for_ip( $ip, qq{

default webconverger
label webconverger
	kernel iso/live/vmlinuz-2.6.30-backports.1-486
	append initrd=iso/live/initrd.img-2.6.30-backports.1-486 fetch=http://${server::ip}:7777/webconverger/iso/live/filesystem.squashfs boot=live quiet nosudo splash video=vesa:ywrap,mtrr vga=788 nopersistent username=webc hostname=$hostname union=aufs homepage=$homepage locale=hr

	});

}

=head1 debirf

debirf is a system that will create diskless, all-in-ram images (kernel and initramfs) that boot entirely into ram and leave the user in a fully functional Debian system. 

L<http://cmrg.fifthhorseman.net/wiki/debirf>

=cut

sub debirf {
	my $ip = shift;

	upstream::iso( 'http://cmrg.mayfirst.org/debirf/debirf-rescue_lenny_2.6.26-1-686.iso' );

	pxelinux::config_for_ip( $ip, qq{

default linux
label linux
	kernel iso/vmlinuz-2.6.26-1-686
	append initrd=iso//debirf-rescue_lenny_2.6.26-1-686.cgz

	});
}

sub tinycore {
	my $ip = shift;
	upstream::iso( 'http://distro.ibiblio.org/pub/linux/distributions/tinycorelinux/2.x/release/tinycore_2.2.iso' );
	pxelinux::config_for_ip( $ip, qq{

default linux
label linux
	kernel iso/boot/bzImage
	append initrd=iso/boot/tinycore.gz

	});
}

sub nfsroot {
	my $ip = shift;

	my $nfsroot = "$server::base_dir/tftp/nfsroot";

	if ( ! -e $nfsroot ) {
		system "apt-get install nfs-kernel-server debootstrap";
	
		if ( ! -e $nfsroot ) {
			mkdir $nfsroot;
			system "debootstrap --arch i386 lenny $nfsroot http://ftp.hr.debian.org/debian";
		}

		write_file "$nfsroot/tmp/configure.sh", qq{
echo "do_initrd = Yes" > /etc/kernel-img.conf

# apt-get install kernel-image-686
apt-get install atl2-modules-2.6-686
echo atl2 >> /etc/initramfs-tools/modules

cat /etc/initramfs-tools/initramfs.conf | sed 's/BOOT=local/BOOT=nfs/' > /tmp/initramfs.conf \
	&& mv /tmp/initramfs.conf /etc/initramfs-tools/initramfs.conf

update-initramfs -u -v

};

		system "chroot $nfsroot /tmp/configure.sh";

		open(my $exports, '>>', '/etc/exports');
		print $exports "$nfsroot\t$server::ip/$server::netmask(rw,async,no_root_squash,no_subtree_check)\n";
		close($exports);

		system "exportfs -rva";

	}

	pxelinux::config_for_ip( $ip, qq{

default nfsroot
label nfsroot
	kernel vmlinuz
	append initrd=initrd.img root=/dev/nfs nfsroot=$server::ip:$nfsroot ro ip=dhcp

	});
}

sub for_ip {
	my $ip = shift;
	my $deploy = client::conf( $ip => 'deploy', default => 'webconverger' );
	eval $deploy . '($ip)';
#	$tftp::dir = "$server::base_dir/tftp/$pxelinux::path_prefix";
}

warn 'loaded';

1;
