C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22 use Carp;
  23
  24 use C4::Debug;
  25 use C4::Context;
  26 use C4::Members qw(AddMember changepassword);
  27 use C4::Members::Attributes;
  28 use C4::Members::AttributeTypes;
  29 use C4::Members::Messaging;
  30 use C4::Auth qw(checkpw_internal);
  31 use Koha::AuthUtils qw(hash_password);
  32 use List::MoreUtils qw( any );
  33 use Net::LDAP;
  34 use Net::LDAP::Filter;
  35
  36 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  37
  38 BEGIN {
  39         require Exporter;
  40         @ISA    = qw(Exporter);
  41         @EXPORT = qw( checkpw_ldap );
  42 }
  43
  44 # Redefine checkpw_ldap:
  45 # connect to LDAP (named or anonymous)
  46 # ~ retrieves $userid from KOHA_CONF mapping
  47 # ~ then compares $password with userPassword
  48 # ~ then gets the LDAP entry
  49 # ~ and calls the memberadd if necessary
  50
  51 sub ldapserver_error {
  52         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  53 }
  54
  55 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  56 my $context = C4::Context->new()        or die 'C4::Context->new failed';
  57 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  58 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  59 my $base      = $ldap->{base}           or die ldapserver_error('base');
  60 $ldapname     = $ldap->{user}           ;
  61 $ldappassword = $ldap->{pass}           ;
  62 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  63 my @mapkeys = keys %mapping;
  64 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  65 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  66 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  67
  68 my %config = (
  69         anonymous => ($ldapname and $ldappassword) ? 0 : 1,
  70     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  71        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  72 );
  73
  74 sub description {
  75         my $result = shift or return;
  76         return "LDAP error #" . $result->code
  77                         . ": " . $result->error_name . "\n"
  78                         . "# " . $result->error_text . "\n";
  79 }
  80
  81 sub search_method {
  82     my $db     = shift or return;
  83     my $userid = shift or return;
  84         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  85         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  86         my $search = $db->search(
  87                   base => $base,
  88                 filter => $filter,
  89                 # attrs => ['*'],
  90     );
  91     die "LDAP search failed to return object : " . $search->error if $search->code;
  92
  93         my $count = $search->count;
  94         if ($search->code > 0) {
  95                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
  96                 return 0;
  97         }
  98         if ($count != 1) {
  99                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count);
 100                 return 0;
 101         }
 102     return $search;
 103 }
 104
 105 sub checkpw_ldap {
 106     my ($dbh, $userid, $password) = @_;
 107     my @hosts = split(',', $prefhost);
 108     my $db = Net::LDAP->new(\@hosts);
 109     unless ( $db ) {
 110         warn "LDAP connexion failed";
 111         return 0;
 112     }
 113
 114         #$debug and $db->debug(5);
 115     my $userldapentry;
 116
 117     if ( $ldap->{auth_by_bind} ) {
 118         my $principal_name;
 119         if ( $ldap->{anonymous_bind} ) {
 120
 121             # Perform an anonymous bind
 122             my $res = $db->bind;
 123             if ( $res->code ) {
 124                 warn "Anonymous LDAP bind failed: " . description($res);
 125                 return 0;
 126             }
 127
 128             # Perform a LDAP search for the given username
 129             my $search = search_method( $db, $userid )
 130               or return 0;    # warnings are in the sub
 131             $userldapentry = $search->shift_entry;
 132             $principal_name = $userldapentry->dn;
 133         }
 134         else {
 135             $principal_name = $ldap->{principal_name};
 136             if ( $principal_name and $principal_name =~ /\%/ ) {
 137                 $principal_name = sprintf( $principal_name, $userid );
 138             }
 139             else {
 140                 $principal_name = $userid;
 141             }
 142         }
 143
 144         # Perform a LDAP bind for the given username using the matched DN
 145         my $res = $db->bind( $principal_name, password => $password );
 146         if ( $res->code ) {
 147             if ( $ldap->{anonymous_bind} ) {
 148                 # With anonymous_bind approach we can be sure we have found the correct user
 149                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 150                 # or password changed). We should not fall back to local accounts in this case.
 151                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 152                 return -1;
 153             } else {
 154                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 155                 # at all, and thus we should fall back to local logins to restore previous behaviour
 156                 # see bug 12831
 157                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 158                 return 0;
 159             }
 160         }
 161         if ( !defined($userldapentry)
 162             && ( $config{update} or $config{replicate} ) )
 163         {
 164             my $search = search_method( $db, $userid ) or return 0;
 165             $userldapentry = $search->shift_entry;
 166         }
 167     } else {
 168                 my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 169                 if ($res->code) {               # connection refused
 170                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 171                         return 0;
 172                 }
 173         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 174         $userldapentry = $search->shift_entry;
 175                 my $cmpmesg = $db->compare( $userldapentry, attr=>'userpassword', value => $password );
 176                 if ($cmpmesg->code != 6) {
 177                         warn "LDAP Auth rejected : invalid password for user '$userid'. " . description($cmpmesg);
 178                         return -1;
 179                 }
 180         }
 181
 182     # To get here, LDAP has accepted our user's login attempt.
 183     # But we still have work to do.  See perldoc below for detailed breakdown.
 184
 185     my (%borrower);
 186         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 187
 188     if (( $borrowernumber and $config{update}   ) or
 189         (!$borrowernumber and $config{replicate})   ) {
 190         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 191         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 192     }
 193
 194     if ($borrowernumber) {
 195         if ($config{update}) { # A1, B1
 196             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 197             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 198         } else { # C1, D1
 199             # maybe update just the password?
 200                 return(1, $cardnumber, $local_userid);
 201         }
 202     } elsif ($config{replicate}) { # A2, C2
 203         $borrowernumber = AddMember(%borrower) or die "AddMember failed";
 204         C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
 205    } else {
 206         return 0;   # B2, D2
 207     }
 208     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 209         my @extended_patron_attributes;
 210         foreach my $attribute_type ( C4::Members::AttributeTypes::GetAttributeTypes() ) {
 211             my $code = $attribute_type->{code};
 212             if ( exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) { # skip empty values
 213                 push @extended_patron_attributes, { code => $code, value => $borrower{$code} };
 214             }
 215         }
 216         #Check before add
 217         my @unique_attr;
 218         foreach my $attr ( @extended_patron_attributes ) {
 219             if (C4::Members::Attributes::CheckUniqueness($attr->{code}, $attr->{value}, $borrowernumber)) {
 220                 push @unique_attr, $attr;
 221             } else {
 222                 warn "ERROR_extended_unique_id_failed $attr->{code} $attr->{value}";
 223             }
 224         }
 225         C4::Members::Attributes::SetBorrowerAttributes($borrowernumber, \@unique_attr, 'no_branch_limit');
 226     }
 227 return(1, $cardnumber, $userid);
 228 }
 229
 230 # Pass LDAP entry object and local cardnumber (userid).
 231 # Returns borrower hash.
 232 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 233 # Ensure that mandatory fields are correctly filled!
 234 #
 235 sub ldap_entry_2_hash {
 236         my $userldapentry = shift;
 237         my %borrower = ( cardnumber => shift );
 238         my %memberhash;
 239         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 240         if ($debug) {
 241                 foreach (keys %$userldapentry) {
 242                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 243                 }
 244         }
 245         my $x = $userldapentry->{attrs} or return;
 246         foreach (keys %$x) {
 247                 $memberhash{$_} = join ' ', @{$x->{$_}};
 248                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 249         }
 250         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 251                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 252         foreach my $key (keys %mapping) {
 253                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 254                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 255                 unless (defined $data) {
 256                         $data = $mapping{$key}->{content} || '';        # default or failsafe ''
 257                 }
 258                 $borrower{$key} = ($data ne '') ? $data : ' ' ;
 259         }
 260         $borrower{initials} = $memberhash{initials} ||
 261                 ( substr($borrower{'firstname'},0,1)
 262                 . substr($borrower{ 'surname' },0,1)
 263                 . " ");
 264
 265         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 266         my $dbh = C4::Context->dbh;
 267         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 268         $sth->execute( uc($borrower{'categorycode'}) );
 269         unless ( my $row = $sth->fetchrow_hashref ) {
 270                 my $default = $mapping{'categorycode'}->{content};
 271                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 272                 $borrower{'categorycode'} = $default
 273         }
 274
 275         return %borrower;
 276 }
 277
 278 sub exists_local {
 279         my $arg = shift;
 280         my $dbh = C4::Context->dbh;
 281         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 282
 283         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 284         $sth->execute($arg);
 285         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 286         ($sth->rows == 1) and return $sth->fetchrow;
 287
 288         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 289         $sth->execute($arg);
 290         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 291         ($sth->rows == 1) and return $sth->fetchrow;
 292         return 0;
 293 }
 294
 295 # This function performs a password update, given the userid, borrowerid,
 296 # and digested password. It will verify that things are correct and return the
 297 # borrowers cardnumber. The idea is that it is used to keep the local
 298 # passwords in sync with the LDAP passwords.
 299 #
 300 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 301 #
 302 # Note: if the LDAP config has the update_password tag set to a false value,
 303 # then this will not update the password, it will simply return the cardnumber.
 304 sub _do_changepassword {
 305     my ($userid, $borrowerid, $password) = @_;
 306
 307     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 308
 309         # We don't store the password in the database
 310         my $sth = C4::Context->dbh->prepare(
 311             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 312         $sth->execute($borrowerid);
 313         die "Unable to access borrowernumber "
 314             . "with userid=$userid, "
 315             . "borrowernumber=$borrowerid"
 316           if !$sth->rows;
 317         my ($cardnum) = $sth->fetchrow;
 318         $sth = C4::Context->dbh->prepare(
 319             'UPDATE borrowers SET password = null WHERE borrowernumber=?');
 320         $sth->execute($borrowerid);
 321         return $cardnum;
 322     }
 323     my $digest = hash_password($password);
 324
 325     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 326     changepassword($userid, $borrowerid, $digest);
 327
 328     my ($ok, $cardnum) = checkpw_internal(C4::Context->dbh, $userid, $password);
 329     return $cardnum if $ok;
 330
 331     warn "Password mismatch after update to borrowernumber=$borrowerid";
 332     return;
 333 }
 334
 335 sub update_local {
 336     my $userid     = shift or croak "No userid";
 337     my $password   = shift or croak "No password";
 338     my $borrowerid = shift or croak "No borrowerid";
 339     my $borrower   = shift or croak "No borrower record";
 340
 341     my @keys = keys %$borrower;
 342     my $dbh = C4::Context->dbh;
 343     my $query = "UPDATE  borrowers\nSET     " .
 344         join(',', map {"$_=?"} @keys) .
 345         "\nWHERE   borrowernumber=? ";
 346     my $sth = $dbh->prepare($query);
 347     if ($debug) {
 348         print STDERR $query, "\n",
 349             join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 350         print STDERR "\nuserid = $userid\n";
 351     }
 352     $sth->execute(
 353         ((map {$borrower->{$_}} @keys), $borrowerid)
 354     );
 355
 356     # MODIFY PASSWORD/LOGIN if password was mapped
 357     _do_changepassword($userid, $borrowerid, $password) if $borrower->{'password'};
 358 }
 359
 360 1;
 361 __END__
 362
 363 =head1 NAME
 364
 365 C4::Auth - Authenticates Koha users
 366
 367 =head1 SYNOPSIS
 368
 369   use C4::Auth_with_ldap;
 370
 371 =head1 LDAP Configuration
 372
 373     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 374         working LDAP servers.
 375         To use it :
 376            * Modify ldapserver element in KOHA_CONF
 377            * Establish field mapping in <mapping> element.
 378
 379         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 380         the username would match the "uid" field, and the password should match the "userpassword" field.
 381
 382         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 383         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 384
 385         mysql> show COLUMNS from borrowers;
 386                 +---------------------+--------------+------+-----+---------+----------------+
 387                 | Field               | Type         | Null | Key | Default | Extra          |
 388                 +---------------------+--------------+------+-----+---------+----------------+
 389                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 390                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 391                 | surname             | mediumtext   | NO   |     | NULL    |                |
 392                 | firstname           | text         | YES  |     | NULL    |                |
 393                 | title               | mediumtext   | YES  |     | NULL    |                |
 394                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 395                 | initials            | text         | YES  |     | NULL    |                |
 396                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 397                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 398                 | address             | mediumtext   | NO   |     | NULL    |                |
 399                 | address2            | text         | YES  |     | NULL    |                |
 400                 | city                | mediumtext   | NO   |     | NULL    |                |
 401                 | state               | mediumtext   | YES  |     | NULL    |                |
 402                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 403                 | country             | text         | YES  |     | NULL    |                |
 404                 | email               | mediumtext   | YES  |     | NULL    |                |
 405                 | phone               | text         | YES  |     | NULL    |                |
 406                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 407                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 408                 | emailpro            | text         | YES  |     | NULL    |                |
 409                 | phonepro            | text         | YES  |     | NULL    |                |
 410                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 411                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 412                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 413                 | B_address2          | text         | YES  |     | NULL    |                |
 414                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 415                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 416                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 417                 | B_country           | text         | YES  |     | NULL    |                |
 418                 | B_email             | text         | YES  |     | NULL    |                |
 419                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 420                 | dateofbirth         | date         | YES  |     | NULL    |                |
 421                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 422                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 423                 | dateenrolled        | date         | YES  |     | NULL    |                |
 424                 | dateexpiry          | date         | YES  |     | NULL    |                |
 425                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 426                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 427                 | debarred            | date         | YES  |     | NULL    |                |
 428                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 429                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 430                 | contactfirstname    | text         | YES  |     | NULL    |                |
 431                 | contacttitle        | text         | YES  |     | NULL    |                |
 432                 | guarantorid         | int(11)      | YES  | MUL | NULL    |                |
 433                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 434                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 435                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 436                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 437                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 438                 | password            | varchar(30)  | YES  |     | NULL    |                |
 439                 | flags               | int(11)      | YES  |     | NULL    |                |
 440                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 441                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 442                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 443                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 444                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 445                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 446                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 447                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 448                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 449                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 450                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 451                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 452                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 453                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 454                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 455                 | privacy             | int(11)      | NO   |     | 1       |                |
 456                 +---------------------+--------------+------+-----+---------+----------------+
 457                 66 rows in set (0.00 sec)
 458                 Where Null="NO", the field is required.
 459
 460 =head1 KOHA_CONF and field mapping
 461
 462 Example XML stanza for LDAP configuration in KOHA_CONF.
 463
 464  <config>
 465   ...
 466   <useldapserver>1</useldapserver>
 467   <!-- LDAP SERVER (optional) -->
 468   <ldapserver id="ldapserver">
 469     <hostname>localhost</hostname>
 470     <base>dc=metavore,dc=com</base>
 471     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 472     <pass>metavore</pass>          <!-- password, if not anonymous -->
 473     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 474     <update>1</update>             <!-- update existing users in Koha database -->
 475     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 476                                         password comparison, e.g., to use Active Directory -->
 477     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 478                                             an anonymous bind, even when auth_by_bind is on -->
 479     <principal_name>%s@my_domain.com</principal_name>
 480                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 481                                         Not used with anonymous_bind. -->
 482     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 483                                               synced to the local database -->
 484     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 485       <firstname    is="givenname"      ></firstname>
 486       <surname      is="sn"             ></surname>
 487       <address      is="postaladdress"  ></address>
 488       <city         is="l"              >Athens, OH</city>
 489       <zipcode      is="postalcode"     ></zipcode>
 490       <branchcode   is="branch"         >MAIN</branchcode>
 491       <userid       is="uid"            ></userid>
 492       <password     is="userpassword"   ></password>
 493       <email        is="mail"           ></email>
 494       <categorycode is="employeetype"   >PT</categorycode>
 495       <phone        is="telephonenumber"></phone>
 496     </mapping>
 497   </ldapserver>
 498  </config>
 499
 500 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 501 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 502 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 503 patron).
 504
 505 =head1 CONFIGURATION
 506
 507 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 508 your configuration and the presence of a matching Koha user in your local DB:
 509
 510                          LOCAL_USER
 511  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 512    A1      1       1        1      OK : We're updating them anyway.
 513    A2      1       1        0      OK : We're adding them anyway.
 514    B1      1       0        1      OK : We update them.
 515    B2      1       0        0     FAIL: We cannot add new user.
 516    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 517    C2      0       1        0      OK : We add the new user.
 518    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 519    D2      0       0        0     FAIL: We cannot add new user.
 520
 521 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 522 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 523 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 524
 525 If you choose NOT to update local users, the borrowers table will not be affected at all.
 526 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 527 the local table never contained the LDAP values.
 528
 529 =head2 auth_by_bind
 530
 531 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 532
 533 =head2 principal_name
 534
 535 Provides an optional sprintf-style format for manipulating the userid before the bind.
 536 Even though the userPrincipalName is one intended target, any uniquely identifying
 537 attribute that the server allows to be used for binding could be used.
 538
 539 Currently, principal_name only operates when auth_by_bind is enabled.
 540
 541 =head2 update_password
 542
 543 If this tag is left out or set to a true value, then the user's LDAP password
 544 will be stored (hashed) in the local Koha database. If you don't want this
 545 to happen, then set the value of this to '0'. Note that if passwords are not
 546 stored locally, and the connection to the LDAP system fails, then the users
 547 will not be able to log in at all.
 548
 549 =head2 Active Directory
 550
 551 The auth_by_bind and principal_name settings are recommended for Active Directory.
 552
 553 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 554 we would typically under openldap.  Instead of:
 555
 556     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 557
 558 We might get:
 559
 560     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 561
 562 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 563 in Koha userids.  But the userPrincipalName should be consistent, something like:
 564
 565     userPrincipalName: barnes.7@my_company.com
 566
 567 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 568 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 569 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 570 like this:
 571     <principal_name>%s@core.my_company.com</principal_name>
 572
 573 The user of the previous example, barnes.7, would then attempt to bind as:
 574     barnes.7@core.my_company.com
 575
 576 =head1 SEE ALSO
 577
 578 CGI(3)
 579
 580 Net::LDAP()
 581
 582 XML::Simple()
 583
 584 Digest::MD5(3)
 585
 586 sprintf()
 587
 588 =cut
 589
 590 # For reference, here's an important difference in the data structure we rely on.
 591 # ========================================
 592 # Using attrs instead of {asn}->attributes
 593 # ========================================
 594 #
 595 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 596 #       LDAP key: ->{             cn}->{           sss} = sss
 597 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 598 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 599 #
 600 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 601 #       LDAP key: ->{      givenname}->{Steve} = Steve
 602 #