#set terminal pngcairo color size 800,600
#set output
set terminal canvas size 800,600 standalone mousing jsdir 'gnuplot' title 'Bakaceva 3'
# dpavlin@subvision:~/zc/www$ ln -sf /usr/share/gnuplot/gnuplot/5.4/js gnuplot
set output '/home/dpavlin/zc/www/location.html'

set xdata time
set timefmt "%Y-%m-%d %H:%M:%S"

set datafile separator ","

set grid
set key outside tmargin center

set format x ""

set multiplot layout 3,1

set lmargin at screen 0.125


set ylabel "X degrees"

# https://stackoverflow.com/questions/9082807/gnuplot-plot-points-with-color-based-values-in-one-string-column-and-show-strin

map_color(pn) = ( \
pn == 2012230015 ? 0xff0000 : \
pn == 2009210010 ? 0x00ff00 : \
pn == 2008050077 ? 0x0000ff : \
pn == 2012230028 ? 0xff00ff : \
pn == 2012230011 ? 0x00ffff : \
0xff00ff )

plot "/dev/shm/location.txt" using 1:2:(map_color($6)) with points notitle linecolor rgbcolor variable pointtype 0

set tmargin 0

set ylabel "Y degrees"
plot "/dev/shm/location.txt" using 1:3:(map_color($6)) with points notitle linecolor rgbcolor variable pointtype 0

set tmargin 0

set xlabel "time"
set format x "%d.%m."

set ylabel "celsius"
set yrange [ * : * ]

plot "/dev/shm/location.txt" using 1:4:(map_color($6)) with points notitle lc rgbcolor variable pointtype 0