lib/BackupPC/Xfer/Rsync.pm

   1 #============================================================= -*-perl-*-
   2 #
   3 # BackupPC::Xfer::Rsync package
   4 #
   5 # DESCRIPTION
   6 #
   7 #   This library defines a BackupPC::Xfer::Rsync class for managing
   8 #   the rsync-based transport of backup data from the client.
   9 #
  10 # AUTHOR
  11 #   Craig Barratt  <cbarratt@users.sourceforge.net>
  12 #
  13 # COPYRIGHT
  14 #   Copyright (C) 2002-2003  Craig Barratt
  15 #
  16 #   This program is free software; you can redistribute it and/or modify
  17 #   it under the terms of the GNU General Public License as published by
  18 #   the Free Software Foundation; either version 2 of the License, or
  19 #   (at your option) any later version.
  20 #
  21 #   This program is distributed in the hope that it will be useful,
  22 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 #   GNU General Public License for more details.
  25 #
  26 #   You should have received a copy of the GNU General Public License
  27 #   along with this program; if not, write to the Free Software
  28 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  29 #
  30 #========================================================================
  31 #
  32 # Version 2.1.0, released 20 Jun 2004.
  33 #
  34 # See http://backuppc.sourceforge.net.
  35 #
  36 #========================================================================
  37
  38 package BackupPC::Xfer::Rsync;
  39
  40 use strict;
  41 use BackupPC::View;
  42 use BackupPC::Xfer::RsyncFileIO;
  43
  44 use vars qw( $RsyncLibOK $RsyncLibErr );
  45
  46 BEGIN {
  47     eval "use File::RsyncP;";
  48     if ( $@ ) {
  49         #
  50         # Rsync module doesn't exist.
  51         #
  52         $RsyncLibOK = 0;
  53         $RsyncLibErr = "File::RsyncP module doesn't exist";
  54     } else {
  55         #
  56         # Note: also update configure.pl when this version number is changed!
  57         #
  58         if ( $File::RsyncP::VERSION < 0.52 ) {
  59             $RsyncLibOK = 0;
  60             $RsyncLibErr = "File::RsyncP module version"
  61                          . " ($File::RsyncP::VERSION) too old: need 0.52";
  62         } else {
  63             $RsyncLibOK = 1;
  64         }
  65     }
  66 };
  67
  68 sub new
  69 {
  70     my($class, $bpc, $args) = @_;
  71
  72     return if ( !$RsyncLibOK );
  73     $args ||= {};
  74     my $t = bless {
  75         bpc       => $bpc,
  76         conf      => { $bpc->Conf },
  77         host      => "",
  78         hostIP    => "",
  79         shareName => "",
  80         badFiles  => [],
  81
  82         #
  83         # Various stats
  84         #
  85         byteCnt         => 0,
  86         fileCnt         => 0,
  87         xferErrCnt      => 0,
  88         xferBadShareCnt => 0,
  89         xferBadFileCnt  => 0,
  90         xferOK          => 0,
  91
  92         #
  93         # User's args
  94         #
  95         %$args,
  96     }, $class;
  97
  98     return $t;
  99 }
 100
 101 sub args
 102 {
 103     my($t, $args) = @_;
 104
 105     foreach my $arg ( keys(%$args) ) {
 106         $t->{$arg} = $args->{$arg};
 107     }
 108 }
 109
 110 sub useTar
 111 {
 112     return 0;
 113 }
 114
 115 sub start
 116 {
 117     my($t) = @_;
 118     my $bpc = $t->{bpc};
 119     my $conf = $t->{conf};
 120     my(@fileList, $rsyncClientCmd, $rsyncArgs, $logMsg,
 121        $incrDate, $argList, $fioArgs);
 122
 123     #
 124     # We add a slash to the share name we pass to rsync
 125     #
 126     ($t->{shareNameSlash} = "$t->{shareName}/") =~ s{//+$}{/};
 127
 128     if ( $t->{type} eq "restore" ) {
 129         $rsyncClientCmd = $conf->{RsyncClientRestoreCmd};
 130         $rsyncArgs = $conf->{RsyncRestoreArgs};
 131         my $remoteDir = "$t->{shareName}/$t->{pathHdrDest}";
 132         $remoteDir    =~ s{//+}{/}g;
 133         $argList = ['--server', @$rsyncArgs, '.', $remoteDir];
 134         $fioArgs = {
 135             client   => $t->{bkupSrcHost},
 136             share    => $t->{bkupSrcShare},
 137             viewNum  => $t->{bkupSrcNum},
 138             fileList => $t->{fileList},
 139         };
 140         $logMsg = "restore started below directory $t->{shareName}"
 141                 . " to host $t->{host}";
 142     } else {
 143         #
 144         # Turn $conf->{BackupFilesOnly} and $conf->{BackupFilesExclude}
 145         # into a hash of arrays of files, and $conf->{RsyncShareName}
 146         # to an array
 147         #
 148         $bpc->backupFileConfFix($conf, "RsyncShareName");
 149
 150         if ( defined($conf->{BackupFilesOnly}{$t->{shareName}}) ) {
 151             my(@inc, @exc, %incDone, %excDone);
 152             foreach my $file ( @{$conf->{BackupFilesOnly}{$t->{shareName}}} ) {
 153                 #
 154                 # If the user wants to just include /home/craig, then
 155                 # we need to do create include/exclude pairs at
 156                 # each level:
 157                 #     --include /home --exclude /*
 158                 #     --include /home/craig --exclude /home/*
 159                 #
 160                 # It's more complex if the user wants to include multiple
 161                 # deep paths.  For example, if they want /home/craig and
 162                 # /var/log, then we need this mouthfull:
 163                 #     --include /home --include /var --exclude /*
 164                 #     --include /home/craig --exclude /home/*
 165                 #     --include /var/log --exclude /var/*
 166                 #
 167                 # To make this easier we do all the includes first and all
 168                 # of the excludes at the end (hopefully they commute).
 169                 #
 170                 $file =~ s{/$}{};
 171                 $file = "/$file";
 172                 $file =~ s{//+}{/}g;
 173                 if ( $file eq "/" ) {
 174                     #
 175                     # This is a special case: if the user specifies
 176                     # "/" then just include it and don't exclude "/*".
 177                     #
 178                     push(@inc, $file) if ( !$incDone{$file} );
 179                     next;
 180                 }
 181                 my $f = "";
 182                 while ( $file =~ m{^/([^/]*)(.*)} ) {
 183                     my $elt = $1;
 184                     $file = $2;
 185                     if ( $file eq "/" ) {
 186                         #
 187                         # preserve a tailing slash
 188                         #
 189                         $file = "";
 190                         $elt = "$elt/";
 191                     }
 192                     push(@exc, "$f/*") if ( !$excDone{"$f/*"} );
 193                     $excDone{"$f/*"} = 1;
 194                     $f = "$f/$elt";
 195                     push(@inc, $f) if ( !$incDone{$f} );
 196                     $incDone{$f} = 1;
 197                 }
 198             }
 199             foreach my $file ( @inc ) {
 200                 push(@fileList, "--include=$file");
 201             }
 202             foreach my $file ( @exc ) {
 203                 push(@fileList, "--exclude=$file");
 204             }
 205         }
 206         if ( defined($conf->{BackupFilesExclude}{$t->{shareName}}) ) {
 207             foreach my $file ( @{$conf->{BackupFilesExclude}{$t->{shareName}}} )
 208             {
 209                 #
 210                 # just append additional exclude lists onto the end
 211                 #
 212                 push(@fileList, "--exclude=$file");
 213             }
 214         }
 215         if ( $t->{type} eq "full" ) {
 216             if ( $t->{partialNum} ) {
 217                 $logMsg = "full backup started for directory $t->{shareName};"
 218                         . " updating partial $t->{partialNum}";
 219             } else {
 220                 $logMsg = "full backup started for directory $t->{shareName}";
 221             }
 222         } else {
 223             $incrDate = $bpc->timeStamp($t->{lastFull} - 3600, 1);
 224             $logMsg = "incr backup started back to $incrDate for directory"
 225                     . " $t->{shareName}";
 226         }
 227
 228         #
 229         # A full dump is implemented with --ignore-times: this causes all
 230         # files to be checksummed, even if the attributes are the same.
 231         # That way all the file contents are checked, but you get all
 232         # the efficiencies of rsync: only files deltas need to be
 233         # transferred, even though it is a full dump.
 234         #
 235         $rsyncArgs = $conf->{RsyncArgs};
 236         $rsyncArgs = [@$rsyncArgs, @fileList] if ( @fileList );
 237         $rsyncArgs = [@$rsyncArgs, "--ignore-times"]
 238                                     if ( $t->{type} eq "full" );
 239         $rsyncClientCmd = $conf->{RsyncClientCmd};
 240         $argList = ['--server', '--sender', @$rsyncArgs,
 241                               '.', $t->{shareNameSlash}];
 242         eval {
 243             $argList = File::RsyncP->excludeStrip($argList);
 244         };
 245         $fioArgs = {
 246             client     => $t->{client},
 247             share      => $t->{shareName},
 248             viewNum    => $t->{lastFullBkupNum},
 249             partialNum => $t->{partialNum},
 250         };
 251     }
 252
 253     #
 254     # Merge variables into $rsyncClientCmd
 255     #
 256     my $args = {
 257         host      => $t->{host},
 258         hostIP    => $t->{hostIP},
 259         client    => $t->{client},
 260         shareName => $t->{shareName},
 261         shareNameSlash => $t->{shareNameSlash},
 262         rsyncPath => $conf->{RsyncClientPath},
 263         sshPath   => $conf->{SshPath},
 264         argList   => $argList,
 265     };
 266     $rsyncClientCmd = $bpc->cmdVarSubstitute($rsyncClientCmd, $args);
 267
 268     #
 269     # Create the Rsync object, and tell it to use our own File::RsyncP::FileIO
 270     # module, which handles all the special BackupPC file storage
 271     # (compression, mangling, hardlinks, special files, attributes etc).
 272     #
 273     $t->{rsyncClientCmd} = $rsyncClientCmd;
 274     $t->{rs} = File::RsyncP->new({
 275         logLevel     => $t->{logLevel} || $conf->{RsyncLogLevel},
 276         rsyncCmd     => sub {
 277                             $bpc->verbose(0);
 278                             $bpc->cmdExecOrEval($rsyncClientCmd, $args);
 279                         },
 280         rsyncCmdType => "full",
 281         rsyncArgs    => $rsyncArgs,
 282         timeout      => $conf->{ClientTimeout},
 283         doPartial    => defined($t->{partialNum}) ? 1 : undef,
 284         logHandler   =>
 285                 sub {
 286                     my($str) = @_;
 287                     $str .= "\n";
 288                     $t->{XferLOG}->write(\$str);
 289                     if ( $str =~ /^Remote\[1\]: read errors mapping "(.*)"/ ) {
 290                         #
 291                         # Files with read errors (eg: region locked files
 292                         # on WinXX) are filled with 0 by rsync.  Remember
 293                         # them and delete them later.
 294                         #
 295                         my $badFile = $1;
 296                         $badFile =~ s/^\/+//;
 297                         push(@{$t->{badFiles}}, {
 298                                 share => $t->{shareName},
 299                                 file  => $badFile
 300                             });
 301                     }
 302                 },
 303         pidHandler   => sub {
 304                             $t->{pidHandler}(@_);
 305                         },
 306         fio          => BackupPC::Xfer::RsyncFileIO->new({
 307                             xfer       => $t,
 308                             bpc        => $t->{bpc},
 309                             conf       => $t->{conf},
 310                             backups    => $t->{backups},
 311                             logLevel   => $t->{logLevel}
 312                                               || $conf->{RsyncLogLevel},
 313                             logHandler => sub {
 314                                               my($str) = @_;
 315                                               $str .= "\n";
 316                                               $t->{XferLOG}->write(\$str);
 317                                           },
 318                             cacheCheckProb => $conf->{RsyncCsumCacheVerifyProb},
 319                             %$fioArgs,
 320                       }),
 321     });
 322
 323     delete($t->{_errStr});
 324
 325     return $logMsg;
 326 }
 327
 328 sub run
 329 {
 330     my($t) = @_;
 331     my $rs = $t->{rs};
 332     my $conf = $t->{conf};
 333     my($remoteSend, $remoteDir, $remoteDirDaemon);
 334
 335     alarm($conf->{ClientTimeout});
 336     if ( $t->{type} eq "restore" ) {
 337         $remoteSend       = 0;
 338         ($remoteDir       = "$t->{shareName}/$t->{pathHdrDest}") =~ s{//+}{/}g;
 339         ($remoteDirDaemon = "$t->{shareName}/$t->{pathHdrDest}") =~ s{//+}{/}g;
 340         $remoteDirDaemon  = $t->{shareNameSlash}
 341                                 if ( $t->{pathHdrDest} eq ""
 342                                               || $t->{pathHdrDest} eq "/" );
 343     } else {
 344         $remoteSend      = 1;
 345         $remoteDir       = $t->{shareNameSlash};
 346         $remoteDirDaemon = ".";
 347     }
 348     if ( $t->{XferMethod} eq "rsync" ) {
 349         #
 350         # Run rsync command
 351         #
 352         my $str = "Running: "
 353                 . $t->{bpc}->execCmd2ShellCmd(@{$t->{rsyncClientCmd}})
 354                 . "\n";
 355         $t->{XferLOG}->write(\$str);
 356         $rs->remoteStart($remoteSend, $remoteDir);
 357     } else {
 358         #
 359         # Connect to the rsync server
 360         #
 361         if ( defined(my $err = $rs->serverConnect($t->{hostIP},
 362                                              $conf->{RsyncdClientPort})) ) {
 363             $t->{hostError} = $err;
 364             my $str = "Error connecting to rsync daemon at $t->{hostIP}"
 365                     . ":$conf->{RsyncdClientPort}: $err\n";
 366             $t->{XferLOG}->write(\$str);
 367             return;
 368         }
 369         #
 370         # Pass module name, and follow it with a slash if it already
 371         # contains a slash; otherwise just keep the plain module name.
 372         #
 373         my $module = $t->{shareName};
 374         $module = $t->{shareNameSlash} if ( $module =~ /\// );
 375         if ( defined(my $err = $rs->serverService($module,
 376                                              $conf->{RsyncdUserName},
 377                                              $conf->{RsyncdPasswd},
 378                                              $conf->{RsyncdAuthRequired})) ) {
 379             my $str = "Error connecting to module $module at $t->{hostIP}"
 380                     . ":$conf->{RsyncdClientPort}: $err\n";
 381             $t->{XferLOG}->write(\$str);
 382             $t->{hostError} = $err;
 383             return;
 384         }
 385         $rs->serverStart($remoteSend, $remoteDirDaemon);
 386     }
 387     my $error = $rs->go($t->{shareNameSlash});
 388     $rs->serverClose();
 389
 390     #
 391     # TODO: generate sensible stats
 392     #
 393     # $rs->{stats}{totalWritten}
 394     # $rs->{stats}{totalSize}
 395     #
 396     my $stats = $rs->statsFinal;
 397     if ( !defined($error) && defined($stats) ) {
 398         $t->{xferOK} = 1;
 399     } else {
 400         $t->{xferOK} = 0;
 401     }
 402     $t->{xferErrCnt} = $stats->{remoteErrCnt}
 403                      + $stats->{childStats}{errorCnt}
 404                      + $stats->{parentStats}{errorCnt};
 405     $t->{byteCnt}    = $stats->{childStats}{TotalFileSize}
 406                      + $stats->{parentStats}{TotalFileSize};
 407     $t->{fileCnt}    = $stats->{childStats}{TotalFileCnt}
 408                      + $stats->{parentStats}{TotalFileCnt};
 409     my $str = "Done: $t->{fileCnt} files, $t->{byteCnt} bytes\n";
 410     $t->{XferLOG}->write(\$str);
 411     #
 412     # TODO: get error count, and call fio to get stats...
 413     #
 414     $t->{hostError} = $error if ( defined($error) );
 415
 416     if ( $t->{type} eq "restore" ) {
 417         return (
 418             $t->{fileCnt},
 419             $t->{byteCnt},
 420             0,
 421             0
 422         );
 423     } else {
 424         return (
 425             0,
 426             $stats->{childStats}{ExistFileCnt}
 427                 + $stats->{parentStats}{ExistFileCnt},
 428             $stats->{childStats}{ExistFileSize}
 429                 + $stats->{parentStats}{ExistFileSize},
 430             $stats->{childStats}{ExistFileCompSize}
 431                 + $stats->{parentStats}{ExistFileCompSize},
 432             $stats->{childStats}{TotalFileCnt}
 433                 + $stats->{parentStats}{TotalFileCnt},
 434             $stats->{childStats}{TotalFileSize}
 435                 + $stats->{parentStats}{TotalFileSize},
 436         );
 437     }
 438 }
 439
 440 sub abort
 441 {
 442     my($t, $reason) = @_;
 443     my $rs = $t->{rs};
 444
 445     $rs->abort($reason);
 446     return 1;
 447 }
 448
 449 sub setSelectMask
 450 {
 451     my($t, $FDreadRef) = @_;
 452 }
 453
 454 sub errStr
 455 {
 456     my($t) = @_;
 457
 458     return $RsyncLibErr if ( !defined($t) || ref($t) ne "HASH" );
 459     return $t->{_errStr};
 460 }
 461
 462 sub xferPid
 463 {
 464     my($t) = @_;
 465
 466     return ();
 467 }
 468
 469 sub logMsg
 470 {
 471     my($t, $msg) = @_;
 472
 473     push(@{$t->{_logMsg}}, $msg);
 474 }
 475
 476 sub logMsgGet
 477 {
 478     my($t) = @_;
 479
 480     return shift(@{$t->{_logMsg}});
 481 }
 482
 483 #
 484 # Returns a hash ref giving various status information about
 485 # the transfer.
 486 #
 487 sub getStats
 488 {
 489     my($t) = @_;
 490
 491     return { map { $_ => $t->{$_} }
 492             qw(byteCnt fileCnt xferErrCnt xferBadShareCnt xferBadFileCnt
 493                xferOK hostAbort hostError lastOutputLine)
 494     };
 495 }
 496
 497 sub getBadFiles
 498 {
 499     my($t) = @_;
 500
 501     return @{$t->{badFiles}};
 502 }
 503
 504 1;