C4/Languages.pm

   1 package C4::Languages;
   2
   3 # Copyright 2006 (C) LibLime
   4 # Joshua Ferraro <jmf@liblime.com>
   5 # Portions Copyright 2009 Chris Cormack and the Koha Dev Team
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along with
  18 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  19 # Suite 330, Boston, MA  02111-1307 USA
  20
  21
  22 use strict;
  23 #use warnings;   #FIXME: turn off warnings before release
  24 use Carp;
  25 use C4::Context;
  26 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $DEBUG);
  27
  28 eval {
  29     require Memoize::Memcached;
  30     import Memoize::Memcached qw(memoize_memcached);
  31
  32     my $memcached = {
  33         servers    => [ C4::Context->config('memcached_servers') ],
  34         key_prefix => C4::Context->config('memcached_namespace'),
  35     };
  36
  37     memoize_memcached('getTranslatedLanguages', memcached => $memcached, expire_time => 600); #cache for 10 minutes
  38     memoize_memcached('getFrameworkLanguages' , memcached => $memcached, expire_time => 600);
  39     memoize_memcached('getAllLanguages',        memcached => $memcached, expire_time => 600);
  40 };
  41
  42 BEGIN {
  43     $VERSION = 3.00;
  44     require Exporter;
  45     @ISA    = qw(Exporter);
  46     @EXPORT = qw(
  47         &getFrameworkLanguages
  48         &getTranslatedLanguages
  49         &getAllLanguages
  50     );
  51     @EXPORT_OK = qw(getFrameworkLanguages getTranslatedLanguages getAllLanguages get_bidi regex_lang_subtags language_get_description accept_language);
  52     $DEBUG = 0;
  53 }
  54
  55 =head1 NAME
  56
  57 C4::Languages - Perl Module containing language list functions for Koha
  58
  59 =head1 SYNOPSIS
  60
  61 use C4::Languages;
  62
  63 =head1 DESCRIPTION
  64
  65 =head1 FUNCTIONS
  66
  67 =head2 getFrameworkLanguages
  68
  69 Returns a reference to an array of hashes:
  70
  71  my $languages = getFrameworkLanguages();
  72  for my $language(@$languages) {
  73     print "$language->{language_code}\n"; # language code in iso 639-2
  74     print "$language->{language_name}\n"; # language name in native script
  75     print "$language->{language_locale_name}\n"; # language name in current locale
  76  }
  77
  78 =cut
  79
  80 sub getFrameworkLanguages {
  81     # get a hash with all language codes, names, and locale names
  82     my $all_languages = getAllLanguages();
  83     my @languages;
  84
  85     # find the available directory names
  86     my $dir=C4::Context->config('intranetdir')."/installer/data/";
  87     opendir (MYDIR,$dir);
  88     my @listdir= grep { !/^\.|CVS/ && -d "$dir/$_"} readdir(MYDIR);
  89     closedir MYDIR;
  90
  91     # pull out all data for the dir names that exist
  92     for my $dirname (@listdir) {
  93         for my $language_set (@$all_languages) {
  94
  95             if ($dirname eq $language_set->{language_code}) {
  96                 push @languages, {
  97                     'language_code'=>$dirname,
  98                     'language_description'=>$language_set->{language_description},
  99                     'native_descrition'=>$language_set->{language_native_description} }
 100             }
 101         }
 102     }
 103     return \@languages;
 104 }
 105
 106 =head2 getTranslatedLanguages
 107
 108 Returns a reference to an array of hashes:
 109
 110  my $languages = getTranslatedLanguages();
 111  print "Available translated languages:\n";
 112  for my $language(@$trlanguages) {
 113     print "$language->{language_code}\n"; # language code in iso 639-2
 114     print "$language->{language_name}\n"; # language name in native script
 115     print "$language->{language_locale_name}\n"; # language name in current locale
 116  }
 117
 118 =cut
 119
 120 sub getTranslatedLanguages {
 121     my ($interface, $theme, $current_language, $which) = @_;
 122     my $htdocs;
 123     my $all_languages = getAllLanguages();
 124     my @languages;
 125     my @enabled_languages;
 126
 127     if ($interface && $interface eq 'opac' ) {
 128         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
 129         $htdocs = C4::Context->config('opachtdocs');
 130         if ( $theme and -d "$htdocs/$theme" ) {
 131             (@languages) = _get_language_dirs($htdocs,$theme);
 132         }
 133         else {
 134             for my $theme ( _get_themes('opac') ) {
 135                 push @languages, _get_language_dirs($htdocs,$theme);
 136             }
 137         }
 138     }
 139     elsif ($interface && $interface eq 'intranet' ) {
 140         @enabled_languages = split ",", C4::Context->preference('language');
 141         $htdocs = C4::Context->config('intrahtdocs');
 142         if ( $theme and -d "$htdocs/$theme" ) {
 143             @languages = _get_language_dirs($htdocs,$theme);
 144         }
 145         else {
 146             foreach my $theme ( _get_themes('intranet') ) {
 147                 push @languages, _get_language_dirs($htdocs,$theme);
 148             }
 149         }
 150     }
 151     else {
 152         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
 153         my $htdocs = C4::Context->config('intrahtdocs');
 154         foreach my $theme ( _get_themes('intranet') ) {
 155             push @languages, _get_language_dirs($htdocs,$theme);
 156         }
 157         $htdocs = C4::Context->config('opachtdocs');
 158         foreach my $theme ( _get_themes('opac') ) {
 159             push @languages, _get_language_dirs($htdocs,$theme);
 160         }
 161         my %seen;
 162         $seen{$_}++ for @languages;
 163         @languages = keys %seen;
 164     }
 165     return _build_languages_arrayref($all_languages,\@languages,$current_language,\@enabled_languages);
 166 }
 167
 168 =head2 getAllLanguages
 169
 170 Returns a reference to an array of hashes:
 171
 172  my $alllanguages = getAllLanguages();
 173  print "Available translated languages:\n";
 174  for my $language(@$alllanguages) {
 175     print "$language->{language_code}\n";
 176     print "$language->{language_name}\n";
 177     print "$language->{language_locale_name}\n";
 178  }
 179
 180 =cut
 181
 182 sub getAllLanguages {
 183     my @languages_loop;
 184     my $dbh=C4::Context->dbh;
 185     my $current_language = shift || 'en';
 186     my $sth = $dbh->prepare('SELECT * FROM language_subtag_registry WHERE type=\'language\'');
 187     $sth->execute();
 188     while (my $language_subtag_registry = $sth->fetchrow_hashref) {
 189
 190         # pull out all the script descriptions for each language
 191         my $sth2= $dbh->prepare("SELECT * FROM language_descriptions LEFT JOIN language_rfc4646_to_iso639 on language_rfc4646_to_iso639.rfc4646_subtag = language_descriptions.subtag WHERE type='language' AND subtag =? AND language_descriptions.lang = ?");
 192         $sth2->execute($language_subtag_registry->{subtag},$current_language);
 193
 194         my $sth3 = $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag=? AND lang=?");
 195
 196         # add the correct description info
 197         while (my $language_descriptions = $sth2->fetchrow_hashref) {
 198             $sth3->execute($language_subtag_registry->{subtag},$language_subtag_registry->{subtag});
 199             my $native_description;
 200             while (my $description = $sth3->fetchrow_hashref) {
 201                 $native_description = $description->{description};
 202             }
 203
 204             # fill in the ISO6329 code
 205             $language_subtag_registry->{iso639_2_code} = $language_descriptions->{iso639_2_code};
 206             # fill in the native description of the language, as well as the current language's translation of that if it exists
 207             if ($native_description) {
 208                 $language_subtag_registry->{language_description} = $native_description;
 209                 $language_subtag_registry->{language_description}.=" ($language_descriptions->{description})" if $language_descriptions->{description};
 210             }
 211             else {
 212                 $language_subtag_registry->{language_description} = $language_descriptions->{description};
 213             }
 214         }
 215         push @languages_loop, $language_subtag_registry;
 216     }
 217     return \@languages_loop;
 218 }
 219
 220 =head2 _get_themes
 221
 222 Internal function, returns an array of all available themes.
 223
 224   (@themes) = &_get_themes('opac');
 225   (@themes) = &_get_themes('intranet');
 226
 227 =cut
 228
 229 sub _get_themes {
 230     my $interface = shift;
 231     my $htdocs;
 232     my @themes;
 233     if ( $interface eq 'intranet' ) {
 234         $htdocs = C4::Context->config('intrahtdocs');
 235     }
 236     else {
 237         $htdocs = C4::Context->config('opachtdocs');
 238     }
 239     opendir D, "$htdocs";
 240     my @dirlist = readdir D;
 241     foreach my $directory (@dirlist) {
 242         # if there's an en dir, it's a valid theme
 243         -d "$htdocs/$directory/en" and push @themes, $directory;
 244     }
 245     return @themes;
 246 }
 247
 248 =head2 _get_language_dirs
 249
 250 Internal function, returns an array of directory names, excluding non-language directories
 251
 252 =cut
 253
 254 sub _get_language_dirs {
 255     my ($htdocs,$theme) = @_;
 256     my @lang_strings;
 257     opendir D, "$htdocs/$theme";
 258     for my $lang_string ( readdir D ) {
 259         next if $lang_string =~/^\./;
 260         next if $lang_string eq 'all';
 261         next if $lang_string =~/png$/;
 262         next if $lang_string =~/css$/;
 263         next if $lang_string =~/CVS$/;
 264         next if $lang_string =~/\.txt$/i;     #Don't read the readme.txt !
 265         next if $lang_string =~/img|images|famfam/;
 266         push @lang_strings, $lang_string;
 267     }
 268         return (@lang_strings);
 269 }
 270
 271 =head2 _build_languages_arrayref
 272
 273 Internal function for building the ref to array of hashes
 274
 275 FIXME: this could be rewritten and simplified using map
 276
 277 =cut
 278
 279 sub _build_languages_arrayref {
 280         my ($all_languages,$translated_languages,$current_language,$enabled_languages) = @_;
 281         my @translated_languages = @$translated_languages;
 282         my @languages_loop; # the final reference to an array of hashrefs
 283         my @enabled_languages = @$enabled_languages;
 284         # how many languages are enabled, if one, take note, some contexts won't need to display it
 285         my %seen_languages; # the language tags we've seen
 286         my %found_languages;
 287         my $language_groups;
 288         my $track_language_groups;
 289         my $current_language_regex = regex_lang_subtags($current_language);
 290         # Loop through the translated languages
 291         for my $translated_language (@translated_languages) {
 292             # separate the language string into its subtag types
 293             my $language_subtags_hashref = regex_lang_subtags($translated_language);
 294
 295             # is this language string 'enabled'?
 296             for my $enabled_language (@enabled_languages) {
 297                 #warn "Checking out if $translated_language eq $enabled_language";
 298                 $language_subtags_hashref->{'enabled'} = 1 if $translated_language eq $enabled_language;
 299             }
 300
 301             # group this language, key by langtag
 302             $language_subtags_hashref->{'sublanguage_current'} = 1 if $translated_language eq $current_language;
 303             $language_subtags_hashref->{'rfc4646_subtag'} = $translated_language;
 304             $language_subtags_hashref->{'native_description'} = language_get_description($language_subtags_hashref->{language},$language_subtags_hashref->{language},'language');
 305             $language_subtags_hashref->{'script_description'} = language_get_description($language_subtags_hashref->{script},$language_subtags_hashref->{'language'},'script');
 306             $language_subtags_hashref->{'region_description'} = language_get_description($language_subtags_hashref->{region},$language_subtags_hashref->{'language'},'region');
 307             $language_subtags_hashref->{'variant_description'} = language_get_description($language_subtags_hashref->{variant},$language_subtags_hashref->{'language'},'variant');
 308             $track_language_groups->{$language_subtags_hashref->{'language'}}++;
 309             push ( @{ $language_groups->{$language_subtags_hashref->{language}} }, $language_subtags_hashref );
 310         }
 311         # $key is a language subtag like 'en'
 312         while( my ($key, $value) = each %$language_groups) {
 313
 314             # is this language group enabled? are any of the languages within it enabled?
 315             my $enabled;
 316             for my $enabled_language (@enabled_languages) {
 317                 my $regex_enabled_language = regex_lang_subtags($enabled_language);
 318                 $enabled = 1 if $key eq $regex_enabled_language->{language};
 319             }
 320             push @languages_loop,  {
 321                             # this is only use if there is one
 322                             rfc4646_subtag => @$value[0]->{rfc4646_subtag},
 323                             native_description => language_get_description($key,$key,'language'),
 324                             language => $key,
 325                             sublanguages_loop => $value,
 326                             plural => $track_language_groups->{$key} >1 ? 1 : 0,
 327                             current => $current_language_regex->{language} eq $key ? 1 : 0,
 328                             group_enabled => $enabled,
 329                            };
 330         }
 331         return \@languages_loop;
 332 }
 333
 334 sub language_get_description {
 335     my ($script,$lang,$type) = @_;
 336     my $dbh = C4::Context->dbh;
 337     my $desc;
 338     my $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 339     #warn "QUERY: SELECT description FROM language_descriptions WHERE subtag=$script AND lang=$lang AND type=$type";
 340     $sth->execute($script,$lang,$type);
 341     while (my $descriptions = $sth->fetchrow_hashref) {
 342         $desc = $descriptions->{'description'};
 343     }
 344     unless ($desc) {
 345         $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 346         $sth->execute($script,'en',$type);
 347         while (my $descriptions = $sth->fetchrow_hashref) {
 348             $desc = $descriptions->{'description'};
 349         }
 350     }
 351     return $desc;
 352 }
 353 =head2 regex_lang_subtags
 354
 355 This internal sub takes a string composed according to RFC 4646 as
 356 an input and returns a reference to a hash containing keys and values
 357 for ( language, script, region, variant, extension, privateuse )
 358
 359 =cut
 360
 361 sub regex_lang_subtags {
 362     my $string = shift;
 363
 364     # Regex for recognizing RFC 4646 well-formed tags
 365     # http://www.rfc-editor.org/rfc/rfc4646.txt
 366
 367     # regexes based on : http://unicode.org/cldr/data/tools/java/org/unicode/cldr/util/data/langtagRegex.txt
 368     # The structure requires no forward references, so it reverses the order.
 369     # The uppercase comments are fragments copied from RFC 4646
 370     #
 371     # Note: the tool requires that any real "=" or "#" or ";" in the regex be escaped.
 372
 373     my $alpha   = qr/[a-zA-Z]/ ;    # ALPHA
 374     my $digit   = qr/[0-9]/ ;   # DIGIT
 375     my $alphanum    = qr/[a-zA-Z0-9]/ ; # ALPHA / DIGIT
 376     my $x   = qr/[xX]/ ;    # private use singleton
 377     my $singleton = qr/[a-w y-z A-W Y-Z]/ ; # other singleton
 378     my $s   = qr/[-]/ ; # separator -- lenient parsers will use [-_]
 379
 380     # Now do the components. The structure is slightly different to allow for capturing the right components.
 381     # The notation (?:....) is a non-capturing version of (...): so the "?:" can be deleted if someone doesn't care about capturing.
 382
 383     my $extlang = qr{(?: $s $alpha{3} )}x ; # *3("-" 3ALPHA)
 384     my $language    = qr{(?: $alpha{2,3} | $alpha{4,8} )}x ;
 385     #my $language   = qr{(?: $alpha{2,3}$extlang{0,3} | $alpha{4,8} )}x ;   # (2*3ALPHA [ extlang ]) / 4ALPHA / 5*8ALPHA
 386
 387     my $script  = qr{(?: $alpha{4} )}x ;    # 4ALPHA
 388
 389     my $region  = qr{(?: $alpha{2} | $digit{3} )}x ;     # 2ALPHA / 3DIGIT
 390
 391     my $variantSub  = qr{(?: $digit$alphanum{3} | $alphanum{5,8} )}x ;  # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 392     my $variant = qr{(?: $variantSub (?: $s$variantSub )* )}x ; # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 393
 394     my $extensionSub    = qr{(?: $singleton (?: $s$alphanum{2,8} )+ )}x ;   # singleton 1*("-" (2*8alphanum))
 395     my $extension   = qr{(?: $extensionSub (?: $s$extensionSub )* )}x ; # singleton 1*("-" (2*8alphanum))
 396
 397     my $privateuse  = qr{(?: $x (?: $s$alphanum{1,8} )+ )}x ;   # ("x"/"X") 1*("-" (1*8alphanum))
 398
 399     # Define certain grandfathered codes, since otherwise the regex is pretty useless.
 400     # Since these are limited, this is safe even later changes to the registry --
 401     # the only oddity is that it might change the type of the tag, and thus
 402     # the results from the capturing groups.
 403     # http://www.iana.org/assignments/language-subtag-registry
 404     # Note that these have to be compared case insensitively, requiring (?i) below.
 405
 406     my $grandfathered   = qr{(?: (?i)
 407         en $s GB $s oed
 408     |   i $s (?: ami | bnn | default | enochian | hak | klingon | lux | mingo | navajo | pwn | tao | tay | tsu )
 409     |   sgn $s (?: BE $s fr | BE $s nl | CH $s de)
 410 )}x;
 411
 412     # For well-formedness, we don't need the ones that would otherwise pass, so they are commented out here
 413
 414     #   |   art $s lojban
 415     #   |   cel $s gaulish
 416     #   |   en $s (?: boont | GB $s oed | scouse )
 417     #   |   no $s (?: bok | nyn)
 418     #   |   zh $s (?: cmn | cmn $s Hans | cmn $s Hant | gan | guoyu | hakka | min | min $s nan | wuu | xiang | yue)
 419
 420     # Here is the final breakdown, with capturing groups for each of these components
 421     # The language, variants, extensions, grandfathered, and private-use may have interior '-'
 422
 423     #my $root = qr{(?: ($language) (?: $s ($script) )? 40% (?: $s ($region) )? 40% (?: $s ($variant) )? 10% (?: $s ($extension) )? 5% (?: $s ($privateuse) )? 5% ) 90% | ($grandfathered) 5% | ($privateuse) 5% };
 424
 425     $string =~  qr{^ (?:($language)) (?:$s($script))? (?:$s($region))?  (?:$s($variant))?  (?:$s($extension))?  (?:$s($privateuse))? $}xi;  # |($grandfathered) | ($privateuse) $}xi;
 426     my %subtag = (
 427         'rfc4646_subtag' => $string,
 428         'language' => $1,
 429         'script' => $2,
 430         'region' => $3,
 431         'variant' => $4,
 432         'extension' => $5,
 433         'privateuse' => $6,
 434     );
 435     return \%subtag;
 436 }
 437
 438 # Script Direction Resources:
 439 # http://www.w3.org/International/questions/qa-scripts
 440 sub get_bidi {
 441     my ($language_script)= @_;
 442     my $dbh = C4::Context->dbh;
 443     my $bidi;
 444     my $sth = $dbh->prepare('SELECT bidi FROM language_script_bidi WHERE rfc4646_subtag=?');
 445     $sth->execute($language_script);
 446     while (my $result = $sth->fetchrow_hashref) {
 447         $bidi = $result->{'bidi'};
 448     }
 449     return $bidi;
 450 };
 451
 452 sub accept_language {
 453     # referenced http://search.cpan.org/src/CGILMORE/I18N-AcceptLanguage-1.04/lib/I18N/AcceptLanguage.pm
 454     # FIXME: since this is only used in Output.pm as of Jan 8 2008, maybe it should be IN Output.pm
 455     my ($clientPreferences,$supportedLanguages) = @_;
 456     my @languages = ();
 457     if ($clientPreferences) {
 458         # There should be no whitespace anways, but a cleanliness/sanity check
 459         $clientPreferences =~ s/\s//g;
 460         # Prepare the list of client-acceptable languages
 461         foreach my $tag (split(/,/, $clientPreferences)) {
 462             my ($language, $quality) = split(/\;/, $tag);
 463             $quality =~ s/^q=//i if $quality;
 464             $quality = 1 unless $quality;
 465             next if $quality <= 0;
 466             # We want to force the wildcard to be last
 467             $quality = 0 if ($language eq '*');
 468             # Pushing lowercase language here saves processing later
 469             push(@languages, { quality => $quality,
 470                language => $language,
 471                lclanguage => lc($language) });
 472         }
 473     } else {
 474         carp "accept_language(x,y) called with no clientPreferences (x).";
 475     }
 476     # Prepare the list of server-supported languages
 477     my %supportedLanguages = ();
 478     my %secondaryLanguages = ();
 479     foreach my $language (@$supportedLanguages) {
 480         # warn "Language supported: " . $language->{language};
 481         my $subtag = $language->{rfc4646_subtag};
 482         $supportedLanguages{lc($subtag)} = $subtag;
 483         if ( $subtag =~ /^([^-]+)-?/ ) {
 484             $secondaryLanguages{lc($1)} = $subtag;
 485         }
 486     }
 487
 488     # Reverse sort the list, making best quality at the front of the array
 489     @languages = sort { $b->{quality} <=> $a->{quality} } @languages;
 490     my $secondaryMatch = '';
 491     foreach my $tag (@languages) {
 492         if (exists($supportedLanguages{$tag->{lclanguage}})) {
 493             # Client en-us eq server en-us
 494             return $supportedLanguages{$tag->{language}} if exists($supportedLanguages{$tag->{language}});
 495             return $supportedLanguages{$tag->{lclanguage}};
 496         } elsif (exists($secondaryLanguages{$tag->{lclanguage}})) {
 497             # Client en eq server en-us
 498             return $secondaryLanguages{$tag->{language}} if exists($secondaryLanguages{$tag->{language}});
 499             return $supportedLanguages{$tag->{lclanguage}};
 500         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 501             # Client en-gb eq server en-us
 502             $secondaryMatch = $secondaryLanguages{$1};
 503         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 504             # FIXME: We just checked the exact same conditional!
 505             # Client en-us eq server en
 506             $secondaryMatch = $supportedLanguages{$1};
 507         } elsif ($tag->{lclanguage} eq '*') {
 508         # * matches every language not already specified.
 509         # It doesn't care which we pick, so let's pick the default,
 510         # if available, then the first in the array.
 511         #return $acceptor->defaultLanguage() if $acceptor->defaultLanguage();
 512         return $supportedLanguages->[0];
 513         }
 514     }
 515     # No primary matches. Secondary? (ie, en-us requested and en supported)
 516     return $secondaryMatch if $secondaryMatch;
 517     return undef;   # else, we got nothing.
 518 }
 519 1;
 520
 521 __END__
 522
 523 =head1 AUTHOR
 524
 525 Joshua Ferraro
 526
 527 =cut