board/hmi1001/u-boot.lds

   1 /*
   2  * (C) Copyright 2003-2004
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   /* Read-only sections, merged into text segment: */
  31   . = + SIZEOF_HEADERS;
  32   .interp : { *(.interp) }
  33   .hash          : { *(.hash)           }
  34   .dynsym        : { *(.dynsym)         }
  35   .dynstr        : { *(.dynstr)         }
  36   .rel.text      : { *(.rel.text)               }
  37   .rela.text     : { *(.rela.text)      }
  38   .rel.data      : { *(.rel.data)               }
  39   .rela.data     : { *(.rela.data)      }
  40   .rel.rodata    : { *(.rel.rodata)     }
  41   .rela.rodata   : { *(.rela.rodata)    }
  42   .rel.got       : { *(.rel.got)                }
  43   .rela.got      : { *(.rela.got)               }
  44   .rel.ctors     : { *(.rel.ctors)      }
  45   .rela.ctors    : { *(.rela.ctors)     }
  46   .rel.dtors     : { *(.rel.dtors)      }
  47   .rela.dtors    : { *(.rela.dtors)     }
  48   .rel.bss       : { *(.rel.bss)                }
  49   .rela.bss      : { *(.rela.bss)               }
  50   .rel.plt       : { *(.rel.plt)                }
  51   .rela.plt      : { *(.rela.plt)               }
  52   .init          : { *(.init)   }
  53   .plt : { *(.plt) }
  54   .text      :
  55   {
  56     /* WARNING - the following is hand-optimized to fit within  */
  57     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  58
  59     cpu/mpc5xxx/start.o          (.text)
  60     cpu/mpc5xxx/traps.o          (.text)
  61     lib_generic/crc32.o         (.text)
  62     lib_ppc/cache.o             (.text)
  63     lib_ppc/time.o              (.text)
  64
  65     . = DEFINED(env_offset) ? env_offset : .;
  66     common/environment.o        (.ppcenv)
  67
  68     *(.text)
  69     *(.fixup)
  70     *(.got1)
  71     . = ALIGN(16);
  72     *(.rodata)
  73     *(.rodata1)
  74     *(.rodata.str1.4)
  75     *(.eh_frame)
  76   }
  77   .fini      : { *(.fini)    } =0
  78   .ctors     : { *(.ctors)   }
  79   .dtors     : { *(.dtors)   }
  80
  81   /* Read-write section, merged into data segment: */
  82   . = (. + 0x0FFF) & 0xFFFFF000;
  83   _erotext = .;
  84   PROVIDE (erotext = .);
  85   .reloc   :
  86   {
  87     *(.got)
  88     _GOT2_TABLE_ = .;
  89     *(.got2)
  90     _FIXUP_TABLE_ = .;
  91     *(.fixup)
  92   }
  93   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  94   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  95
  96   .data    :
  97   {
  98     *(.data)
  99     *(.data1)
 100     *(.sdata)
 101     *(.sdata2)
 102     *(.dynamic)
 103     CONSTRUCTORS
 104   }
 105   _edata  =  .;
 106   PROVIDE (edata = .);
 107
 108   . = .;
 109   __u_boot_cmd_start = .;
 110   .u_boot_cmd : { *(.u_boot_cmd) }
 111   __u_boot_cmd_end = .;
 112
 113
 114   . = .;
 115   __start___ex_table = .;
 116   __ex_table : { *(__ex_table) }
 117   __stop___ex_table = .;
 118
 119   . = ALIGN(4096);
 120   __init_begin = .;
 121   .text.init : { *(.text.init) }
 122   .data.init : { *(.data.init) }
 123   . = ALIGN(4096);
 124   __init_end = .;
 125
 126   __bss_start = .;
 127   .bss       :
 128   {
 129    *(.sbss) *(.scommon)
 130    *(.dynbss)
 131    *(.bss)
 132    *(COMMON)
 133   }
 134   _end = . ;
 135   PROVIDE (end = .);
 136 }