board/linkstation/u-boot.lds

   1 /*
   2  * (C) Copyright 2001
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /*
  26 SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib); SEARCH_DIR(/usr/lib/gcc-lib/ppc-linux/3.3.3);
  27 */
  28 /* Do we need any of these for elf?
  29    __DYNAMIC = 0;    */
  30 SECTIONS
  31 {
  32   /* Read-only sections, merged into text segment: */
  33   . = + SIZEOF_HEADERS;
  34   .interp        : { *(.interp)         }
  35   .hash          : { *(.hash)           }
  36   .dynsym        : { *(.dynsym)         }
  37   .dynstr        : { *(.dynstr)         }
  38   .rel.text      : { *(.rel.text)       }
  39   .rela.text     : { *(.rela.text)      }
  40   .rel.data      : { *(.rel.data)       }
  41   .rela.data     : { *(.rela.data)      }
  42   .rel.rodata    : { *(.rel.rodata)     }
  43   .rela.rodata   : { *(.rela.rodata)    }
  44   .rel.got       : { *(.rel.got)        }
  45   .rela.got      : { *(.rela.got)       }
  46   .rel.ctors     : { *(.rel.ctors)      }
  47   .rela.ctors    : { *(.rela.ctors)     }
  48   .rel.dtors     : { *(.rel.dtors)      }
  49   .rela.dtors    : { *(.rela.dtors)     }
  50   .rel.bss       : { *(.rel.bss)        }
  51   .rela.bss      : { *(.rela.bss)       }
  52   .rel.plt       : { *(.rel.plt)        }
  53   .rela.plt      : { *(.rela.plt)       }
  54   .init          : { *(.init)           }
  55   .plt           : { *(.plt)            }
  56   .text      :
  57   {
  58     cpu/mpc824x/start.o         (.text)
  59     lib_ppc/board.o             (.text)
  60     lib_ppc/ppcstring.o         (.text)
  61     lib_generic/vsprintf.o      (.text)
  62     lib_generic/crc32.o         (.text)
  63     lib_generic/zlib.o          (.text)
  64
  65     . = DEFINED(env_offset) ? env_offset : .;
  66     common/environment.o        (.text)
  67
  68     *(.text)
  69
  70     *(.fixup)
  71     *(.got1)
  72     . = ALIGN(16);
  73     *(.rodata)
  74     *(.rodata1)
  75     *(.rodata.str1.4)
  76     *(.eh_frame)
  77   }
  78   .fini      : { *(.fini)    } =0
  79   .ctors     : { *(.ctors)   }
  80   .dtors     : { *(.dtors)   }
  81
  82   /* Read-write section, merged into data segment: */
  83   . = (. + 0x0FFF) & 0xFFFFF000;
  84   _erotext = .;
  85   PROVIDE (erotext = .);
  86   .reloc   :
  87   {
  88     *(.got)
  89     _GOT2_TABLE_ = .;
  90     *(.got2)
  91     _FIXUP_TABLE_ = .;
  92     *(.fixup)
  93   }
  94   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  95   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  96
  97   .data    :
  98   {
  99     *(.data)
 100     *(.data1)
 101     *(.sdata)
 102     *(.sdata2)
 103     *(.dynamic)
 104     CONSTRUCTORS
 105   }
 106   _edata  =  .;
 107   PROVIDE (edata = .);
 108
 109   . = .;
 110   __u_boot_cmd_start = .;
 111   .u_boot_cmd : { *(.u_boot_cmd) }
 112   __u_boot_cmd_end = .;
 113
 114
 115   . = .;
 116   __start___ex_table = .;
 117   __ex_table : { *(__ex_table) }
 118   __stop___ex_table = .;
 119
 120   . = ALIGN(4096);
 121   __init_begin = .;
 122   .text.init : { *(.text.init) }
 123   .data.init : { *(.data.init) }
 124   . = ALIGN(4096);
 125   __init_end = .;
 126
 127   __bss_start = .;
 128   .bss       :
 129   {
 130    *(.sbss) *(.scommon)
 131    *(.dynbss)
 132    *(.bss)
 133    *(COMMON)
 134   }
 135
 136   _end = . ;
 137   PROVIDE (end = .);
 138 }