if ( ! exists("mono") ) {
	set terminal pngcairo color size 600,800
} else {
	set terminal pngcairo mono size 600,800
}

set xdata time
set timefmt "%s"

set xtics format "%H"

set pointsize 0.2

set output '/dev/shm/temp2.png'

unset border

set multiplot
set size 1, 0.5

set origin 0.0, 0.5

if ( ! exists("t_mean")) {

t_mean=25
t_spread=25

h_mean = 50
h_spread = 30

print "using default mean and spread"
}

min_t = t_mean - t_spread
max_t = t_mean + t_spread

set ytics nomirror
set y2tics

plot "/dev/shm/DS18B20-temperature" using ($1+7200):($2 > min_t && $2 < max_t ? $2 : '') with dots title "DS18B20 deg. C" \
,"/dev/shm/DHT22-temperature" using ($1+7200):($2 > min_t && $2 < max_t ? $2 : '') with dots title "DHT22 deg. C" \
,"/dev/shm/rtl_433-temperature" using ($1+7200):($2) with dots title "RTL433 deg. C"

set origin 0.0, 0.0


min_h = h_mean - h_spread
max_h = h_mean + h_spread

plot "/dev/shm/DHT22-humidity" using ($1+7200):($2 > min_h && $2 < max_h ? $2 : '') with dots title "DHT22 % hum" \
,"/dev/shm/rtl_433-humidity" using ($1+7200):($2) with dots title "RTL433 % hum" 

unset multiplot