#!/usr/bin/perl

use warnings;
use strict;

use CGI qw/:standard/;
use CGI::Carp qw/fatalsToBrowser/;
use File::Slurp;
use YAML;
use Search::Estraier;

print header;

sub dump_yaml {
	my $name = shift;
	print qq|<pre># $name\n|, YAML::Dump( @_ ), qq|</pre>|;
}

my $path = $ENV{PATH_INFO};
my $dir = $0;
$dir =~ s{/[^/]+.cgi}{};

my $config = YAML::LoadFile( "$dir/$path/config.yml" );

my $database = (keys %{ $config->{databases} })[0];
die "$database not in $path" unless $path =~ m{\Q$database\E};

my $estraier = YAML::LoadFile( "$dir/../var/estraier/$database.yaml" );

my $db = $config->{databases}->{$database};

my @attr = keys %{ $estraier->{attr} }; # FIXME replace with real gnerated lookup

print
	start_html(
		-title => $db->{name},
		-style => '../../style.css',
	),
	h1( $db->{name} ),
	qq|<div id=description>|, $db->{description}, qq|</div>|,
	start_form,
		radio_group(
			-name => 'attr',
			-values => [ @attr ],
#			-linebreak => 0,
		),
		textfield( -name => 'search' ),
		submit
;

print	end_form;

if ( my $search = param('search') ) {

	print qq|<div id="results">|;

	my $node = Search::Estraier::Node->new(
		url => $config->{hyperestraier}->{masterurl} . '/node/' . $database,
		croak_on_error => 1,
	);

	my $cond = Search::Estraier::Condition->new;
	$cond->set_phrase( $search );
	my $nres = $node->search( $cond, 0 );

	if ( ! $nres ) {
		my $no_results = "No results for search '%s'";
		printf qq|<div class="error">$no_results</div>|, $search;
	} else {
		my $results = "Got %d results for search '%s'";
		printf qq|<div class="message">$results</div>|, $nres->hits, $search;

		print qq|<ol>|;

		foreach my $i ( 1 .. $nres->doc_num ) {
			my $rdoc = $nres->get_doc( $i - 1 );
			print qq|<li>|;
			print qq|<div><label>$_</label><span class=$_>|, $rdoc->attr( $_ ), qq|</span></div>|
				foreach @attr;
			print qq|</li>\n|;
		}
		print qq|</ol>|;
	}
	print qq|</div>|;
}

dump_yaml( 'estraier', $estraier );
dump_yaml( 'db', $db );

print	end_html;