CROSBI.pm

   1 package CROSBI;
   2
   3 use warnings;
   4 use strict;
   5
   6 use MARC::Record;
   7 use Data::Dump qw/dump/;
   8 use DBI;
   9 use utf8;
  10
  11 use base 'Scraper';
  12
  13 my $debug = $ENV{DEBUG} || 0;
  14
  15 sub diag {
  16         warn "# ", @_, $/;
  17 }
  18
  19
  20 # Koha Z39.50 query:
  21 #
  22 # Bib-1 @and @and @and @and @and @and @and @or
  23 # @attr 1=4 title
  24 # @attr 1=7 isbn
  25 # @attr 1=8 issn
  26 # @attr 1=1003 author
  27 # @attr 1=16 dewey (godina)
  28 # @attr 1=21 subject-holding
  29 # @attr 1=12 control-no
  30 # @attr 1=1007 standard-id
  31 # @attr 1=1016 any
  32
  33 sub usemap {{
  34         4               => 'fti_pr:',
  35         7               => 'fti_pr:',
  36         8               => 'fti_pr:',
  37         1003            => 'fti_au:',
  38         16              => 'fti_pr:',
  39         21              => 'fti_pr:',
  40         12              => 'fti_pr:',
  41         1007            => 'pti_pr:',
  42         1016            => 'fti_au,fti_pr:',
  43 }};
  44
  45 =for sql
  46
  47 =cut
  48
  49 my $dbname = 'bibliografija';
  50
  51 sub search {
  52         my ( $self, $query ) = @_;
  53
  54         utf8::decode( $query );
  55         warn "QUERY",dump( $query );
  56
  57         die "need query" unless defined $query;
  58
  59         my $table = lc $self->{database};
  60         $table =~ s/^crosbi-//g;
  61
  62         my $sql = qq{
  63
  64 select *
  65 from $table
  66 inner join rad_ustanova using (id)
  67 left outer join rad_napomena using (id)
  68 left outer join rad_projekt using (id)
  69 left outer join rad_godina using (id)
  70 left outer join rad_podrucje using (id)
  71 left outer join url using (id)
  72 where rad_ustanova.sifra = ?
  73         };
  74
  75         my @exec = (
  76                 130, # FIXME ustanova
  77         );
  78
  79         if ( $query =~ s/^(fti_.+):// ) {
  80                 my $tsquery = join(' & ', split(/\s+/,$query) );
  81
  82                 my @or;
  83                 foreach my $f ( split(/,/,$1) ) {
  84                         push @or, "$f @@ to_tsquery(?)";
  85                         push @exec, $tsquery;
  86                 };
  87                 $sql .= "and ( " . join(" or ", @or) . ")";
  88         } else {
  89                 warn "INVALID QUERY [$query]";
  90         }
  91
  92 warn "XXX SQL = ",$sql, dump( @exec );
  93
  94         my $dbh = DBI->connect_cached("dbi:Pg:dbname=$dbname", '', '', {AutoCommit => 0});
  95
  96         my $sth = $dbh->prepare( $sql );
  97
  98         $sth->execute( @exec );
  99
 100         my $hits = $sth->rows;
 101
 102         $self->{_sth} = $sth;
 103
 104         warn "# [$query] $hits hits\n";
 105
 106         return $self->{hits} = $hits;
 107 }
 108
 109 my $langrecode008 = {
 110         'bugarski' => 'bul',
 111         'Češki' => 'cze',
 112         'češki' => 'cze',
 113         'ENG' => 'eng',
 114         'Esperanto' => 'epo',
 115         'FRA' => 'fra',
 116         'GER' => 'ger',
 117         'HRV' => 'hrv',
 118         'ITA' => 'ita',
 119         'Japanski' => 'jpn',
 120         'Latinski' => 'lat',
 121         'mađarski' => 'hun',
 122         'Madžarski' => 'hun',
 123         'Makedonski' => 'mac',
 124         'nizozemski' => 'dut',
 125         'Poljski' => 'pol',
 126         'poljski' => 'pol',
 127         'Portugalski' => 'por',
 128         'portugalski' => 'por',
 129         'RUS' => 'rus',
 130         'Rumunjski' => 'rum',
 131         'rumunjski' => 'rum',
 132         'rusinski' => 'sla',
 133         'slovački' => 'slo',
 134         'slovenski' => 'slv',
 135         'SLV' => 'slv',
 136         'SPA' => 'spa',
 137         'Srpski' => 'srp',
 138         'srpski' => 'srp',
 139         'Turski' => 'tur',
 140         'turski' => 'tur',
 141         'ukrajinski' => 'ukr',
 142         'HRV-ENG' => 'mul',
 143         'HRV-GER' => 'mul',
 144         'hrvatsko-francuski' => 'mul',
 145 } ;
 146
 147 sub next_marc {
 148         my ($self,$format) = @_;
 149
 150         $format ||= 'marc';
 151
 152         my $sth = $self->{_sth} || die "no _sth";
 153
 154         my $row = $sth->fetchrow_hashref;
 155
 156         die "no row" unless $row;
 157
 158         my $id = $row->{id} || die "no id";
 159
 160         my $marc = MARC::Record->new;
 161         $marc->encoding('UTF-8');
 162
 163         my $leader = $marc->leader;
 164
 165 # /srv/webpac2/conf/crosbi/2016-12-12/casopis-dbi2marc.pl
 166
 167 ## LDR 05 - n - new
 168 ## LDR 06 - a - language material
 169 ## LDR 07 - a - monographic component part
 170
 171         $leader =~ s/^(....)...(.+)/$1naa$2/;
 172
 173 ## LDR 17 - Encoding level ; 7 - minimal level, u - unknown
 174 ## LDR 18 - i = isbd ; u = unknown
 175
 176         $leader =~ s/^(.{17})..(.+)/$1uu$2/;
 177
 178         $marc->leader( $leader );
 179         warn "# leader [$leader]";
 180
 181
 182 ### 008 - All materials
 183
 184 ## 008 - 00-05 - Date entered on file
 185
 186         my $f008 = $1 . $2 . $3 if $row->{time_date} =~ m/\d\d(\d\d)-(\d\d)-(\d\d)/;
 187
 188 ## 008 06 - Type of date/Publication status
 189
 190         $f008 .= 's';
 191
 192 ## 008 07-10 - Date 1
 193
 194         $f008 .= substr($row->{datum},0,4);
 195
 196 ## 008 11-14 - Date 2
 197
 198         #$f008 .= '    ';
 199
 200         $f008 .= ' ' x ( 15 - length($f008) ); # pad to 15 position
 201 ## 008 15-17 - Place of publication, production, or execution - ako nema 102, popunjava se s |
 202         $f008 .= 'xx ';
 203
 204 ## 008 35-37 - Language
 205         $f008 .= ' ' x ( 35 - length($f008) ); # pad to 35 position
 206         if ( my $lng = $langrecode008->{ $row->{jezik} } ) {
 207                 $f008 .= $lng;
 208         } else {
 209                 warn "INFO unknown jezik [$row->{jezik}] insert into langrecode008!";
 210                 #$f008 .= '   ';
 211         }
 212         $f008 .= ' ' x ( 38 - length($f008) );
 213 ## 008 38 - Modified record
 214         $f008 .= '|';
 215 ## 008 39 - Cataloging source - d (other)
 216         $f008 .= 'd';
 217
 218         warn "# 008 ",length($f008);
 219
 220         $marc->add_fields('008', $f008); # FIXME - mglavica check
 221
 222
 223         if ( my $doi = $row->{doi} ) {
 224
 225                 $marc->add_fields('024','7',' ',
 226                         2 => 'doi',
 227                         a => $doi,
 228                 );
 229
 230         }
 231
 232 ### 035$
 233
 234 ## marc 035a - System Number
 235 ## polje moze  sadrzavati slova i razmake
 236 ## moguc problem u pretrazivanju ako ima zagrade, kako bi trebalo po standardu
 237
 238         $marc->add_fields('035',' ',' ',
 239                 a => join('', '(CROSBI)', $row->{id})
 240         );
 241
 242 ### 040
 243 ## za sve je isti
 244
 245         $marc->add_fields('040',' ',' ',
 246                 'a' => 'HR-ZaFF',
 247                 'b' => 'hrv',
 248                 'c' => 'HR-ZaFF',
 249                 'e' => 'ppiak'
 250         );
 251
 252 ### 041 - indikatori
 253 # i1=0 - Item not a translation/does not include a translation
 254 # i1=1 - Item is or includes a translation
 255 # i1=' ' - No information provided
 256
 257 ### 041
 258 # ponovljivo potpolje (041a) - marc_repeatable_subfield
 259 # koristi se kad ima vise od jednog jezika, ili kad se radi o prijevodu
 260
 261         $marc->add_fields('041',' ',' ', map {
 262                 ( a => lc($_) )
 263         } split(/-/, $row->{jezik}));
 264
 265
 266 ### 080
 267 ### 245 indikatori
 268 ## i1 = 0 zza anonimne publikacije, i1 = 1 ako postoji 700 ili 710
 269 ## i2 = pretpostavlja se na temelju clana na pocetku naslova i jezika
 270
 271         my ( $first_author, $authors ) = split(/ ;\s*/,$row->{autori});
 272
 273         $marc->add_fields(100,'1',' ','a' => $first_author );
 274
 275
 276
 277         my $naslov = $row->{naslov}; # XXX title?
 278
 279         my $i2 =
 280                 $naslov =~ m/^Eine /                            ? 5 :
 281                 $naslov =~ m/(Die|Das|Der|Ein|Les|Los|The) /    ? 4 :
 282                 $naslov =~ m/^(Um|Un|An|La|Le|Lo|Il) /          ? 3 :
 283                 $naslov =~ m/^(A|L) /                           ? 2 :
 284                 $naslov =~ m/^L'/                               ? 2 :
 285                                                                   0;
 286
 287         $marc->add_fields(245,'1',$i2,
 288                 'a' => $naslov . ' /',
 289                 'c' => $row->{autori} . '.',
 290         );
 291
 292         $marc->add_fields(246,'3',' ',
 293                 'i' => 'Naslov na engleskom:',
 294                 'a' => $row->{title}
 295         );
 296
 297         sub page_range {
 298                 my ( $prefix, $from, $to ) = @_;
 299                 my $out;
 300                 if ( $from ) {
 301                         $out = $prefix . $from;
 302                         $out .= '-' . $to if $to;
 303                 }
 304                 return $out;
 305         }
 306
 307         $marc->add_fields(300,' ',' ',
 308                 a => page_range('',$row->{stranica_prva},$row->{stranica_zadnja}),
 309                 f => 'str.'
 310         );
 311
 312         $marc->add_fields(363,' ',' ',
 313                 a => $row->{volumen},
 314                 b => $row->{broj},
 315                 i => $row->{godina},
 316         );
 317
 318 # /data/FF/crosbi/2016-12-12/casopis-rad_napomena.sql
 319
 320         $marc->add_fields(500,' ',' ',
 321                 a => substr($row->{napomena}, 0, 9999), # XXX marc limit for one subfield is 4 digits in dictionary
 322         );
 323
 324         $marc->add_fields(520,' ',' ',
 325                 a => substr($row->{sazetak}, 0, 9999)
 326         );
 327
 328
 329         if ( $row->{rad_projekt} ) {
 330                 $marc->add_fields(536,' ',' ',
 331                         a => 'Projekt MZOS',
 332                         f => 'projekt',
 333                 );
 334         }
 335
 336         $marc->add_fields(546,' ',' ',
 337                 a => $row->{jezik}
 338         );
 339
 340         $marc->add_fields(690,' ',' ',
 341                 a => $row->{sifra}
 342         );
 343
 344
 345         $marc->add_fields(693,' ',' ',
 346                 a => $row->{kljucne_rijeci},
 347                 1 => 'hrv',
 348                 2 => 'crosbi',
 349         );
 350         $marc->add_fields(693,' ',' ',
 351                 a => $row->{key_words},
 352                 1 => 'eng',
 353                 2 => 'crosbi',
 354         );
 355
 356         if ( $row->{autori} =~ m/ ; / ) {
 357                 my @a = split(/ ; /, $row->{autori});
 358                 shift @a; # skip first
 359                 $marc->add_fields(700,'1',' ',
 360                         a => $_,
 361                         4 => 'aut'
 362                 ) foreach @a;
 363         }
 364
 365         $marc->add_fields(773,'0',' ',
 366                 t => $row->{casopis},
 367                 x => $row->{issn},
 368                 g => "$row->{volumen} ($row->{godina}), $row->{broj} ;" . page_range(' str. ',$row->{stranica_prva}, $row->{stranica_zadnja}),
 369         );
 370
 371         if ( my $file = $row->{datoteka} ) {
 372                 $marc->add_fields(856,' ',' ',
 373                         u => "http://bib.irb.hr/datoteka/$file",
 374                 );
 375         };
 376
 377         foreach my $name (qw( openurl url )) {
 378                 next if ! $row->{$name};
 379                 $marc->add_fields(856,' ',' ',
 380                         u => $row->{$name},
 381                 );
 382         }
 383
 384         my @f942 = (
 385                 c => 'CLA'
 386         );
 387         if ( $row->{status_rada} ) {
 388                 push @f942, (
 389                 f => 1,
 390                 g => $row->{status_rada}
 391                 );
 392         }
 393         push @f942, t => '1.01' if $row->{kategorija} =~ m/Znanstveni/;
 394         push @f942, t => '1.04' if $row->{kategorija} =~ m/Strucni/;
 395
 396         $marc->add_fields(942,' ',' ',
 397                 @f942,
 398                 u => '1',
 399                 z => join(' - ', $row->{kategorija}, $row->{vrsta_rada}),
 400         );
 401
 402 =for later
 403         $marc->add_fields(999,' ',' ',
 404                 a => $row->{}
 405         );
 406
 407 =cut
 408
 409 #       diag "# hash ",dump($hash);
 410         diag "# marc\n", $marc->as_formatted;
 411
 412         $self->save_marc( "$id.marc", $marc->as_usmarc );
 413
 414         return $id;
 415
 416 }
 417
 418 1;