board/mpc8560ads/u-boot.lds

   1 /*
   2  * (C) Copyright 2002,2003,Motorola,Inc.
   3  * Xianghua Xiao, X.Xiao@motorola.com.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   .resetvec 0xFFFFFFFC :
  31   {
  32     *(.resetvec)
  33   } = 0xffff
  34
  35   .bootpg 0xFFFFF000 :
  36   {
  37     cpu/mpc85xx/start.o (.bootpg)
  38     board/mpc8560ads/init.o (.bootpg)
  39   } = 0xffff
  40
  41   /* Read-only sections, merged into text segment: */
  42   . = + SIZEOF_HEADERS;
  43   .interp : { *(.interp) }
  44   .hash          : { *(.hash)           }
  45   .dynsym        : { *(.dynsym)         }
  46   .dynstr        : { *(.dynstr)         }
  47   .rel.text      : { *(.rel.text)               }
  48   .rela.text     : { *(.rela.text)      }
  49   .rel.data      : { *(.rel.data)               }
  50   .rela.data     : { *(.rela.data)      }
  51   .rel.rodata    : { *(.rel.rodata)     }
  52   .rela.rodata   : { *(.rela.rodata)    }
  53   .rel.got       : { *(.rel.got)                }
  54   .rela.got      : { *(.rela.got)               }
  55   .rel.ctors     : { *(.rel.ctors)      }
  56   .rela.ctors    : { *(.rela.ctors)     }
  57   .rel.dtors     : { *(.rel.dtors)      }
  58   .rela.dtors    : { *(.rela.dtors)     }
  59   .rel.bss       : { *(.rel.bss)                }
  60   .rela.bss      : { *(.rela.bss)               }
  61   .rel.plt       : { *(.rel.plt)                }
  62   .rela.plt      : { *(.rela.plt)               }
  63   .init          : { *(.init)   }
  64   .plt : { *(.plt) }
  65   .text      :
  66   {
  67     cpu/mpc85xx/start.o (.text)
  68     board/mpc8560ads/init.o (.text)
  69     cpu/mpc85xx/commproc.o (.text)
  70     cpu/mpc85xx/traps.o (.text)
  71     cpu/mpc85xx/interrupts.o (.text)
  72     cpu/mpc85xx/serial_scc.o (.text)
  73     cpu/mpc85xx/ether_fcc.o (.text)
  74     cpu/mpc85xx/cpu_init.o (.text)
  75     cpu/mpc85xx/cpu.o (.text)
  76     cpu/mpc85xx/speed.o (.text)
  77     cpu/mpc85xx/i2c.o (.text)
  78     cpu/mpc85xx/spd_sdram.o (.text)
  79     common/dlmalloc.o (.text)
  80     lib_generic/crc32.o (.text)
  81     lib_ppc/extable.o (.text)
  82     lib_generic/zlib.o (.text)
  83     *(.text)
  84     *(.fixup)
  85     *(.got1)
  86    }
  87     _etext = .;
  88     PROVIDE (etext = .);
  89     .rodata    :
  90    {
  91     *(.rodata)
  92     *(.rodata1)
  93     *(.rodata.str1.4)
  94     *(.eh_frame)
  95   }
  96   .fini      : { *(.fini)    } =0
  97   .ctors     : { *(.ctors)   }
  98   .dtors     : { *(.dtors)   }
  99
 100   /* Read-write section, merged into data segment: */
 101   . = (. + 0x00FF) & 0xFFFFFF00;
 102   _erotext = .;
 103   PROVIDE (erotext = .);
 104   .reloc   :
 105   {
 106     *(.got)
 107     _GOT2_TABLE_ = .;
 108     *(.got2)
 109     _FIXUP_TABLE_ = .;
 110     *(.fixup)
 111   }
 112   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
 113   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
 114
 115   .data    :
 116   {
 117     *(.data)
 118     *(.data1)
 119     *(.sdata)
 120     *(.sdata2)
 121     *(.dynamic)
 122     CONSTRUCTORS
 123   }
 124   _edata  =  .;
 125   PROVIDE (edata = .);
 126
 127   . = .;
 128   __u_boot_cmd_start = .;
 129   .u_boot_cmd : { *(.u_boot_cmd) }
 130   __u_boot_cmd_end = .;
 131
 132   . = .;
 133   __start___ex_table = .;
 134   __ex_table : { *(__ex_table) }
 135   __stop___ex_table = .;
 136
 137   . = ALIGN(256);
 138   __init_begin = .;
 139   .text.init : { *(.text.init) }
 140   .data.init : { *(.data.init) }
 141   . = ALIGN(256);
 142   __init_end = .;
 143
 144   __bss_start = .;
 145   .bss       :
 146   {
 147    *(.sbss) *(.scommon)
 148    *(.dynbss)
 149    *(.bss)
 150    *(COMMON)
 151   }
 152   _end = . ;
 153   PROVIDE (end = .);
 154 }