board/esd/dasa_sim/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   .resetvec 0xFFFFFFFC :
  31   {
  32     *(.resetvec)
  33   } = 0xffff
  34
  35   /* Read-only sections, merged into text segment: */
  36   . = + SIZEOF_HEADERS;
  37   .interp : { *(.interp) }
  38   .hash          : { *(.hash)           }
  39   .dynsym        : { *(.dynsym)         }
  40   .dynstr        : { *(.dynstr)         }
  41   .rel.text      : { *(.rel.text)               }
  42   .rela.text     : { *(.rela.text)      }
  43   .rel.data      : { *(.rel.data)               }
  44   .rela.data     : { *(.rela.data)      }
  45   .rel.rodata    : { *(.rel.rodata)     }
  46   .rela.rodata   : { *(.rela.rodata)    }
  47   .rel.got       : { *(.rel.got)                }
  48   .rela.got      : { *(.rela.got)               }
  49   .rel.ctors     : { *(.rel.ctors)      }
  50   .rela.ctors    : { *(.rela.ctors)     }
  51   .rel.dtors     : { *(.rel.dtors)      }
  52   .rela.dtors    : { *(.rela.dtors)     }
  53   .rel.bss       : { *(.rel.bss)                }
  54   .rela.bss      : { *(.rela.bss)               }
  55   .rel.plt       : { *(.rel.plt)                }
  56   .rela.plt      : { *(.rela.plt)               }
  57   .init          : { *(.init)   }
  58   .plt : { *(.plt) }
  59   .text      :
  60   {
  61     /* WARNING - the following is hand-optimized to fit within  */
  62     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  63
  64     cpu/ppc4xx/start.o          (.text)
  65     cpu/ppc4xx/traps.o          (.text)
  66     cpu/ppc4xx/interrupts.o     (.text)
  67     cpu/ppc4xx/serial.o         (.text)
  68     cpu/ppc4xx/cpu_init.o       (.text)
  69     cpu/ppc4xx/speed.o          (.text)
  70     common/dlmalloc.o           (.text)
  71     lib_ppc/extable.o           (.text)
  72     lib_ppc/board.o             (.text)
  73     lib_generic/zlib.o          (.text)
  74     lib_generic/crc32.o         (.text)
  75
  76     common/cmd_boot.o           (.text)
  77     common/cmd_bootm.o          (.text)
  78     common/cmd_flash.o          (.text)
  79     common/cmd_mem.o            (.text)
  80     common/cmd_nvedit.o         (.text)
  81     common/console.o            (.text)
  82     common/lists.o              (.text)
  83     common/main.o               (.text)
  84
  85     board/esd/dasa_sim/flash.o  (.text)
  86     common/cmd_nvedit.o (.text)
  87     board/esd/dasa_sim/cmd_dasa_sim.o   (.text)
  88     net/bootp.o (.text)
  89
  90     . = env_offset;
  91     common/environment.o(.text)
  92
  93     *(.text)
  94     *(.fixup)
  95     *(.got1)
  96   }
  97   _etext = .;
  98   PROVIDE (etext = .);
  99   .rodata    :
 100   {
 101     *(.rodata)
 102     *(.rodata1)
 103     *(.rodata.str1.4)
 104     *(.eh_frame)
 105   }
 106   .fini      : { *(.fini)    } =0
 107   .ctors     : { *(.ctors)   }
 108   .dtors     : { *(.dtors)   }
 109
 110   /* Read-write section, merged into data segment: */
 111   . = (. + 0x0FFF) & 0xFFFFF000;
 112   _erotext = .;
 113   PROVIDE (erotext = .);
 114   .reloc   :
 115   {
 116     *(.got)
 117     _GOT2_TABLE_ = .;
 118     *(.got2)
 119     _FIXUP_TABLE_ = .;
 120     *(.fixup)
 121   }
 122   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
 123   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 124
 125   .data    :
 126   {
 127     *(.data)
 128     *(.data1)
 129     *(.sdata)
 130     *(.sdata2)
 131     *(.dynamic)
 132     CONSTRUCTORS
 133   }
 134   _edata  =  .;
 135   PROVIDE (edata = .);
 136
 137   . = .;
 138   __u_boot_cmd_start = .;
 139   .u_boot_cmd : { *(.u_boot_cmd) }
 140   __u_boot_cmd_end = .;
 141
 142
 143   . = .;
 144   __start___ex_table = .;
 145   __ex_table : { *(__ex_table) }
 146   __stop___ex_table = .;
 147
 148   . = ALIGN(4096);
 149   __init_begin = .;
 150   .text.init : { *(.text.init) }
 151   .data.init : { *(.data.init) }
 152   . = ALIGN(4096);
 153   __init_end = .;
 154
 155   __bss_start = .;
 156   .bss       :
 157   {
 158    *(.sbss) *(.scommon)
 159    *(.dynbss)
 160    *(.bss)
 161    *(COMMON)
 162   }
 163   _end = . ;
 164   PROVIDE (end = .);
 165 }