bin/BackupPC_dump

   1 #!/bin/perl -T
   2 #============================================================= -*-perl-*-
   3 #
   4 # BackupPC_dump: Dump a single client.
   5 #
   6 # DESCRIPTION
   7 #
   8 #   Usage: BackupPC_dump [-i] [-f] [-d] [-e] [-v] <client>
   9 #
  10 #   Flags:
  11 #
  12 #     -i   Do an incremental dump, overriding any scheduling (but a full
  13 #          dump will be done if no dumps have yet succeeded)
  14 #
  15 #     -f   Do a full dump, overriding any scheduling.
  16 #
  17 #     -d   Host is a DHCP pool address, and the client argument
  18 #          just an IP address.  We lookup the NetBios name from
  19 #          the IP address.
  20 #
  21 #     -e   Just do an dump expiry check for the client.  Don't do anything
  22 #          else.  This is used periodically by BackupPC to make sure that
  23 #          dhcp hosts have correctly expired old backups.  Without this,
  24 #          dhcp hosts that are no longer on the network will not expire
  25 #          old backups.
  26 #
  27 #     -v   verbose.  for manual usage: prints failure reasons in more detail.
  28 #
  29 #   BackupPC_dump is run periodically by BackupPC to backup $client.
  30 #   The file $TopDir/pc/$client/backups is read to decide whether a
  31 #   full or incremental backup needs to be run.  If no backup is
  32 #   scheduled, or a ping to $client fails, then BackupPC_dump quits.
  33 #
  34 #   The backup is done using the selected XferMethod (smb, tar, rsync etc),
  35 #   extracting the dump into $TopDir/pc/$client/new.  The xfer output is
  36 #   put into $TopDir/pc/$client/XferLOG.
  37 #
  38 #   If the dump succeeds (based on parsing the output of the XferMethod):
  39 #     - $TopDir/pc/$client/new is renamed to $TopDir/pc/$client/nnn, where
  40 #           nnn is the next sequential dump number.
  41 #     - $TopDir/pc/$client/XferLOG is renamed to $TopDir/pc/$client/XferLOG.nnn.
  42 #     - $TopDir/pc/$client/backups is updated.
  43 #
  44 #   If the dump fails:
  45 #     - $TopDir/pc/$client/new is moved to $TopDir/trash for later removal.
  46 #     - $TopDir/pc/$client/XferLOG is renamed to $TopDir/pc/$client/XferLOG.bad
  47 #           for later viewing.
  48 #
  49 #   BackupPC_dump communicates to BackupPC via printing to STDOUT.
  50 #
  51 # AUTHOR
  52 #   Craig Barratt  <cbarratt@users.sourceforge.net>
  53 #
  54 # COPYRIGHT
  55 #   Copyright (C) 2001  Craig Barratt
  56 #
  57 #   This program is free software; you can redistribute it and/or modify
  58 #   it under the terms of the GNU General Public License as published by
  59 #   the Free Software Foundation; either version 2 of the License, or
  60 #   (at your option) any later version.
  61 #
  62 #   This program is distributed in the hope that it will be useful,
  63 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  64 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  65 #   GNU General Public License for more details.
  66 #
  67 #   You should have received a copy of the GNU General Public License
  68 #   along with this program; if not, write to the Free Software
  69 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  70 #
  71 #========================================================================
  72 #
  73 # Version 2.0.0beta3, released 1 Jun 2003.
  74 #
  75 # See http://backuppc.sourceforge.net.
  76 #
  77 #========================================================================
  78
  79 use strict;
  80 use lib "/usr/local/BackupPC/lib";
  81 use BackupPC::Lib;
  82 use BackupPC::FileZIO;
  83 use BackupPC::Xfer::Smb;
  84 use BackupPC::Xfer::Tar;
  85 use BackupPC::Xfer::Rsync;
  86 use Socket;
  87 use File::Path;
  88 use Getopt::Std;
  89
  90 ###########################################################################
  91 # Initialize
  92 ###########################################################################
  93
  94 die("BackupPC::Lib->new failed\n") if ( !(my $bpc = BackupPC::Lib->new) );
  95 my $TopDir = $bpc->TopDir();
  96 my $BinDir = $bpc->BinDir();
  97 my %Conf   = $bpc->Conf();
  98 my $NeedPostCmd;
  99 my $Hosts;
 100
 101 $bpc->ChildInit();
 102
 103 my %opts;
 104 if ( !getopts("defiv", \%opts) || @ARGV != 1 ) {
 105     print("usage: $0 [-d] [-e] [-f] [-i] [-v] <client>\n");
 106     exit(1);
 107 }
 108 if ( $ARGV[0] !~ /^([\w\.\s-]+)$/ ) {
 109     print("$0: bad client name '$ARGV[0]'\n");
 110     exit(1);
 111 }
 112 my $client = $1;   # BackupPC's client name (might not be real host name)
 113 my $hostIP;        # this is the IP address
 114 my $host;          # this is the real host name
 115
 116 my($clientURI, $user);
 117
 118 $bpc->verbose(1) if ( $opts{v} );
 119
 120 if ( $opts{d} ) {
 121     #
 122     # The client name $client is simply a DHCP address.  We need to check
 123     # if there is any machine at this address, and if so, get the actual
 124     # host name via NetBios using nmblookup.
 125     #
 126     $hostIP = $client;
 127     if ( $bpc->CheckHostAlive($hostIP) < 0 ) {
 128         print("Exiting because CheckHostAlive($hostIP) failed\n")
 129                             if ( $opts{v} );
 130         exit(1);
 131     }
 132     if ( $Conf{NmbLookupCmd} eq "" ) {
 133         print("Exiting because \$Conf{NmbLookupCmd} is empty\n")
 134                             if ( $opts{v} );
 135         exit(1);
 136     }
 137     ($client, $user) = $bpc->NetBiosInfoGet($hostIP);
 138     if ( $client !~ /^([\w\.\s-]+)$/ ) {
 139         print("Exiting because NetBiosInfoGet($hostIP) returned '$client',"
 140             . " an invalid host name\n")
 141                             if ( $opts{v} );
 142         exit(1)
 143     }
 144     $Hosts = $bpc->HostInfoRead($client);
 145     $host = $client;
 146 } else {
 147     $Hosts = $bpc->HostInfoRead($client);
 148 }
 149 if ( !defined($Hosts->{$client}) ) {
 150     print("Exiting because host $client does not exist in the hosts file\n")
 151                             if ( $opts{v} );
 152     exit(1)
 153 }
 154
 155 my $Dir     = "$TopDir/pc/$client";
 156 my @xferPid = ();
 157 my $tarPid  = -1;
 158
 159 #
 160 # Re-read config file, so we can include the PC-specific config
 161 #
 162 $clientURI = $bpc->uriEsc($client);
 163 if ( defined(my $error = $bpc->ConfigRead($client)) ) {
 164     print("dump failed: Can't read PC's config file: $error\n");
 165     exit(1);
 166 }
 167 %Conf = $bpc->Conf();
 168
 169 #
 170 # Catch various signals
 171 #
 172 $SIG{INT}  = \&catch_signal;
 173 $SIG{ALRM} = \&catch_signal;
 174 $SIG{TERM} = \&catch_signal;
 175 $SIG{PIPE} = \&catch_signal;
 176 $SIG{STOP} = \&catch_signal;
 177 $SIG{TSTP} = \&catch_signal;
 178 $SIG{TTIN} = \&catch_signal;
 179 my $Pid = $$;
 180
 181 #
 182 # Make sure we eventually timeout if there is no activity from
 183 # the data transport program.
 184 #
 185 alarm($Conf{ClientTimeout});
 186
 187 mkpath($Dir, 0, 0777) if ( !-d $Dir );
 188 if ( !-f "$Dir/LOCK" ) {
 189     open(LOCK, ">", "$Dir/LOCK") && close(LOCK);
 190 }
 191 open(LOG, ">>", "$Dir/LOG");
 192 select(LOG); $| = 1; select(STDOUT);
 193
 194 #
 195 # For the -e option we just expire backups and quit
 196 #
 197 if ( $opts{e} ) {
 198     BackupExpire($client);
 199     exit(0);
 200 }
 201
 202 if ( !$opts{d} ) {
 203     #
 204     # In the non-DHCP case, make sure the host can be looked up
 205     # via NS, or otherwise find the IP address via NetBios.
 206     #
 207     if ( $Conf{ClientNameAlias} ne "" ) {
 208         $host = $Conf{ClientNameAlias};
 209     } else {
 210         $host = $client;
 211     }
 212     if ( !defined(gethostbyname($host)) ) {
 213         #
 214         # Ok, NS doesn't know about it.  Maybe it is a NetBios name
 215         # instead.
 216         #
 217         print("Name server doesn't know about $host; trying NetBios\n")
 218                         if ( $opts{v} );
 219         if ( !defined($hostIP = $bpc->NetBiosHostIPFind($host)) ) {
 220             print(LOG $bpc->timeStamp, "Can't find host $host via netbios\n");
 221             print("host not found\n");
 222             exit(1);
 223         }
 224     } else {
 225         $hostIP = $host;
 226     }
 227 }
 228
 229 ###########################################################################
 230 # Figure out what to do and do it
 231 ###########################################################################
 232
 233 #
 234 # See if we should skip this host during a certain range
 235 # of times.
 236 #
 237 my $err = $bpc->ServerConnect($Conf{ServerHost}, $Conf{ServerPort});
 238 if ( $err ne "" ) {
 239     print("Can't connect to server ($err)\n");
 240     print(LOG $bpc->timeStamp, "Can't connect to server ($err)\n");
 241     exit(1);
 242 }
 243 my $reply = $bpc->ServerMesg("status host($clientURI)");
 244 $reply = $1 if ( $reply =~ /(.*)/s );
 245 my(%StatusHost);
 246 eval($reply);
 247 $bpc->ServerDisconnect();
 248
 249 #
 250 # For DHCP tell BackupPC which host this is
 251 #
 252 if ( $opts{d} ) {
 253     if ( $StatusHost{activeJob} ) {
 254         # oops, something is already running for this host
 255         print("Exiting because backup is already running for $client\n")
 256                         if ( $opts{v} );
 257         exit(0);
 258     }
 259     print("DHCP $hostIP $clientURI\n");
 260 }
 261
 262 my($needLink, @Backups, $type, $lastBkupNum, $lastFullBkupNum);
 263 my $lastFull = 0;
 264 my $lastIncr = 0;
 265
 266 if ( $Conf{FullPeriod} == -1 && !$opts{f} && !$opts{i}
 267         || $Conf{FullPeriod} == -2 ) {
 268     NothingToDo($needLink);
 269 }
 270
 271 if ( !$opts{i} && !$opts{f} && $Conf{BlackoutGoodCnt} >= 0
 272              && $StatusHost{aliveCnt} >= $Conf{BlackoutGoodCnt} ) {
 273     my($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime(time);
 274     my($currHours) = $hour + $min / 60 + $sec / 3600;
 275     if ( $Conf{BlackoutHourBegin} <= $currHours
 276               && $currHours <= $Conf{BlackoutHourEnd}
 277               && grep($_ == $wday, @{$Conf{BlackoutWeekDays}}) ) {
 278 #        print(LOG $bpc->timeStamp, "skipping because of blackout"
 279 #                    . " (alive $StatusHost{aliveCnt} times)\n");
 280         NothingToDo($needLink);
 281     }
 282 }
 283
 284 if ( !$opts{i} && !$opts{f} && $StatusHost{backoffTime} > time ) {
 285     printf(LOG "%sskipping because of user requested delay (%.1f hours left)",
 286                 $bpc->timeStamp, ($StatusHost{backoffTime} - time) / 3600);
 287     NothingToDo($needLink);
 288 }
 289
 290 #
 291 # Now see if there are any old backups we should delete
 292 #
 293 BackupExpire($client);
 294
 295 #
 296 # Read Backup information, and find times of the most recent full and
 297 # incremental backups
 298 #
 299 @Backups = $bpc->BackupInfoRead($client);
 300 for ( my $i = 0 ; $i < @Backups ; $i++ ) {
 301     $needLink = 1 if ( $Backups[$i]{nFilesNew} eq ""
 302                         || -f "$Dir/NewFileList.$Backups[$i]{num}" );
 303     $lastBkupNum = $Backups[$i]{num};
 304     if ( $Backups[$i]{type} eq "full" ) {
 305         if ( $lastFull < $Backups[$i]{startTime} ) {
 306             $lastFull = $Backups[$i]{startTime};
 307             $lastFullBkupNum = $Backups[$i]{num};
 308         }
 309     } else {
 310         $lastIncr = $Backups[$i]{startTime}
 311                 if ( $lastIncr < $Backups[$i]{startTime} );
 312     }
 313 }
 314
 315 #
 316 # Decide whether we do nothing, or a full or incremental backup.
 317 #
 318 if ( @Backups == 0
 319         || $opts{f}
 320         || (!$opts{i} && (time - $lastFull > $Conf{FullPeriod} * 24*3600
 321             && time - $lastIncr > $Conf{IncrPeriod} * 24*3600)) ) {
 322     $type = "full";
 323 } elsif ( $opts{i} || (time - $lastIncr > $Conf{IncrPeriod} * 24*3600
 324         && time - $lastFull > $Conf{IncrPeriod} * 24*3600) ) {
 325     $type = "incr";
 326 } else {
 327     NothingToDo($needLink);
 328 }
 329
 330 #
 331 # Check if $host is alive
 332 #
 333 my $delay = $bpc->CheckHostAlive($hostIP);
 334 if ( $delay < 0 ) {
 335     print(LOG $bpc->timeStamp, "no ping response\n");
 336     print("no ping response\n");
 337     print("link $clientURI\n") if ( $needLink );
 338     exit(1);
 339 } elsif ( $delay > $Conf{PingMaxMsec} ) {
 340     printf(LOG "%sping too slow: %.4gmsec\n", $bpc->timeStamp, $delay);
 341     printf("ping too slow: %.4gmsec (threshold is %gmsec)\n",
 342                     $delay, $Conf{PingMaxMsec});
 343     print("link $clientURI\n") if ( $needLink );
 344     exit(1);
 345 }
 346
 347 #
 348 # Make sure it is really the machine we expect (only for fixed addresses,
 349 # since we got the DHCP address above).
 350 #
 351 if ( !$opts{d} && (my $errMsg = CorrectHostCheck($hostIP, $host)) ) {
 352     print(LOG $bpc->timeStamp, "dump failed: $errMsg\n");
 353     print("dump failed: $errMsg\n");
 354     exit(1);
 355 } elsif ( $opts{d} ) {
 356     print(LOG $bpc->timeStamp, "$host is dhcp $hostIP, user is $user\n");
 357 }
 358
 359 #
 360 # Get a clean directory $Dir/new
 361 #
 362 $bpc->RmTreeDefer("$TopDir/trash", "$Dir/new") if ( -d "$Dir/new" );
 363
 364 #
 365 # Setup file extension for compression and open XferLOG output file
 366 #
 367 $Conf{CompressLevel} = 0 if ( !BackupPC::FileZIO->compOk );
 368 my $fileExt = $Conf{CompressLevel} > 0 ? ".z" : "";
 369 my $XferLOG = BackupPC::FileZIO->open("$Dir/XferLOG$fileExt", 1,
 370                                      $Conf{CompressLevel});
 371 if ( !defined($XferLOG) ) {
 372     print(LOG $bpc->timeStamp, "dump failed: unable to open/create"
 373                              . " $Dir/XferLOG$fileExt\n");
 374     print("dump failed: unable to open/create $Dir/XferLOG$fileExt\n");
 375     exit(1);
 376 }
 377 $XferLOG->writeTeeStdout(1) if ( $opts{v} );
 378 unlink("$Dir/NewFileList");
 379 my $startTime = time();
 380
 381 my $tarErrs       = 0;
 382 my $nFilesExist   = 0;
 383 my $sizeExist     = 0;
 384 my $sizeExistComp = 0;
 385 my $nFilesTotal   = 0;
 386 my $sizeTotal     = 0;
 387 my($logMsg, %stat, $xfer, $ShareNames);
 388 my $newFilesFH;
 389
 390 if ( $Conf{XferMethod} eq "tar" ) {
 391     $ShareNames = $Conf{TarShareName};
 392 } elsif ( $Conf{XferMethod} eq "rsync" || $Conf{XferMethod} eq "rsyncd" ) {
 393     $ShareNames = $Conf{RsyncShareName};
 394 } else {
 395     $ShareNames = $Conf{SmbShareName};
 396 }
 397
 398 $ShareNames = [ $ShareNames ] unless ref($ShareNames) eq "ARRAY";
 399
 400 #
 401 # Run an optional pre-dump command
 402 #
 403 UserCommandRun("DumpPreUserCmd");
 404 $NeedPostCmd = 1;
 405
 406 #
 407 # Now backup each of the shares
 408 #
 409 for my $shareName ( @$ShareNames ) {
 410     local(*RH, *WH);
 411
 412     $stat{xferOK} = $stat{hostAbort} = undef;
 413     $stat{hostError} = $stat{lastOutputLine} = undef;
 414     if ( -d "$Dir/new/$shareName" ) {
 415         print(LOG $bpc->timeStamp,
 416                   "unexpected repeated share name $shareName skipped\n");
 417         next;
 418     }
 419
 420     if ( $Conf{XferMethod} eq "tar" ) {
 421         #
 422         # Use tar (eg: tar/ssh) as the transport program.
 423         #
 424         $xfer = BackupPC::Xfer::Tar->new($bpc);
 425     } elsif ( $Conf{XferMethod} eq "rsync" || $Conf{XferMethod} eq "rsyncd" ) {
 426         #
 427         # Use rsync as the transport program.
 428         #
 429         if ( !defined($xfer = BackupPC::Xfer::Rsync->new($bpc)) ) {
 430             my $errStr = BackupPC::Xfer::Rsync::errStr;
 431             print(LOG $bpc->timeStamp, "dump failed: $errStr\n");
 432             print("dump failed: $errStr\n");
 433             UserCommandRun("DumpPostUserCmd") if ( $NeedPostCmd );
 434             exit(1);
 435         }
 436     } else {
 437         #
 438         # Default is to use smbclient (smb) as the transport program.
 439         #
 440         $xfer = BackupPC::Xfer::Smb->new($bpc);
 441     }
 442
 443     my $useTar = $xfer->useTar;
 444
 445     if ( $useTar ) {
 446         #
 447         # This xfer method outputs a tar format file, so we start a
 448         # BackupPC_tarExtract to extract the data.
 449         #
 450         # Create a socketpair to connect the Xfer method to BackupPC_tarExtract
 451         # WH is the write handle for writing, provided to the transport
 452         # program, and RH is the other end of the socket for reading,
 453         # provided to BackupPC_tarExtract.
 454         #
 455         if ( socketpair(RH, WH, AF_UNIX, SOCK_STREAM, PF_UNSPEC) ) {
 456             shutdown(RH, 1);    # no writing to this socket
 457             shutdown(WH, 0);    # no reading from this socket
 458             setsockopt(RH, SOL_SOCKET, SO_RCVBUF, 8 * 65536);
 459             setsockopt(WH, SOL_SOCKET, SO_SNDBUF, 8 * 65536);
 460         } else {
 461             #
 462             # Default to pipe() if socketpair() doesn't work.
 463             #
 464             pipe(RH, WH);
 465         }
 466
 467         #
 468         # fork a child for BackupPC_tarExtract.  TAR is a file handle
 469         # on which we (the parent) read the stdout & stderr from
 470         # BackupPC_tarExtract.
 471         #
 472         if ( !defined($tarPid = open(TAR, "-|")) ) {
 473             print(LOG $bpc->timeStamp, "can't fork to run tar\n");
 474             print("can't fork to run tar\n");
 475             close(RH);
 476             close(WH);
 477             last;
 478         }
 479         if ( !$tarPid ) {
 480             #
 481             # This is the tar child.  Close the write end of the pipe,
 482             # clone STDERR to STDOUT, clone STDIN from RH, and then
 483             # exec BackupPC_tarExtract.
 484             #
 485             setpgrp 0,0;
 486             close(WH);
 487             close(STDERR);
 488             open(STDERR, ">&STDOUT");
 489             close(STDIN);
 490             open(STDIN, "<&RH");
 491             exec("$BinDir/BackupPC_tarExtract", $client, $shareName,
 492                          $Conf{CompressLevel});
 493             print(LOG $bpc->timeStamp,
 494                         "can't exec $BinDir/BackupPC_tarExtract\n");
 495             exit(0);
 496         }
 497     } elsif ( !defined($newFilesFH) ) {
 498         #
 499         # We need to create the NewFileList output file
 500         #
 501         local(*NEW_FILES);
 502         open(NEW_FILES, ">", "$TopDir/pc/$client/NewFileList")
 503                      || die("can't open $TopDir/pc/$client/NewFileList");
 504         $newFilesFH = *NEW_FILES;
 505     }
 506
 507     #
 508     # Run the transport program
 509     #
 510     $xfer->args({
 511         host        => $host,
 512         client      => $client,
 513         hostIP      => $hostIP,
 514         shareName   => $shareName,
 515         pipeRH      => *RH,
 516         pipeWH      => *WH,
 517         XferLOG     => $XferLOG,
 518         newFilesFH  => $newFilesFH,
 519         outDir      => $Dir,
 520         type        => $type,
 521         lastFull    => $lastFull,
 522         lastBkupNum => $lastBkupNum,
 523         lastFullBkupNum => $lastFullBkupNum,
 524         backups     => \@Backups,
 525         compress    => $Conf{CompressLevel},
 526         XferMethod  => $Conf{XferMethod},
 527         pidHandler  => \&pidHandler,
 528     });
 529
 530     if ( !defined($logMsg = $xfer->start()) ) {
 531         print(LOG $bpc->timeStamp, "xfer start failed: ", $xfer->errStr, "\n");
 532         print("dump failed: ", $xfer->errStr, "\n");
 533         print("link $clientURI\n") if ( $needLink );
 534         #
 535         # kill off the tar process, first nicely then forcefully
 536         #
 537         if ( $tarPid > 0 ) {
 538             kill(2, $tarPid);
 539             sleep(1);
 540             kill(9, $tarPid);
 541         }
 542         if ( @xferPid ) {
 543             kill(2, @xferPid);
 544             sleep(1);
 545             kill(9, @xferPid);
 546         }
 547         UserCommandRun("DumpPostUserCmd") if ( $NeedPostCmd );
 548         exit(1);
 549     }
 550
 551     @xferPid = $xfer->xferPid;
 552
 553     if ( $useTar ) {
 554         #
 555         # The parent must close both handles on the pipe since the children
 556         # are using these handles now.
 557         #
 558         close(RH);
 559         close(WH);
 560     }
 561     print(LOG $bpc->timeStamp, $logMsg, "\n");
 562     print("started $type dump, share=$shareName\n");
 563
 564     pidHandler(@xferPid);
 565
 566     if ( $useTar ) {
 567         #
 568         # Parse the output of the transfer program and BackupPC_tarExtract
 569         # while they run.  Since we might be reading from two or more children
 570         # we use a select.
 571         #
 572         my($FDread, $tarOut, $mesg);
 573         vec($FDread, fileno(TAR), 1) = 1 if ( $useTar );
 574         $xfer->setSelectMask(\$FDread);
 575
 576         SCAN: while ( 1 ) {
 577             my $ein = $FDread;
 578             last if ( $FDread =~ /^\0*$/ );
 579             select(my $rout = $FDread, undef, $ein, undef);
 580             if ( $useTar ) {
 581                 if ( vec($rout, fileno(TAR), 1) ) {
 582                     if ( sysread(TAR, $mesg, 8192) <= 0 ) {
 583                         vec($FDread, fileno(TAR), 1) = 0;
 584                         close(TAR);
 585                     } else {
 586                         $tarOut .= $mesg;
 587                     }
 588                 }
 589                 while ( $tarOut =~ /(.*?)[\n\r]+(.*)/s ) {
 590                     $_ = $1;
 591                     $tarOut = $2;
 592                     $XferLOG->write(\"tarExtract: $_\n");
 593                     if ( /^Done: (\d+) errors, (\d+) filesExist, (\d+) sizeExist, (\d+) sizeExistComp, (\d+) filesTotal, (\d+) sizeTotal/ ) {
 594                         $tarErrs       += $1;
 595                         $nFilesExist   += $2;
 596                         $sizeExist     += $3;
 597                         $sizeExistComp += $4;
 598                         $nFilesTotal   += $5;
 599                         $sizeTotal     += $6;
 600                     }
 601                 }
 602             }
 603             last if ( !$xfer->readOutput(\$FDread, $rout) );
 604             while ( my $str = $xfer->logMsgGet ) {
 605                 print(LOG $bpc->timeStamp, "xfer: $str\n");
 606             }
 607             if ( $xfer->getStats->{fileCnt} == 1 ) {
 608                 #
 609                 # Make sure it is still the machine we expect.  We do this while
 610                 # the transfer is running to avoid a potential race condition if
 611                 # the ip address was reassigned by dhcp just before we started
 612                 # the transfer.
 613                 #
 614                 if ( my $errMsg = CorrectHostCheck($hostIP, $host) ) {
 615                     $stat{hostError} = $errMsg if ( $stat{hostError} eq "" );
 616                     last SCAN;
 617                 }
 618             }
 619         }
 620     } else {
 621         #
 622         # otherwise the xfer module does everything for us
 623         #
 624         my @results = $xfer->run();
 625         $tarErrs       += $results[0];
 626         $nFilesExist   += $results[1];
 627         $sizeExist     += $results[2];
 628         $sizeExistComp += $results[3];
 629         $nFilesTotal   += $results[4];
 630         $sizeTotal     += $results[5];
 631     }
 632
 633     #
 634     # Merge the xfer status (need to accumulate counts)
 635     #
 636     my $newStat = $xfer->getStats;
 637     foreach my $k ( (keys(%stat), keys(%$newStat)) ) {
 638         next if ( !defined($newStat->{$k}) );
 639         if ( $k =~ /Cnt$/ ) {
 640             $stat{$k} += $newStat->{$k};
 641             delete($newStat->{$k});
 642             next;
 643         }
 644         if ( !defined($stat{$k}) ) {
 645             $stat{$k} = $newStat->{$k};
 646             delete($newStat->{$k});
 647             next;
 648         }
 649     }
 650     $stat{xferOK} = 0 if ( $stat{hostError} || $stat{hostAbort} );
 651     if ( !$stat{xferOK} ) {
 652         #
 653         # kill off the tranfer program, first nicely then forcefully
 654         #
 655         if ( @xferPid ) {
 656             kill(2, @xferPid);
 657             sleep(1);
 658             kill(9, @xferPid);
 659         }
 660         #
 661         # kill off the tar process, first nicely then forcefully
 662         #
 663         if ( $tarPid > 0 ) {
 664             kill(2, $tarPid);
 665             sleep(1);
 666             kill(9, $tarPid);
 667         }
 668         #
 669         # don't do any more shares on this host
 670         #
 671         last;
 672     }
 673 }
 674 my $lastNum  = -1;
 675
 676 #
 677 # Do one last check to make sure it is still the machine we expect.
 678 #
 679 if ( $stat{xferOK} && (my $errMsg = CorrectHostCheck($hostIP, $host)) ) {
 680     $stat{hostError} = $errMsg;
 681     $stat{xferOK} = 0;
 682 }
 683
 684 UserCommandRun("DumpPostUserCmd") if ( $NeedPostCmd );
 685 $XferLOG->close();
 686 close($newFilesFH) if ( defined($newFilesFH) );
 687
 688 if ( $stat{xferOK} ) {
 689     @Backups = $bpc->BackupInfoRead($client);
 690     for ( my $i = 0 ; $i < @Backups ; $i++ ) {
 691         $lastNum = $Backups[$i]{num} if ( $lastNum < $Backups[$i]{num} );
 692     }
 693     $lastNum++;
 694     $bpc->RmTreeDefer("$TopDir/trash", "$Dir/$lastNum")
 695                                 if ( -d "$Dir/$lastNum" );
 696     if ( !rename("$Dir/new", "$Dir/$lastNum") ) {
 697         print(LOG $bpc->timeStamp,
 698                   "Rename $Dir/new -> $Dir/$lastNum failed\n");
 699         $stat{xferOK} = 0;
 700     }
 701     rename("$Dir/XferLOG$fileExt", "$Dir/XferLOG.$lastNum$fileExt");
 702     rename("$Dir/NewFileList", "$Dir/NewFileList.$lastNum");
 703 }
 704 my $endTime = time();
 705
 706 #
 707 # If the dump failed, clean up
 708 #
 709 if ( !$stat{xferOK} ) {
 710     #
 711     # wait a short while and see if the system is still alive
 712     #
 713     $stat{hostError} = $stat{lastOutputLine} if ( $stat{hostError} eq "" );
 714     if ( $stat{hostError} ) {
 715         print(LOG $bpc->timeStamp,
 716                   "Got fatal error during xfer ($stat{hostError})\n");
 717     }
 718     sleep(10);
 719     if ( $bpc->CheckHostAlive($hostIP) < 0 ) {
 720         $stat{hostAbort} = 1;
 721     }
 722     if ( $stat{hostAbort} ) {
 723         $stat{hostError} = "lost network connection during backup";
 724     }
 725     print(LOG $bpc->timeStamp, "Dump aborted ($stat{hostError})\n");
 726     unlink("$Dir/timeStamp.level0");
 727     unlink("$Dir/SmbLOG.bad");
 728     unlink("$Dir/SmbLOG.bad$fileExt");
 729     unlink("$Dir/XferLOG.bad");
 730     unlink("$Dir/XferLOG.bad$fileExt");
 731     unlink("$Dir/NewFileList");
 732     rename("$Dir/XferLOG$fileExt", "$Dir/XferLOG.bad$fileExt");
 733     $bpc->RmTreeDefer("$TopDir/trash", "$Dir/new") if ( -d "$Dir/new" );
 734     print("dump failed: $stat{hostError}\n");
 735     print("link $clientURI\n") if ( $needLink );
 736     exit(1);
 737 }
 738
 739 #
 740 # Add the new backup information to the backup file
 741 #
 742 @Backups = $bpc->BackupInfoRead($client);
 743 my $i = @Backups;
 744 $Backups[$i]{num}           = $lastNum;
 745 $Backups[$i]{type}          = $type;
 746 $Backups[$i]{startTime}     = $startTime;
 747 $Backups[$i]{endTime}       = $endTime;
 748 $Backups[$i]{size}          = $sizeTotal;
 749 $Backups[$i]{nFiles}        = $nFilesTotal;
 750 $Backups[$i]{xferErrs}      = $stat{xferErrCnt} || 0;
 751 $Backups[$i]{xferBadFile}   = $stat{xferBadFileCnt} || 0;
 752 $Backups[$i]{xferBadShare}  = $stat{xferBadShareCnt} || 0;
 753 $Backups[$i]{nFilesExist}   = $nFilesExist;
 754 $Backups[$i]{sizeExist}     = $sizeExist;
 755 $Backups[$i]{sizeExistComp} = $sizeExistComp;
 756 $Backups[$i]{tarErrs}       = $tarErrs;
 757 $Backups[$i]{compress}      = $Conf{CompressLevel};
 758 $Backups[$i]{noFill}        = $type eq "full" ? 0 : 1;
 759 $Backups[$i]{mangle}        = 1;        # name mangling always on for v1.04+
 760 $bpc->BackupInfoWrite($client, @Backups);
 761
 762 unlink("$Dir/timeStamp.level0");
 763
 764 #
 765 # Now remove the bad files, replacing them if possible with links to
 766 # earlier backups.
 767 #
 768 foreach my $file ( $xfer->getBadFiles ) {
 769     my $j;
 770     unlink("$Dir/$lastNum/$file");
 771     for ( $j = $i - 1 ; $j >= 0 ; $j-- ) {
 772         next if ( !-f "$Dir/$Backups[$j]{num}/$file" );
 773         if ( !link("$Dir/$Backups[$j]{num}/$file", "$Dir/$lastNum/$file") ) {
 774             print(LOG $bpc->timeStamp,
 775                       "Unable to link $lastNum/$file to"
 776                     . " $Backups[$j]{num}/$file\n");
 777         } else {
 778             print(LOG $bpc->timeStamp,
 779                       "Bad file $lastNum/$file replaced by link to"
 780                     . " $Backups[$j]{num}/$file\n");
 781         }
 782         last;
 783     }
 784     if ( $j < 0 ) {
 785         print(LOG $bpc->timeStamp,
 786                   "Removed bad file $lastNum/$file (no older"
 787                 . " copy to link to)\n");
 788     }
 789 }
 790
 791 my $otherCount = $stat{xferErrCnt} - $stat{xferBadFileCnt}
 792                                    - $stat{xferBadShareCnt};
 793 print(LOG $bpc->timeStamp,
 794           "$type backup $lastNum complete, $stat{fileCnt} files,"
 795         . " $stat{byteCnt} bytes,"
 796         . " $stat{xferErrCnt} xferErrs ($stat{xferBadFileCnt} bad files,"
 797         . " $stat{xferBadShareCnt} bad shares, $otherCount other)\n");
 798
 799 BackupExpire($client);
 800
 801 print("$type backup complete\n");
 802
 803 ###########################################################################
 804 # Subroutines
 805 ###########################################################################
 806
 807 sub NothingToDo
 808 {
 809     my($needLink) = @_;
 810
 811     print("nothing to do\n");
 812     print("link $clientURI\n") if ( $needLink );
 813     exit(0);
 814 }
 815
 816 sub catch_signal
 817 {
 818     my $signame = shift;
 819     my $fileExt = $Conf{CompressLevel} > 0 ? ".z" : "";
 820
 821     #
 822     # Children quit quietly on ALRM
 823     #
 824     exit(1) if ( $Pid != $$ && $signame eq "ALRM" );
 825
 826     #
 827     # Ignore other signals in children
 828     #
 829     return if ( $Pid != $$ );
 830
 831     print(LOG $bpc->timeStamp, "cleaning up after signal $signame\n");
 832     $SIG{$signame} = 'IGNORE';
 833     UserCommandRun("DumpPostUserCmd") if ( $NeedPostCmd );
 834     $XferLOG->write(\"exiting after signal $signame\n");
 835     $XferLOG->close();
 836     if ( @xferPid ) {
 837         kill(2, @xferPid);
 838         sleep(1);
 839         kill(9, @xferPid);
 840     }
 841     if ( $tarPid > 0 ) {
 842         kill(2, $tarPid);
 843         sleep(1);
 844         kill(9, $tarPid);
 845     }
 846     unlink("$Dir/timeStamp.level0");
 847     unlink("$Dir/NewFileList");
 848     unlink("$Dir/XferLOG.bad");
 849     unlink("$Dir/XferLOG.bad$fileExt");
 850     rename("$Dir/XferLOG$fileExt", "$Dir/XferLOG.bad$fileExt");
 851     $bpc->RmTreeDefer("$TopDir/trash", "$Dir/new") if ( -d "$Dir/new" );
 852     if ( $signame eq "INT" ) {
 853         print("dump failed: aborted by user (signal=$signame)\n");
 854     } else {
 855         print("dump failed: received signal=$signame\n");
 856     }
 857     print("link $clientURI\n") if ( $needLink );
 858     exit(1);
 859 }
 860
 861 #
 862 # Decide which old backups should be expired by moving them
 863 # to $TopDir/trash.
 864 #
 865 sub BackupExpire
 866 {
 867     my($client) = @_;
 868     my($Dir) = "$TopDir/pc/$client";
 869     my(@Backups) = $bpc->BackupInfoRead($client);
 870     my($cntFull, $cntIncr, $firstFull, $firstIncr, $oldestIncr, $oldestFull);
 871
 872     while ( 1 ) {
 873         $cntFull = $cntIncr = 0;
 874         $oldestIncr = $oldestFull = 0;
 875         for ( $i = 0 ; $i < @Backups ; $i++ ) {
 876             if ( $Backups[$i]{type} eq "full" ) {
 877                 $firstFull = $i if ( $cntFull == 0 );
 878                 $cntFull++;
 879             } else {
 880                 $firstIncr = $i if ( $cntIncr == 0 );
 881                 $cntIncr++;
 882             }
 883         }
 884         $oldestIncr = (time - $Backups[$firstIncr]{startTime}) / (24 * 3600)
 885                         if ( $cntIncr > 0 );
 886         $oldestFull = (time - $Backups[$firstFull]{startTime}) / (24 * 3600)
 887                         if ( $cntFull > 0 );
 888         if ( $cntIncr > $Conf{IncrKeepCnt}
 889                 || ($cntIncr > $Conf{IncrKeepCntMin}
 890                     && $oldestIncr > $Conf{IncrAgeMax})
 891                && (@Backups <= $firstIncr + 1
 892                         || $Backups[$firstIncr]{noFill}
 893                         || !$Backups[$firstIncr + 1]{noFill}) ) {
 894             #
 895             # Only delete an incr backup if the Conf settings are satisfied.
 896             # We also must make sure that either this backup is the most
 897             # recent one, or it is not filled, or the next backup is filled.
 898             # (We can't deleted a filled incr if the next backup is not
 899             # filled.)
 900             #
 901             print(LOG $bpc->timeStamp,
 902                       "removing incr backup $Backups[$firstIncr]{num}\n");
 903             $bpc->RmTreeDefer("$TopDir/trash",
 904                               "$Dir/$Backups[$firstIncr]{num}");
 905             unlink("$Dir/SmbLOG.$Backups[$firstIncr]{num}")
 906                         if ( -f "$Dir/SmbLOG.$Backups[$firstIncr]{num}" );
 907             unlink("$Dir/SmbLOG.$Backups[$firstIncr]{num}.z")
 908                         if ( -f "$Dir/SmbLOG.$Backups[$firstIncr]{num}.z" );
 909             unlink("$Dir/XferLOG.$Backups[$firstIncr]{num}")
 910                         if ( -f "$Dir/XferLOG.$Backups[$firstIncr]{num}" );
 911             unlink("$Dir/XferLOG.$Backups[$firstIncr]{num}.z")
 912                         if ( -f "$Dir/XferLOG.$Backups[$firstIncr]{num}.z" );
 913             splice(@Backups, $firstIncr, 1);
 914         } elsif ( ($cntFull > $Conf{FullKeepCnt}
 915                     || ($cntFull > $Conf{FullKeepCntMin}
 916                         && $oldestFull > $Conf{FullAgeMax}))
 917                && (@Backups <= $firstFull + 1
 918                         || !$Backups[$firstFull + 1]{noFill}) ) {
 919             #
 920             # Only delete a full backup if the Conf settings are satisfied.
 921             # We also must make sure that either this backup is the most
 922             # recent one, or the next backup is filled.
 923             # (We can't deleted a full backup if the next backup is not
 924             # filled.)
 925             #
 926             print(LOG $bpc->timeStamp,
 927                    "removing full backup $Backups[$firstFull]{num}\n");
 928             $bpc->RmTreeDefer("$TopDir/trash",
 929                               "$Dir/$Backups[$firstFull]{num}");
 930             unlink("$Dir/SmbLOG.$Backups[$firstFull]{num}")
 931                         if ( -f "$Dir/SmbLOG.$Backups[$firstFull]{num}" );
 932             unlink("$Dir/SmbLOG.$Backups[$firstFull]{num}.z")
 933                         if ( -f "$Dir/SmbLOG.$Backups[$firstFull]{num}.z" );
 934             unlink("$Dir/XferLOG.$Backups[$firstFull]{num}")
 935                         if ( -f "$Dir/XferLOG.$Backups[$firstFull]{num}" );
 936             unlink("$Dir/XferLOG.$Backups[$firstFull]{num}.z")
 937                         if ( -f "$Dir/XferLOG.$Backups[$firstFull]{num}.z" );
 938             splice(@Backups, $firstFull, 1);
 939         } else {
 940             last;
 941         }
 942     }
 943     $bpc->BackupInfoWrite($client, @Backups);
 944 }
 945
 946 sub CorrectHostCheck
 947 {
 948     my($hostIP, $host) = @_;
 949     return if ( $hostIP eq $host && !$Conf{FixedIPNetBiosNameCheck}
 950                 || $Conf{NmbLookupCmd} eq "" );
 951     my($netBiosHost, $netBiosUser) = $bpc->NetBiosInfoGet($hostIP);
 952     return "host $host has mismatching netbios name $netBiosHost"
 953                 if ( $netBiosHost ne $host );
 954     return;
 955 }
 956
 957 #
 958 # The Xfer method might tell us from time to time about processes
 959 # it forks.  We tell BackupPC about this (for status displays) and
 960 # keep track of the pids in case we cancel the backup
 961 #
 962 sub pidHandler
 963 {
 964     @xferPid = @_;
 965     @xferPid = grep(/./, @xferPid);
 966     return if ( !@xferPid && $tarPid < 0 );
 967     my @pids = @xferPid;
 968     push(@pids, $tarPid) if ( $tarPid > 0 );
 969     my $str = join(",", @pids);
 970     $XferLOG->write(\"Xfer PIDs are now $str\n") if ( defined($XferLOG) );
 971     print("xferPids $str\n");
 972 }
 973
 974 #
 975 # Run an optional pre- or post-dump command
 976 #
 977 sub UserCommandRun
 978 {
 979     my($type) = @_;
 980
 981     return if ( !defined($Conf{$type}) );
 982     my $vars = {
 983         xfer       => $xfer,
 984         client     => $client,
 985         host       => $host,
 986         hostIP     => $hostIP,
 987         user       => $Hosts->{$client}{user},
 988         moreUsers  => $Hosts->{$client}{moreUsers},
 989         share      => $ShareNames->[0],
 990         shares     => $ShareNames,
 991         XferMethod => $Conf{XferMethod},
 992         sshPath    => $Conf{SshPath},
 993         LOG        => *LOG,
 994         XferLOG    => $XferLOG,
 995         stat       => \%stat,
 996         xferOK     => $stat{xferOK},
 997         type       => $type,
 998     };
 999     my $cmd = $bpc->cmdVarSubstitute($Conf{$type}, $vars);
1000     $XferLOG->write(\"Executing $type: @$cmd\n");
1001     #
1002     # Run the user's command, dumping the stdout/stderr into the
1003     # Xfer log file.  Also supply the optional $vars and %Conf in
1004     # case the command is really perl code instead of a shell
1005     # command.
1006     #
1007     $bpc->cmdSystemOrEval($cmd,
1008             sub {
1009                 $XferLOG->write(\$_[0]);
1010             },
1011             $vars, \%Conf);
1012 }