board/esd/ar405/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   .resetvec 0xFFFFFFFC :
  31   {
  32     *(.resetvec)
  33   } = 0xffff
  34
  35   /* Read-only sections, merged into text segment: */
  36   . = + SIZEOF_HEADERS;
  37   .interp : { *(.interp) }
  38   .hash          : { *(.hash)           }
  39   .dynsym        : { *(.dynsym)         }
  40   .dynstr        : { *(.dynstr)         }
  41   .rel.text      : { *(.rel.text)               }
  42   .rela.text     : { *(.rela.text)      }
  43   .rel.data      : { *(.rel.data)               }
  44   .rela.data     : { *(.rela.data)      }
  45   .rel.rodata    : { *(.rel.rodata)     }
  46   .rela.rodata   : { *(.rela.rodata)    }
  47   .rel.got       : { *(.rel.got)                }
  48   .rela.got      : { *(.rela.got)               }
  49   .rel.ctors     : { *(.rel.ctors)      }
  50   .rela.ctors    : { *(.rela.ctors)     }
  51   .rel.dtors     : { *(.rel.dtors)      }
  52   .rela.dtors    : { *(.rela.dtors)     }
  53   .rel.bss       : { *(.rel.bss)                }
  54   .rela.bss      : { *(.rela.bss)               }
  55   .rel.plt       : { *(.rel.plt)                }
  56   .rela.plt      : { *(.rela.plt)               }
  57   .init          : { *(.init)   }
  58   .plt : { *(.plt) }
  59   .text      :
  60   {
  61     /* WARNING - the following is hand-optimized to fit within  */
  62     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  63
  64     cpu/ppc4xx/start.o          (.text)
  65     cpu/ppc4xx/traps.o          (.text)
  66     cpu/ppc4xx/interrupts.o     (.text)
  67     cpu/ppc4xx/serial.o         (.text)
  68     cpu/ppc4xx/cpu_init.o       (.text)
  69     cpu/ppc4xx/speed.o          (.text)
  70     cpu/ppc4xx/4xx_enet.o       (.text)
  71     common/dlmalloc.o           (.text)
  72     lib_generic/crc32.o         (.text)
  73     lib_ppc/extable.o           (.text)
  74     lib_ppc/board.o             (.text)
  75     lib_generic/zlib.o          (.text)
  76
  77     common/cmd_boot.o           (.text)
  78     common/cmd_bootm.o          (.text)
  79     common/cmd_flash.o          (.text)
  80     common/cmd_mem.o            (.text)
  81     common/cmd_nvedit.o         (.text)
  82     common/console.o            (.text)
  83     common/lists.o              (.text)
  84     common/main.o               (.text)
  85
  86 /*
  87     . = DEFINED(env_offset) ? env_offset : .;
  88     common/environment.o        (.ppcenv)
  89 */
  90     common/environment.o        (.text)
  91
  92     *(.text)
  93     *(.fixup)
  94     *(.got1)
  95   }
  96   _etext = .;
  97   PROVIDE (etext = .);
  98   .rodata    :
  99   {
 100     *(.rodata)
 101     *(.rodata1)
 102     *(.rodata.str1.4)
 103     *(.eh_frame)
 104   }
 105   .fini      : { *(.fini)    } =0
 106   .ctors     : { *(.ctors)   }
 107   .dtors     : { *(.dtors)   }
 108
 109   /* Read-write section, merged into data segment: */
 110   . = (. + 0x00FF) & 0xFFFFFF00;
 111   _erotext = .;
 112   PROVIDE (erotext = .);
 113   .reloc   :
 114   {
 115     *(.got)
 116     _GOT2_TABLE_ = .;
 117     *(.got2)
 118     _FIXUP_TABLE_ = .;
 119     *(.fixup)
 120   }
 121   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
 122   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 123
 124   .data    :
 125   {
 126     *(.data)
 127     *(.data1)
 128     *(.sdata)
 129     *(.sdata2)
 130     *(.dynamic)
 131     CONSTRUCTORS
 132   }
 133   _edata  =  .;
 134   PROVIDE (edata = .);
 135
 136   . = .;
 137   __u_boot_cmd_start = .;
 138   .u_boot_cmd : { *(.u_boot_cmd) }
 139   __u_boot_cmd_end = .;
 140
 141
 142   . = .;
 143   __start___ex_table = .;
 144   __ex_table : { *(__ex_table) }
 145   __stop___ex_table = .;
 146
 147   . = ALIGN(256);
 148   __init_begin = .;
 149   .text.init : { *(.text.init) }
 150   .data.init : { *(.data.init) }
 151   . = ALIGN(256);
 152   __init_end = .;
 153
 154   __bss_start = .;
 155   .bss       :
 156   {
 157    *(.sbss) *(.scommon)
 158    *(.dynbss)
 159    *(.bss)
 160    *(COMMON)
 161   }
 162   _end = . ;
 163   PROVIDE (end = .);
 164 }