C4/Items.pm

   1 package C4::Items;
   2
   3 # Copyright 2007 LibLime, Inc.
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along with
  17 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  18 # Suite 330, Boston, MA  02111-1307 USA
  19
  20 use strict;
  21
  22 use C4::Context;
  23 use C4::Koha;
  24 use C4::Biblio;
  25 use C4::Dates qw/format_date format_date_in_iso/;
  26 use MARC::Record;
  27 use C4::ClassSource;
  28 use C4::Log;
  29 use C4::Branch;
  30 require C4::Reserves;
  31 use C4::Charset;
  32
  33 use vars qw($VERSION @ISA @EXPORT);
  34
  35 BEGIN {
  36     $VERSION = 3.01;
  37
  38         require Exporter;
  39     @ISA = qw( Exporter );
  40
  41     # function exports
  42     @EXPORT = qw(
  43         GetItem
  44         AddItemFromMarc
  45         AddItem
  46         AddItemBatchFromMarc
  47         ModItemFromMarc
  48         ModItem
  49         ModDateLastSeen
  50         ModItemTransfer
  51         DelItem
  52
  53         CheckItemPreSave
  54
  55         GetItemStatus
  56         GetItemLocation
  57         GetLostItems
  58         GetItemsForInventory
  59         GetItemsCount
  60         GetItemInfosOf
  61         GetItemsByBiblioitemnumber
  62         GetItemsInfo
  63         get_itemnumbers_of
  64         GetItemnumberFromBarcode
  65     );
  66 }
  67
  68 =head1 NAME
  69
  70 C4::Items - item management functions
  71
  72 =head1 DESCRIPTION
  73
  74 This module contains an API for manipulating item
  75 records in Koha, and is used by cataloguing, circulation,
  76 acquisitions, and serials management.
  77
  78 A Koha item record is stored in two places: the
  79 items table and embedded in a MARC tag in the XML
  80 version of the associated bib record in C<biblioitems.marcxml>.
  81 This is done to allow the item information to be readily
  82 indexed (e.g., by Zebra), but means that each item
  83 modification transaction must keep the items table
  84 and the MARC XML in sync at all times.
  85
  86 Consequently, all code that creates, modifies, or deletes
  87 item records B<must> use an appropriate function from
  88 C<C4::Items>.  If no existing function is suitable, it is
  89 better to add one to C<C4::Items> than to use add
  90 one-off SQL statements to add or modify items.
  91
  92 The items table will be considered authoritative.  In other
  93 words, if there is ever a discrepancy between the items
  94 table and the MARC XML, the items table should be considered
  95 accurate.
  96
  97 =head1 HISTORICAL NOTE
  98
  99 Most of the functions in C<C4::Items> were originally in
 100 the C<C4::Biblio> module.
 101
 102 =head1 CORE EXPORTED FUNCTIONS
 103
 104 The following functions are meant for use by users
 105 of C<C4::Items>
 106
 107 =cut
 108
 109 =head2 GetItem
 110
 111 =over 4
 112
 113 $item = GetItem($itemnumber,$barcode,$serial);
 114
 115 =back
 116
 117 Return item information, for a given itemnumber or barcode.
 118 The return value is a hashref mapping item column
 119 names to values.  If C<$serial> is true, include serial publication data.
 120
 121 =cut
 122
 123 sub GetItem {
 124     my ($itemnumber,$barcode, $serial) = @_;
 125     my $dbh = C4::Context->dbh;
 126         my $data;
 127     if ($itemnumber) {
 128         my $sth = $dbh->prepare("
 129             SELECT * FROM items
 130             WHERE itemnumber = ?");
 131         $sth->execute($itemnumber);
 132         $data = $sth->fetchrow_hashref;
 133     } else {
 134         my $sth = $dbh->prepare("
 135             SELECT * FROM items
 136             WHERE barcode = ?"
 137             );
 138         $sth->execute($barcode);
 139         $data = $sth->fetchrow_hashref;
 140     }
 141     if ( $serial) {
 142     my $ssth = $dbh->prepare("SELECT serialseq,publisheddate from serialitems left join serial on serialitems.serialid=serial.serialid where serialitems.itemnumber=?");
 143         $ssth->execute($data->{'itemnumber'}) ;
 144         ($data->{'serialseq'} , $data->{'publisheddate'}) = $ssth->fetchrow_array();
 145                 warn $data->{'serialseq'} , $data->{'publisheddate'};
 146     }
 147         #if we don't have an items.itype, use biblioitems.itemtype.
 148         if( ! $data->{'itype'} ) {
 149                 my $sth = $dbh->prepare("SELECT itemtype FROM biblioitems  WHERE biblionumber = ?");
 150                 $sth->execute($data->{'biblionumber'});
 151                 ($data->{'itype'}) = $sth->fetchrow_array;
 152         }
 153     return $data;
 154 }    # sub GetItem
 155
 156 =head2 AddItemFromMarc
 157
 158 =over 4
 159
 160 my ($biblionumber, $biblioitemnumber, $itemnumber)
 161     = AddItemFromMarc($source_item_marc, $biblionumber);
 162
 163 =back
 164
 165 Given a MARC::Record object containing an embedded item
 166 record and a biblionumber, create a new item record.
 167
 168 =cut
 169
 170 sub AddItemFromMarc {
 171     my ( $source_item_marc, $biblionumber ) = @_;
 172     my $dbh = C4::Context->dbh;
 173
 174     # parse item hash from MARC
 175     my $frameworkcode = GetFrameworkCode( $biblionumber );
 176     my $item = &TransformMarcToKoha( $dbh, $source_item_marc, $frameworkcode );
 177     my $unlinked_item_subfields = _get_unlinked_item_subfields($source_item_marc, $frameworkcode);
 178     return AddItem($item, $biblionumber, $dbh, $frameworkcode, $unlinked_item_subfields);
 179 }
 180
 181 =head2 AddItem
 182
 183 =over 4
 184
 185 my ($biblionumber, $biblioitemnumber, $itemnumber)
 186     = AddItem($item, $biblionumber[, $dbh, $frameworkcode, $unlinked_item_subfields]);
 187
 188 =back
 189
 190 Given a hash containing item column names as keys,
 191 create a new Koha item record.
 192
 193 The first two optional parameters (C<$dbh> and C<$frameworkcode>)
 194 do not need to be supplied for general use; they exist
 195 simply to allow them to be picked up from AddItemFromMarc.
 196
 197 The final optional parameter, C<$unlinked_item_subfields>, contains
 198 an arrayref containing subfields present in the original MARC
 199 representation of the item (e.g., from the item editor) that are
 200 not mapped to C<items> columns directly but should instead
 201 be stored in C<items.more_subfields_xml> and included in
 202 the biblio items tag for display and indexing.
 203
 204 =cut
 205
 206 sub AddItem {
 207     my $item = shift;
 208     my $biblionumber = shift;
 209
 210     my $dbh           = @_ ? shift : C4::Context->dbh;
 211     my $frameworkcode = @_ ? shift : GetFrameworkCode( $biblionumber );
 212     my $unlinked_item_subfields;
 213     if (@_) {
 214         $unlinked_item_subfields = shift
 215     };
 216
 217     # needs old biblionumber and biblioitemnumber
 218     $item->{'biblionumber'} = $biblionumber;
 219     my $sth = $dbh->prepare("SELECT biblioitemnumber FROM biblioitems WHERE biblionumber=?");
 220     $sth->execute( $item->{'biblionumber'} );
 221     ($item->{'biblioitemnumber'}) = $sth->fetchrow;
 222
 223     _set_defaults_for_add($item);
 224     _set_derived_columns_for_add($item);
 225     $item->{'more_subfields_xml'} = _get_unlinked_subfields_xml($unlinked_item_subfields);
 226     # FIXME - checks here
 227         my ( $itemnumber, $error ) = _koha_new_item( $item, $item->{barcode} );
 228     $item->{'itemnumber'} = $itemnumber;
 229
 230     # create MARC tag representing item and add to bib
 231     my $new_item_marc = _marc_from_item_hash($item, $frameworkcode, $unlinked_item_subfields);
 232     _add_item_field_to_biblio($new_item_marc, $item->{'biblionumber'}, $frameworkcode );
 233
 234     logaction(C4::Context->userenv->{'number'},"CATALOGUING","ADD",$itemnumber,"item")
 235         if C4::Context->preference("CataloguingLog");
 236
 237     return ($item->{biblionumber}, $item->{biblioitemnumber}, $itemnumber);
 238 }
 239
 240 =head2 AddItemBatchFromMarc
 241
 242 =over 4
 243
 244 ($itemnumber_ref, $error_ref) = AddItemBatchFromMarc($record, $biblionumber, $biblioitemnumber, $frameworkcode);
 245
 246 =back
 247
 248 Efficiently create item records from a MARC biblio record with
 249 embedded item fields.  This routine is suitable for batch jobs.
 250
 251 This API assumes that the bib record has already been
 252 saved to the C<biblio> and C<biblioitems> tables.  It does
 253 not expect that C<biblioitems.marc> and C<biblioitems.marcxml>
 254 are populated, but it will do so via a call to ModBibiloMarc.
 255
 256 The goal of this API is to have a similar effect to using AddBiblio
 257 and AddItems in succession, but without inefficient repeated
 258 parsing of the MARC XML bib record.
 259
 260 This function returns an arrayref of new itemsnumbers and an arrayref of item
 261 errors encountered during the processing.  Each entry in the errors
 262 list is a hashref containing the following keys:
 263
 264 =over 2
 265
 266 =item item_sequence
 267
 268 Sequence number of original item tag in the MARC record.
 269
 270 =item item_barcode
 271
 272 Item barcode, provide to assist in the construction of
 273 useful error messages.
 274
 275 =item error_condition
 276
 277 Code representing the error condition.  Can be 'duplicate_barcode',
 278 'invalid_homebranch', or 'invalid_holdingbranch'.
 279
 280 =item error_information
 281
 282 Additional information appropriate to the error condition.
 283
 284 =back
 285
 286 =cut
 287
 288 sub AddItemBatchFromMarc {
 289     my ($record, $biblionumber, $biblioitemnumber, $frameworkcode) = @_;
 290     my $error;
 291     my @itemnumbers = ();
 292     my @errors = ();
 293     my $dbh = C4::Context->dbh;
 294
 295     # loop through the item tags and start creating items
 296     my @bad_item_fields = ();
 297     my ($itemtag, $itemsubfield) = &GetMarcFromKohaField("items.itemnumber",'');
 298     my $item_sequence_num = 0;
 299     ITEMFIELD: foreach my $item_field ($record->field($itemtag)) {
 300         $item_sequence_num++;
 301         # we take the item field and stick it into a new
 302         # MARC record -- this is required so far because (FIXME)
 303         # TransformMarcToKoha requires a MARC::Record, not a MARC::Field
 304         # and there is no TransformMarcFieldToKoha
 305         my $temp_item_marc = MARC::Record->new();
 306         $temp_item_marc->append_fields($item_field);
 307
 308         # add biblionumber and biblioitemnumber
 309         my $item = TransformMarcToKoha( $dbh, $temp_item_marc, $frameworkcode, 'items' );
 310         my $unlinked_item_subfields = _get_unlinked_item_subfields($temp_item_marc, $frameworkcode);
 311         $item->{'more_subfields_xml'} = _get_unlinked_subfields_xml($unlinked_item_subfields);
 312         $item->{'biblionumber'} = $biblionumber;
 313         $item->{'biblioitemnumber'} = $biblioitemnumber;
 314
 315         # check for duplicate barcode
 316         my %item_errors = CheckItemPreSave($item);
 317         if (%item_errors) {
 318             push @errors, _repack_item_errors($item_sequence_num, $item, \%item_errors);
 319             push @bad_item_fields, $item_field;
 320             next ITEMFIELD;
 321         }
 322
 323         _set_defaults_for_add($item);
 324         _set_derived_columns_for_add($item);
 325         my ( $itemnumber, $error ) = _koha_new_item( $item, $item->{barcode} );
 326         warn $error if $error;
 327         push @itemnumbers, $itemnumber; # FIXME not checking error
 328         $item->{'itemnumber'} = $itemnumber;
 329
 330         &logaction(C4::Context->userenv->{'number'},"CATALOGUING","ADD",$itemnumber,"item")
 331         if C4::Context->preference("CataloguingLog");
 332
 333         my $new_item_marc = _marc_from_item_hash($item, $frameworkcode, $unlinked_item_subfields);
 334         $item_field->replace_with($new_item_marc->field($itemtag));
 335     }
 336
 337     # remove any MARC item fields for rejected items
 338     foreach my $item_field (@bad_item_fields) {
 339         $record->delete_field($item_field);
 340     }
 341
 342     # update the MARC biblio
 343     $biblionumber = ModBiblioMarc( $record, $biblionumber, $frameworkcode );
 344
 345     return (\@itemnumbers, \@errors);
 346 }
 347
 348 =head2 ModItemFromMarc
 349
 350 =over 4
 351
 352 ModItemFromMarc($item_marc, $biblionumber, $itemnumber);
 353
 354 =back
 355
 356 This function updates an item record based on a supplied
 357 C<MARC::Record> object containing an embedded item field.
 358 This API is meant for the use of C<additem.pl>; for
 359 other purposes, C<ModItem> should be used.
 360
 361 =cut
 362
 363 sub ModItemFromMarc {
 364     my $item_marc = shift;
 365     my $biblionumber = shift;
 366     my $itemnumber = shift;
 367
 368     my $dbh = C4::Context->dbh;
 369     my $frameworkcode = GetFrameworkCode( $biblionumber );
 370     my $item = &TransformMarcToKoha( $dbh, $item_marc, $frameworkcode );
 371     my $unlinked_item_subfields = _get_unlinked_item_subfields($item_marc, $frameworkcode);
 372
 373     return ModItem($item, $biblionumber, $itemnumber, $dbh, $frameworkcode, $unlinked_item_subfields);
 374 }
 375
 376 =head2 ModItem
 377
 378 =over 4
 379
 380 ModItem({ column => $newvalue }, $biblionumber, $itemnumber[, $original_item_marc]);
 381
 382 =back
 383
 384 Change one or more columns in an item record and update
 385 the MARC representation of the item.
 386
 387 The first argument is a hashref mapping from item column
 388 names to the new values.  The second and third arguments
 389 are the biblionumber and itemnumber, respectively.
 390
 391 The fourth, optional parameter, C<$unlinked_item_subfields>, contains
 392 an arrayref containing subfields present in the original MARC
 393 representation of the item (e.g., from the item editor) that are
 394 not mapped to C<items> columns directly but should instead
 395 be stored in C<items.more_subfields_xml> and included in
 396 the biblio items tag for display and indexing.
 397
 398 If one of the changed columns is used to calculate
 399 the derived value of a column such as C<items.cn_sort>,
 400 this routine will perform the necessary calculation
 401 and set the value.
 402
 403 =cut
 404
 405 sub ModItem {
 406     my $item = shift;
 407     my $biblionumber = shift;
 408     my $itemnumber = shift;
 409
 410     # if $biblionumber is undefined, get it from the current item
 411     unless (defined $biblionumber) {
 412         $biblionumber = _get_single_item_column('biblionumber', $itemnumber);
 413     }
 414
 415     my $dbh           = @_ ? shift : C4::Context->dbh;
 416     my $frameworkcode = @_ ? shift : GetFrameworkCode( $biblionumber );
 417
 418     my $unlinked_item_subfields;
 419     if (@_) {
 420         $unlinked_item_subfields = shift;
 421         $item->{'more_subfields_xml'} = _get_unlinked_subfields_xml($unlinked_item_subfields);
 422     };
 423
 424     $item->{'itemnumber'} = $itemnumber or return undef;
 425     _set_derived_columns_for_mod($item);
 426     _do_column_fixes_for_mod($item);
 427     # FIXME add checks
 428     # duplicate barcode
 429     # attempt to change itemnumber
 430     # attempt to change biblionumber (if we want
 431     # an API to relink an item to a different bib,
 432     # it should be a separate function)
 433
 434     # update items table
 435     _koha_modify_item($item);
 436
 437     # update biblio MARC XML
 438     my $whole_item = GetItem($itemnumber) or die "FAILED GetItem($itemnumber)";
 439
 440     unless (defined $unlinked_item_subfields) {
 441         $unlinked_item_subfields = _parse_unlinked_item_subfields_from_xml($whole_item->{'more_subfields_xml'});
 442     }
 443     my $new_item_marc = _marc_from_item_hash($whole_item, $frameworkcode, $unlinked_item_subfields)
 444         or die "FAILED _marc_from_item_hash($whole_item, $frameworkcode)";
 445
 446     _replace_item_field_in_biblio($new_item_marc, $biblionumber, $itemnumber, $frameworkcode);
 447         (C4::Context->userenv eq '0') and die "userenv is '0', not hashref";         # logaction line would crash anyway
 448         ($new_item_marc       eq '0') and die "$new_item_marc is '0', not hashref";  # logaction line would crash anyway
 449     logaction(C4::Context->userenv->{'number'},"CATALOGUING","MODIFY",$itemnumber,$new_item_marc->as_formatted)
 450         if C4::Context->preference("CataloguingLog");
 451 }
 452
 453 =head2 ModItemTransfer
 454
 455 =over 4
 456
 457 ModItemTransfer($itenumber, $frombranch, $tobranch);
 458
 459 =back
 460
 461 Marks an item as being transferred from one branch
 462 to another.
 463
 464 =cut
 465
 466 sub ModItemTransfer {
 467     my ( $itemnumber, $frombranch, $tobranch ) = @_;
 468
 469     my $dbh = C4::Context->dbh;
 470
 471     #new entry in branchtransfers....
 472     my $sth = $dbh->prepare(
 473         "INSERT INTO branchtransfers (itemnumber, frombranch, datesent, tobranch)
 474         VALUES (?, ?, NOW(), ?)");
 475     $sth->execute($itemnumber, $frombranch, $tobranch);
 476
 477     ModItem({ holdingbranch => $tobranch }, undef, $itemnumber);
 478     ModDateLastSeen($itemnumber);
 479     return;
 480 }
 481
 482 =head2 ModDateLastSeen
 483
 484 =over 4
 485
 486 ModDateLastSeen($itemnum);
 487
 488 =back
 489
 490 Mark item as seen. Is called when an item is issued, returned or manually marked during inventory/stocktaking.
 491 C<$itemnum> is the item number
 492
 493 =cut
 494
 495 sub ModDateLastSeen {
 496     my ($itemnumber) = @_;
 497
 498     my $today = C4::Dates->new();
 499     ModItem({ itemlost => 0, datelastseen => $today->output("iso") }, undef, $itemnumber);
 500 }
 501
 502 =head2 DelItem
 503
 504 =over 4
 505
 506 DelItem($biblionumber, $itemnumber);
 507
 508 =back
 509
 510 Exported function (core API) for deleting an item record in Koha.
 511
 512 =cut
 513
 514 sub DelItem {
 515     my ( $dbh, $biblionumber, $itemnumber ) = @_;
 516
 517     # FIXME check the item has no current issues
 518
 519     _koha_delete_item( $dbh, $itemnumber );
 520
 521     # get the MARC record
 522     my $record = GetMarcBiblio($biblionumber);
 523     my $frameworkcode = GetFrameworkCode($biblionumber);
 524
 525     # backup the record
 526     my $copy2deleted = $dbh->prepare("UPDATE deleteditems SET marc=? WHERE itemnumber=?");
 527     $copy2deleted->execute( $record->as_usmarc(), $itemnumber );
 528
 529     #search item field code
 530     my ( $itemtag, $itemsubfield ) = GetMarcFromKohaField("items.itemnumber",$frameworkcode);
 531     my @fields = $record->field($itemtag);
 532
 533     # delete the item specified
 534     foreach my $field (@fields) {
 535         if ( $field->subfield($itemsubfield) eq $itemnumber ) {
 536             $record->delete_field($field);
 537         }
 538     }
 539     &ModBiblioMarc( $record, $biblionumber, $frameworkcode );
 540     &logaction(C4::Context->userenv->{'number'},"CATALOGUING","DELETE",$itemnumber,"item")
 541         if C4::Context->preference("CataloguingLog");
 542 }
 543
 544 =head2 CheckItemPreSave
 545
 546 =over 4
 547
 548     my $item_ref = TransformMarcToKoha($marc, 'items');
 549     # do stuff
 550     my %errors = CheckItemPreSave($item_ref);
 551     if (exists $errors{'duplicate_barcode'}) {
 552         print "item has duplicate barcode: ", $errors{'duplicate_barcode'}, "\n";
 553     } elsif (exists $errors{'invalid_homebranch'}) {
 554         print "item has invalid home branch: ", $errors{'invalid_homebranch'}, "\n";
 555     } elsif (exists $errors{'invalid_holdingbranch'}) {
 556         print "item has invalid holding branch: ", $errors{'invalid_holdingbranch'}, "\n";
 557     } else {
 558         print "item is OK";
 559     }
 560
 561 =back
 562
 563 Given a hashref containing item fields, determine if it can be
 564 inserted or updated in the database.  Specifically, checks for
 565 database integrity issues, and returns a hash containing any
 566 of the following keys, if applicable.
 567
 568 =over 2
 569
 570 =item duplicate_barcode
 571
 572 Barcode, if it duplicates one already found in the database.
 573
 574 =item invalid_homebranch
 575
 576 Home branch, if not defined in branches table.
 577
 578 =item invalid_holdingbranch
 579
 580 Holding branch, if not defined in branches table.
 581
 582 =back
 583
 584 This function does NOT implement any policy-related checks,
 585 e.g., whether current operator is allowed to save an
 586 item that has a given branch code.
 587
 588 =cut
 589
 590 sub CheckItemPreSave {
 591     my $item_ref = shift;
 592
 593     my %errors = ();
 594
 595     # check for duplicate barcode
 596     if (exists $item_ref->{'barcode'} and defined $item_ref->{'barcode'}) {
 597         my $existing_itemnumber = GetItemnumberFromBarcode($item_ref->{'barcode'});
 598         if ($existing_itemnumber) {
 599             if (!exists $item_ref->{'itemnumber'}                       # new item
 600                 or $item_ref->{'itemnumber'} != $existing_itemnumber) { # existing item
 601                 $errors{'duplicate_barcode'} = $item_ref->{'barcode'};
 602             }
 603         }
 604     }
 605
 606     # check for valid home branch
 607     if (exists $item_ref->{'homebranch'} and defined $item_ref->{'homebranch'}) {
 608         my $branch_name = GetBranchName($item_ref->{'homebranch'});
 609         unless (defined $branch_name) {
 610             # relies on fact that branches.branchname is a non-NULL column,
 611             # so GetBranchName returns undef only if branch does not exist
 612             $errors{'invalid_homebranch'} = $item_ref->{'homebranch'};
 613         }
 614     }
 615
 616     # check for valid holding branch
 617     if (exists $item_ref->{'holdingbranch'} and defined $item_ref->{'holdingbranch'}) {
 618         my $branch_name = GetBranchName($item_ref->{'holdingbranch'});
 619         unless (defined $branch_name) {
 620             # relies on fact that branches.branchname is a non-NULL column,
 621             # so GetBranchName returns undef only if branch does not exist
 622             $errors{'invalid_holdingbranch'} = $item_ref->{'holdingbranch'};
 623         }
 624     }
 625
 626     return %errors;
 627
 628 }
 629
 630 =head1 EXPORTED SPECIAL ACCESSOR FUNCTIONS
 631
 632 The following functions provide various ways of
 633 getting an item record, a set of item records, or
 634 lists of authorized values for certain item fields.
 635
 636 Some of the functions in this group are candidates
 637 for refactoring -- for example, some of the code
 638 in C<GetItemsByBiblioitemnumber> and C<GetItemsInfo>
 639 has copy-and-paste work.
 640
 641 =cut
 642
 643 =head2 GetItemStatus
 644
 645 =over 4
 646
 647 $itemstatushash = GetItemStatus($fwkcode);
 648
 649 =back
 650
 651 Returns a list of valid values for the
 652 C<items.notforloan> field.
 653
 654 NOTE: does B<not> return an individual item's
 655 status.
 656
 657 Can be MARC dependant.
 658 fwkcode is optional.
 659 But basically could be can be loan or not
 660 Create a status selector with the following code
 661
 662 =head3 in PERL SCRIPT
 663
 664 =over 4
 665
 666 my $itemstatushash = getitemstatus;
 667 my @itemstatusloop;
 668 foreach my $thisstatus (keys %$itemstatushash) {
 669     my %row =(value => $thisstatus,
 670                 statusname => $itemstatushash->{$thisstatus}->{'statusname'},
 671             );
 672     push @itemstatusloop, \%row;
 673 }
 674 $template->param(statusloop=>\@itemstatusloop);
 675
 676 =back
 677
 678 =head3 in TEMPLATE
 679
 680 =over 4
 681
 682 <select name="statusloop">
 683     <option value="">Default</option>
 684 <!-- TMPL_LOOP name="statusloop" -->
 685     <option value="<!-- TMPL_VAR name="value" -->" <!-- TMPL_IF name="selected" -->selected<!-- /TMPL_IF -->><!-- TMPL_VAR name="statusname" --></option>
 686 <!-- /TMPL_LOOP -->
 687 </select>
 688
 689 =back
 690
 691 =cut
 692
 693 sub GetItemStatus {
 694
 695     # returns a reference to a hash of references to status...
 696     my ($fwk) = @_;
 697     my %itemstatus;
 698     my $dbh = C4::Context->dbh;
 699     my $sth;
 700     $fwk = '' unless ($fwk);
 701     my ( $tag, $subfield ) =
 702       GetMarcFromKohaField( "items.notforloan", $fwk );
 703     if ( $tag and $subfield ) {
 704         my $sth =
 705           $dbh->prepare(
 706             "SELECT authorised_value
 707             FROM marc_subfield_structure
 708             WHERE tagfield=?
 709                 AND tagsubfield=?
 710                 AND frameworkcode=?
 711             "
 712           );
 713         $sth->execute( $tag, $subfield, $fwk );
 714         if ( my ($authorisedvaluecat) = $sth->fetchrow ) {
 715             my $authvalsth =
 716               $dbh->prepare(
 717                 "SELECT authorised_value,lib
 718                 FROM authorised_values
 719                 WHERE category=?
 720                 ORDER BY lib
 721                 "
 722               );
 723             $authvalsth->execute($authorisedvaluecat);
 724             while ( my ( $authorisedvalue, $lib ) = $authvalsth->fetchrow ) {
 725                 $itemstatus{$authorisedvalue} = $lib;
 726             }
 727             $authvalsth->finish;
 728             return \%itemstatus;
 729             exit 1;
 730         }
 731         else {
 732
 733             #No authvalue list
 734             # build default
 735         }
 736         $sth->finish;
 737     }
 738
 739     #No authvalue list
 740     #build default
 741     $itemstatus{"1"} = "Not For Loan";
 742     return \%itemstatus;
 743 }
 744
 745 =head2 GetItemLocation
 746
 747 =over 4
 748
 749 $itemlochash = GetItemLocation($fwk);
 750
 751 =back
 752
 753 Returns a list of valid values for the
 754 C<items.location> field.
 755
 756 NOTE: does B<not> return an individual item's
 757 location.
 758
 759 where fwk stands for an optional framework code.
 760 Create a location selector with the following code
 761
 762 =head3 in PERL SCRIPT
 763
 764 =over 4
 765
 766 my $itemlochash = getitemlocation;
 767 my @itemlocloop;
 768 foreach my $thisloc (keys %$itemlochash) {
 769     my $selected = 1 if $thisbranch eq $branch;
 770     my %row =(locval => $thisloc,
 771                 selected => $selected,
 772                 locname => $itemlochash->{$thisloc},
 773             );
 774     push @itemlocloop, \%row;
 775 }
 776 $template->param(itemlocationloop => \@itemlocloop);
 777
 778 =back
 779
 780 =head3 in TEMPLATE
 781
 782 =over 4
 783
 784 <select name="location">
 785     <option value="">Default</option>
 786 <!-- TMPL_LOOP name="itemlocationloop" -->
 787     <option value="<!-- TMPL_VAR name="locval" -->" <!-- TMPL_IF name="selected" -->selected<!-- /TMPL_IF -->><!-- TMPL_VAR name="locname" --></option>
 788 <!-- /TMPL_LOOP -->
 789 </select>
 790
 791 =back
 792
 793 =cut
 794
 795 sub GetItemLocation {
 796
 797     # returns a reference to a hash of references to location...
 798     my ($fwk) = @_;
 799     my %itemlocation;
 800     my $dbh = C4::Context->dbh;
 801     my $sth;
 802     $fwk = '' unless ($fwk);
 803     my ( $tag, $subfield ) =
 804       GetMarcFromKohaField( "items.location", $fwk );
 805     if ( $tag and $subfield ) {
 806         my $sth =
 807           $dbh->prepare(
 808             "SELECT authorised_value
 809             FROM marc_subfield_structure
 810             WHERE tagfield=?
 811                 AND tagsubfield=?
 812                 AND frameworkcode=?"
 813           );
 814         $sth->execute( $tag, $subfield, $fwk );
 815         if ( my ($authorisedvaluecat) = $sth->fetchrow ) {
 816             my $authvalsth =
 817               $dbh->prepare(
 818                 "SELECT authorised_value,lib
 819                 FROM authorised_values
 820                 WHERE category=?
 821                 ORDER BY lib"
 822               );
 823             $authvalsth->execute($authorisedvaluecat);
 824             while ( my ( $authorisedvalue, $lib ) = $authvalsth->fetchrow ) {
 825                 $itemlocation{$authorisedvalue} = $lib;
 826             }
 827             $authvalsth->finish;
 828             return \%itemlocation;
 829             exit 1;
 830         }
 831         else {
 832
 833             #No authvalue list
 834             # build default
 835         }
 836         $sth->finish;
 837     }
 838
 839     #No authvalue list
 840     #build default
 841     $itemlocation{"1"} = "Not For Loan";
 842     return \%itemlocation;
 843 }
 844
 845 =head2 GetLostItems
 846
 847 =over 4
 848
 849 $items = GetLostItems($where,$orderby);
 850
 851 =back
 852
 853 This function get the items lost into C<$items>.
 854
 855 =over 2
 856
 857 =item input:
 858 C<$where> is a hashref. it containts a field of the items table as key
 859 and the value to match as value.
 860 C<$orderby> is a field of the items table.
 861
 862 =item return:
 863 C<$items> is a reference to an array full of hasref which keys are items' table column.
 864
 865 =item usage in the perl script:
 866
 867 my %where;
 868 $where{barcode} = 0001548;
 869 my $items = GetLostItems( \%where, "homebranch" );
 870 $template->param(itemsloop => $items);
 871
 872 =back
 873
 874 =cut
 875
 876 sub GetLostItems {
 877     # Getting input args.
 878     my $where   = shift;
 879     my $orderby = shift;
 880     my $dbh     = C4::Context->dbh;
 881
 882     my $query   = "
 883         SELECT *
 884         FROM   items
 885         WHERE  itemlost IS NOT NULL
 886           AND  itemlost <> 0
 887     ";
 888     foreach my $key (keys %$where) {
 889         $query .= " AND " . $key . " LIKE '%" . $where->{$key} . "%'";
 890     }
 891     $query .= " ORDER BY ".$orderby if defined $orderby;
 892
 893     my $sth = $dbh->prepare($query);
 894     $sth->execute;
 895     my @items;
 896     while ( my $row = $sth->fetchrow_hashref ){
 897         push @items, $row;
 898     }
 899     return \@items;
 900 }
 901
 902 =head2 GetItemsForInventory
 903
 904 =over 4
 905
 906 $itemlist = GetItemsForInventory($minlocation,$maxlocation,$datelastseen,$offset,$size)
 907
 908 =back
 909
 910 Retrieve a list of title/authors/barcode/callnumber, for biblio inventory.
 911
 912 The sub returns a list of hashes, containing itemnumber, author, title, barcode & item callnumber.
 913 It is ordered by callnumber,title.
 914
 915 The minlocation & maxlocation parameters are used to specify a range of item callnumbers
 916 the datelastseen can be used to specify that you want to see items not seen since a past date only.
 917 offset & size can be used to retrieve only a part of the whole listing (defaut behaviour)
 918
 919 =cut
 920
 921 sub GetItemsForInventory {
 922     my ( $minlocation, $maxlocation,$location, $itemtype, $datelastseen, $branch, $offset, $size ) = @_;
 923     my $dbh = C4::Context->dbh;
 924     my $sth;
 925     if ($datelastseen) {
 926         $datelastseen=format_date_in_iso($datelastseen);
 927         my $query =
 928                 "SELECT itemnumber,barcode,itemcallnumber,title,author,biblio.biblionumber,datelastseen
 929                  FROM items
 930                    LEFT JOIN biblio ON items.biblionumber=biblio.biblionumber
 931                    LEFT JOIN biblioitems on items.biblionumber=biblioitems.biblionumber
 932                  WHERE itemcallnumber>= ?
 933                    AND itemcallnumber <=?
 934                    AND (datelastseen< ? OR datelastseen IS NULL)";
 935         $query.= " AND items.location=".$dbh->quote($location) if $location;
 936         $query.= " AND items.homebranch=".$dbh->quote($branch) if $branch;
 937         $query.= " AND biblioitems.itemtype=".$dbh->quote($itemtype) if $itemtype;
 938         $query .= " ORDER BY itemcallnumber,title";
 939         $sth = $dbh->prepare($query);
 940         $sth->execute( $minlocation, $maxlocation, $datelastseen );
 941     }
 942     else {
 943         my $query ="
 944                 SELECT itemnumber,barcode,itemcallnumber,biblio.biblionumber,title,author,datelastseen
 945                 FROM items
 946                     LEFT JOIN biblio ON items.biblionumber=biblio.biblionumber
 947                    LEFT JOIN biblioitems on items.biblionumber=biblioitems.biblionumber
 948                 WHERE itemcallnumber>= ?
 949                   AND itemcallnumber <=?";
 950         $query.= " AND items.location=".$dbh->quote($location) if $location;
 951         $query.= " AND items.homebranch=".$dbh->quote($branch) if $branch;
 952         $query.= " AND biblioitems.itemtype=".$dbh->quote($itemtype) if $itemtype;
 953         $query .= " ORDER BY itemcallnumber,title";
 954         $sth = $dbh->prepare($query);
 955         $sth->execute( $minlocation, $maxlocation );
 956     }
 957     my @results;
 958     $size--;
 959     while ( my $row = $sth->fetchrow_hashref ) {
 960         $offset-- if ($offset);
 961         $row->{datelastseen}=format_date($row->{datelastseen});
 962         if ( ( !$offset ) && $size ) {
 963             push @results, $row;
 964             $size--;
 965         }
 966     }
 967     return \@results;
 968 }
 969
 970 =head2 GetItemsCount
 971
 972 =over 4
 973 $count = &GetItemsCount( $biblionumber);
 974
 975 =back
 976
 977 This function return count of item with $biblionumber
 978
 979 =cut
 980
 981 sub GetItemsCount {
 982     my ( $biblionumber ) = @_;
 983     my $dbh = C4::Context->dbh;
 984     my $query = "SELECT count(*)
 985           FROM  items
 986           WHERE biblionumber=?";
 987     my $sth = $dbh->prepare($query);
 988     $sth->execute($biblionumber);
 989     my $count = $sth->fetchrow;
 990     $sth->finish;
 991     return ($count);
 992 }
 993
 994 =head2 GetItemInfosOf
 995
 996 =over 4
 997
 998 GetItemInfosOf(@itemnumbers);
 999
1000 =back
1001
1002 =cut
1003
1004 sub GetItemInfosOf {
1005     my @itemnumbers = @_;
1006
1007     my $query = '
1008         SELECT *
1009         FROM items
1010         WHERE itemnumber IN (' . join( ',', @itemnumbers ) . ')
1011     ';
1012     return get_infos_of( $query, 'itemnumber' );
1013 }
1014
1015 =head2 GetItemsByBiblioitemnumber
1016
1017 =over 4
1018
1019 GetItemsByBiblioitemnumber($biblioitemnumber);
1020
1021 =back
1022
1023 Returns an arrayref of hashrefs suitable for use in a TMPL_LOOP
1024 Called by C<C4::XISBN>
1025
1026 =cut
1027
1028 sub GetItemsByBiblioitemnumber {
1029     my ( $bibitem ) = @_;
1030     my $dbh = C4::Context->dbh;
1031     my $sth = $dbh->prepare("SELECT * FROM items WHERE items.biblioitemnumber = ?") || die $dbh->errstr;
1032     # Get all items attached to a biblioitem
1033     my $i = 0;
1034     my @results;
1035     $sth->execute($bibitem) || die $sth->errstr;
1036     while ( my $data = $sth->fetchrow_hashref ) {
1037         # Foreach item, get circulation information
1038         my $sth2 = $dbh->prepare( "SELECT * FROM issues,borrowers
1039                                    WHERE itemnumber = ?
1040                                    AND issues.borrowernumber = borrowers.borrowernumber"
1041         );
1042         $sth2->execute( $data->{'itemnumber'} );
1043         if ( my $data2 = $sth2->fetchrow_hashref ) {
1044             # if item is out, set the due date and who it is out too
1045             $data->{'date_due'}   = $data2->{'date_due'};
1046             $data->{'cardnumber'} = $data2->{'cardnumber'};
1047             $data->{'borrowernumber'}   = $data2->{'borrowernumber'};
1048         }
1049         else {
1050             # set date_due to blank, so in the template we check itemlost, and wthdrawn
1051             $data->{'date_due'} = '';
1052         }    # else
1053         $sth2->finish;
1054         # Find the last 3 people who borrowed this item.
1055         my $query2 = "SELECT * FROM old_issues, borrowers WHERE itemnumber = ?
1056                       AND old_issues.borrowernumber = borrowers.borrowernumber
1057                       ORDER BY returndate desc,timestamp desc LIMIT 3";
1058         $sth2 = $dbh->prepare($query2) || die $dbh->errstr;
1059         $sth2->execute( $data->{'itemnumber'} ) || die $sth2->errstr;
1060         my $i2 = 0;
1061         while ( my $data2 = $sth2->fetchrow_hashref ) {
1062             $data->{"timestamp$i2"} = $data2->{'timestamp'};
1063             $data->{"card$i2"}      = $data2->{'cardnumber'};
1064             $data->{"borrower$i2"}  = $data2->{'borrowernumber'};
1065             $i2++;
1066         }
1067         $sth2->finish;
1068         push(@results,$data);
1069     }
1070     $sth->finish;
1071     return (\@results);
1072 }
1073
1074 =head2 GetItemsInfo
1075
1076 =over 4
1077
1078 @results = GetItemsInfo($biblionumber, $type);
1079
1080 =back
1081
1082 Returns information about books with the given biblionumber.
1083
1084 C<$type> may be either C<intra> or anything else. If it is not set to
1085 C<intra>, then the search will exclude lost, very overdue, and
1086 withdrawn items.
1087
1088 C<GetItemsInfo> returns a list of references-to-hash. Each element
1089 contains a number of keys. Most of them are table items from the
1090 C<biblio>, C<biblioitems>, C<items>, and C<itemtypes> tables in the
1091 Koha database. Other keys include:
1092
1093 =over 2
1094
1095 =item C<$data-E<gt>{branchname}>
1096
1097 The name (not the code) of the branch to which the book belongs.
1098
1099 =item C<$data-E<gt>{datelastseen}>
1100
1101 This is simply C<items.datelastseen>, except that while the date is
1102 stored in YYYY-MM-DD format in the database, here it is converted to
1103 DD/MM/YYYY format. A NULL date is returned as C<//>.
1104
1105 =item C<$data-E<gt>{datedue}>
1106
1107 =item C<$data-E<gt>{class}>
1108
1109 This is the concatenation of C<biblioitems.classification>, the book's
1110 Dewey code, and C<biblioitems.subclass>.
1111
1112 =item C<$data-E<gt>{ocount}>
1113
1114 I think this is the number of copies of the book available.
1115
1116 =item C<$data-E<gt>{order}>
1117
1118 If this is set, it is set to C<One Order>.
1119
1120 =back
1121
1122 =cut
1123
1124 sub GetItemsInfo {
1125     my ( $biblionumber, $type ) = @_;
1126     my $dbh   = C4::Context->dbh;
1127     my $query = "SELECT *,items.notforloan as itemnotforloan
1128                  FROM items
1129                  LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
1130                  LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber";
1131     $query .=  (C4::Context->preference('item-level_itypes')) ?
1132                      " LEFT JOIN itemtypes on items.itype = itemtypes.itemtype "
1133                     : " LEFT JOIN itemtypes on biblioitems.itemtype = itemtypes.itemtype ";
1134     $query .= "WHERE items.biblionumber = ? ORDER BY items.dateaccessioned desc" ;
1135     my $sth = $dbh->prepare($query);
1136     $sth->execute($biblionumber);
1137     my $i = 0;
1138     my @results;
1139     my ( $date_due, $count_reserves, $serial );
1140
1141     my $isth    = $dbh->prepare(
1142         "SELECT issues.*,borrowers.cardnumber,borrowers.surname,borrowers.firstname,borrowers.branchcode as bcode
1143         FROM   issues LEFT JOIN borrowers ON issues.borrowernumber=borrowers.borrowernumber
1144         WHERE  itemnumber = ?"
1145        );
1146         my $ssth = $dbh->prepare("SELECT serialseq,publisheddate from serialitems left join serial on serialitems.serialid=serial.serialid where serialitems.itemnumber=? ");
1147         while ( my $data = $sth->fetchrow_hashref ) {
1148         my $datedue = '';
1149         $isth->execute( $data->{'itemnumber'} );
1150         if ( my $idata = $isth->fetchrow_hashref ) {
1151             $data->{borrowernumber} = $idata->{borrowernumber};
1152             $data->{cardnumber}     = $idata->{cardnumber};
1153             $data->{surname}     = $idata->{surname};
1154             $data->{firstname}     = $idata->{firstname};
1155             $datedue                = $idata->{'date_due'};
1156         if (C4::Context->preference("IndependantBranches")){
1157         my $userenv = C4::Context->userenv;
1158         if ( ($userenv) && ( $userenv->{flags} != 1 ) ) {
1159             $data->{'NOTSAMEBRANCH'} = 1 if ($idata->{'bcode'} ne $userenv->{branch});
1160         }
1161         }
1162         }
1163                 if ( $data->{'serial'}) {
1164                         $ssth->execute($data->{'itemnumber'}) ;
1165                         ($data->{'serialseq'} , $data->{'publisheddate'}) = $ssth->fetchrow_array();
1166                         $serial = 1;
1167         }
1168                 if ( $datedue eq '' ) {
1169             my ( $restype, $reserves ) =
1170               C4::Reserves::CheckReserves( $data->{'itemnumber'} );
1171             if ($restype) {
1172                 $count_reserves = $restype;
1173             }
1174         }
1175         $isth->finish;
1176         $ssth->finish;
1177         #get branch information.....
1178         my $bsth = $dbh->prepare(
1179             "SELECT * FROM branches WHERE branchcode = ?
1180         "
1181         );
1182         $bsth->execute( $data->{'holdingbranch'} );
1183         if ( my $bdata = $bsth->fetchrow_hashref ) {
1184             $data->{'branchname'} = $bdata->{'branchname'};
1185         }
1186         $data->{'datedue'}        = $datedue;
1187         $data->{'count_reserves'} = $count_reserves;
1188
1189         # get notforloan complete status if applicable
1190         my $sthnflstatus = $dbh->prepare(
1191             'SELECT authorised_value
1192             FROM   marc_subfield_structure
1193             WHERE  kohafield="items.notforloan"
1194         '
1195         );
1196
1197         $sthnflstatus->execute;
1198         my ($authorised_valuecode) = $sthnflstatus->fetchrow;
1199         if ($authorised_valuecode) {
1200             $sthnflstatus = $dbh->prepare(
1201                 "SELECT lib FROM authorised_values
1202                  WHERE  category=?
1203                  AND authorised_value=?"
1204             );
1205             $sthnflstatus->execute( $authorised_valuecode,
1206                 $data->{itemnotforloan} );
1207             my ($lib) = $sthnflstatus->fetchrow;
1208             $data->{notforloanvalue} = $lib;
1209         }
1210
1211         # my stack procedures
1212         my $stackstatus = $dbh->prepare(
1213             'SELECT authorised_value
1214              FROM   marc_subfield_structure
1215              WHERE  kohafield="items.stack"
1216         '
1217         );
1218         $stackstatus->execute;
1219
1220         ($authorised_valuecode) = $stackstatus->fetchrow;
1221         if ($authorised_valuecode) {
1222             $stackstatus = $dbh->prepare(
1223                 "SELECT lib
1224                  FROM   authorised_values
1225                  WHERE  category=?
1226                  AND    authorised_value=?
1227             "
1228             );
1229             $stackstatus->execute( $authorised_valuecode, $data->{stack} );
1230             my ($lib) = $stackstatus->fetchrow;
1231             $data->{stack} = $lib;
1232         }
1233         # Find the last 3 people who borrowed this item.
1234         my $sth2 = $dbh->prepare("SELECT * FROM old_issues,borrowers
1235                                     WHERE itemnumber = ?
1236                                     AND old_issues.borrowernumber = borrowers.borrowernumber
1237                                     LIMIT 3");
1238         $sth2->execute($data->{'itemnumber'});
1239         my $ii = 0;
1240         while (my $data2 = $sth2->fetchrow_hashref()) {
1241             $data->{"timestamp$ii"} = $data2->{'timestamp'} if $data2->{'timestamp'};
1242             $data->{"card$ii"}      = $data2->{'cardnumber'} if $data2->{'cardnumber'};
1243             $data->{"borrower$ii"}  = $data2->{'borrowernumber'} if $data2->{'borrowernumber'};
1244             $ii++;
1245         }
1246
1247         $results[$i] = $data;
1248         $i++;
1249     }
1250     $sth->finish;
1251         if($serial) {
1252                 return( sort { $b->{'publisheddate'} cmp $a->{'publisheddate'} } @results );
1253         } else {
1254         return (@results);
1255         }
1256 }
1257
1258 =head2 get_itemnumbers_of
1259
1260 =over 4
1261
1262 my @itemnumbers_of = get_itemnumbers_of(@biblionumbers);
1263
1264 =back
1265
1266 Given a list of biblionumbers, return the list of corresponding itemnumbers
1267 for each biblionumber.
1268
1269 Return a reference on a hash where keys are biblionumbers and values are
1270 references on array of itemnumbers.
1271
1272 =cut
1273
1274 sub get_itemnumbers_of {
1275     my @biblionumbers = @_;
1276
1277     my $dbh = C4::Context->dbh;
1278
1279     my $query = '
1280         SELECT itemnumber,
1281             biblionumber
1282         FROM items
1283         WHERE biblionumber IN (?' . ( ',?' x scalar @biblionumbers - 1 ) . ')
1284     ';
1285     my $sth = $dbh->prepare($query);
1286     $sth->execute(@biblionumbers);
1287
1288     my %itemnumbers_of;
1289
1290     while ( my ( $itemnumber, $biblionumber ) = $sth->fetchrow_array ) {
1291         push @{ $itemnumbers_of{$biblionumber} }, $itemnumber;
1292     }
1293
1294     return \%itemnumbers_of;
1295 }
1296
1297 =head2 GetItemnumberFromBarcode
1298
1299 =over 4
1300
1301 $result = GetItemnumberFromBarcode($barcode);
1302
1303 =back
1304
1305 =cut
1306
1307 sub GetItemnumberFromBarcode {
1308     my ($barcode) = @_;
1309     my $dbh = C4::Context->dbh;
1310
1311     my $rq =
1312       $dbh->prepare("SELECT itemnumber FROM items WHERE items.barcode=?");
1313     $rq->execute($barcode);
1314     my ($result) = $rq->fetchrow;
1315     return ($result);
1316 }
1317
1318 =head1 LIMITED USE FUNCTIONS
1319
1320 The following functions, while part of the public API,
1321 are not exported.  This is generally because they are
1322 meant to be used by only one script for a specific
1323 purpose, and should not be used in any other context
1324 without careful thought.
1325
1326 =cut
1327
1328 =head2 GetMarcItem
1329
1330 =over 4
1331
1332 my $item_marc = GetMarcItem($biblionumber, $itemnumber);
1333
1334 =back
1335
1336 Returns MARC::Record of the item passed in parameter.
1337 This function is meant for use only in C<cataloguing/additem.pl>,
1338 where it is needed to support that script's MARC-like
1339 editor.
1340
1341 =cut
1342
1343 sub GetMarcItem {
1344     my ( $biblionumber, $itemnumber ) = @_;
1345
1346     # GetMarcItem has been revised so that it does the following:
1347     #  1. Gets the item information from the items table.
1348     #  2. Converts it to a MARC field for storage in the bib record.
1349     #
1350     # The previous behavior was:
1351     #  1. Get the bib record.
1352     #  2. Return the MARC tag corresponding to the item record.
1353     #
1354     # The difference is that one treats the items row as authoritative,
1355     # while the other treats the MARC representation as authoritative
1356     # under certain circumstances.
1357
1358     my $itemrecord = GetItem($itemnumber);
1359
1360     # Tack on 'items.' prefix to column names so that TransformKohaToMarc will work.
1361     # Also, don't emit a subfield if the underlying field is blank.
1362     my $mungeditem = { map {  $itemrecord->{$_} ne '' ? ("items.$_" => $itemrecord->{$_}) : ()  } keys %{ $itemrecord } };
1363     my $itemmarc = TransformKohaToMarc($mungeditem);
1364
1365     my $unlinked_item_subfields = _parse_unlinked_item_subfields_from_xml($mungeditem->{'items.more_subfields_xml'});
1366     if (defined $unlinked_item_subfields and $#$unlinked_item_subfields > -1) {
1367         my @fields = $itemmarc->fields();
1368         if ($#fields > -1) {
1369             $fields[0]->add_subfields(@$unlinked_item_subfields);
1370         }
1371     }
1372
1373     return $itemmarc;
1374
1375 }
1376
1377 =head1 PRIVATE FUNCTIONS AND VARIABLES
1378
1379 The following functions are not meant to be called
1380 directly, but are documented in order to explain
1381 the inner workings of C<C4::Items>.
1382
1383 =cut
1384
1385 =head2 %derived_columns
1386
1387 This hash keeps track of item columns that
1388 are strictly derived from other columns in
1389 the item record and are not meant to be set
1390 independently.
1391
1392 Each key in the hash should be the name of a
1393 column (as named by TransformMarcToKoha).  Each
1394 value should be hashref whose keys are the
1395 columns on which the derived column depends.  The
1396 hashref should also contain a 'BUILDER' key
1397 that is a reference to a sub that calculates
1398 the derived value.
1399
1400 =cut
1401
1402 my %derived_columns = (
1403     'items.cn_sort' => {
1404         'itemcallnumber' => 1,
1405         'items.cn_source' => 1,
1406         'BUILDER' => \&_calc_items_cn_sort,
1407     }
1408 );
1409
1410 =head2 _set_derived_columns_for_add
1411
1412 =over 4
1413
1414 _set_derived_column_for_add($item);
1415
1416 =back
1417
1418 Given an item hash representing a new item to be added,
1419 calculate any derived columns.  Currently the only
1420 such column is C<items.cn_sort>.
1421
1422 =cut
1423
1424 sub _set_derived_columns_for_add {
1425     my $item = shift;
1426
1427     foreach my $column (keys %derived_columns) {
1428         my $builder = $derived_columns{$column}->{'BUILDER'};
1429         my $source_values = {};
1430         foreach my $source_column (keys %{ $derived_columns{$column} }) {
1431             next if $source_column eq 'BUILDER';
1432             $source_values->{$source_column} = $item->{$source_column};
1433         }
1434         $builder->($item, $source_values);
1435     }
1436 }
1437
1438 =head2 _set_derived_columns_for_mod
1439
1440 =over 4
1441
1442 _set_derived_column_for_mod($item);
1443
1444 =back
1445
1446 Given an item hash representing a new item to be modified.
1447 calculate any derived columns.  Currently the only
1448 such column is C<items.cn_sort>.
1449
1450 This routine differs from C<_set_derived_columns_for_add>
1451 in that it needs to handle partial item records.  In other
1452 words, the caller of C<ModItem> may have supplied only one
1453 or two columns to be changed, so this function needs to
1454 determine whether any of the columns to be changed affect
1455 any of the derived columns.  Also, if a derived column
1456 depends on more than one column, but the caller is not
1457 changing all of then, this routine retrieves the unchanged
1458 values from the database in order to ensure a correct
1459 calculation.
1460
1461 =cut
1462
1463 sub _set_derived_columns_for_mod {
1464     my $item = shift;
1465
1466     foreach my $column (keys %derived_columns) {
1467         my $builder = $derived_columns{$column}->{'BUILDER'};
1468         my $source_values = {};
1469         my %missing_sources = ();
1470         my $must_recalc = 0;
1471         foreach my $source_column (keys %{ $derived_columns{$column} }) {
1472             next if $source_column eq 'BUILDER';
1473             if (exists $item->{$source_column}) {
1474                 $must_recalc = 1;
1475                 $source_values->{$source_column} = $item->{$source_column};
1476             } else {
1477                 $missing_sources{$source_column} = 1;
1478             }
1479         }
1480         if ($must_recalc) {
1481             foreach my $source_column (keys %missing_sources) {
1482                 $source_values->{$source_column} = _get_single_item_column($source_column, $item->{'itemnumber'});
1483             }
1484             $builder->($item, $source_values);
1485         }
1486     }
1487 }
1488
1489 =head2 _do_column_fixes_for_mod
1490
1491 =over 4
1492
1493 _do_column_fixes_for_mod($item);
1494
1495 =back
1496
1497 Given an item hashref containing one or more
1498 columns to modify, fix up certain values.
1499 Specifically, set to 0 any passed value
1500 of C<notforloan>, C<damaged>, C<itemlost>, or
1501 C<wthdrawn> that is either undefined or
1502 contains the empty string.
1503
1504 =cut
1505
1506 sub _do_column_fixes_for_mod {
1507     my $item = shift;
1508
1509     if (exists $item->{'notforloan'} and
1510         (not defined $item->{'notforloan'} or $item->{'notforloan'} eq '')) {
1511         $item->{'notforloan'} = 0;
1512     }
1513     if (exists $item->{'damaged'} and
1514         (not defined $item->{'damaged'} or $item->{'damaged'} eq '')) {
1515         $item->{'damaged'} = 0;
1516     }
1517     if (exists $item->{'itemlost'} and
1518         (not defined $item->{'itemlost'} or $item->{'itemlost'} eq '')) {
1519         $item->{'itemlost'} = 0;
1520     }
1521     if (exists $item->{'wthdrawn'} and
1522         (not defined $item->{'wthdrawn'} or $item->{'wthdrawn'} eq '')) {
1523         $item->{'wthdrawn'} = 0;
1524     }
1525 }
1526
1527 =head2 _get_single_item_column
1528
1529 =over 4
1530
1531 _get_single_item_column($column, $itemnumber);
1532
1533 =back
1534
1535 Retrieves the value of a single column from an C<items>
1536 row specified by C<$itemnumber>.
1537
1538 =cut
1539
1540 sub _get_single_item_column {
1541     my $column = shift;
1542     my $itemnumber = shift;
1543
1544     my $dbh = C4::Context->dbh;
1545     my $sth = $dbh->prepare("SELECT $column FROM items WHERE itemnumber = ?");
1546     $sth->execute($itemnumber);
1547     my ($value) = $sth->fetchrow();
1548     return $value;
1549 }
1550
1551 =head2 _calc_items_cn_sort
1552
1553 =over 4
1554
1555 _calc_items_cn_sort($item, $source_values);
1556
1557 =back
1558
1559 Helper routine to calculate C<items.cn_sort>.
1560
1561 =cut
1562
1563 sub _calc_items_cn_sort {
1564     my $item = shift;
1565     my $source_values = shift;
1566
1567     $item->{'items.cn_sort'} = GetClassSort($source_values->{'items.cn_source'}, $source_values->{'itemcallnumber'}, "");
1568 }
1569
1570 =head2 _set_defaults_for_add
1571
1572 =over 4
1573
1574 _set_defaults_for_add($item_hash);
1575
1576 =back
1577
1578 Given an item hash representing an item to be added, set
1579 correct default values for columns whose default value
1580 is not handled by the DBMS.  This includes the following
1581 columns:
1582
1583 =over 2
1584
1585 =item *
1586
1587 C<items.dateaccessioned>
1588
1589 =item *
1590
1591 C<items.notforloan>
1592
1593 =item *
1594
1595 C<items.damaged>
1596
1597 =item *
1598
1599 C<items.itemlost>
1600
1601 =item *
1602
1603 C<items.wthdrawn>
1604
1605 =back
1606
1607 =cut
1608
1609 sub _set_defaults_for_add {
1610     my $item = shift;
1611
1612     # if dateaccessioned is provided, use it. Otherwise, set to NOW()
1613     if (!(exists $item->{'dateaccessioned'}) ||
1614          ($item->{'dateaccessioned'} eq '')) {
1615         # FIXME add check for invalid date
1616         my $today = C4::Dates->new();
1617         $item->{'dateaccessioned'} =  $today->output("iso"); #TODO: check time issues
1618     }
1619
1620     # various item status fields cannot be null
1621     $item->{'notforloan'} = 0 unless exists $item->{'notforloan'} and defined $item->{'notforloan'} and $item->{'notforloan'} ne '';
1622     $item->{'damaged'}    = 0 unless exists $item->{'damaged'}    and defined $item->{'damaged'}    and $item->{'damaged'} ne '';
1623     $item->{'itemlost'}   = 0 unless exists $item->{'itemlost'}   and defined $item->{'itemlost'}   and $item->{'itemlost'} ne '';
1624     $item->{'wthdrawn'}   = 0 unless exists $item->{'wthdrawn'}   and defined $item->{'wthdrawn'}   and $item->{'wthdrawn'} ne '';
1625 }
1626
1627 =head2 _koha_new_item
1628
1629 =over 4
1630
1631 my ($itemnumber,$error) = _koha_new_item( $item, $barcode );
1632
1633 =back
1634
1635 Perform the actual insert into the C<items> table.
1636
1637 =cut
1638
1639 sub _koha_new_item {
1640     my ( $item, $barcode ) = @_;
1641     my $dbh=C4::Context->dbh;
1642     my $error;
1643     my $query =
1644            "INSERT INTO items SET
1645             biblionumber        = ?,
1646             biblioitemnumber    = ?,
1647             barcode             = ?,
1648             dateaccessioned     = ?,
1649             booksellerid        = ?,
1650             homebranch          = ?,
1651             price               = ?,
1652             replacementprice    = ?,
1653             replacementpricedate = NOW(),
1654             datelastborrowed    = ?,
1655             datelastseen        = NOW(),
1656             stack               = ?,
1657             notforloan          = ?,
1658             damaged             = ?,
1659             itemlost            = ?,
1660             wthdrawn            = ?,
1661             itemcallnumber      = ?,
1662             restricted          = ?,
1663             itemnotes           = ?,
1664             holdingbranch       = ?,
1665             paidfor             = ?,
1666             location            = ?,
1667             onloan              = ?,
1668             issues              = ?,
1669             renewals            = ?,
1670             reserves            = ?,
1671             cn_source           = ?,
1672             cn_sort             = ?,
1673             ccode               = ?,
1674             itype               = ?,
1675             materials           = ?,
1676                         uri                 = ?,
1677             more_subfields_xml  = ?
1678           ";
1679     my $sth = $dbh->prepare($query);
1680    $sth->execute(
1681             $item->{'biblionumber'},
1682             $item->{'biblioitemnumber'},
1683             $barcode,
1684             $item->{'dateaccessioned'},
1685             $item->{'booksellerid'},
1686             $item->{'homebranch'},
1687             $item->{'price'},
1688             $item->{'replacementprice'},
1689             $item->{datelastborrowed},
1690             $item->{stack},
1691             $item->{'notforloan'},
1692             $item->{'damaged'},
1693             $item->{'itemlost'},
1694             $item->{'wthdrawn'},
1695             $item->{'itemcallnumber'},
1696             $item->{'restricted'},
1697             $item->{'itemnotes'},
1698             $item->{'holdingbranch'},
1699             $item->{'paidfor'},
1700             $item->{'location'},
1701             $item->{'onloan'},
1702             $item->{'issues'},
1703             $item->{'renewals'},
1704             $item->{'reserves'},
1705             $item->{'items.cn_source'},
1706             $item->{'items.cn_sort'},
1707             $item->{'ccode'},
1708             $item->{'itype'},
1709             $item->{'materials'},
1710             $item->{'uri'},
1711             $item->{'more_subfields_xml'},
1712     );
1713     my $itemnumber = $dbh->{'mysql_insertid'};
1714     if ( defined $sth->errstr ) {
1715         $error.="ERROR in _koha_new_item $query".$sth->errstr;
1716     }
1717     $sth->finish();
1718     return ( $itemnumber, $error );
1719 }
1720
1721 =head2 _koha_modify_item
1722
1723 =over 4
1724
1725 my ($itemnumber,$error) =_koha_modify_item( $item );
1726
1727 =back
1728
1729 Perform the actual update of the C<items> row.  Note that this
1730 routine accepts a hashref specifying the columns to update.
1731
1732 =cut
1733
1734 sub _koha_modify_item {
1735     my ( $item ) = @_;
1736     my $dbh=C4::Context->dbh;
1737     my $error;
1738
1739     my $query = "UPDATE items SET ";
1740     my @bind;
1741     for my $key ( keys %$item ) {
1742         $query.="$key=?,";
1743         push @bind, $item->{$key};
1744     }
1745     $query =~ s/,$//;
1746     $query .= " WHERE itemnumber=?";
1747     push @bind, $item->{'itemnumber'};
1748     my $sth = C4::Context->dbh->prepare($query);
1749     $sth->execute(@bind);
1750     if ( C4::Context->dbh->errstr ) {
1751         $error.="ERROR in _koha_modify_item $query".$dbh->errstr;
1752         warn $error;
1753     }
1754     $sth->finish();
1755     return ($item->{'itemnumber'},$error);
1756 }
1757
1758 =head2 _koha_delete_item
1759
1760 =over 4
1761
1762 _koha_delete_item( $dbh, $itemnum );
1763
1764 =back
1765
1766 Internal function to delete an item record from the koha tables
1767
1768 =cut
1769
1770 sub _koha_delete_item {
1771     my ( $dbh, $itemnum ) = @_;
1772
1773     # save the deleted item to deleteditems table
1774     my $sth = $dbh->prepare("SELECT * FROM items WHERE itemnumber=?");
1775     $sth->execute($itemnum);
1776     my $data = $sth->fetchrow_hashref();
1777     $sth->finish();
1778     my $query = "INSERT INTO deleteditems SET ";
1779     my @bind  = ();
1780     foreach my $key ( keys %$data ) {
1781         $query .= "$key = ?,";
1782         push( @bind, $data->{$key} );
1783     }
1784     $query =~ s/\,$//;
1785     $sth = $dbh->prepare($query);
1786     $sth->execute(@bind);
1787     $sth->finish();
1788
1789     # delete from items table
1790     $sth = $dbh->prepare("DELETE FROM items WHERE itemnumber=?");
1791     $sth->execute($itemnum);
1792     $sth->finish();
1793     return undef;
1794 }
1795
1796 =head2 _marc_from_item_hash
1797
1798 =over 4
1799
1800 my $item_marc = _marc_from_item_hash($item, $frameworkcode[, $unlinked_item_subfields]);
1801
1802 =back
1803
1804 Given an item hash representing a complete item record,
1805 create a C<MARC::Record> object containing an embedded
1806 tag representing that item.
1807
1808 The third, optional parameter C<$unlinked_item_subfields> is
1809 an arrayref of subfields (not mapped to C<items> fields per the
1810 framework) to be added to the MARC representation
1811 of the item.
1812
1813 =cut
1814
1815 sub _marc_from_item_hash {
1816     my $item = shift;
1817     my $frameworkcode = shift;
1818     my $unlinked_item_subfields;
1819     if (@_) {
1820         $unlinked_item_subfields = shift;
1821     }
1822
1823     # Tack on 'items.' prefix to column names so lookup from MARC frameworks will work
1824     # Also, don't emit a subfield if the underlying field is blank.
1825     my $mungeditem = { map {  (defined($item->{$_}) and $item->{$_} ne '') ?
1826                                 (/^items\./ ? ($_ => $item->{$_}) : ("items.$_" => $item->{$_}))
1827                                 : ()  } keys %{ $item } };
1828
1829     my $item_marc = MARC::Record->new();
1830     foreach my $item_field (keys %{ $mungeditem }) {
1831         my ($tag, $subfield) = GetMarcFromKohaField($item_field, $frameworkcode);
1832         next unless defined $tag and defined $subfield; # skip if not mapped to MARC field
1833         if (my $field = $item_marc->field($tag)) {
1834             $field->add_subfields($subfield => $mungeditem->{$item_field});
1835         } else {
1836             my $add_subfields = [];
1837             if (defined $unlinked_item_subfields and ref($unlinked_item_subfields) eq 'ARRAY' and $#$unlinked_item_subfields > -1) {
1838                 $add_subfields = $unlinked_item_subfields;
1839             }
1840             $item_marc->add_fields( $tag, " ", " ", $subfield =>  $mungeditem->{$item_field}, @$add_subfields);
1841         }
1842     }
1843
1844     return $item_marc;
1845 }
1846
1847 =head2 _add_item_field_to_biblio
1848
1849 =over 4
1850
1851 _add_item_field_to_biblio($item_marc, $biblionumber, $frameworkcode);
1852
1853 =back
1854
1855 Adds the fields from a MARC record containing the
1856 representation of a Koha item record to the MARC
1857 biblio record.  The input C<$item_marc> record
1858 is expect to contain just one field, the embedded
1859 item information field.
1860
1861 =cut
1862
1863 sub _add_item_field_to_biblio {
1864     my ($item_marc, $biblionumber, $frameworkcode) = @_;
1865
1866     my $biblio_marc = GetMarcBiblio($biblionumber);
1867
1868     foreach my $field ($item_marc->fields()) {
1869         $biblio_marc->append_fields($field);
1870     }
1871
1872     ModBiblioMarc($biblio_marc, $biblionumber, $frameworkcode);
1873 }
1874
1875 =head2 _replace_item_field_in_biblio
1876
1877 =over
1878
1879 &_replace_item_field_in_biblio($item_marc, $biblionumber, $itemnumber, $frameworkcode)
1880
1881 =back
1882
1883 Given a MARC::Record C<$item_marc> containing one tag with the MARC
1884 representation of the item, examine the biblio MARC
1885 for the corresponding tag for that item and
1886 replace it with the tag from C<$item_marc>.
1887
1888 =cut
1889
1890 sub _replace_item_field_in_biblio {
1891     my ($ItemRecord, $biblionumber, $itemnumber, $frameworkcode) = @_;
1892     my $dbh = C4::Context->dbh;
1893
1894     # get complete MARC record & replace the item field by the new one
1895     my $completeRecord = GetMarcBiblio($biblionumber);
1896     my ($itemtag,$itemsubfield) = GetMarcFromKohaField("items.itemnumber",$frameworkcode);
1897     my $itemField = $ItemRecord->field($itemtag);
1898     my @items = $completeRecord->field($itemtag);
1899     my $found = 0;
1900     foreach (@items) {
1901         if ($_->subfield($itemsubfield) eq $itemnumber) {
1902             $_->replace_with($itemField);
1903             $found = 1;
1904         }
1905     }
1906
1907     unless ($found) {
1908         # If we haven't found the matching field,
1909         # just add it.  However, this means that
1910         # there is likely a bug.
1911         $completeRecord->append_fields($itemField);
1912     }
1913
1914     # save the record
1915     ModBiblioMarc($completeRecord, $biblionumber, $frameworkcode);
1916 }
1917
1918 =head2 _repack_item_errors
1919
1920 Add an error message hash generated by C<CheckItemPreSave>
1921 to a list of errors.
1922
1923 =cut
1924
1925 sub _repack_item_errors {
1926     my $item_sequence_num = shift;
1927     my $item_ref = shift;
1928     my $error_ref = shift;
1929
1930     my @repacked_errors = ();
1931
1932     foreach my $error_code (sort keys %{ $error_ref }) {
1933         my $repacked_error = {};
1934         $repacked_error->{'item_sequence'} = $item_sequence_num;
1935         $repacked_error->{'item_barcode'} = exists($item_ref->{'barcode'}) ? $item_ref->{'barcode'} : '';
1936         $repacked_error->{'error_code'} = $error_code;
1937         $repacked_error->{'error_information'} = $error_ref->{$error_code};
1938         push @repacked_errors, $repacked_error;
1939     }
1940
1941     return @repacked_errors;
1942 }
1943
1944 =head2 _get_unlinked_item_subfields
1945
1946 =over 4
1947
1948 my $unlinked_item_subfields = _get_unlinked_item_subfields($original_item_marc, $frameworkcode);
1949
1950 =back
1951
1952 =cut
1953
1954 sub _get_unlinked_item_subfields {
1955     my $original_item_marc = shift;
1956     my $frameworkcode = shift;
1957
1958     my $marcstructure = GetMarcStructure(1, $frameworkcode);
1959
1960     # assume that this record has only one field, and that that
1961     # field contains only the item information
1962     my $subfields = [];
1963     my @fields = $original_item_marc->fields();
1964     if ($#fields > -1) {
1965         my $field = $fields[0];
1966             my $tag = $field->tag();
1967         foreach my $subfield ($field->subfields()) {
1968             if (defined $subfield->[1] and
1969                 $subfield->[1] ne '' and
1970                 !$marcstructure->{$tag}->{$subfield->[0]}->{'kohafield'}) {
1971                 push @$subfields, $subfield->[0] => $subfield->[1];
1972             }
1973         }
1974     }
1975     return $subfields;
1976 }
1977
1978 =head2 _get_unlinked_subfields_xml
1979
1980 =over 4
1981
1982 my $unlinked_subfields_xml = _get_unlinked_subfields_xml($unlinked_item_subfields);
1983
1984 =back
1985
1986 =cut
1987
1988 sub _get_unlinked_subfields_xml {
1989     my $unlinked_item_subfields = shift;
1990
1991     my $xml;
1992     if (defined $unlinked_item_subfields and ref($unlinked_item_subfields) eq 'ARRAY' and $#$unlinked_item_subfields > -1) {
1993         my $marc = MARC::Record->new();
1994         # use of tag 999 is arbitrary, and doesn't need to match the item tag
1995         # used in the framework
1996         $marc->append_fields(MARC::Field->new('999', ' ', ' ', @$unlinked_item_subfields));
1997         $xml = $marc->as_xml();
1998     }
1999
2000     return $xml;
2001 }
2002
2003 =head2 _parse_unlinked_item_subfields_from_xml
2004
2005 =over 4
2006
2007 my $unlinked_item_subfields = _parse_unlinked_item_subfields_from_xml($whole_item->{'more_subfields_xml'}):
2008
2009 =back
2010
2011 =cut
2012
2013 sub  _parse_unlinked_item_subfields_from_xml {
2014     my $xml = shift;
2015
2016     return unless defined $xml and $xml ne "";
2017     my $marc = MARC::Record->new_from_xml(StripNonXmlChars($xml), 'UTF-8', C4::Context->preference("marcflavour"));
2018     my $unlinked_subfields = [];
2019     my @fields = $marc->fields();
2020     if ($#fields > -1) {
2021         foreach my $subfield ($fields[0]->subfields()) {
2022             push @$unlinked_subfields, $subfield->[0] => $subfield->[1];
2023         }
2024     }
2025     return $unlinked_subfields;
2026 }
2027
2028 1;