configure.pl

   1 #!/bin/perl
   2 #============================================================= -*-perl-*-
   3 #
   4 # configure.pl: Configuration and installation program for BackupPC
   5 #
   6 # DESCRIPTION
   7 #
   8 #   This script should be run as root:
   9 #
  10 #        perl configure.pl
  11 #
  12 #   The installation steps are described as the script runs.
  13 #
  14 # AUTHOR
  15 #   Craig Barratt <cbarratt@users.sourceforge.net>
  16 #
  17 # COPYRIGHT
  18 #   Copyright (C) 2001-2004  Craig Barratt
  19 #
  20 #   This program is free software; you can redistribute it and/or modify
  21 #   it under the terms of the GNU General Public License as published by
  22 #   the Free Software Foundation; either version 2 of the License, or
  23 #   (at your option) any later version.
  24 #
  25 #   This program is distributed in the hope that it will be useful,
  26 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  27 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  28 #   GNU General Public License for more details.
  29 #
  30 #   You should have received a copy of the GNU General Public License
  31 #   along with this program; if not, write to the Free Software
  32 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  33 #
  34 #========================================================================
  35 #
  36 # Version 2.0.0_CVS, released 18 Jan 2003.
  37 #
  38 # See http://backuppc.sourceforge.net.
  39 #
  40 #========================================================================
  41
  42 use strict;
  43 no  utf8;
  44 use vars qw(%Conf %OrigConf);
  45 use lib "./lib";
  46
  47 my @Packages = qw(ExtUtils::MakeMaker File::Path File::Spec File::Copy
  48                   DirHandle Digest::MD5 Data::Dumper Getopt::Std
  49                   BackupPC::Lib BackupPC::FileZIO);
  50
  51 foreach my $pkg ( @Packages ) {
  52     eval "use $pkg";
  53     next if ( !$@ );
  54     die <<EOF;
  55
  56 BackupPC needs the package $pkg.  Please install $pkg
  57 before installing BackupPC.
  58
  59 EOF
  60 }
  61
  62 if ( $< != 0 ) {
  63     print <<EOF;
  64
  65 This configure script should be run as root, rather than uid $<.
  66 Provided uid $< has sufficient permissions to create the data and
  67 install directories, then it should be ok to proceed.  Otherwise,
  68 please quit and restart as root.
  69
  70 EOF
  71     exit unless prompt("--> Do you want to continue?", "y") =~ /y/i;
  72 }
  73
  74 print <<EOF;
  75
  76 Is this a new installation or upgrade for BackupPC?  If this is
  77 an upgrade please tell me the full path of the existing BackupPC
  78 configuration file (eg: /xxxx/conf/config.pl).  Otherwise, just
  79 hit return.
  80
  81 EOF
  82
  83 #
  84 # Check if this is an upgrade, in which case read the existing
  85 # config file to get all the defaults.
  86 #
  87 my $ConfigPath = "";
  88 while ( 1 ) {
  89     $ConfigPath = prompt("--> Full path to existing conf/config.pl",
  90                                     $ConfigPath);
  91     last if ( $ConfigPath eq ""
  92             || ($ConfigPath =~ /^\// && -r $ConfigPath && -w $ConfigPath) );
  93     my $problem = "is not an absolute path";
  94     $problem = "is not writable" if ( !-w $ConfigPath );
  95     $problem = "is not readable" if ( !-r $ConfigPath );
  96     $problem = "doesn't exist"   if ( !-f $ConfigPath );
  97     print("The file '$ConfigPath' $problem.\n");
  98 }
  99 my $bpc;
 100 if ( $ConfigPath ne "" && -r $ConfigPath ) {
 101     (my $topDir = $ConfigPath) =~ s{/[^/]+/[^/]+$}{};
 102     die("BackupPC::Lib->new failed\n")
 103             if ( !($bpc = BackupPC::Lib->new($topDir, ".", 1)) );
 104     %Conf = $bpc->Conf();
 105     %OrigConf = %Conf;
 106     $Conf{TopDir} = $topDir;
 107     my $err = $bpc->ServerConnect($Conf{ServerHost}, $Conf{ServerPort}, 1);
 108     if ( $err eq "" ) {
 109         print <<EOF;
 110
 111 BackupPC is running on $Conf{ServerHost}.  You need to stop BackupPC
 112 before you can upgrade the code.  Depending upon your installation,
 113 you could run "/etc/init.d/backuppc stop".
 114
 115 EOF
 116         exit(1);
 117     }
 118 }
 119
 120 #
 121 # These are the programs whose paths we need to find
 122 #
 123 my %Programs = (
 124     perl           => "PerlPath",
 125     'gtar/tar'     => "TarClientPath",
 126     smbclient      => "SmbClientPath",
 127     nmblookup      => "NmbLookupPath",
 128     rsync          => "RsyncClientPath",
 129     ping           => "PingPath",
 130     df             => "DfPath",
 131     'ssh/ssh2'     => "SshPath",
 132     sendmail       => "SendmailPath",
 133     hostname       => "HostnamePath",
 134     split          => "SplitPath",
 135     'parchive/par' => "ParPath",
 136     cat            => "CatPath",
 137     gzip           => "GzipPath",
 138     bzip2          => "Bzip2Path",
 139 );
 140
 141 foreach my $prog ( sort(keys(%Programs)) ) {
 142     my $path;
 143     foreach my $subProg ( split(/\//, $prog) ) {
 144         $path ||= FindProgram("$ENV{PATH}:/bin:/usr/bin:/sbin:/usr/sbin",
 145                               $subProg);
 146     }
 147     $Conf{$Programs{$prog}} ||= $path;
 148 }
 149
 150 while ( 1 ) {
 151     print <<EOF;
 152
 153 I found the following locations for these programs:
 154
 155 EOF
 156     foreach my $prog ( sort(keys(%Programs)) ) {
 157         printf("    %-12s => %s\n", $prog, $Conf{$Programs{$prog}});
 158     }
 159     print "\n";
 160     last if (prompt('--> Are these paths correct?', 'y') =~ /^y/i);
 161     foreach my $prog ( sort(keys(%Programs)) ) {
 162         $Conf{$Programs{$prog}} = prompt("--> $prog path",
 163                                          $Conf{$Programs{$prog}});
 164     }
 165 }
 166
 167 my $Perl56 = system($Conf{PerlPath}
 168                         . q{ -e 'exit($^V && $^V ge v5.6.0 ? 1 : 0);'});
 169
 170 if ( !$Perl56 ) {
 171     print <<EOF;
 172
 173 BackupPC needs perl version 5.6.0 or later.  $Conf{PerlPath} appears
 174 to be an older version.  Please upgrade to a newer version of perl
 175 and re-run this configure script.
 176
 177 EOF
 178     exit(1);
 179 }
 180
 181 print <<EOF;
 182
 183 Please tell me the hostname of the machine that BackupPC will run on.
 184
 185 EOF
 186 chomp($Conf{ServerHost} = `$Conf{HostnamePath}`)
 187         if ( defined($Conf{HostnamePath}) && !defined($Conf{ServerHost}) );
 188 $Conf{ServerHost} = prompt("--> BackupPC will run on host", $Conf{ServerHost});
 189
 190 print <<EOF;
 191
 192 BackupPC should run as a dedicated user with limited privileges.  You
 193 need to create a user.  This user will need read/write permission on
 194 the main data directory and read/execute permission on the install
 195 directory (these directories will be setup shortly).
 196
 197 The primary group for this user should also be chosen carefully.
 198 By default the install directories will have group write permission.
 199 The data directories and files will have group read permission but
 200 no other permission.
 201
 202 EOF
 203 my($name, $passwd, $Uid, $Gid);
 204 while ( 1 ) {
 205     $Conf{BackupPCUser} = prompt("--> BackupPC should run as user",
 206                                  $Conf{BackupPCUser} || "backuppc");
 207     ($name, $passwd, $Uid, $Gid) = getpwnam($Conf{BackupPCUser});
 208     last if ( $name ne "" );
 209     print <<EOF;
 210
 211 getpwnam() says that user $Conf{BackupPCUser} doesn't exist.  Please check the
 212 name and verify that this user is in the passwd file.
 213
 214 EOF
 215 }
 216
 217 print <<EOF;
 218
 219 Please specify an install directory for BackupPC.  This is where the
 220 BackupPC scripts, library and documentation will be installed.
 221
 222 EOF
 223
 224 while ( 1 ) {
 225     $Conf{InstallDir} = prompt("--> Install directory (full path)",
 226                                $Conf{InstallDir});
 227     last if ( $Conf{InstallDir} =~ /^\// );
 228 }
 229
 230 print <<EOF;
 231
 232 Please specify a data directory for BackupPC.  This is where the
 233 configuration files, LOG files and all the PC backups are stored.
 234 This file system needs to be big enough to accommodate all the
 235 PCs you expect to backup (eg: at least 1-2GB per machine).
 236
 237 EOF
 238
 239 while ( 1 ) {
 240     $Conf{TopDir} = prompt("--> Data directory (full path)", $Conf{TopDir});
 241     last if ( $Conf{TopDir} =~ /^\// );
 242 }
 243
 244 if ( !defined($Conf{CompressLevel}) ) {
 245     $Conf{CompressLevel} = BackupPC::FileZIO->compOk ? 3 : 0;
 246     if ( $ConfigPath eq "" && $Conf{CompressLevel} ) {
 247         print <<EOF;
 248
 249 BackupPC can compress pool files, providing around a 40% reduction in pool
 250 size (your mileage may vary). Specify the compression level (0 turns
 251 off compression, and 1 to 9 represent good/fastest to best/slowest).
 252 The recommended values are 0 (off) or 3 (reasonable compression and speed).
 253 Increasing the compression level to 5 will use around 20% more cpu time
 254 and give perhaps 2-3% more compression.
 255
 256 EOF
 257     } elsif ( $ConfigPath eq "" ) {
 258         print <<EOF;
 259
 260 BackupPC can compress pool files, but it needs the Compress::Zlib
 261 package installed (see www.cpan.org). Compression will provide around a
 262 40% reduction in pool size, at the expense of cpu time.  You can leave
 263 compression off and run BackupPC without compression, in which case you
 264 should leave the compression level at 0 (which means off).  You could
 265 install Compress::Zlib and turn compression on later, but read the
 266 documentation first about how to do this.  Or the better choice is
 267 to quit, install Compress::Zlib, and re-run configure.pl.
 268
 269 EOF
 270     } elsif ( $Conf{CompressLevel} ) {
 271         $Conf{CompressLevel} = 0;
 272         print <<EOF;
 273
 274 BackupPC now supports pool file compression.  Since you are upgrading
 275 BackupPC you probably have existing uncompressed backups.  You have
 276 several choices if you want to turn on compression.  You can run
 277 the script BackupPC_compressPool to convert everything to compressed
 278 form.  Or you can simply turn on compression, so that new backups
 279 will be compressed.  This will increase the pool storage requirement,
 280 since both uncompressed and compressed copies of files will be stored.
 281 But eventually the old uncompressed backups will expire, recovering
 282 the pool storage.  Please see the documentation for more details.
 283
 284 If you are not sure what to do, leave the Compression Level at 0,
 285 which disables compression.  You can always read the documentation
 286 and turn it on later.
 287
 288 EOF
 289     } else {
 290         $Conf{CompressLevel} = 0;
 291         print <<EOF;
 292
 293 BackupPC now supports pool file compression, but it needs the
 294 Compress::Zlib module (see www.cpan.org).  For now, leave
 295 the compression level set at 0 to disable compression.  If you
 296 want you can install Compress::Zlib and turn compression on.
 297 Please see the documentation for more details about converting
 298 old backups to compressed form.
 299
 300 EOF
 301     }
 302     while ( 1 ) {
 303         $Conf{CompressLevel}
 304                     = prompt("--> Compression level", $Conf{CompressLevel});
 305         last if ( $Conf{CompressLevel} =~ /^\d+$/ );
 306     }
 307 }
 308
 309 print <<EOF;
 310
 311 BackupPC has a powerful CGI perl interface that runs under Apache.
 312 A single executable needs to be installed in a cgi-bin directory.
 313 This executable needs to run as set-uid $Conf{BackupPCUser}, or
 314 it can be run under mod_perl with Apache running as user $Conf{BackupPCUser}.
 315
 316 Leave this path empty if you don't want to install the CGI interface.
 317
 318 EOF
 319
 320 while ( 1 ) {
 321     $Conf{CgiDir} = prompt("--> CGI bin directory (full path)", $Conf{CgiDir});
 322     last if ( $Conf{CgiDir} =~ /^\// || $Conf{CgiDir} eq "" );
 323 }
 324
 325 if ( $Conf{CgiDir} ne "" ) {
 326
 327     print <<EOF;
 328
 329 BackupPC's CGI script needs to display various GIF images that
 330 should be stored where Apache can serve them.  They should be
 331 placed somewher under Apache's DocumentRoot.  BackupPC also
 332 needs to know the URL to access these images.  Example:
 333
 334     Apache image directory:  /usr/local/apache/htdocs/BackupPC
 335     URL for image directory: /BackupPC
 336
 337 The URL for the image directory should start with a slash.
 338
 339 EOF
 340     while ( 1 ) {
 341         $Conf{CgiImageDir} = prompt("--> Apache image directory (full path)",
 342                                         $Conf{CgiImageDir});
 343         last if ( $Conf{CgiImageDir} =~ /^\// );
 344     }
 345     while ( 1 ) {
 346         $Conf{CgiImageDirURL} = prompt("--> URL for image directory (omit http://host; starts with '/')",
 347                                         $Conf{CgiImageDirURL});
 348         last if ( $Conf{CgiImageDirURL} =~ /^\// );
 349     }
 350 }
 351
 352 print <<EOF;
 353
 354 Ok, we're about to:
 355
 356   - install the binaries, lib and docs in $Conf{InstallDir},
 357   - create the data directory $Conf{TopDir},
 358   - create/update the config.pl file $Conf{TopDir}/conf,
 359   - optionally install the cgi-bin interface.
 360
 361 EOF
 362
 363 exit unless prompt("--> Do you want to continue?", "y") =~ /y/i;
 364
 365 #
 366 # Create install directories
 367 #
 368 foreach my $dir ( qw(bin doc
 369                      lib/BackupPC/CGI
 370                      lib/BackupPC/Lang
 371                      lib/BackupPC/Xfer
 372                      lib/BackupPC/Zip
 373                  ) ) {
 374     next if ( -d "$Conf{InstallDir}/$dir" );
 375     mkpath("$Conf{InstallDir}/$dir", 0, 0775);
 376     if ( !-d "$Conf{InstallDir}/$dir"
 377             || !chown($Uid, $Gid, "$Conf{InstallDir}/$dir") ) {
 378         die("Failed to create or chown $Conf{InstallDir}/$dir\n");
 379     } else {
 380         print("Created $Conf{InstallDir}/$dir\n");
 381     }
 382 }
 383
 384 #
 385 # Create CGI image directory
 386 #
 387 foreach my $dir ( ($Conf{CgiImageDir}) ) {
 388     next if ( $dir eq "" || -d $dir );
 389     mkpath($dir, 0, 0775);
 390     if ( !-d $dir || !chown($Uid, $Gid, $dir) ) {
 391         die("Failed to create or chown $dir");
 392     } else {
 393         print("Created $dir\n");
 394     }
 395 }
 396
 397 #
 398 # Create $TopDir's top-level directories
 399 #
 400 foreach my $dir ( qw(. conf pool cpool pc trash log) ) {
 401     mkpath("$Conf{TopDir}/$dir", 0, 0750) if ( !-d "$Conf{TopDir}/$dir" );
 402     if ( !-d "$Conf{TopDir}/$dir"
 403             || !chown($Uid, $Gid, "$Conf{TopDir}/$dir") ) {
 404         die("Failed to create or chown $Conf{TopDir}/$dir\n");
 405     } else {
 406         print("Created $Conf{TopDir}/$dir\n");
 407     }
 408 }
 409
 410 printf("Installing binaries in $Conf{InstallDir}/bin\n");
 411 foreach my $prog ( qw(BackupPC BackupPC_dump BackupPC_link BackupPC_nightly
 412         BackupPC_sendEmail BackupPC_tarCreate BackupPC_trashClean
 413         BackupPC_tarExtract BackupPC_compressPool BackupPC_zcat
 414         BackupPC_archive BackupPC_archiveHost
 415         BackupPC_restore BackupPC_serverMesg BackupPC_zipCreate ) ) {
 416     InstallFile("bin/$prog", "$Conf{InstallDir}/bin/$prog", 0555);
 417 }
 418
 419 #
 420 # Remove unused binaries from older versions
 421 #
 422 unlink("$Conf{InstallDir}/bin/BackupPC_queueAll");
 423
 424 printf("Installing library in $Conf{InstallDir}/lib\n");
 425 foreach my $lib ( qw(
 426         BackupPC/Lib.pm
 427         BackupPC/FileZIO.pm
 428         BackupPC/Attrib.pm
 429         BackupPC/PoolWrite.pm
 430         BackupPC/View.pm
 431         BackupPC/Xfer/Archive.pm
 432         BackupPC/Xfer/Tar.pm
 433         BackupPC/Xfer/Smb.pm
 434         BackupPC/Xfer/Rsync.pm
 435         BackupPC/Xfer/RsyncDigest.pm
 436         BackupPC/Xfer/RsyncFileIO.pm
 437         BackupPC/Zip/FileMember.pm
 438         BackupPC/Lang/en.pm
 439         BackupPC/Lang/fr.pm
 440         BackupPC/Lang/es.pm
 441         BackupPC/Lang/de.pm
 442         BackupPC/Lang/it.pm
 443         BackupPC/CGI/AdminOptions.pm
 444         BackupPC/CGI/Archive.pm
 445         BackupPC/CGI/ArchiveInfo.pm
 446         BackupPC/CGI/Browse.pm
 447         BackupPC/CGI/DirHistory.pm
 448         BackupPC/CGI/EmailSummary.pm
 449         BackupPC/CGI/GeneralInfo.pm
 450         BackupPC/CGI/HostInfo.pm
 451         BackupPC/CGI/Lib.pm
 452         BackupPC/CGI/LOGlist.pm
 453         BackupPC/CGI/Queue.pm
 454         BackupPC/CGI/ReloadServer.pm
 455         BackupPC/CGI/RestoreFile.pm
 456         BackupPC/CGI/RestoreInfo.pm
 457         BackupPC/CGI/Restore.pm
 458         BackupPC/CGI/StartServer.pm
 459         BackupPC/CGI/StartStopBackup.pm
 460         BackupPC/CGI/StopServer.pm
 461         BackupPC/CGI/Summary.pm
 462         BackupPC/CGI/View.pm
 463     ) ) {
 464     InstallFile("lib/$lib", "$Conf{InstallDir}/lib/$lib", 0444);
 465 }
 466
 467 if ( $Conf{CgiImageDir} ne "" ) {
 468     printf("Installing images in $Conf{CgiImageDir}\n");
 469     foreach my $img ( <images/*> ) {
 470         (my $destImg = $img) =~ s{^images/}{};
 471         InstallFile($img, "$Conf{CgiImageDir}/$destImg", 0444, 1);
 472     }
 473 }
 474
 475 printf("Making init.d scripts\n");
 476 foreach my $init ( qw(gentoo-backuppc gentoo-backuppc.conf linux-backuppc
 477                       solaris-backuppc debian-backuppc suse-backuppc) ) {
 478     InstallFile("init.d/src/$init", "init.d/$init", 0444);
 479 }
 480
 481 printf("Installing docs in $Conf{InstallDir}/doc\n");
 482 foreach my $doc ( qw(BackupPC.pod BackupPC.html) ) {
 483     InstallFile("doc/$doc", "$Conf{InstallDir}/doc/$doc", 0444);
 484 }
 485
 486 printf("Installing config.pl and hosts in $Conf{TopDir}/conf\n");
 487 InstallFile("conf/hosts", "$Conf{TopDir}/conf/hosts", 0644)
 488                     if ( !-f "$Conf{TopDir}/conf/hosts" );
 489
 490 #
 491 # Now do the config file.  If there is an existing config file we
 492 # merge in the new config file, adding any new configuration
 493 # parameters and deleting ones that are no longer needed.
 494 #
 495 my $dest = "$Conf{TopDir}/conf/config.pl";
 496 my ($newConf, $newVars) = ConfigParse("conf/config.pl");
 497 my ($oldConf, $oldVars);
 498 if ( -f $dest ) {
 499     ($oldConf, $oldVars) = ConfigParse($dest);
 500     $newConf = ConfigMerge($oldConf, $oldVars, $newConf, $newVars);
 501 }
 502 $Conf{EMailFromUserName}  ||= $Conf{BackupPCUser};
 503 $Conf{EMailAdminUserName} ||= $Conf{BackupPCUser};
 504
 505 #
 506 # Update various config parameters
 507 #
 508
 509 #
 510 # Guess $Conf{CgiURL}
 511 #
 512 if ( !defined($Conf{CgiURL}) ) {
 513     if ( $Conf{CgiDir} =~ m{cgi-bin(/.*)} ) {
 514         $Conf{CgiURL} = "'http://$Conf{ServerHost}/cgi-bin$1/BackupPC_Admin'";
 515     } else {
 516         $Conf{CgiURL} = "'http://$Conf{ServerHost}/cgi-bin/BackupPC_Admin'";
 517     }
 518 }
 519
 520 #
 521 # The smbclient commands have moved from hard-coded to the config file.
 522 # $Conf{SmbClientArgs} no longer exists, so merge it into the new
 523 # commands if it still exists.
 524 #
 525 if ( defined($Conf{SmbClientArgs}) ) {
 526     if ( $Conf{SmbClientArgs} ne "" ) {
 527         foreach my $param ( qw(SmbClientRestoreCmd SmbClientFullCmd
 528                                 SmbClientIncrCmd) ) {
 529             $newConf->[$newVars->{$param}]{text}
 530                             =~ s/(-E\s+-N)/$1 $Conf{SmbClientArgs}/;
 531         }
 532     }
 533     delete($Conf{SmbClientArgs});
 534 }
 535
 536 #
 537 # The blackout timing settings are now stored in a list of hashes, rather
 538 # than three scalar parameters.
 539 #
 540 if ( defined($Conf{BlackoutHourBegin}) ) {
 541     $Conf{BlackoutPeriods} = [
 542          {
 543              hourBegin => $Conf{BlackoutHourBegin},
 544              hourEnd   => $Conf{BlackoutHourEnd},
 545              weekDays  => $Conf{BlackoutWeekDays},
 546          }
 547     ];
 548     delete($Conf{BlackoutHourBegin});
 549     delete($Conf{BlackoutHourEnd});
 550     delete($Conf{BlackoutWeekDays});
 551 }
 552
 553 #
 554 # $Conf{RsyncLogLevel} has been replaced by $Conf{XferLogLevel}
 555 #
 556 $Conf{XferLogLevel} = $Conf{RsyncLogLevel};
 557
 558 #
 559 # IncrFill should now be off
 560 #
 561 $Conf{IncrFill} = 0;
 562
 563 #
 564 # Figure out sensible arguments for the ping command
 565 #
 566 if ( defined($Conf{PingArgs}) ) {
 567     $Conf{PingCmd} = '$pingPath ' . $Conf{PingArgs};
 568 } elsif ( !defined($Conf{PingCmd}) ) {
 569     if ( $^O eq "solaris" || $^O eq "sunos" ) {
 570         $Conf{PingCmd} = '$pingPath -s $host 56 1';
 571     } elsif ( ($^O eq "linux" || $^O eq "openbsd" || $^O eq "netbsd")
 572             && !system("$Conf{PingPath} -c 1 -w 3 localhost") ) {
 573         $Conf{PingCmd} = '$pingPath -c 1 -w 3 $host';
 574     } else {
 575         $Conf{PingCmd} = '$pingPath -c 1 $host';
 576     }
 577     delete($Conf{PingArgs});
 578 }
 579
 580 #
 581 # Figure out sensible arguments for the df command
 582 #
 583 if ( !defined($Conf{DfCmd}) ) {
 584     if ( $^O eq "solaris" || $^O eq "sunos" ) {
 585         $Conf{DfCmd} = '$dfPath -k $topDir';
 586     }
 587 }
 588
 589 #
 590 # $Conf{SmbClientTimeout} is now $Conf{ClientTimeout}
 591 #
 592 if ( defined($Conf{SmbClientTimeout}) ) {
 593     $Conf{ClientTimeout} = $Conf{SmbClientTimeout};
 594     delete($Conf{SmbClientTimeout});
 595 }
 596
 597 my $confCopy = "$dest.pre-__VERSION__";
 598 if ( -f $dest && !-f $confCopy ) {
 599     #
 600     # Make copy of config file, preserving ownership and modes
 601     #
 602     printf("Making backup copy of $dest -> $confCopy\n");
 603     my @stat = stat($dest);
 604     my $mode = $stat[2];
 605     my $uid  = $stat[4];
 606     my $gid  = $stat[5];
 607     die("can't copy($dest, $confCopy)\n")  unless copy($dest, $confCopy);
 608     die("can't chown $uid, $gid $confCopy\n")
 609                                            unless chown($uid, $gid, $confCopy);
 610     die("can't chmod $mode $confCopy\n")   unless chmod($mode, $confCopy);
 611 }
 612 open(OUT, ">", $dest) || die("can't open $dest for writing\n");
 613 binmode(OUT);
 614 my $blockComment;
 615 foreach my $var ( @$newConf ) {
 616     if ( length($blockComment)
 617           && substr($var->{text}, 0, length($blockComment)) eq $blockComment ) {
 618         $var->{text} = substr($var->{text}, length($blockComment));
 619         $blockComment = undef;
 620     }
 621     $blockComment = $1 if ( $var->{text} =~ /^([\s\n]*#{70}.*#{70}[\s\n]+)/s );
 622     $var->{text} =~ s/^\s*\$Conf\{(.*?)\}(\s*=\s*['"]?)(.*?)(['"]?\s*;)/
 623                 defined($Conf{$1}) && ref($Conf{$1}) eq ""
 624                                    && $Conf{$1} ne $OrigConf{$1}
 625                                    ? "\$Conf{$1}$2$Conf{$1}$4"
 626                                    : "\$Conf{$1}$2$3$4"/emg;
 627     print OUT $var->{text};
 628 }
 629 close(OUT);
 630 if ( !defined($oldConf) ) {
 631     die("can't chmod 0640 mode $dest\n")  unless chmod(0640, $dest);
 632     die("can't chown $Uid, $Gid $dest\n") unless chown($Uid, $Gid, $dest);
 633 }
 634
 635 if ( $Conf{CgiDir} ne "" ) {
 636     printf("Installing cgi script BackupPC_Admin in $Conf{CgiDir}\n");
 637     mkpath("$Conf{CgiDir}", 0, 0755);
 638     InstallFile("cgi-bin/BackupPC_Admin", "$Conf{CgiDir}/BackupPC_Admin",
 639                 04554);
 640 }
 641
 642 print <<EOF;
 643
 644 Ok, it looks like we are finished.  There are several more things you
 645 will need to do:
 646
 647   - Browse through the config file, $Conf{TopDir}/conf/config.pl,
 648     and make sure all the settings are correct.  In particular, you
 649     will need to set the smb share password and user name, backup
 650     policies and check the email message headers and bodies.
 651
 652   - Edit the list of hosts to backup in $Conf{TopDir}/conf/hosts.
 653
 654   - Read the documentation in $Conf{InstallDir}/doc/BackupPC.html.
 655     Please pay special attention to the security section.
 656
 657   - Verify that the CGI script BackupPC_Admin runs correctly.  You might
 658     need to change the permissions or group ownership of BackupPC_Admin.
 659
 660   - BackupPC should be ready to start.  Don't forget to run it
 661     as user $Conf{BackupPCUser}!  The installation also contains an
 662     init.d/backuppc script that can be copied to /etc/init.d
 663     so that BackupPC can auto-start on boot.  This will also enable
 664     administrative users to start the server from the CGI interface.
 665     See init.d/README.
 666
 667 Enjoy!
 668 EOF
 669
 670 if ( `$Conf{PerlPath} -V` =~ /uselargefiles=undef/ ) {
 671     print <<EOF;
 672
 673 WARNING: your perl, $Conf{PerlPath}, does not support large files.
 674 This means BackupPC won't be able to backup files larger than 2GB.
 675 To solve this problem you should build/install a new version of perl
 676 with large file support enabled.  Use
 677
 678     $Conf{PerlPath} -V | egrep uselargefiles
 679
 680 to check if perl has large file support (undef means no support).
 681
 682 EOF
 683 }
 684
 685 exit(0);
 686
 687 ###########################################################################
 688 # Subroutines
 689 ###########################################################################
 690
 691 sub InstallFile
 692 {
 693     my($prog, $dest, $mode, $binary) = @_;
 694     my $first = 1;
 695     my($uid, $gid) = ($Uid, $Gid);
 696
 697     if ( -f $dest ) {
 698         #
 699         # preserve ownership and modes of files that already exist
 700         #
 701         my @stat = stat($dest);
 702         $mode = $stat[2];
 703         $uid  = $stat[4];
 704         $gid  = $stat[5];
 705     }
 706     unlink($dest) if ( -f $dest );
 707     if ( $binary ) {
 708         die("can't copy($prog, $dest)\n") unless copy($prog, $dest);
 709     } else {
 710         open(PROG, $prog)     || die("can't open $prog for reading\n");
 711         open(OUT, ">", $dest) || die("can't open $dest for writing\n");
 712         binmode(PROG);
 713         binmode(OUT);
 714         while ( <PROG> ) {
 715             s/__INSTALLDIR__/$Conf{InstallDir}/g;
 716             s/__TOPDIR__/$Conf{TopDir}/g;
 717             s/__BACKUPPCUSER__/$Conf{BackupPCUser}/g;
 718             s/__CGIDIR__/$Conf{CgiDir}/g;
 719             if ( $first && /^#.*bin\/perl/ ) {
 720                 #
 721                 # Fill in correct path to perl (no taint for >= 2.0.1).
 722                 #
 723                 print OUT "#!$Conf{PerlPath}\n";
 724             } else {
 725                 print OUT;
 726             }
 727             $first = 0;
 728         }
 729         close(PROG);
 730         close(OUT);
 731     }
 732     die("can't chown $uid, $gid $dest") unless chown($uid, $gid, $dest);
 733     die("can't chmod $mode $dest")      unless chmod($mode, $dest);
 734 }
 735
 736 sub FindProgram
 737 {
 738     my($path, $prog) = @_;
 739     foreach my $dir ( split(/:/, $path) ) {
 740         my $file = File::Spec->catfile($dir, $prog);
 741         return $file if ( -x $file );
 742     }
 743 }
 744
 745 sub ConfigParse
 746 {
 747     my($file) = @_;
 748     open(C, $file) || die("can't open $file");
 749     binmode(C);
 750     my($out, @conf, $var);
 751     my $comment = 1;
 752     my $allVars = {};
 753     my $endLine = undef;
 754     while ( <C> ) {
 755         if ( /^#/ && !defined($endLine) ) {
 756             if ( $comment ) {
 757                 $out .= $_;
 758             } else {
 759                 if ( $out ne "" ) {
 760                     $allVars->{$var} = @conf if ( defined($var) );
 761                     push(@conf, {
 762                         text => $out,
 763                         var => $var,
 764                     });
 765                 }
 766                 $var = undef;
 767                 $comment = 1;
 768                 $out = $_;
 769             }
 770         } elsif ( /^\s*\$Conf\{([^}]*)/ ) {
 771             $comment = 0;
 772             if ( defined($var) ) {
 773                 $allVars->{$var} = @conf if ( defined($var) );
 774                 push(@conf, {
 775                     text => $out,
 776                     var => $var,
 777                 });
 778                 $out = $_;
 779             } else {
 780                 $out .= $_;
 781             }
 782             $var = $1;
 783             $endLine = $1 if ( /^\s*\$Conf\{[^}]*} *= *<<(.*);/ );
 784             $endLine = $1 if ( /^\s*\$Conf\{[^}]*} *= *<<'(.*)';/ );
 785         } else {
 786             $endLine = undef if ( defined($endLine) && /^\Q$endLine[\n\r]*$/ );
 787             $out .= $_;
 788         }
 789     }
 790     if ( $out ne "" ) {
 791         $allVars->{$var} = @conf if ( defined($var) );
 792         push(@conf, {
 793             text => $out,
 794             var  => $var,
 795         });
 796     }
 797     close(C);
 798     return (\@conf, $allVars);
 799 }
 800
 801 sub ConfigMerge
 802 {
 803     my($old, $oldVars, $new, $newVars) = @_;
 804     my $posn = 0;
 805     my $res;
 806
 807     #
 808     # Find which config parameters are not needed any longer
 809     #
 810     foreach my $var ( @$old ) {
 811         next if ( !defined($var->{var}) || defined($newVars->{$var->{var}}) );
 812         #print(STDERR "Deleting old config parameter $var->{var}\n");
 813         $var->{delete} = 1;
 814     }
 815     #
 816     # Find which config parameters are new
 817     #
 818     foreach my $var ( @$new ) {
 819         next if ( !defined($var->{var}) );
 820         if ( defined($oldVars->{$var->{var}}) ) {
 821             $posn = $oldVars->{$var->{var}};
 822         } else {
 823             #print(STDERR "New config parameter $var->{var}: $var->{text}\n");
 824             push(@{$old->[$posn]{new}}, $var);
 825         }
 826     }
 827     #
 828     # Create merged config file
 829     #
 830     foreach my $var ( @$old ) {
 831         next if ( $var->{delete} );
 832         push(@$res, $var);
 833         foreach my $new ( @{$var->{new}} ) {
 834             push(@$res, $new);
 835         }
 836     }
 837     return $res;
 838 }