C4/Items.pm

   1 package C4::Items;
   2
   3 # Copyright 2007 LibLime, Inc.
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along with
  17 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  18 # Suite 330, Boston, MA  02111-1307 USA
  19
  20 use strict;
  21
  22 use C4::Context;
  23 use C4::Koha;
  24 use C4::Biblio;
  25 use C4::Dates qw/format_date format_date_in_iso/;
  26 use MARC::Record;
  27 use C4::ClassSource;
  28 use C4::Log;
  29 use C4::Branch;
  30 require C4::Reserves;
  31 use C4::Charset;
  32
  33 use vars qw($VERSION @ISA @EXPORT);
  34
  35 BEGIN {
  36     $VERSION = 3.01;
  37
  38         require Exporter;
  39     @ISA = qw( Exporter );
  40
  41     # function exports
  42     @EXPORT = qw(
  43         GetItem
  44         AddItemFromMarc
  45         AddItem
  46         AddItemBatchFromMarc
  47         ModItemFromMarc
  48         ModItem
  49         ModDateLastSeen
  50         ModItemTransfer
  51         DelItem
  52
  53         CheckItemPreSave
  54
  55         GetItemStatus
  56         GetItemLocation
  57         GetLostItems
  58         GetItemsForInventory
  59         GetItemsCount
  60         GetItemInfosOf
  61         GetItemsByBiblioitemnumber
  62         GetItemsInfo
  63         get_itemnumbers_of
  64         GetItemnumberFromBarcode
  65     );
  66 }
  67
  68 =head1 NAME
  69
  70 C4::Items - item management functions
  71
  72 =head1 DESCRIPTION
  73
  74 This module contains an API for manipulating item
  75 records in Koha, and is used by cataloguing, circulation,
  76 acquisitions, and serials management.
  77
  78 A Koha item record is stored in two places: the
  79 items table and embedded in a MARC tag in the XML
  80 version of the associated bib record in C<biblioitems.marcxml>.
  81 This is done to allow the item information to be readily
  82 indexed (e.g., by Zebra), but means that each item
  83 modification transaction must keep the items table
  84 and the MARC XML in sync at all times.
  85
  86 Consequently, all code that creates, modifies, or deletes
  87 item records B<must> use an appropriate function from
  88 C<C4::Items>.  If no existing function is suitable, it is
  89 better to add one to C<C4::Items> than to use add
  90 one-off SQL statements to add or modify items.
  91
  92 The items table will be considered authoritative.  In other
  93 words, if there is ever a discrepancy between the items
  94 table and the MARC XML, the items table should be considered
  95 accurate.
  96
  97 =head1 HISTORICAL NOTE
  98
  99 Most of the functions in C<C4::Items> were originally in
 100 the C<C4::Biblio> module.
 101
 102 =head1 CORE EXPORTED FUNCTIONS
 103
 104 The following functions are meant for use by users
 105 of C<C4::Items>
 106
 107 =cut
 108
 109 =head2 GetItem
 110
 111 =over 4
 112
 113 $item = GetItem($itemnumber,$barcode,$serial);
 114
 115 =back
 116
 117 Return item information, for a given itemnumber or barcode.
 118 The return value is a hashref mapping item column
 119 names to values.  If C<$serial> is true, include serial publication data.
 120
 121 =cut
 122
 123 sub GetItem {
 124     my ($itemnumber,$barcode, $serial) = @_;
 125     my $dbh = C4::Context->dbh;
 126         my $data;
 127     if ($itemnumber) {
 128         my $sth = $dbh->prepare("
 129             SELECT * FROM items
 130             WHERE itemnumber = ?");
 131         $sth->execute($itemnumber);
 132         $data = $sth->fetchrow_hashref;
 133     } else {
 134         my $sth = $dbh->prepare("
 135             SELECT * FROM items
 136             WHERE barcode = ?"
 137             );
 138         $sth->execute($barcode);
 139         $data = $sth->fetchrow_hashref;
 140     }
 141     if ( $serial) {
 142     my $ssth = $dbh->prepare("SELECT serialseq,publisheddate from serialitems left join serial on serialitems.serialid=serial.serialid where serialitems.itemnumber=?");
 143         $ssth->execute($data->{'itemnumber'}) ;
 144         ($data->{'serialseq'} , $data->{'publisheddate'}) = $ssth->fetchrow_array();
 145                 warn $data->{'serialseq'} , $data->{'publisheddate'};
 146     }
 147         #if we don't have an items.itype, use biblioitems.itemtype.
 148         if( ! $data->{'itype'} ) {
 149                 my $sth = $dbh->prepare("SELECT itemtype FROM biblioitems  WHERE biblionumber = ?");
 150                 $sth->execute($data->{'biblionumber'});
 151                 ($data->{'itype'}) = $sth->fetchrow_array;
 152         }
 153     return $data;
 154 }    # sub GetItem
 155
 156 =head2 AddItemFromMarc
 157
 158 =over 4
 159
 160 my ($biblionumber, $biblioitemnumber, $itemnumber)
 161     = AddItemFromMarc($source_item_marc, $biblionumber);
 162
 163 =back
 164
 165 Given a MARC::Record object containing an embedded item
 166 record and a biblionumber, create a new item record.
 167
 168 =cut
 169
 170 sub AddItemFromMarc {
 171     my ( $source_item_marc, $biblionumber ) = @_;
 172     my $dbh = C4::Context->dbh;
 173
 174     # parse item hash from MARC
 175     my $frameworkcode = GetFrameworkCode( $biblionumber );
 176     my $item = &TransformMarcToKoha( $dbh, $source_item_marc, $frameworkcode );
 177     my $unlinked_item_subfields = _get_unlinked_item_subfields($source_item_marc, $frameworkcode);
 178     return AddItem($item, $biblionumber, $dbh, $frameworkcode, $unlinked_item_subfields);
 179 }
 180
 181 =head2 AddItem
 182
 183 =over 4
 184
 185 my ($biblionumber, $biblioitemnumber, $itemnumber)
 186     = AddItem($item, $biblionumber[, $dbh, $frameworkcode, $unlinked_item_subfields]);
 187
 188 =back
 189
 190 Given a hash containing item column names as keys,
 191 create a new Koha item record.
 192
 193 The first two optional parameters (C<$dbh> and C<$frameworkcode>)
 194 do not need to be supplied for general use; they exist
 195 simply to allow them to be picked up from AddItemFromMarc.
 196
 197 The final optional parameter, C<$unlinked_item_subfields>, contains
 198 an arrayref containing subfields present in the original MARC
 199 representation of the item (e.g., from the item editor) that are
 200 not mapped to C<items> columns directly but should instead
 201 be stored in C<items.more_subfields_xml> and included in
 202 the biblio items tag for display and indexing.
 203
 204 =cut
 205
 206 sub AddItem {
 207     my $item = shift;
 208     my $biblionumber = shift;
 209
 210     my $dbh           = @_ ? shift : C4::Context->dbh;
 211     my $frameworkcode = @_ ? shift : GetFrameworkCode( $biblionumber );
 212     my $unlinked_item_subfields;
 213     if (@_) {
 214         $unlinked_item_subfields = shift
 215     };
 216
 217     # needs old biblionumber and biblioitemnumber
 218     $item->{'biblionumber'} = $biblionumber;
 219     my $sth = $dbh->prepare("SELECT biblioitemnumber FROM biblioitems WHERE biblionumber=?");
 220     $sth->execute( $item->{'biblionumber'} );
 221     ($item->{'biblioitemnumber'}) = $sth->fetchrow;
 222
 223     _set_defaults_for_add($item);
 224     _set_derived_columns_for_add($item);
 225     $item->{'more_subfields_xml'} = _get_unlinked_subfields_xml($unlinked_item_subfields);
 226     # FIXME - checks here
 227         my ( $itemnumber, $error ) = _koha_new_item( $item, $item->{barcode} );
 228     $item->{'itemnumber'} = $itemnumber;
 229
 230     # create MARC tag representing item and add to bib
 231     my $new_item_marc = _marc_from_item_hash($item, $frameworkcode, $unlinked_item_subfields);
 232     _add_item_field_to_biblio($new_item_marc, $item->{'biblionumber'}, $frameworkcode );
 233
 234     logaction("CATALOGUING", "ADD", $itemnumber, "item") if C4::Context->preference("CataloguingLog");
 235
 236     return ($item->{biblionumber}, $item->{biblioitemnumber}, $itemnumber);
 237 }
 238
 239 =head2 AddItemBatchFromMarc
 240
 241 =over 4
 242
 243 ($itemnumber_ref, $error_ref) = AddItemBatchFromMarc($record, $biblionumber, $biblioitemnumber, $frameworkcode);
 244
 245 =back
 246
 247 Efficiently create item records from a MARC biblio record with
 248 embedded item fields.  This routine is suitable for batch jobs.
 249
 250 This API assumes that the bib record has already been
 251 saved to the C<biblio> and C<biblioitems> tables.  It does
 252 not expect that C<biblioitems.marc> and C<biblioitems.marcxml>
 253 are populated, but it will do so via a call to ModBibiloMarc.
 254
 255 The goal of this API is to have a similar effect to using AddBiblio
 256 and AddItems in succession, but without inefficient repeated
 257 parsing of the MARC XML bib record.
 258
 259 This function returns an arrayref of new itemsnumbers and an arrayref of item
 260 errors encountered during the processing.  Each entry in the errors
 261 list is a hashref containing the following keys:
 262
 263 =over 2
 264
 265 =item item_sequence
 266
 267 Sequence number of original item tag in the MARC record.
 268
 269 =item item_barcode
 270
 271 Item barcode, provide to assist in the construction of
 272 useful error messages.
 273
 274 =item error_condition
 275
 276 Code representing the error condition.  Can be 'duplicate_barcode',
 277 'invalid_homebranch', or 'invalid_holdingbranch'.
 278
 279 =item error_information
 280
 281 Additional information appropriate to the error condition.
 282
 283 =back
 284
 285 =cut
 286
 287 sub AddItemBatchFromMarc {
 288     my ($record, $biblionumber, $biblioitemnumber, $frameworkcode) = @_;
 289     my $error;
 290     my @itemnumbers = ();
 291     my @errors = ();
 292     my $dbh = C4::Context->dbh;
 293
 294     # loop through the item tags and start creating items
 295     my @bad_item_fields = ();
 296     my ($itemtag, $itemsubfield) = &GetMarcFromKohaField("items.itemnumber",'');
 297     my $item_sequence_num = 0;
 298     ITEMFIELD: foreach my $item_field ($record->field($itemtag)) {
 299         $item_sequence_num++;
 300         # we take the item field and stick it into a new
 301         # MARC record -- this is required so far because (FIXME)
 302         # TransformMarcToKoha requires a MARC::Record, not a MARC::Field
 303         # and there is no TransformMarcFieldToKoha
 304         my $temp_item_marc = MARC::Record->new();
 305         $temp_item_marc->append_fields($item_field);
 306
 307         # add biblionumber and biblioitemnumber
 308         my $item = TransformMarcToKoha( $dbh, $temp_item_marc, $frameworkcode, 'items' );
 309         my $unlinked_item_subfields = _get_unlinked_item_subfields($temp_item_marc, $frameworkcode);
 310         $item->{'more_subfields_xml'} = _get_unlinked_subfields_xml($unlinked_item_subfields);
 311         $item->{'biblionumber'} = $biblionumber;
 312         $item->{'biblioitemnumber'} = $biblioitemnumber;
 313
 314         # check for duplicate barcode
 315         my %item_errors = CheckItemPreSave($item);
 316         if (%item_errors) {
 317             push @errors, _repack_item_errors($item_sequence_num, $item, \%item_errors);
 318             push @bad_item_fields, $item_field;
 319             next ITEMFIELD;
 320         }
 321
 322         _set_defaults_for_add($item);
 323         _set_derived_columns_for_add($item);
 324         my ( $itemnumber, $error ) = _koha_new_item( $item, $item->{barcode} );
 325         warn $error if $error;
 326         push @itemnumbers, $itemnumber; # FIXME not checking error
 327         $item->{'itemnumber'} = $itemnumber;
 328
 329         logaction("CATALOGUING", "ADD", $itemnumber, "item") if C4::Context->preference("CataloguingLog");
 330
 331         my $new_item_marc = _marc_from_item_hash($item, $frameworkcode, $unlinked_item_subfields);
 332         $item_field->replace_with($new_item_marc->field($itemtag));
 333     }
 334
 335     # remove any MARC item fields for rejected items
 336     foreach my $item_field (@bad_item_fields) {
 337         $record->delete_field($item_field);
 338     }
 339
 340     # update the MARC biblio
 341     $biblionumber = ModBiblioMarc( $record, $biblionumber, $frameworkcode );
 342
 343     return (\@itemnumbers, \@errors);
 344 }
 345
 346 =head2 ModItemFromMarc
 347
 348 =over 4
 349
 350 ModItemFromMarc($item_marc, $biblionumber, $itemnumber);
 351
 352 =back
 353
 354 This function updates an item record based on a supplied
 355 C<MARC::Record> object containing an embedded item field.
 356 This API is meant for the use of C<additem.pl>; for
 357 other purposes, C<ModItem> should be used.
 358
 359 This function uses the hash %default_values_for_mod_from_marc,
 360 which contains default values for item fields to
 361 apply when modifying an item.  This is needed beccause
 362 if an item field's value is cleared, TransformMarcToKoha
 363 does not include the column in the
 364 hash that's passed to ModItem, which without
 365 use of this hash makes it impossible to clear
 366 an item field's value.  See bug 2466.
 367
 368 Note that only columns that can be directly
 369 changed from the cataloging and serials
 370 item editors are included in this hash.
 371
 372 =cut
 373
 374 my %default_values_for_mod_from_marc = (
 375     barcode              => undef,
 376     booksellerid         => undef,
 377     ccode                => undef,
 378     'items.cn_source'    => undef,
 379     copynumber           => undef,
 380     damaged              => 0,
 381     dateaccessioned      => undef,
 382     enumchron            => undef,
 383     holdingbranch        => undef,
 384     homebranch           => undef,
 385     itemcallnumber       => undef,
 386     itemlost             => 0,
 387     itemnotes            => undef,
 388     itype                => undef,
 389     location             => undef,
 390     materials            => undef,
 391     notforloan           => 0,
 392     paidfor              => undef,
 393     price                => undef,
 394     replacementprice     => undef,
 395     replacementpricedate => undef,
 396     restricted           => undef,
 397     stack                => undef,
 398     uri                  => undef,
 399     wthdrawn             => 0,
 400 );
 401
 402 sub ModItemFromMarc {
 403     my $item_marc = shift;
 404     my $biblionumber = shift;
 405     my $itemnumber = shift;
 406
 407     my $dbh = C4::Context->dbh;
 408     my $frameworkcode = GetFrameworkCode( $biblionumber );
 409     my $item = &TransformMarcToKoha( $dbh, $item_marc, $frameworkcode );
 410     foreach my $item_field (keys %default_values_for_mod_from_marc) {
 411         $item->{$item_field} = $default_values_for_mod_from_marc{$item_field} unless exists $item->{$item_field};
 412     }
 413     my $unlinked_item_subfields = _get_unlinked_item_subfields($item_marc, $frameworkcode);
 414
 415     return ModItem($item, $biblionumber, $itemnumber, $dbh, $frameworkcode, $unlinked_item_subfields);
 416 }
 417
 418 =head2 ModItem
 419
 420 =over 4
 421
 422 ModItem({ column => $newvalue }, $biblionumber, $itemnumber[, $original_item_marc]);
 423
 424 =back
 425
 426 Change one or more columns in an item record and update
 427 the MARC representation of the item.
 428
 429 The first argument is a hashref mapping from item column
 430 names to the new values.  The second and third arguments
 431 are the biblionumber and itemnumber, respectively.
 432
 433 The fourth, optional parameter, C<$unlinked_item_subfields>, contains
 434 an arrayref containing subfields present in the original MARC
 435 representation of the item (e.g., from the item editor) that are
 436 not mapped to C<items> columns directly but should instead
 437 be stored in C<items.more_subfields_xml> and included in
 438 the biblio items tag for display and indexing.
 439
 440 If one of the changed columns is used to calculate
 441 the derived value of a column such as C<items.cn_sort>,
 442 this routine will perform the necessary calculation
 443 and set the value.
 444
 445 =cut
 446
 447 sub ModItem {
 448     my $item = shift;
 449     my $biblionumber = shift;
 450     my $itemnumber = shift;
 451
 452     # if $biblionumber is undefined, get it from the current item
 453     unless (defined $biblionumber) {
 454         $biblionumber = _get_single_item_column('biblionumber', $itemnumber);
 455     }
 456
 457     my $dbh           = @_ ? shift : C4::Context->dbh;
 458     my $frameworkcode = @_ ? shift : GetFrameworkCode( $biblionumber );
 459
 460     my $unlinked_item_subfields;
 461     if (@_) {
 462         $unlinked_item_subfields = shift;
 463         $item->{'more_subfields_xml'} = _get_unlinked_subfields_xml($unlinked_item_subfields);
 464     };
 465
 466     $item->{'itemnumber'} = $itemnumber or return undef;
 467     _set_derived_columns_for_mod($item);
 468     _do_column_fixes_for_mod($item);
 469     # FIXME add checks
 470     # duplicate barcode
 471     # attempt to change itemnumber
 472     # attempt to change biblionumber (if we want
 473     # an API to relink an item to a different bib,
 474     # it should be a separate function)
 475
 476     # update items table
 477     _koha_modify_item($item);
 478
 479     # update biblio MARC XML
 480     my $whole_item = GetItem($itemnumber) or die "FAILED GetItem($itemnumber)";
 481
 482     unless (defined $unlinked_item_subfields) {
 483         $unlinked_item_subfields = _parse_unlinked_item_subfields_from_xml($whole_item->{'more_subfields_xml'});
 484     }
 485     my $new_item_marc = _marc_from_item_hash($whole_item, $frameworkcode, $unlinked_item_subfields)
 486         or die "FAILED _marc_from_item_hash($whole_item, $frameworkcode)";
 487
 488     _replace_item_field_in_biblio($new_item_marc, $biblionumber, $itemnumber, $frameworkcode);
 489         ($new_item_marc       eq '0') and die "$new_item_marc is '0', not hashref";  # logaction line would crash anyway
 490     logaction("CATALOGUING", "MODIFY", $itemnumber, $new_item_marc->as_formatted) if C4::Context->preference("CataloguingLog");
 491 }
 492
 493 =head2 ModItemTransfer
 494
 495 =over 4
 496
 497 ModItemTransfer($itenumber, $frombranch, $tobranch);
 498
 499 =back
 500
 501 Marks an item as being transferred from one branch
 502 to another.
 503
 504 =cut
 505
 506 sub ModItemTransfer {
 507     my ( $itemnumber, $frombranch, $tobranch ) = @_;
 508
 509     my $dbh = C4::Context->dbh;
 510
 511     #new entry in branchtransfers....
 512     my $sth = $dbh->prepare(
 513         "INSERT INTO branchtransfers (itemnumber, frombranch, datesent, tobranch)
 514         VALUES (?, ?, NOW(), ?)");
 515     $sth->execute($itemnumber, $frombranch, $tobranch);
 516
 517     ModItem({ holdingbranch => $tobranch }, undef, $itemnumber);
 518     ModDateLastSeen($itemnumber);
 519     return;
 520 }
 521
 522 =head2 ModDateLastSeen
 523
 524 =over 4
 525
 526 ModDateLastSeen($itemnum);
 527
 528 =back
 529
 530 Mark item as seen. Is called when an item is issued, returned or manually marked during inventory/stocktaking.
 531 C<$itemnum> is the item number
 532
 533 =cut
 534
 535 sub ModDateLastSeen {
 536     my ($itemnumber) = @_;
 537
 538     my $today = C4::Dates->new();
 539     ModItem({ itemlost => 0, datelastseen => $today->output("iso") }, undef, $itemnumber);
 540 }
 541
 542 =head2 DelItem
 543
 544 =over 4
 545
 546 DelItem($biblionumber, $itemnumber);
 547
 548 =back
 549
 550 Exported function (core API) for deleting an item record in Koha.
 551
 552 =cut
 553
 554 sub DelItem {
 555     my ( $dbh, $biblionumber, $itemnumber ) = @_;
 556
 557     # FIXME check the item has no current issues
 558
 559     _koha_delete_item( $dbh, $itemnumber );
 560
 561     # get the MARC record
 562     my $record = GetMarcBiblio($biblionumber);
 563     my $frameworkcode = GetFrameworkCode($biblionumber);
 564
 565     # backup the record
 566     my $copy2deleted = $dbh->prepare("UPDATE deleteditems SET marc=? WHERE itemnumber=?");
 567     $copy2deleted->execute( $record->as_usmarc(), $itemnumber );
 568
 569     #search item field code
 570     my ( $itemtag, $itemsubfield ) = GetMarcFromKohaField("items.itemnumber",$frameworkcode);
 571     my @fields = $record->field($itemtag);
 572
 573     # delete the item specified
 574     foreach my $field (@fields) {
 575         if ( $field->subfield($itemsubfield) eq $itemnumber ) {
 576             $record->delete_field($field);
 577         }
 578     }
 579     &ModBiblioMarc( $record, $biblionumber, $frameworkcode );
 580     logaction("CATALOGUING", "DELETE", $itemnumber, "item") if C4::Context->preference("CataloguingLog");
 581 }
 582
 583 =head2 CheckItemPreSave
 584
 585 =over 4
 586
 587     my $item_ref = TransformMarcToKoha($marc, 'items');
 588     # do stuff
 589     my %errors = CheckItemPreSave($item_ref);
 590     if (exists $errors{'duplicate_barcode'}) {
 591         print "item has duplicate barcode: ", $errors{'duplicate_barcode'}, "\n";
 592     } elsif (exists $errors{'invalid_homebranch'}) {
 593         print "item has invalid home branch: ", $errors{'invalid_homebranch'}, "\n";
 594     } elsif (exists $errors{'invalid_holdingbranch'}) {
 595         print "item has invalid holding branch: ", $errors{'invalid_holdingbranch'}, "\n";
 596     } else {
 597         print "item is OK";
 598     }
 599
 600 =back
 601
 602 Given a hashref containing item fields, determine if it can be
 603 inserted or updated in the database.  Specifically, checks for
 604 database integrity issues, and returns a hash containing any
 605 of the following keys, if applicable.
 606
 607 =over 2
 608
 609 =item duplicate_barcode
 610
 611 Barcode, if it duplicates one already found in the database.
 612
 613 =item invalid_homebranch
 614
 615 Home branch, if not defined in branches table.
 616
 617 =item invalid_holdingbranch
 618
 619 Holding branch, if not defined in branches table.
 620
 621 =back
 622
 623 This function does NOT implement any policy-related checks,
 624 e.g., whether current operator is allowed to save an
 625 item that has a given branch code.
 626
 627 =cut
 628
 629 sub CheckItemPreSave {
 630     my $item_ref = shift;
 631
 632     my %errors = ();
 633
 634     # check for duplicate barcode
 635     if (exists $item_ref->{'barcode'} and defined $item_ref->{'barcode'}) {
 636         my $existing_itemnumber = GetItemnumberFromBarcode($item_ref->{'barcode'});
 637         if ($existing_itemnumber) {
 638             if (!exists $item_ref->{'itemnumber'}                       # new item
 639                 or $item_ref->{'itemnumber'} != $existing_itemnumber) { # existing item
 640                 $errors{'duplicate_barcode'} = $item_ref->{'barcode'};
 641             }
 642         }
 643     }
 644
 645     # check for valid home branch
 646     if (exists $item_ref->{'homebranch'} and defined $item_ref->{'homebranch'}) {
 647         my $branch_name = GetBranchName($item_ref->{'homebranch'});
 648         unless (defined $branch_name) {
 649             # relies on fact that branches.branchname is a non-NULL column,
 650             # so GetBranchName returns undef only if branch does not exist
 651             $errors{'invalid_homebranch'} = $item_ref->{'homebranch'};
 652         }
 653     }
 654
 655     # check for valid holding branch
 656     if (exists $item_ref->{'holdingbranch'} and defined $item_ref->{'holdingbranch'}) {
 657         my $branch_name = GetBranchName($item_ref->{'holdingbranch'});
 658         unless (defined $branch_name) {
 659             # relies on fact that branches.branchname is a non-NULL column,
 660             # so GetBranchName returns undef only if branch does not exist
 661             $errors{'invalid_holdingbranch'} = $item_ref->{'holdingbranch'};
 662         }
 663     }
 664
 665     return %errors;
 666
 667 }
 668
 669 =head1 EXPORTED SPECIAL ACCESSOR FUNCTIONS
 670
 671 The following functions provide various ways of
 672 getting an item record, a set of item records, or
 673 lists of authorized values for certain item fields.
 674
 675 Some of the functions in this group are candidates
 676 for refactoring -- for example, some of the code
 677 in C<GetItemsByBiblioitemnumber> and C<GetItemsInfo>
 678 has copy-and-paste work.
 679
 680 =cut
 681
 682 =head2 GetItemStatus
 683
 684 =over 4
 685
 686 $itemstatushash = GetItemStatus($fwkcode);
 687
 688 =back
 689
 690 Returns a list of valid values for the
 691 C<items.notforloan> field.
 692
 693 NOTE: does B<not> return an individual item's
 694 status.
 695
 696 Can be MARC dependant.
 697 fwkcode is optional.
 698 But basically could be can be loan or not
 699 Create a status selector with the following code
 700
 701 =head3 in PERL SCRIPT
 702
 703 =over 4
 704
 705 my $itemstatushash = getitemstatus;
 706 my @itemstatusloop;
 707 foreach my $thisstatus (keys %$itemstatushash) {
 708     my %row =(value => $thisstatus,
 709                 statusname => $itemstatushash->{$thisstatus}->{'statusname'},
 710             );
 711     push @itemstatusloop, \%row;
 712 }
 713 $template->param(statusloop=>\@itemstatusloop);
 714
 715 =back
 716
 717 =head3 in TEMPLATE
 718
 719 =over 4
 720
 721 <select name="statusloop">
 722     <option value="">Default</option>
 723 <!-- TMPL_LOOP name="statusloop" -->
 724     <option value="<!-- TMPL_VAR name="value" -->" <!-- TMPL_IF name="selected" -->selected<!-- /TMPL_IF -->><!-- TMPL_VAR name="statusname" --></option>
 725 <!-- /TMPL_LOOP -->
 726 </select>
 727
 728 =back
 729
 730 =cut
 731
 732 sub GetItemStatus {
 733
 734     # returns a reference to a hash of references to status...
 735     my ($fwk) = @_;
 736     my %itemstatus;
 737     my $dbh = C4::Context->dbh;
 738     my $sth;
 739     $fwk = '' unless ($fwk);
 740     my ( $tag, $subfield ) =
 741       GetMarcFromKohaField( "items.notforloan", $fwk );
 742     if ( $tag and $subfield ) {
 743         my $sth =
 744           $dbh->prepare(
 745             "SELECT authorised_value
 746             FROM marc_subfield_structure
 747             WHERE tagfield=?
 748                 AND tagsubfield=?
 749                 AND frameworkcode=?
 750             "
 751           );
 752         $sth->execute( $tag, $subfield, $fwk );
 753         if ( my ($authorisedvaluecat) = $sth->fetchrow ) {
 754             my $authvalsth =
 755               $dbh->prepare(
 756                 "SELECT authorised_value,lib
 757                 FROM authorised_values
 758                 WHERE category=?
 759                 ORDER BY lib
 760                 "
 761               );
 762             $authvalsth->execute($authorisedvaluecat);
 763             while ( my ( $authorisedvalue, $lib ) = $authvalsth->fetchrow ) {
 764                 $itemstatus{$authorisedvalue} = $lib;
 765             }
 766             $authvalsth->finish;
 767             return \%itemstatus;
 768             exit 1;
 769         }
 770         else {
 771
 772             #No authvalue list
 773             # build default
 774         }
 775         $sth->finish;
 776     }
 777
 778     #No authvalue list
 779     #build default
 780     $itemstatus{"1"} = "Not For Loan";
 781     return \%itemstatus;
 782 }
 783
 784 =head2 GetItemLocation
 785
 786 =over 4
 787
 788 $itemlochash = GetItemLocation($fwk);
 789
 790 =back
 791
 792 Returns a list of valid values for the
 793 C<items.location> field.
 794
 795 NOTE: does B<not> return an individual item's
 796 location.
 797
 798 where fwk stands for an optional framework code.
 799 Create a location selector with the following code
 800
 801 =head3 in PERL SCRIPT
 802
 803 =over 4
 804
 805 my $itemlochash = getitemlocation;
 806 my @itemlocloop;
 807 foreach my $thisloc (keys %$itemlochash) {
 808     my $selected = 1 if $thisbranch eq $branch;
 809     my %row =(locval => $thisloc,
 810                 selected => $selected,
 811                 locname => $itemlochash->{$thisloc},
 812             );
 813     push @itemlocloop, \%row;
 814 }
 815 $template->param(itemlocationloop => \@itemlocloop);
 816
 817 =back
 818
 819 =head3 in TEMPLATE
 820
 821 =over 4
 822
 823 <select name="location">
 824     <option value="">Default</option>
 825 <!-- TMPL_LOOP name="itemlocationloop" -->
 826     <option value="<!-- TMPL_VAR name="locval" -->" <!-- TMPL_IF name="selected" -->selected<!-- /TMPL_IF -->><!-- TMPL_VAR name="locname" --></option>
 827 <!-- /TMPL_LOOP -->
 828 </select>
 829
 830 =back
 831
 832 =cut
 833
 834 sub GetItemLocation {
 835
 836     # returns a reference to a hash of references to location...
 837     my ($fwk) = @_;
 838     my %itemlocation;
 839     my $dbh = C4::Context->dbh;
 840     my $sth;
 841     $fwk = '' unless ($fwk);
 842     my ( $tag, $subfield ) =
 843       GetMarcFromKohaField( "items.location", $fwk );
 844     if ( $tag and $subfield ) {
 845         my $sth =
 846           $dbh->prepare(
 847             "SELECT authorised_value
 848             FROM marc_subfield_structure
 849             WHERE tagfield=?
 850                 AND tagsubfield=?
 851                 AND frameworkcode=?"
 852           );
 853         $sth->execute( $tag, $subfield, $fwk );
 854         if ( my ($authorisedvaluecat) = $sth->fetchrow ) {
 855             my $authvalsth =
 856               $dbh->prepare(
 857                 "SELECT authorised_value,lib
 858                 FROM authorised_values
 859                 WHERE category=?
 860                 ORDER BY lib"
 861               );
 862             $authvalsth->execute($authorisedvaluecat);
 863             while ( my ( $authorisedvalue, $lib ) = $authvalsth->fetchrow ) {
 864                 $itemlocation{$authorisedvalue} = $lib;
 865             }
 866             $authvalsth->finish;
 867             return \%itemlocation;
 868             exit 1;
 869         }
 870         else {
 871
 872             #No authvalue list
 873             # build default
 874         }
 875         $sth->finish;
 876     }
 877
 878     #No authvalue list
 879     #build default
 880     $itemlocation{"1"} = "Not For Loan";
 881     return \%itemlocation;
 882 }
 883
 884 =head2 GetLostItems
 885
 886 =over 4
 887
 888 $items = GetLostItems( $where, $orderby );
 889
 890 =back
 891
 892 This function gets a list of lost items.
 893
 894 =over 2
 895
 896 =item input:
 897
 898 C<$where> is a hashref. it containts a field of the items table as key
 899 and the value to match as value. For example:
 900
 901 { barcode    => 'abc123',
 902   homebranch => 'CPL',    }
 903
 904 C<$orderby> is a field of the items table by which the resultset
 905 should be orderd.
 906
 907 =item return:
 908
 909 C<$items> is a reference to an array full of hashrefs with columns
 910 from the "items" table as keys.
 911
 912 =item usage in the perl script:
 913
 914 my $where = { barcode => '0001548' };
 915 my $items = GetLostItems( $where, "homebranch" );
 916 $template->param( itemsloop => $items );
 917
 918 =back
 919
 920 =cut
 921
 922 sub GetLostItems {
 923     # Getting input args.
 924     my $where   = shift;
 925     my $orderby = shift;
 926     my $dbh     = C4::Context->dbh;
 927
 928     my $query   = "
 929         SELECT *
 930         FROM   items, biblio, authorised_values
 931         WHERE
 932                         items.biblionumber = biblio.biblionumber
 933                         AND items.itemlost = authorised_values.authorised_value
 934                         AND authorised_values.category = 'LOST'
 935                 AND itemlost IS NOT NULL
 936                 AND itemlost <> 0
 937
 938     ";
 939     my @query_parameters;
 940     foreach my $key (keys %$where) {
 941         $query .= " AND $key LIKE ?";
 942         push @query_parameters, "%$where->{$key}%";
 943     }
 944     if ( defined $orderby ) {
 945         $query .= ' ORDER BY ?';
 946         push @query_parameters, $orderby;
 947     }
 948
 949     my $sth = $dbh->prepare($query);
 950     $sth->execute( @query_parameters );
 951     my $items = [];
 952     while ( my $row = $sth->fetchrow_hashref ){
 953         push @$items, $row;
 954     }
 955     return $items;
 956 }
 957
 958 =head2 GetItemsForInventory
 959
 960 =over 4
 961
 962 $itemlist = GetItemsForInventory($minlocation, $maxlocation, $location, $itemtype $datelastseen, $branch, $offset, $size);
 963
 964 =back
 965
 966 Retrieve a list of title/authors/barcode/callnumber, for biblio inventory.
 967
 968 The sub returns a reference to a list of hashes, each containing
 969 itemnumber, author, title, barcode, item callnumber, and date last
 970 seen. It is ordered by callnumber then title.
 971
 972 The required minlocation & maxlocation parameters are used to specify a range of item callnumbers
 973 the datelastseen can be used to specify that you want to see items not seen since a past date only.
 974 offset & size can be used to retrieve only a part of the whole listing (defaut behaviour)
 975
 976 =cut
 977
 978 sub GetItemsForInventory {
 979     my ( $minlocation, $maxlocation,$location, $itemtype, $datelastseen, $branch, $offset, $size ) = @_;
 980     my $dbh = C4::Context->dbh;
 981
 982     my $query = <<'END_SQL';
 983 SELECT itemnumber, barcode, itemcallnumber, title, author, biblio.biblionumber, datelastseen
 984 FROM items
 985   LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
 986   LEFT JOIN biblioitems on items.biblionumber = biblioitems.biblionumber
 987 WHERE itemcallnumber >= ?
 988   AND itemcallnumber <= ?
 989 END_SQL
 990     my @bind_params = ( $minlocation, $maxlocation );
 991
 992     if ($datelastseen) {
 993         $datelastseen = format_date_in_iso($datelastseen);
 994         $query .= ' AND (datelastseen < ? OR datelastseen IS NULL) ';
 995         push @bind_params, $datelastseen;
 996     }
 997
 998     if ( $location ) {
 999         $query.= ' AND items.location = ? ';
1000         push @bind_params, $location;
1001     }
1002
1003     if ( $branch ) {
1004         $query.= ' AND items.homebranch = ? ';
1005         push @bind_params, $branch;
1006     }
1007
1008     if ( $itemtype ) {
1009         $query.= ' AND biblioitems.itemtype = ? ';
1010         push @bind_params, $itemtype;
1011     }
1012
1013     $query .= ' ORDER BY itemcallnumber, title';
1014     my $sth = $dbh->prepare($query);
1015     $sth->execute( @bind_params );
1016
1017     my @results;
1018     $size--;
1019     while ( my $row = $sth->fetchrow_hashref ) {
1020         $offset-- if ($offset);
1021         $row->{datelastseen}=format_date($row->{datelastseen});
1022         if ( ( !$offset ) && $size ) {
1023             push @results, $row;
1024             $size--;
1025         }
1026     }
1027     return \@results;
1028 }
1029
1030 =head2 GetItemsCount
1031
1032 =over 4
1033 $count = &GetItemsCount( $biblionumber);
1034
1035 =back
1036
1037 This function return count of item with $biblionumber
1038
1039 =cut
1040
1041 sub GetItemsCount {
1042     my ( $biblionumber ) = @_;
1043     my $dbh = C4::Context->dbh;
1044     my $query = "SELECT count(*)
1045           FROM  items
1046           WHERE biblionumber=?";
1047     my $sth = $dbh->prepare($query);
1048     $sth->execute($biblionumber);
1049     my $count = $sth->fetchrow;
1050     $sth->finish;
1051     return ($count);
1052 }
1053
1054 =head2 GetItemInfosOf
1055
1056 =over 4
1057
1058 GetItemInfosOf(@itemnumbers);
1059
1060 =back
1061
1062 =cut
1063
1064 sub GetItemInfosOf {
1065     my @itemnumbers = @_;
1066
1067     my $query = '
1068         SELECT *
1069         FROM items
1070         WHERE itemnumber IN (' . join( ',', @itemnumbers ) . ')
1071     ';
1072     return get_infos_of( $query, 'itemnumber' );
1073 }
1074
1075 =head2 GetItemsByBiblioitemnumber
1076
1077 =over 4
1078
1079 GetItemsByBiblioitemnumber($biblioitemnumber);
1080
1081 =back
1082
1083 Returns an arrayref of hashrefs suitable for use in a TMPL_LOOP
1084 Called by C<C4::XISBN>
1085
1086 =cut
1087
1088 sub GetItemsByBiblioitemnumber {
1089     my ( $bibitem ) = @_;
1090     my $dbh = C4::Context->dbh;
1091     my $sth = $dbh->prepare("SELECT * FROM items WHERE items.biblioitemnumber = ?") || die $dbh->errstr;
1092     # Get all items attached to a biblioitem
1093     my $i = 0;
1094     my @results;
1095     $sth->execute($bibitem) || die $sth->errstr;
1096     while ( my $data = $sth->fetchrow_hashref ) {
1097         # Foreach item, get circulation information
1098         my $sth2 = $dbh->prepare( "SELECT * FROM issues,borrowers
1099                                    WHERE itemnumber = ?
1100                                    AND issues.borrowernumber = borrowers.borrowernumber"
1101         );
1102         $sth2->execute( $data->{'itemnumber'} );
1103         if ( my $data2 = $sth2->fetchrow_hashref ) {
1104             # if item is out, set the due date and who it is out too
1105             $data->{'date_due'}   = $data2->{'date_due'};
1106             $data->{'cardnumber'} = $data2->{'cardnumber'};
1107             $data->{'borrowernumber'}   = $data2->{'borrowernumber'};
1108         }
1109         else {
1110             # set date_due to blank, so in the template we check itemlost, and wthdrawn
1111             $data->{'date_due'} = '';
1112         }    # else
1113         $sth2->finish;
1114         # Find the last 3 people who borrowed this item.
1115         my $query2 = "SELECT * FROM old_issues, borrowers WHERE itemnumber = ?
1116                       AND old_issues.borrowernumber = borrowers.borrowernumber
1117                       ORDER BY returndate desc,timestamp desc LIMIT 3";
1118         $sth2 = $dbh->prepare($query2) || die $dbh->errstr;
1119         $sth2->execute( $data->{'itemnumber'} ) || die $sth2->errstr;
1120         my $i2 = 0;
1121         while ( my $data2 = $sth2->fetchrow_hashref ) {
1122             $data->{"timestamp$i2"} = $data2->{'timestamp'};
1123             $data->{"card$i2"}      = $data2->{'cardnumber'};
1124             $data->{"borrower$i2"}  = $data2->{'borrowernumber'};
1125             $i2++;
1126         }
1127         $sth2->finish;
1128         push(@results,$data);
1129     }
1130     $sth->finish;
1131     return (\@results);
1132 }
1133
1134 =head2 GetItemsInfo
1135
1136 =over 4
1137
1138 @results = GetItemsInfo($biblionumber, $type);
1139
1140 =back
1141
1142 Returns information about books with the given biblionumber.
1143
1144 C<$type> may be either C<intra> or anything else. If it is not set to
1145 C<intra>, then the search will exclude lost, very overdue, and
1146 withdrawn items.
1147
1148 C<GetItemsInfo> returns a list of references-to-hash. Each element
1149 contains a number of keys. Most of them are table items from the
1150 C<biblio>, C<biblioitems>, C<items>, and C<itemtypes> tables in the
1151 Koha database. Other keys include:
1152
1153 =over 2
1154
1155 =item C<$data-E<gt>{branchname}>
1156
1157 The name (not the code) of the branch to which the book belongs.
1158
1159 =item C<$data-E<gt>{datelastseen}>
1160
1161 This is simply C<items.datelastseen>, except that while the date is
1162 stored in YYYY-MM-DD format in the database, here it is converted to
1163 DD/MM/YYYY format. A NULL date is returned as C<//>.
1164
1165 =item C<$data-E<gt>{datedue}>
1166
1167 =item C<$data-E<gt>{class}>
1168
1169 This is the concatenation of C<biblioitems.classification>, the book's
1170 Dewey code, and C<biblioitems.subclass>.
1171
1172 =item C<$data-E<gt>{ocount}>
1173
1174 I think this is the number of copies of the book available.
1175
1176 =item C<$data-E<gt>{order}>
1177
1178 If this is set, it is set to C<One Order>.
1179
1180 =back
1181
1182 =cut
1183
1184 sub GetItemsInfo {
1185     my ( $biblionumber, $type ) = @_;
1186     my $dbh   = C4::Context->dbh;
1187     my $query = "SELECT items.*,biblio.*,biblioitems.volume,biblioitems.number,biblioitems.itemtype,biblioitems.isbn,biblioitems.issn,biblioitems.publicationyear,biblioitems.publishercode,biblioitems.volumedate,biblioitems.volumedesc,biblioitems.lccn,biblioitems.url,items.notforloan as itemnotforloan
1188                  FROM items
1189                  LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
1190                  LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber";
1191     $query .=  (C4::Context->preference('item-level_itypes')) ?
1192                      " LEFT JOIN itemtypes on items.itype = itemtypes.itemtype "
1193                     : " LEFT JOIN itemtypes on biblioitems.itemtype = itemtypes.itemtype ";
1194     $query .= "WHERE items.biblionumber = ? ORDER BY items.dateaccessioned desc" ;
1195     my $sth = $dbh->prepare($query);
1196     $sth->execute($biblionumber);
1197     my $i = 0;
1198     my @results;
1199     my ( $date_due, $count_reserves, $serial );
1200
1201     my $isth    = $dbh->prepare(
1202         "SELECT issues.*,borrowers.cardnumber,borrowers.surname,borrowers.firstname,borrowers.branchcode as bcode
1203         FROM   issues LEFT JOIN borrowers ON issues.borrowernumber=borrowers.borrowernumber
1204         WHERE  itemnumber = ?"
1205        );
1206         my $ssth = $dbh->prepare("SELECT serialseq,publisheddate from serialitems left join serial on serialitems.serialid=serial.serialid where serialitems.itemnumber=? ");
1207         while ( my $data = $sth->fetchrow_hashref ) {
1208         my $datedue = '';
1209         $isth->execute( $data->{'itemnumber'} );
1210         if ( my $idata = $isth->fetchrow_hashref ) {
1211             $data->{borrowernumber} = $idata->{borrowernumber};
1212             $data->{cardnumber}     = $idata->{cardnumber};
1213             $data->{surname}     = $idata->{surname};
1214             $data->{firstname}     = $idata->{firstname};
1215             $datedue                = $idata->{'date_due'};
1216         if (C4::Context->preference("IndependantBranches")){
1217         my $userenv = C4::Context->userenv;
1218         if ( ($userenv) && ( $userenv->{flags} != 1 ) ) {
1219             $data->{'NOTSAMEBRANCH'} = 1 if ($idata->{'bcode'} ne $userenv->{branch});
1220         }
1221         }
1222         }
1223                 if ( $data->{'serial'}) {
1224                         $ssth->execute($data->{'itemnumber'}) ;
1225                         ($data->{'serialseq'} , $data->{'publisheddate'}) = $ssth->fetchrow_array();
1226                         $serial = 1;
1227         }
1228                 if ( $datedue eq '' ) {
1229             my ( $restype, $reserves ) =
1230               C4::Reserves::CheckReserves( $data->{'itemnumber'} );
1231             if ($restype) {
1232                 $count_reserves = $restype;
1233             }
1234         }
1235         $isth->finish;
1236         $ssth->finish;
1237         #get branch information.....
1238         my $bsth = $dbh->prepare(
1239             "SELECT * FROM branches WHERE branchcode = ?
1240         "
1241         );
1242         $bsth->execute( $data->{'holdingbranch'} );
1243         if ( my $bdata = $bsth->fetchrow_hashref ) {
1244             $data->{'branchname'} = $bdata->{'branchname'};
1245         }
1246         $data->{'datedue'}        = $datedue;
1247         $data->{'count_reserves'} = $count_reserves;
1248
1249         # get notforloan complete status if applicable
1250         my $sthnflstatus = $dbh->prepare(
1251             'SELECT authorised_value
1252             FROM   marc_subfield_structure
1253             WHERE  kohafield="items.notforloan"
1254         '
1255         );
1256
1257         $sthnflstatus->execute;
1258         my ($authorised_valuecode) = $sthnflstatus->fetchrow;
1259         if ($authorised_valuecode) {
1260             $sthnflstatus = $dbh->prepare(
1261                 "SELECT lib FROM authorised_values
1262                  WHERE  category=?
1263                  AND authorised_value=?"
1264             );
1265             $sthnflstatus->execute( $authorised_valuecode,
1266                 $data->{itemnotforloan} );
1267             my ($lib) = $sthnflstatus->fetchrow;
1268             $data->{notforloanvalue} = $lib;
1269         }
1270                 $data->{itypenotforloan} = $data->{notforloan} if (C4::Context->preference('item-level_itypes'));
1271
1272         # my stack procedures
1273         my $stackstatus = $dbh->prepare(
1274             'SELECT authorised_value
1275              FROM   marc_subfield_structure
1276              WHERE  kohafield="items.stack"
1277         '
1278         );
1279         $stackstatus->execute;
1280
1281         ($authorised_valuecode) = $stackstatus->fetchrow;
1282         if ($authorised_valuecode) {
1283             $stackstatus = $dbh->prepare(
1284                 "SELECT lib
1285                  FROM   authorised_values
1286                  WHERE  category=?
1287                  AND    authorised_value=?
1288             "
1289             );
1290             $stackstatus->execute( $authorised_valuecode, $data->{stack} );
1291             my ($lib) = $stackstatus->fetchrow;
1292             $data->{stack} = $lib;
1293         }
1294         # Find the last 3 people who borrowed this item.
1295         my $sth2 = $dbh->prepare("SELECT * FROM old_issues,borrowers
1296                                     WHERE itemnumber = ?
1297                                     AND old_issues.borrowernumber = borrowers.borrowernumber
1298                                     ORDER BY returndate DESC
1299                                     LIMIT 3");
1300         $sth2->execute($data->{'itemnumber'});
1301         my $ii = 0;
1302         while (my $data2 = $sth2->fetchrow_hashref()) {
1303             $data->{"timestamp$ii"} = $data2->{'timestamp'} if $data2->{'timestamp'};
1304             $data->{"card$ii"}      = $data2->{'cardnumber'} if $data2->{'cardnumber'};
1305             $data->{"borrower$ii"}  = $data2->{'borrowernumber'} if $data2->{'borrowernumber'};
1306             $ii++;
1307         }
1308
1309         $results[$i] = $data;
1310         $i++;
1311     }
1312     $sth->finish;
1313         if($serial) {
1314                 return( sort { ($b->{'publisheddate'} || $b->{'enumchron'}) cmp ($a->{'publisheddate'} || $a->{'enumchron'}) } @results );
1315         } else {
1316         return (@results);
1317         }
1318 }
1319
1320 =head2 get_itemnumbers_of
1321
1322 =over 4
1323
1324 my @itemnumbers_of = get_itemnumbers_of(@biblionumbers);
1325
1326 =back
1327
1328 Given a list of biblionumbers, return the list of corresponding itemnumbers
1329 for each biblionumber.
1330
1331 Return a reference on a hash where keys are biblionumbers and values are
1332 references on array of itemnumbers.
1333
1334 =cut
1335
1336 sub get_itemnumbers_of {
1337     my @biblionumbers = @_;
1338
1339     my $dbh = C4::Context->dbh;
1340
1341     my $query = '
1342         SELECT itemnumber,
1343             biblionumber
1344         FROM items
1345         WHERE biblionumber IN (?' . ( ',?' x scalar @biblionumbers - 1 ) . ')
1346     ';
1347     my $sth = $dbh->prepare($query);
1348     $sth->execute(@biblionumbers);
1349
1350     my %itemnumbers_of;
1351
1352     while ( my ( $itemnumber, $biblionumber ) = $sth->fetchrow_array ) {
1353         push @{ $itemnumbers_of{$biblionumber} }, $itemnumber;
1354     }
1355
1356     return \%itemnumbers_of;
1357 }
1358
1359 =head2 GetItemnumberFromBarcode
1360
1361 =over 4
1362
1363 $result = GetItemnumberFromBarcode($barcode);
1364
1365 =back
1366
1367 =cut
1368
1369 sub GetItemnumberFromBarcode {
1370     my ($barcode) = @_;
1371     my $dbh = C4::Context->dbh;
1372
1373     my $rq =
1374       $dbh->prepare("SELECT itemnumber FROM items WHERE items.barcode=?");
1375     $rq->execute($barcode);
1376     my ($result) = $rq->fetchrow;
1377     return ($result);
1378 }
1379
1380 =head3 get_item_authorised_values
1381
1382   find the types and values for all authorised values assigned to this item.
1383
1384   parameters:
1385     itemnumber
1386
1387   returns: a hashref malling the authorised value to the value set for this itemnumber
1388
1389     $authorised_values = {
1390              'CCODE'      => undef,
1391              'DAMAGED'    => '0',
1392              'LOC'        => '3',
1393              'LOST'       => '0'
1394              'NOT_LOAN'   => '0',
1395              'RESTRICTED' => undef,
1396              'STACK'      => undef,
1397              'WITHDRAWN'  => '0',
1398              'branches'   => 'CPL',
1399              'cn_source'  => undef,
1400              'itemtypes'  => 'SER',
1401            };
1402
1403    Notes: see C4::Biblio::get_biblio_authorised_values for a similar method at the biblio level.
1404
1405 =cut
1406
1407 sub get_item_authorised_values {
1408     my $itemnumber = shift;
1409
1410     # assume that these entries in the authorised_value table are item level.
1411     my $query = q(SELECT distinct authorised_value, kohafield
1412                     FROM marc_subfield_structure
1413                     WHERE kohafield like 'item%'
1414                       AND authorised_value != '' );
1415
1416     my $itemlevel_authorised_values = C4::Context->dbh->selectall_hashref( $query, 'authorised_value' );
1417     my $iteminfo = GetItem( $itemnumber );
1418     # warn( Data::Dumper->Dump( [ $itemlevel_authorised_values ], [ 'itemlevel_authorised_values' ] ) );
1419     my $return;
1420     foreach my $this_authorised_value ( keys %$itemlevel_authorised_values ) {
1421         my $field = $itemlevel_authorised_values->{ $this_authorised_value }->{'kohafield'};
1422         $field =~ s/^items\.//;
1423         if ( exists $iteminfo->{ $field } ) {
1424             $return->{ $this_authorised_value } = $iteminfo->{ $field };
1425         }
1426     }
1427     # warn( Data::Dumper->Dump( [ $return ], [ 'return' ] ) );
1428     return $return;
1429 }
1430
1431 =head3 get_authorised_value_images
1432
1433   find a list of icons that are appropriate for display based on the
1434   authorised values for a biblio.
1435
1436   parameters: listref of authorised values, such as comes from
1437     get_item_ahtorised_values or
1438     from C4::Biblio::get_biblio_authorised_values
1439
1440   returns: listref of hashrefs for each image. Each hashref looks like
1441     this:
1442
1443       { imageurl => '/intranet-tmpl/prog/img/itemtypeimg/npl/WEB.gif',
1444         label    => '',
1445         category => '',
1446         value    => '', }
1447
1448   Notes: Currently, I put on the full path to the images on the staff
1449   side. This should either be configurable or not done at all. Since I
1450   have to deal with 'intranet' or 'opac' in
1451   get_biblio_authorised_values, perhaps I should be passing it in.
1452
1453 =cut
1454
1455 sub get_authorised_value_images {
1456     my $authorised_values = shift;
1457
1458     my @imagelist;
1459
1460     my $authorised_value_list = GetAuthorisedValues();
1461     # warn ( Data::Dumper->Dump( [ $authorised_value_list ], [ 'authorised_value_list' ] ) );
1462     foreach my $this_authorised_value ( @$authorised_value_list ) {
1463         if ( exists $authorised_values->{ $this_authorised_value->{'category'} }
1464              && $authorised_values->{ $this_authorised_value->{'category'} } eq $this_authorised_value->{'authorised_value'} ) {
1465             # warn ( Data::Dumper->Dump( [ $this_authorised_value ], [ 'this_authorised_value' ] ) );
1466             if ( defined $this_authorised_value->{'imageurl'} ) {
1467                 push @imagelist, { imageurl => C4::Koha::getitemtypeimagelocation( 'intranet', $this_authorised_value->{'imageurl'} ),
1468                                    label    => $this_authorised_value->{'lib'},
1469                                    category => $this_authorised_value->{'category'},
1470                                    value    => $this_authorised_value->{'authorised_value'}, };
1471             }
1472         }
1473     }
1474
1475     # warn ( Data::Dumper->Dump( [ \@imagelist ], [ 'imagelist' ] ) );
1476     return \@imagelist;
1477
1478 }
1479
1480 =head1 LIMITED USE FUNCTIONS
1481
1482 The following functions, while part of the public API,
1483 are not exported.  This is generally because they are
1484 meant to be used by only one script for a specific
1485 purpose, and should not be used in any other context
1486 without careful thought.
1487
1488 =cut
1489
1490 =head2 GetMarcItem
1491
1492 =over 4
1493
1494 my $item_marc = GetMarcItem($biblionumber, $itemnumber);
1495
1496 =back
1497
1498 Returns MARC::Record of the item passed in parameter.
1499 This function is meant for use only in C<cataloguing/additem.pl>,
1500 where it is needed to support that script's MARC-like
1501 editor.
1502
1503 =cut
1504
1505 sub GetMarcItem {
1506     my ( $biblionumber, $itemnumber ) = @_;
1507
1508     # GetMarcItem has been revised so that it does the following:
1509     #  1. Gets the item information from the items table.
1510     #  2. Converts it to a MARC field for storage in the bib record.
1511     #
1512     # The previous behavior was:
1513     #  1. Get the bib record.
1514     #  2. Return the MARC tag corresponding to the item record.
1515     #
1516     # The difference is that one treats the items row as authoritative,
1517     # while the other treats the MARC representation as authoritative
1518     # under certain circumstances.
1519
1520     my $itemrecord = GetItem($itemnumber);
1521
1522     # Tack on 'items.' prefix to column names so that TransformKohaToMarc will work.
1523     # Also, don't emit a subfield if the underlying field is blank.
1524     my $mungeditem = { map {  $itemrecord->{$_} ne '' ? ("items.$_" => $itemrecord->{$_}) : ()  } keys %{ $itemrecord } };
1525     my $itemmarc = TransformKohaToMarc($mungeditem);
1526
1527     my $unlinked_item_subfields = _parse_unlinked_item_subfields_from_xml($mungeditem->{'items.more_subfields_xml'});
1528     if (defined $unlinked_item_subfields and $#$unlinked_item_subfields > -1) {
1529         my @fields = $itemmarc->fields();
1530         if ($#fields > -1) {
1531             $fields[0]->add_subfields(@$unlinked_item_subfields);
1532         }
1533     }
1534
1535     return $itemmarc;
1536
1537 }
1538
1539 =head1 PRIVATE FUNCTIONS AND VARIABLES
1540
1541 The following functions are not meant to be called
1542 directly, but are documented in order to explain
1543 the inner workings of C<C4::Items>.
1544
1545 =cut
1546
1547 =head2 %derived_columns
1548
1549 This hash keeps track of item columns that
1550 are strictly derived from other columns in
1551 the item record and are not meant to be set
1552 independently.
1553
1554 Each key in the hash should be the name of a
1555 column (as named by TransformMarcToKoha).  Each
1556 value should be hashref whose keys are the
1557 columns on which the derived column depends.  The
1558 hashref should also contain a 'BUILDER' key
1559 that is a reference to a sub that calculates
1560 the derived value.
1561
1562 =cut
1563
1564 my %derived_columns = (
1565     'items.cn_sort' => {
1566         'itemcallnumber' => 1,
1567         'items.cn_source' => 1,
1568         'BUILDER' => \&_calc_items_cn_sort,
1569     }
1570 );
1571
1572 =head2 _set_derived_columns_for_add
1573
1574 =over 4
1575
1576 _set_derived_column_for_add($item);
1577
1578 =back
1579
1580 Given an item hash representing a new item to be added,
1581 calculate any derived columns.  Currently the only
1582 such column is C<items.cn_sort>.
1583
1584 =cut
1585
1586 sub _set_derived_columns_for_add {
1587     my $item = shift;
1588
1589     foreach my $column (keys %derived_columns) {
1590         my $builder = $derived_columns{$column}->{'BUILDER'};
1591         my $source_values = {};
1592         foreach my $source_column (keys %{ $derived_columns{$column} }) {
1593             next if $source_column eq 'BUILDER';
1594             $source_values->{$source_column} = $item->{$source_column};
1595         }
1596         $builder->($item, $source_values);
1597     }
1598 }
1599
1600 =head2 _set_derived_columns_for_mod
1601
1602 =over 4
1603
1604 _set_derived_column_for_mod($item);
1605
1606 =back
1607
1608 Given an item hash representing a new item to be modified.
1609 calculate any derived columns.  Currently the only
1610 such column is C<items.cn_sort>.
1611
1612 This routine differs from C<_set_derived_columns_for_add>
1613 in that it needs to handle partial item records.  In other
1614 words, the caller of C<ModItem> may have supplied only one
1615 or two columns to be changed, so this function needs to
1616 determine whether any of the columns to be changed affect
1617 any of the derived columns.  Also, if a derived column
1618 depends on more than one column, but the caller is not
1619 changing all of then, this routine retrieves the unchanged
1620 values from the database in order to ensure a correct
1621 calculation.
1622
1623 =cut
1624
1625 sub _set_derived_columns_for_mod {
1626     my $item = shift;
1627
1628     foreach my $column (keys %derived_columns) {
1629         my $builder = $derived_columns{$column}->{'BUILDER'};
1630         my $source_values = {};
1631         my %missing_sources = ();
1632         my $must_recalc = 0;
1633         foreach my $source_column (keys %{ $derived_columns{$column} }) {
1634             next if $source_column eq 'BUILDER';
1635             if (exists $item->{$source_column}) {
1636                 $must_recalc = 1;
1637                 $source_values->{$source_column} = $item->{$source_column};
1638             } else {
1639                 $missing_sources{$source_column} = 1;
1640             }
1641         }
1642         if ($must_recalc) {
1643             foreach my $source_column (keys %missing_sources) {
1644                 $source_values->{$source_column} = _get_single_item_column($source_column, $item->{'itemnumber'});
1645             }
1646             $builder->($item, $source_values);
1647         }
1648     }
1649 }
1650
1651 =head2 _do_column_fixes_for_mod
1652
1653 =over 4
1654
1655 _do_column_fixes_for_mod($item);
1656
1657 =back
1658
1659 Given an item hashref containing one or more
1660 columns to modify, fix up certain values.
1661 Specifically, set to 0 any passed value
1662 of C<notforloan>, C<damaged>, C<itemlost>, or
1663 C<wthdrawn> that is either undefined or
1664 contains the empty string.
1665
1666 =cut
1667
1668 sub _do_column_fixes_for_mod {
1669     my $item = shift;
1670
1671     if (exists $item->{'notforloan'} and
1672         (not defined $item->{'notforloan'} or $item->{'notforloan'} eq '')) {
1673         $item->{'notforloan'} = 0;
1674     }
1675     if (exists $item->{'damaged'} and
1676         (not defined $item->{'damaged'} or $item->{'damaged'} eq '')) {
1677         $item->{'damaged'} = 0;
1678     }
1679     if (exists $item->{'itemlost'} and
1680         (not defined $item->{'itemlost'} or $item->{'itemlost'} eq '')) {
1681         $item->{'itemlost'} = 0;
1682     }
1683     if (exists $item->{'wthdrawn'} and
1684         (not defined $item->{'wthdrawn'} or $item->{'wthdrawn'} eq '')) {
1685         $item->{'wthdrawn'} = 0;
1686     }
1687 }
1688
1689 =head2 _get_single_item_column
1690
1691 =over 4
1692
1693 _get_single_item_column($column, $itemnumber);
1694
1695 =back
1696
1697 Retrieves the value of a single column from an C<items>
1698 row specified by C<$itemnumber>.
1699
1700 =cut
1701
1702 sub _get_single_item_column {
1703     my $column = shift;
1704     my $itemnumber = shift;
1705
1706     my $dbh = C4::Context->dbh;
1707     my $sth = $dbh->prepare("SELECT $column FROM items WHERE itemnumber = ?");
1708     $sth->execute($itemnumber);
1709     my ($value) = $sth->fetchrow();
1710     return $value;
1711 }
1712
1713 =head2 _calc_items_cn_sort
1714
1715 =over 4
1716
1717 _calc_items_cn_sort($item, $source_values);
1718
1719 =back
1720
1721 Helper routine to calculate C<items.cn_sort>.
1722
1723 =cut
1724
1725 sub _calc_items_cn_sort {
1726     my $item = shift;
1727     my $source_values = shift;
1728
1729     $item->{'items.cn_sort'} = GetClassSort($source_values->{'items.cn_source'}, $source_values->{'itemcallnumber'}, "");
1730 }
1731
1732 =head2 _set_defaults_for_add
1733
1734 =over 4
1735
1736 _set_defaults_for_add($item_hash);
1737
1738 =back
1739
1740 Given an item hash representing an item to be added, set
1741 correct default values for columns whose default value
1742 is not handled by the DBMS.  This includes the following
1743 columns:
1744
1745 =over 2
1746
1747 =item *
1748
1749 C<items.dateaccessioned>
1750
1751 =item *
1752
1753 C<items.notforloan>
1754
1755 =item *
1756
1757 C<items.damaged>
1758
1759 =item *
1760
1761 C<items.itemlost>
1762
1763 =item *
1764
1765 C<items.wthdrawn>
1766
1767 =back
1768
1769 =cut
1770
1771 sub _set_defaults_for_add {
1772     my $item = shift;
1773
1774     # if dateaccessioned is provided, use it. Otherwise, set to NOW()
1775     if (!(exists $item->{'dateaccessioned'}) ||
1776          ($item->{'dateaccessioned'} eq '')) {
1777         # FIXME add check for invalid date
1778         my $today = C4::Dates->new();
1779         $item->{'dateaccessioned'} =  $today->output("iso"); #TODO: check time issues
1780     }
1781
1782     # various item status fields cannot be null
1783     $item->{'notforloan'} = 0 unless exists $item->{'notforloan'} and defined $item->{'notforloan'} and $item->{'notforloan'} ne '';
1784     $item->{'damaged'}    = 0 unless exists $item->{'damaged'}    and defined $item->{'damaged'}    and $item->{'damaged'} ne '';
1785     $item->{'itemlost'}   = 0 unless exists $item->{'itemlost'}   and defined $item->{'itemlost'}   and $item->{'itemlost'} ne '';
1786     $item->{'wthdrawn'}   = 0 unless exists $item->{'wthdrawn'}   and defined $item->{'wthdrawn'}   and $item->{'wthdrawn'} ne '';
1787 }
1788
1789 =head2 _koha_new_item
1790
1791 =over 4
1792
1793 my ($itemnumber,$error) = _koha_new_item( $item, $barcode );
1794
1795 =back
1796
1797 Perform the actual insert into the C<items> table.
1798
1799 =cut
1800
1801 sub _koha_new_item {
1802     my ( $item, $barcode ) = @_;
1803     my $dbh=C4::Context->dbh;
1804     my $error;
1805     my $query =
1806            "INSERT INTO items SET
1807             biblionumber        = ?,
1808             biblioitemnumber    = ?,
1809             barcode             = ?,
1810             dateaccessioned     = ?,
1811             booksellerid        = ?,
1812             homebranch          = ?,
1813             price               = ?,
1814             replacementprice    = ?,
1815             replacementpricedate = NOW(),
1816             datelastborrowed    = ?,
1817             datelastseen        = NOW(),
1818             stack               = ?,
1819             notforloan          = ?,
1820             damaged             = ?,
1821             itemlost            = ?,
1822             wthdrawn            = ?,
1823             itemcallnumber      = ?,
1824             restricted          = ?,
1825             itemnotes           = ?,
1826             holdingbranch       = ?,
1827             paidfor             = ?,
1828             location            = ?,
1829             onloan              = ?,
1830             issues              = ?,
1831             renewals            = ?,
1832             reserves            = ?,
1833             cn_source           = ?,
1834             cn_sort             = ?,
1835             ccode               = ?,
1836             itype               = ?,
1837             materials           = ?,
1838             uri = ?,
1839             enumchron           = ?,
1840             more_subfields_xml  = ?,
1841             copynumber          = ?
1842           ";
1843     my $sth = $dbh->prepare($query);
1844    $sth->execute(
1845             $item->{'biblionumber'},
1846             $item->{'biblioitemnumber'},
1847             $barcode,
1848             $item->{'dateaccessioned'},
1849             $item->{'booksellerid'},
1850             $item->{'homebranch'},
1851             $item->{'price'},
1852             $item->{'replacementprice'},
1853             $item->{datelastborrowed},
1854             $item->{stack},
1855             $item->{'notforloan'},
1856             $item->{'damaged'},
1857             $item->{'itemlost'},
1858             $item->{'wthdrawn'},
1859             $item->{'itemcallnumber'},
1860             $item->{'restricted'},
1861             $item->{'itemnotes'},
1862             $item->{'holdingbranch'},
1863             $item->{'paidfor'},
1864             $item->{'location'},
1865             $item->{'onloan'},
1866             $item->{'issues'},
1867             $item->{'renewals'},
1868             $item->{'reserves'},
1869             $item->{'items.cn_source'},
1870             $item->{'items.cn_sort'},
1871             $item->{'ccode'},
1872             $item->{'itype'},
1873             $item->{'materials'},
1874             $item->{'uri'},
1875             $item->{'enumchron'},
1876             $item->{'more_subfields_xml'},
1877             $item->{'copynumber'},
1878     );
1879     my $itemnumber = $dbh->{'mysql_insertid'};
1880     if ( defined $sth->errstr ) {
1881         $error.="ERROR in _koha_new_item $query".$sth->errstr;
1882     }
1883     $sth->finish();
1884     return ( $itemnumber, $error );
1885 }
1886
1887 =head2 _koha_modify_item
1888
1889 =over 4
1890
1891 my ($itemnumber,$error) =_koha_modify_item( $item );
1892
1893 =back
1894
1895 Perform the actual update of the C<items> row.  Note that this
1896 routine accepts a hashref specifying the columns to update.
1897
1898 =cut
1899
1900 sub _koha_modify_item {
1901     my ( $item ) = @_;
1902     my $dbh=C4::Context->dbh;
1903     my $error;
1904
1905     my $query = "UPDATE items SET ";
1906     my @bind;
1907     for my $key ( keys %$item ) {
1908         $query.="$key=?,";
1909         push @bind, $item->{$key};
1910     }
1911     $query =~ s/,$//;
1912     $query .= " WHERE itemnumber=?";
1913     push @bind, $item->{'itemnumber'};
1914     my $sth = C4::Context->dbh->prepare($query);
1915     $sth->execute(@bind);
1916     if ( C4::Context->dbh->errstr ) {
1917         $error.="ERROR in _koha_modify_item $query".$dbh->errstr;
1918         warn $error;
1919     }
1920     $sth->finish();
1921     return ($item->{'itemnumber'},$error);
1922 }
1923
1924 =head2 _koha_delete_item
1925
1926 =over 4
1927
1928 _koha_delete_item( $dbh, $itemnum );
1929
1930 =back
1931
1932 Internal function to delete an item record from the koha tables
1933
1934 =cut
1935
1936 sub _koha_delete_item {
1937     my ( $dbh, $itemnum ) = @_;
1938
1939     # save the deleted item to deleteditems table
1940     my $sth = $dbh->prepare("SELECT * FROM items WHERE itemnumber=?");
1941     $sth->execute($itemnum);
1942     my $data = $sth->fetchrow_hashref();
1943     $sth->finish();
1944     my $query = "INSERT INTO deleteditems SET ";
1945     my @bind  = ();
1946     foreach my $key ( keys %$data ) {
1947         $query .= "$key = ?,";
1948         push( @bind, $data->{$key} );
1949     }
1950     $query =~ s/\,$//;
1951     $sth = $dbh->prepare($query);
1952     $sth->execute(@bind);
1953     $sth->finish();
1954
1955     # delete from items table
1956     $sth = $dbh->prepare("DELETE FROM items WHERE itemnumber=?");
1957     $sth->execute($itemnum);
1958     $sth->finish();
1959     return undef;
1960 }
1961
1962 =head2 _marc_from_item_hash
1963
1964 =over 4
1965
1966 my $item_marc = _marc_from_item_hash($item, $frameworkcode[, $unlinked_item_subfields]);
1967
1968 =back
1969
1970 Given an item hash representing a complete item record,
1971 create a C<MARC::Record> object containing an embedded
1972 tag representing that item.
1973
1974 The third, optional parameter C<$unlinked_item_subfields> is
1975 an arrayref of subfields (not mapped to C<items> fields per the
1976 framework) to be added to the MARC representation
1977 of the item.
1978
1979 =cut
1980
1981 sub _marc_from_item_hash {
1982     my $item = shift;
1983     my $frameworkcode = shift;
1984     my $unlinked_item_subfields;
1985     if (@_) {
1986         $unlinked_item_subfields = shift;
1987     }
1988
1989     # Tack on 'items.' prefix to column names so lookup from MARC frameworks will work
1990     # Also, don't emit a subfield if the underlying field is blank.
1991     my $mungeditem = { map {  (defined($item->{$_}) and $item->{$_} ne '') ?
1992                                 (/^items\./ ? ($_ => $item->{$_}) : ("items.$_" => $item->{$_}))
1993                                 : ()  } keys %{ $item } };
1994
1995     my $item_marc = MARC::Record->new();
1996     foreach my $item_field (keys %{ $mungeditem }) {
1997         my ($tag, $subfield) = GetMarcFromKohaField($item_field, $frameworkcode);
1998         next unless defined $tag and defined $subfield; # skip if not mapped to MARC field
1999         if (my $field = $item_marc->field($tag)) {
2000             $field->add_subfields($subfield => $mungeditem->{$item_field});
2001         } else {
2002             my $add_subfields = [];
2003             if (defined $unlinked_item_subfields and ref($unlinked_item_subfields) eq 'ARRAY' and $#$unlinked_item_subfields > -1) {
2004                 $add_subfields = $unlinked_item_subfields;
2005             }
2006             $item_marc->add_fields( $tag, " ", " ", $subfield =>  $mungeditem->{$item_field}, @$add_subfields);
2007         }
2008     }
2009
2010     return $item_marc;
2011 }
2012
2013 =head2 _add_item_field_to_biblio
2014
2015 =over 4
2016
2017 _add_item_field_to_biblio($item_marc, $biblionumber, $frameworkcode);
2018
2019 =back
2020
2021 Adds the fields from a MARC record containing the
2022 representation of a Koha item record to the MARC
2023 biblio record.  The input C<$item_marc> record
2024 is expect to contain just one field, the embedded
2025 item information field.
2026
2027 =cut
2028
2029 sub _add_item_field_to_biblio {
2030     my ($item_marc, $biblionumber, $frameworkcode) = @_;
2031
2032     my $biblio_marc = GetMarcBiblio($biblionumber);
2033     foreach my $field ($item_marc->fields()) {
2034         $biblio_marc->append_fields($field);
2035     }
2036
2037     ModBiblioMarc($biblio_marc, $biblionumber, $frameworkcode);
2038 }
2039
2040 =head2 _replace_item_field_in_biblio
2041
2042 =over
2043
2044 &_replace_item_field_in_biblio($item_marc, $biblionumber, $itemnumber, $frameworkcode)
2045
2046 =back
2047
2048 Given a MARC::Record C<$item_marc> containing one tag with the MARC
2049 representation of the item, examine the biblio MARC
2050 for the corresponding tag for that item and
2051 replace it with the tag from C<$item_marc>.
2052
2053 =cut
2054
2055 sub _replace_item_field_in_biblio {
2056     my ($ItemRecord, $biblionumber, $itemnumber, $frameworkcode) = @_;
2057     my $dbh = C4::Context->dbh;
2058
2059     # get complete MARC record & replace the item field by the new one
2060     my $completeRecord = GetMarcBiblio($biblionumber);
2061     my ($itemtag,$itemsubfield) = GetMarcFromKohaField("items.itemnumber",$frameworkcode);
2062     my $itemField = $ItemRecord->field($itemtag);
2063     my @items = $completeRecord->field($itemtag);
2064     my $found = 0;
2065     foreach (@items) {
2066         if ($_->subfield($itemsubfield) eq $itemnumber) {
2067             $_->replace_with($itemField);
2068             $found = 1;
2069         }
2070     }
2071
2072     unless ($found) {
2073         # If we haven't found the matching field,
2074         # just add it.  However, this means that
2075         # there is likely a bug.
2076         $completeRecord->append_fields($itemField);
2077     }
2078
2079     # save the record
2080     ModBiblioMarc($completeRecord, $biblionumber, $frameworkcode);
2081 }
2082
2083 =head2 _repack_item_errors
2084
2085 Add an error message hash generated by C<CheckItemPreSave>
2086 to a list of errors.
2087
2088 =cut
2089
2090 sub _repack_item_errors {
2091     my $item_sequence_num = shift;
2092     my $item_ref = shift;
2093     my $error_ref = shift;
2094
2095     my @repacked_errors = ();
2096
2097     foreach my $error_code (sort keys %{ $error_ref }) {
2098         my $repacked_error = {};
2099         $repacked_error->{'item_sequence'} = $item_sequence_num;
2100         $repacked_error->{'item_barcode'} = exists($item_ref->{'barcode'}) ? $item_ref->{'barcode'} : '';
2101         $repacked_error->{'error_code'} = $error_code;
2102         $repacked_error->{'error_information'} = $error_ref->{$error_code};
2103         push @repacked_errors, $repacked_error;
2104     }
2105
2106     return @repacked_errors;
2107 }
2108
2109 =head2 _get_unlinked_item_subfields
2110
2111 =over 4
2112
2113 my $unlinked_item_subfields = _get_unlinked_item_subfields($original_item_marc, $frameworkcode);
2114
2115 =back
2116
2117 =cut
2118
2119 sub _get_unlinked_item_subfields {
2120     my $original_item_marc = shift;
2121     my $frameworkcode = shift;
2122
2123     my $marcstructure = GetMarcStructure(1, $frameworkcode);
2124
2125     # assume that this record has only one field, and that that
2126     # field contains only the item information
2127     my $subfields = [];
2128     my @fields = $original_item_marc->fields();
2129     if ($#fields > -1) {
2130         my $field = $fields[0];
2131             my $tag = $field->tag();
2132         foreach my $subfield ($field->subfields()) {
2133             if (defined $subfield->[1] and
2134                 $subfield->[1] ne '' and
2135                 !$marcstructure->{$tag}->{$subfield->[0]}->{'kohafield'}) {
2136                 push @$subfields, $subfield->[0] => $subfield->[1];
2137             }
2138         }
2139     }
2140     return $subfields;
2141 }
2142
2143 =head2 _get_unlinked_subfields_xml
2144
2145 =over 4
2146
2147 my $unlinked_subfields_xml = _get_unlinked_subfields_xml($unlinked_item_subfields);
2148
2149 =back
2150
2151 =cut
2152
2153 sub _get_unlinked_subfields_xml {
2154     my $unlinked_item_subfields = shift;
2155
2156     my $xml;
2157     if (defined $unlinked_item_subfields and ref($unlinked_item_subfields) eq 'ARRAY' and $#$unlinked_item_subfields > -1) {
2158         my $marc = MARC::Record->new();
2159         # use of tag 999 is arbitrary, and doesn't need to match the item tag
2160         # used in the framework
2161         $marc->append_fields(MARC::Field->new('999', ' ', ' ', @$unlinked_item_subfields));
2162         $marc->encoding("UTF-8");
2163         $xml = $marc->as_xml("USMARC");
2164     }
2165
2166     return $xml;
2167 }
2168
2169 =head2 _parse_unlinked_item_subfields_from_xml
2170
2171 =over 4
2172
2173 my $unlinked_item_subfields = _parse_unlinked_item_subfields_from_xml($whole_item->{'more_subfields_xml'}):
2174
2175 =back
2176
2177 =cut
2178
2179 sub  _parse_unlinked_item_subfields_from_xml {
2180     my $xml = shift;
2181
2182     return unless defined $xml and $xml ne "";
2183     my $marc = MARC::Record->new_from_xml(StripNonXmlChars($xml),'UTF-8');
2184     my $unlinked_subfields = [];
2185     my @fields = $marc->fields();
2186     if ($#fields > -1) {
2187         foreach my $subfield ($fields[0]->subfields()) {
2188             push @$unlinked_subfields, $subfield->[0] => $subfield->[1];
2189         }
2190     }
2191     return $unlinked_subfields;
2192 }
2193
2194 1;