C4/Languages.pm

   1 package C4::Languages;
   2
   3 # Copyright 2006 (C) LibLime
   4 # Joshua Ferraro <jmf@liblime.com>
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along with
  18 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  19 # Suite 330, Boston, MA  02111-1307 USA
  20
  21
  22 use strict;
  23 use warnings;   #FIXME: turn off warnings before release
  24 use Carp;
  25 use C4::Context;
  26 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $DEBUG);
  27
  28 BEGIN {
  29     $VERSION = 3.00;
  30     require Exporter;
  31     @ISA    = qw(Exporter);
  32     @EXPORT = qw(
  33         &getFrameworkLanguages
  34         &getTranslatedLanguages
  35         &getAllLanguages
  36     );
  37     @EXPORT_OK = qw(getFrameworkLanguages getTranslatedLanguages getAllLanguages get_bidi regex_lang_subtags language_get_description accept_language);
  38     $DEBUG = 0;
  39 }
  40
  41 =head1 NAME
  42
  43 C4::Languages - Perl Module containing language list functions for Koha
  44
  45 =head1 SYNOPSIS
  46
  47 use C4::Languages;
  48
  49 =head1 DESCRIPTION
  50
  51 =head1 FUNCTIONS
  52
  53 =head2 getFrameworkLanguages
  54
  55 Returns a reference to an array of hashes:
  56
  57  my $languages = getFrameworkLanguages();
  58  for my $language(@$languages) {
  59     print "$language->{language_code}\n"; # language code in iso 639-2
  60     print "$language->{language_name}\n"; # language name in native script
  61     print "$language->{language_locale_name}\n"; # language name in current locale
  62  }
  63
  64 =cut
  65
  66 sub getFrameworkLanguages {
  67     # get a hash with all language codes, names, and locale names
  68     my $all_languages = getAllLanguages();
  69     my @languages;
  70
  71     # find the available directory names
  72     my $dir=C4::Context->config('intranetdir')."/installer/data/";
  73     opendir (MYDIR,$dir);
  74     my @listdir= grep { !/^\.|CVS/ && -d "$dir/$_"} readdir(MYDIR);
  75     closedir MYDIR;
  76
  77     # pull out all data for the dir names that exist
  78     for my $dirname (@listdir) {
  79         for my $language_set (@$all_languages) {
  80
  81             if ($dirname eq $language_set->{language_code}) {
  82                 push @languages, {
  83                     'language_code'=>$dirname,
  84                     'language_description'=>$language_set->{language_description},
  85                     'native_descrition'=>$language_set->{language_native_description} }
  86             }
  87         }
  88     }
  89     return \@languages;
  90 }
  91
  92 =head2 getTranslatedLanguages
  93
  94 Returns a reference to an array of hashes:
  95
  96  my $languages = getTranslatedLanguages();
  97  print "Available translated langauges:\n";
  98  for my $language(@$trlanguages) {
  99     print "$language->{language_code}\n"; # language code in iso 639-2
 100     print "$language->{language_name}\n"; # language name in native script
 101     print "$language->{language_locale_name}\n"; # language name in current locale
 102  }
 103
 104 =cut
 105
 106 sub getTranslatedLanguages {
 107     my ($interface, $theme, $current_language, $which) = @_;
 108     my $htdocs;
 109     my $all_languages = getAllLanguages();
 110     my @languages;
 111     my $lang;
 112     my @enabled_languages;
 113
 114     if ($interface && $interface eq 'opac' ) {
 115         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
 116         $htdocs = C4::Context->config('opachtdocs');
 117         if ( $theme and -d "$htdocs/$theme" ) {
 118             (@languages) = _get_language_dirs($htdocs,$theme);
 119             return _build_languages_arrayref($all_languages,\@languages,$current_language,\@enabled_languages);
 120         }
 121         else {
 122             for my $theme ( _get_themes('opac') ) {
 123                 push @languages, _get_language_dirs($htdocs,$theme);
 124             }
 125             return _build_languages_arrayref($all_languages,\@languages,$current_language,\@enabled_languages);
 126         }
 127     }
 128     elsif ($interface && $interface eq 'intranet' ) {
 129         @enabled_languages = split ",", C4::Context->preference('language');
 130         $htdocs = C4::Context->config('intrahtdocs');
 131         if ( $theme and -d "$htdocs/$theme" ) {
 132             @languages = _get_language_dirs($htdocs,$theme);
 133             return _build_languages_arrayref($all_languages,\@languages,$current_language,\@enabled_languages);
 134         }
 135         else {
 136             foreach my $theme ( _get_themes('intranet') ) {
 137                 push @languages, _get_language_dirs($htdocs,$theme);
 138             }
 139             return _build_languages_arrayref($all_languages,\@languages,$current_language,\@enabled_languages);
 140         }
 141     }
 142     else {
 143         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
 144         my $htdocs = C4::Context->config('intrahtdocs');
 145         foreach my $theme ( _get_themes('intranet') ) {
 146             push @languages, _get_language_dirs($htdocs,$theme);
 147         }
 148         $htdocs = C4::Context->config('opachtdocs');
 149         foreach my $theme ( _get_themes('opac') ) {
 150             push @languages, _get_language_dirs($htdocs,$theme);
 151         }
 152         return _build_languages_arrayref($all_languages,\@languages,$current_language,\@enabled_languages);
 153     }
 154 }
 155
 156 =head2 getAllLanguages
 157
 158 Returns a reference to an array of hashes:
 159
 160  my $alllanguages = getAllLanguages();
 161  print "Available translated langauges:\n";
 162  for my $language(@$alllanguages) {
 163     print "$language->{language_code}\n";
 164     print "$language->{language_name}\n";
 165     print "$language->{language_locale_name}\n";
 166  }
 167
 168 =cut
 169
 170 sub getAllLanguages {
 171     my @languages_loop;
 172     my $dbh=C4::Context->dbh;
 173     my $current_language = 'en';
 174     my $sth = $dbh->prepare('SELECT * FROM language_subtag_registry WHERE type=\'language\'');
 175     $sth->execute();
 176     while (my $language_subtag_registry = $sth->fetchrow_hashref) {
 177
 178         # pull out all the script descriptions for each language
 179         my $sth2= $dbh->prepare("SELECT * FROM language_descriptions LEFT JOIN language_rfc4646_to_iso639 on language_rfc4646_to_iso639.rfc4646_subtag = language_descriptions.subtag WHERE type='language' AND subtag =?");
 180         $sth2->execute($language_subtag_registry->{subtag});
 181
 182         # add the correct description info
 183         while (my $language_descriptions = $sth2->fetchrow_hashref) {
 184         # fill in the ISO6329 code
 185         $language_subtag_registry->{iso639_2_code} = $language_descriptions->{iso639_2_code};
 186             $language_subtag_registry->{language_description} = $language_descriptions->{description};
 187         }
 188         push @languages_loop, $language_subtag_registry;
 189     }
 190     return \@languages_loop;
 191 }
 192
 193 =head2 _get_themes
 194
 195 Internal function, returns an array of all available themes.
 196
 197   (@themes) = &_get_themes('opac');
 198   (@themes) = &_get_themes('intranet');
 199
 200 =cut
 201
 202 sub _get_themes {
 203     my $interface = shift;
 204     my $htdocs;
 205     my @themes;
 206     if ( $interface eq 'intranet' ) {
 207         $htdocs = C4::Context->config('intrahtdocs');
 208     }
 209     else {
 210         $htdocs = C4::Context->config('opachtdocs');
 211     }
 212     opendir D, "$htdocs";
 213     my @dirlist = readdir D;
 214     foreach my $directory (@dirlist) {
 215         # if there's an en dir, it's a valid theme
 216         -d "$htdocs/$directory/en" and push @themes, $directory;
 217     }
 218     return @themes;
 219 }
 220
 221 =head2 _get_language_dirs
 222
 223 Internal function, returns an array of directory names, excluding non-language directories
 224
 225 =cut
 226
 227 sub _get_language_dirs {
 228     my ($htdocs,$theme) = @_;
 229     my @lang_strings;
 230     opendir D, "$htdocs/$theme";
 231     for my $lang_string ( readdir D ) {
 232         next if $lang_string =~/^\./;
 233         next if $lang_string eq 'all';
 234         next if $lang_string =~/png$/;
 235         next if $lang_string =~/css$/;
 236         next if $lang_string =~/CVS$/;
 237         next if $lang_string =~/\.txt$/i;     #Don't read the readme.txt !
 238         next if $lang_string =~/img|images/;
 239         push @lang_strings, $lang_string;
 240     }
 241         return (@lang_strings);
 242 }
 243
 244 =head2 _build_languages_arrayref
 245
 246 Internal function for building the ref to array of hashes
 247
 248 FIXME: this could be rewritten and simplified using map
 249
 250 =cut
 251
 252 sub _build_languages_arrayref {
 253         my ($all_languages,$translated_languages,$current_language,$enabled_languages) = @_;
 254         my @translated_languages = @$translated_languages;
 255         my @languages_loop; # the final reference to an array of hashrefs
 256         my @enabled_languages = @$enabled_languages;
 257         my %seen_languages; # the language tags we've seen
 258         my %found_languages;
 259         my $language_groups;
 260         my $track_language_groups;
 261         my $current_language_regex = regex_lang_subtags($current_language);
 262         # Loop through the translated languages
 263         for my $translated_language (@translated_languages) {
 264             # separate the language string into its subtag types
 265             my $language_subtags_hashref = regex_lang_subtags($translated_language);
 266
 267             # is this language string 'enabled'?
 268             for my $enabled_language (@enabled_languages) {
 269                 #warn "Checking out if $translated_language eq $enabled_language";
 270                 $language_subtags_hashref->{'enabled'} = 1 if $translated_language eq $enabled_language;
 271             }
 272
 273             # group this language, key by langtag
 274             $language_subtags_hashref->{'sublanguage_current'} = 1 if $translated_language eq $current_language;
 275             $language_subtags_hashref->{'rfc4646_subtag'} = $translated_language;
 276             $language_subtags_hashref->{'native_description'} = language_get_description($language_subtags_hashref->{language},$language_subtags_hashref->{language},'language');
 277             $language_subtags_hashref->{'script_description'} = language_get_description($language_subtags_hashref->{script},$language_subtags_hashref->{'language'},'script');
 278             $language_subtags_hashref->{'region_description'} = language_get_description($language_subtags_hashref->{region},$language_subtags_hashref->{'language'},'region');
 279             $language_subtags_hashref->{'variant_description'} = language_get_description($language_subtags_hashref->{variant},$language_subtags_hashref->{'language'},'variant');
 280             $track_language_groups->{$language_subtags_hashref->{'language'}}++;
 281             push ( @{ $language_groups->{$language_subtags_hashref->{language}} }, $language_subtags_hashref );
 282         }
 283         # $key is a language subtag like 'en'
 284         while( my ($key, $value) = each %$language_groups) {
 285
 286             # is this language group enabled? are any of the languages within it enabled?
 287             my $enabled;
 288             for my $enabled_language (@enabled_languages) {
 289                 my $regex_enabled_language = regex_lang_subtags($enabled_language);
 290                 $enabled = 1 if $key eq $regex_enabled_language->{language};
 291             }
 292             push @languages_loop,  {
 293                             # this is only use if there is one
 294                             rfc4646_subtag => @$value[0]->{rfc4646_subtag},
 295                             native_description => language_get_description($key,$key,'language'),
 296                             language => $key,
 297                             sublanguages_loop => $value,
 298                             plural => $track_language_groups->{$key} >1 ? 1 : 0,
 299                             current => $current_language_regex->{language} eq $key ? 1 : 0,
 300                             group_enabled => $enabled,
 301                            };
 302         }
 303         return \@languages_loop;
 304 }
 305
 306 sub language_get_description {
 307     my ($script,$lang,$type) = @_;
 308     my $dbh = C4::Context->dbh;
 309     my $desc;
 310     my $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 311     #warn "QUERY: SELECT description FROM language_descriptions WHERE subtag=$script AND lang=$lang AND type=$type";
 312     $sth->execute($script,$lang,$type);
 313     while (my $descriptions = $sth->fetchrow_hashref) {
 314         $desc = $descriptions->{'description'};
 315     }
 316     unless ($desc) {
 317         $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 318         $sth->execute($script,'en',$type);
 319         while (my $descriptions = $sth->fetchrow_hashref) {
 320             $desc = $descriptions->{'description'};
 321         }
 322     }
 323     return $desc;
 324 }
 325 =head2 regex_lang_subtags
 326
 327 This internal sub takes a string composed according to RFC 4646 as
 328 an input and returns a reference to a hash containing keys and values
 329 for ( language, script, region, variant, extension, privateuse )
 330
 331 =cut
 332
 333 sub regex_lang_subtags {
 334     my $string = shift;
 335
 336     # Regex for recognizing RFC 4646 well-formed tags
 337     # http://www.rfc-editor.org/rfc/rfc4646.txt
 338
 339     # regexes based on : http://unicode.org/cldr/data/tools/java/org/unicode/cldr/util/data/langtagRegex.txt
 340     # The structure requires no forward references, so it reverses the order.
 341     # The uppercase comments are fragments copied from RFC 4646
 342     #
 343     # Note: the tool requires that any real "=" or "#" or ";" in the regex be escaped.
 344
 345     my $alpha   = qr/[a-zA-Z]/ ;    # ALPHA
 346     my $digit   = qr/[0-9]/ ;   # DIGIT
 347     my $alphanum    = qr/[a-zA-Z0-9]/ ; # ALPHA / DIGIT
 348     my $x   = qr/[xX]/ ;    # private use singleton
 349     my $singleton = qr/[a-w y-z A-W Y-Z]/ ; # other singleton
 350     my $s   = qr/[-]/ ; # separator -- lenient parsers will use [-_]
 351
 352     # Now do the components. The structure is slightly different to allow for capturing the right components.
 353     # The notation (?:....) is a non-capturing version of (...): so the "?:" can be deleted if someone doesn't care about capturing.
 354
 355     my $extlang = qr{(?: $s $alpha{3} )}x ; # *3("-" 3ALPHA)
 356     my $language    = qr{(?: $alpha{2,3} | $alpha{4,8} )}x ;
 357     #my $language   = qr{(?: $alpha{2,3}$extlang{0,3} | $alpha{4,8} )}x ;   # (2*3ALPHA [ extlang ]) / 4ALPHA / 5*8ALPHA
 358
 359     my $script  = qr{(?: $alpha{4} )}x ;    # 4ALPHA
 360
 361     my $region  = qr{(?: $alpha{2} | $digit{3} )}x ;     # 2ALPHA / 3DIGIT
 362
 363     my $variantSub  = qr{(?: $digit$alphanum{3} | $alphanum{5,8} )}x ;  # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 364     my $variant = qr{(?: $variantSub (?: $s$variantSub )* )}x ; # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 365
 366     my $extensionSub    = qr{(?: $singleton (?: $s$alphanum{2,8} )+ )}x ;   # singleton 1*("-" (2*8alphanum))
 367     my $extension   = qr{(?: $extensionSub (?: $s$extensionSub )* )}x ; # singleton 1*("-" (2*8alphanum))
 368
 369     my $privateuse  = qr{(?: $x (?: $s$alphanum{1,8} )+ )}x ;   # ("x"/"X") 1*("-" (1*8alphanum))
 370
 371     # Define certain grandfathered codes, since otherwise the regex is pretty useless.
 372     # Since these are limited, this is safe even later changes to the registry --
 373     # the only oddity is that it might change the type of the tag, and thus
 374     # the results from the capturing groups.
 375     # http://www.iana.org/assignments/language-subtag-registry
 376     # Note that these have to be compared case insensitively, requiring (?i) below.
 377
 378     my $grandfathered   = qr{(?: (?i)
 379         en $s GB $s oed
 380     |   i $s (?: ami | bnn | default | enochian | hak | klingon | lux | mingo | navajo | pwn | tao | tay | tsu )
 381     |   sgn $s (?: BE $s fr | BE $s nl | CH $s de)
 382 )}x;
 383
 384     # For well-formedness, we don't need the ones that would otherwise pass, so they are commented out here
 385
 386     #   |   art $s lojban
 387     #   |   cel $s gaulish
 388     #   |   en $s (?: boont | GB $s oed | scouse )
 389     #   |   no $s (?: bok | nyn)
 390     #   |   zh $s (?: cmn | cmn $s Hans | cmn $s Hant | gan | guoyu | hakka | min | min $s nan | wuu | xiang | yue)
 391
 392     # Here is the final breakdown, with capturing groups for each of these components
 393     # The language, variants, extensions, grandfathered, and private-use may have interior '-'
 394
 395     #my $root = qr{(?: ($language) (?: $s ($script) )? 40% (?: $s ($region) )? 40% (?: $s ($variant) )? 10% (?: $s ($extension) )? 5% (?: $s ($privateuse) )? 5% ) 90% | ($grandfathered) 5% | ($privateuse) 5% };
 396
 397     $string =~  qr{^ (?:($language)) (?:$s($script))? (?:$s($region))?  (?:$s($variant))?  (?:$s($extension))?  (?:$s($privateuse))? $}xi;  # |($grandfathered) | ($privateuse) $}xi;
 398     my %subtag = (
 399         'rfc4646_subtag' => $string,
 400         'language' => $1,
 401         'script' => $2,
 402         'region' => $3,
 403         'variant' => $4,
 404         'extension' => $5,
 405         'privateuse' => $6,
 406     );
 407     return \%subtag;
 408 }
 409
 410 # Script Direction Resources:
 411 # http://www.w3.org/International/questions/qa-scripts
 412 sub get_bidi {
 413     my ($language_script)= @_;
 414     my $dbh = C4::Context->dbh;
 415     my $bidi;
 416     my $sth = $dbh->prepare('SELECT bidi FROM language_script_bidi WHERE rfc4646_subtag=?');
 417     $sth->execute($language_script);
 418     while (my $result = $sth->fetchrow_hashref) {
 419         $bidi = $result->{'bidi'};
 420     }
 421     return $bidi;
 422 };
 423
 424 sub accept_language {
 425     # referenced http://search.cpan.org/src/CGILMORE/I18N-AcceptLanguage-1.04/lib/I18N/AcceptLanguage.pm
 426     # FIXME: since this is only used in Output.pm as of Jan 8 2008, maybe it should be IN Output.pm
 427     my ($clientPreferences,$supportedLanguages) = @_;
 428     my @languages = ();
 429     if ($clientPreferences) {
 430         # There should be no whitespace anways, but a cleanliness/sanity check
 431         $clientPreferences =~ s/\s//g;
 432
 433         # Prepare the list of client-acceptable languages
 434         foreach my $tag (split(/,/, $clientPreferences)) {
 435             my ($language, $quality) = split(/\;/, $tag);
 436             $quality =~ s/^q=//i if $quality;
 437             $quality = 1 unless $quality;
 438             next if $quality <= 0;
 439             # We want to force the wildcard to be last
 440             $quality = 0 if ($language eq '*');
 441             # Pushing lowercase language here saves processing later
 442             push(@languages, { quality => $quality,
 443                language => $language,
 444                lclanguage => lc($language) });
 445         }
 446     } else {
 447         carp "accept_language(x,y) called with no clientPreferences (x).";
 448     }
 449     # Prepare the list of server-supported languages
 450     my %supportedLanguages = ();
 451     my %secondaryLanguages = ();
 452     foreach my $language (@$supportedLanguages) {
 453         # warn "Language supported: " . $language->{language_code};
 454         $supportedLanguages{lc($language->{language_code})} = $language->{language_code};
 455         if ($language->{language_code} =~ /^([^-]+)-?/) {
 456             $secondaryLanguages{lc($1)} = $language->{language_code};
 457         }
 458     }
 459
 460     # Reverse sort the list, making best quality at the front of the array
 461     @languages = sort { $b->{quality} <=> $a->{quality} } @languages;
 462     my $secondaryMatch = '';
 463     foreach my $tag (@languages) {
 464         if (exists($supportedLanguages{$tag->{lclanguage}})) {
 465             # Client en-us eq server en-us
 466             return $supportedLanguages{$tag->{language}} if exists($supportedLanguages{$tag->{language}});
 467             return $supportedLanguages{$tag->{lclanguage}};
 468         } elsif (exists($secondaryLanguages{$tag->{lclanguage}})) {
 469             # Client en eq server en-us
 470             return $secondaryLanguages{$tag->{language}} if exists($secondaryLanguages{$tag->{language}});
 471             return $supportedLanguages{$tag->{lclanguage}};
 472         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 473             # Client en-gb eq server en-us
 474             $secondaryMatch = $secondaryLanguages{$1};
 475         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 476             # FIXME: We just checked the exact same conditional!
 477             # Client en-us eq server en
 478             $secondaryMatch = $supportedLanguages{$1};
 479         } elsif ($tag->{lclanguage} eq '*') {
 480         # * matches every language not already specified.
 481         # It doesn't care which we pick, so let's pick the default,
 482         # if available, then the first in the array.
 483         #return $acceptor->defaultLanguage() if $acceptor->defaultLanguage();
 484         return $supportedLanguages->[0];
 485         }
 486     }
 487     # No primary matches. Secondary? (ie, en-us requested and en supported)
 488     return $secondaryMatch if $secondaryMatch;
 489     return undef;   # else, we got nothing.
 490 }
 491 1;
 492
 493 __END__
 494
 495 =head1 AUTHOR
 496
 497 Joshua Ferraro
 498
 499 =cut