#!/usr/bin/perl

use warnings;
use strict;

use CGI qw/:standard/;
use CGI::Carp qw/fatalsToBrowser/;
use File::Slurp;
use YAML;
use Data::Page;
use Data::Dump qw/dump/;
use SWISH::API;
use JSON;

my $range_around = 5;
my $entries_per_page = 30;
my $debug = param('debug');

print header(
	-charset => 'utf-8',
);

sub dump_yaml {
	my $name = shift;
	print qq|<pre># $name\n|, YAML::Dump( @_ ), qq|</pre>| if $debug;
}

sub show_pager {
	my ($pager) = @_;

	my @show_pages;
	my $after_current = 0;

	if ( $pager->current_page <= $range_around + 2 ) {
		@show_pages = ( $pager->first_page .. $pager->current_page );
		$after_current = $range_around - $pager->current_page;
	} else {
		@show_pages = ( $pager->first_page, '', $pager->current_page - $range_around .. $pager->current_page );
	}

	if ( $pager->current_page + $after_current + $range_around + 1 >= $pager->last_page ) {
		push @show_pages, ( $pager->current_page + 1 .. $pager->last_page );
	} else {
		push @show_pages, ( $pager->current_page + 1 .. $pager->current_page + $after_current + $range_around, '', $pager->last_page );
	}

#	dump_yaml( 'show_pages', \@show_pages );

	return '' unless $#show_pages;

	my ( $prev, $next ) = ( '&lt;&lt;', '&gt;&gt;' );

	sub li_a_href {
		my ( $page, $label, $attr ) = @_;
		param( 'current_page', $page );
		my $url = self_url( -query => 1 );
		$attr ||= '';
		$label ||= $page;
		qq|<li$attr><a href="$url" title="$page">$label</a></li>|;
	}

	return
		  $pager->previous_page ? li_a_href( $pager->previous_page, $prev ) : qq|<li class=skip>$prev</li>|
		, ( map {
			if ( $_ eq $pager->current_page ) {
				qq|<li class=current_page>$_</li>|;
			} elsif ( $_ eq '' ) {
				qq|<li class=skip>...</li>|;
			} else {
				li_a_href( $_ );
			}
		} @show_pages )
		, $pager->next_page ? li_a_href( $pager->next_page, $next ) : qq|<li class=skip>$next</li>|
		;
		
}

my $path = $ENV{PATH_INFO} || 'ecas';
my $dir = $0;
$dir =~ s{/[^/]+.cgi}{};

my $config = YAML::LoadFile( "$dir/$path/config.yml" );

my $database = (keys %{ $config->{databases} })[0];
die "$database not in $path" unless $path =~ m{\Q$database\E};

my $html_markup = "$dir/$path/html.pm";
my $html_markup_skip;
if ( -e $html_markup ) {
	require $html_markup;
	$html_markup = $database . '::html';
} else {
	undef $html_markup;
}

my $estraier = YAML::LoadFile( "$dir/../var/estraier/$database.yaml" );

my $db = $config->{databases}->{$database};

my @attr = keys %{ $estraier->{attr} }; # FIXME replace with real gnerated lookup

print
	start_html(
		-title => $db->{name},
		-style => '../../style.css',
	),
	h1( $db->{name} ),
	qq|<div id=description>|, $db->{description}, qq|</div>|,
	start_form( -action => self_url( query => 0 ) ),
		radio_group(
			-name => 'attr',
			-values => [ @attr ],
#			-linebreak => 0,
		),
		textfield( -name => 'search' ),
		popup_menu( -name => 'attr_operator', -values => [ '', 'STRBW', 'STREQ' ],
			-labels => {
				'' => 'Bilo koja riječ',
				'STRBW' => 'Početak',
				'STREQ' => 'Točan oblik',
			},
		),
		submit,
		hidden( -name => 'entries_per_page', -default => $entries_per_page ),
		hidden( -name => 'current_page', -default => 1 ),
		checkbox( -name => 'debug', -default => 0 ), # FIXME hidden?
		qq|<div id=inputs>|,
		h2( 'Select input' ),
		checkbox_group(
			-name => 'only_input',
			-values => [ map { $_->{name} } @{ $db->{input} } ],
			-linebreak=> 'true',
		),
		qq|</div>|,

;

dump_yaml( 'inputs', $db->{input} );
dump_yaml( 'input names', map { $_->{name} } @{ $db->{input} } );

print	end_form;

if ( my $search = param('search') ) {

	print qq|<div id="results">|;

	my $swish = SWISH::API->new( "$dir/../var/swish/$database" );
	$swish->abort_last_error if $swish->Error;

	param( 'entries_per_page', $entries_per_page ) unless param('entries_per_page'); # FIXME not needed?
	my $pager = Data::Page->new;
	$pager->total_entries( param('current_page') * param('entries_per_page') );
	$pager->$_( param($_) ) foreach ( qw/entries_per_page current_page/ );

	dump_yaml( 'pager', $pager );

	my @search = ( "xml=$search" );

#	if ( my $op = param('attr_operator') ) {
#		$cond->add_attr( param('attr') . " $op " . param('search') );
#	}

	my @only_input = param('only_input');

	push @search, '(' . join(') or (', @only_input) . ')' if @only_input;

	my $q = '(' . join(') and (', @search) . ')';
	warn "# query: $q\n";
	my $swish_results = $swish->query( $q );
	$swish->abort_last_error if $swish->Error;

	dump_yaml( 'swish_results', $swish_results );

	$pager->total_entries( $swish_results->hits );

	if ( ! $pager->total_entries ) {
		my $no_results = "No results for search '%s'";
		printf qq|<div class="error">$no_results</div>\n\n|, $search;
	} else {

		my $results = "<b>%d</b> results for search <b>%s</b> showing results %d - %d";
		printf qq|<div class="message">$results</div>\n\n|, $pager->total_entries, $search, $pager->first, $pager->last;

		my $pager_html = join("\n", show_pager( $pager ));

		print qq|<ul class="pager">$pager_html</ul>\n\n| if $pager_html;

		my $start = $pager->first;
		print qq|<ol start=$start>\n|;

		while ( my $result = $swish_results->next_result ) {
			my $data = from_json $result->property('data');

			print qq|<li>|;
			foreach my $attr ( @attr ) {
				next unless defined $data->{$attr};
				my $v = $data->{$attr};
				if ( $html_markup && ! $html_markup_skip->{$attr} ) {
					eval "\$v = $html_markup->$attr( \$v );";
					if ( $@ ) {
						warn "disable html markup for $attr: $@";
						$html_markup_skip->{$attr} = $@;
					}
				}
				print qq|<div><label>$attr</label><span class=$attr>$v</span></div>\n|;
			}
			print qq|</li>\n|;
		}
		print qq|</ol>\n\n|;

		print qq|<ul class="pager bottom">$pager_html</ul>\n\n| if $pager_html;
	}
	print qq|</div>|;

	dump_yaml( 'pager', $pager );

}

dump_yaml( 'db', $db );
dump_yaml( 'html_markup_skip', $html_markup_skip );

print	end_html;