Koha/SearchEngine/Elasticsearch/Search.pm

   1 package Koha::SearchEngine::Elasticsearch::Search;
   2
   3 # Copyright 2014 Catalyst IT
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 =head1 NAME
  21
  22 Koha::SearchEngine::Elasticsearch::Search - search functions for Elasticsearch
  23
  24 =head1 SYNOPSIS
  25
  26     my $searcher =
  27       Koha::SearchEngine::Elasticsearch::Search->new( { index => $index } );
  28     my $builder = Koha::SearchEngine::Elasticsearch::QueryBuilder->new(
  29         { index => $index } );
  30     my $query = $builder->build_query('perl');
  31     my $results = $searcher->search($query);
  32     print "There were " . $results->total . " results.\n";
  33     $results->each(sub {
  34         push @hits, @_[0];
  35     });
  36
  37 =head1 METHODS
  38
  39 =cut
  40
  41 use Modern::Perl;
  42
  43 use base qw(Koha::SearchEngine::Elasticsearch);
  44 use C4::Context;
  45 use Koha::ItemTypes;
  46 use Koha::AuthorisedValues;
  47 use Koha::SearchEngine::QueryBuilder;
  48 use MARC::Record;
  49 use Catmandu::Store::ElasticSearch;
  50
  51 use Data::Dumper; #TODO remove
  52 use Carp qw(cluck);
  53
  54 Koha::SearchEngine::Elasticsearch::Search->mk_accessors(qw( store ));
  55
  56 =head2 search
  57
  58     my $results = $searcher->search($query, $page, $count, %options);
  59
  60 Run a search using the query. It'll return C<$count> results, starting at page
  61 C<$page> (C<$page> counts from 1, anything less that, or C<undef> becomes 1.)
  62 C<$count> is also the number of entries on a page.
  63
  64 C<%options> is a hash containing extra options:
  65
  66 =over 4
  67
  68 =item offset
  69
  70 If provided, this overrides the C<$page> value, and specifies the record as
  71 an offset (i.e. the number of the record to start with), rather than a page.
  72
  73 =back
  74
  75 Returns
  76
  77 =cut
  78
  79 sub search {
  80     my ($self, $query, $page, $count, %options) = @_;
  81
  82     my $params = $self->get_elasticsearch_params();
  83     my %paging;
  84     # 20 is the default number of results per page
  85     $paging{limit} = $count || 20;
  86     # ES/Catmandu doesn't want pages, it wants a record to start from.
  87     if (exists $options{offset}) {
  88         $paging{start} = $options{offset};
  89     } else {
  90         $page = (!defined($page) || ($page <= 0)) ? 0 : $page - 1;
  91         $paging{start} = $page * $paging{limit};
  92     }
  93     $self->store(
  94         Catmandu::Store::ElasticSearch->new(
  95             %$params,
  96         )
  97     ) unless $self->store;
  98     my $results = eval {
  99         $self->store->bag->search( %$query, %paging );
 100     };
 101     if ($@) {
 102         die $self->process_error($@);
 103     }
 104     return $results;
 105 }
 106
 107 =head2 count
 108
 109     my $count = $searcher->count($query);
 110
 111 This mimics a search request, but just gets the result count instead. That's
 112 faster than pulling all the data in, usually.
 113
 114 =cut
 115
 116 sub count {
 117     my ( $self, $query ) = @_;
 118
 119     my $params = $self->get_elasticsearch_params();
 120     $self->store(
 121         Catmandu::Store::ElasticSearch->new( %$params, trace_calls => 0, ) )
 122       unless $self->store;
 123
 124     my $search = $self->store->bag->search( %$query);
 125     my $count = $search->total() || 0;
 126     return $count;
 127 }
 128
 129 =head2 search_compat
 130
 131     my ( $error, $results, $facets ) = $search->search_compat(
 132         $query,            $simple_query, \@sort_by,       \@servers,
 133         $results_per_page, $offset,       $expanded_facet, $branches,
 134         $query_type,       $scan
 135       )
 136
 137 A search interface somewhat compatible with L<C4::Search->getRecords>. Anything
 138 that is returned in the query created by build_query_compat will probably
 139 get ignored here, along with some other things (like C<@servers>.)
 140
 141 =cut
 142
 143 sub search_compat {
 144     my (
 145         $self,     $query,            $simple_query, $sort_by,
 146         $servers,  $results_per_page, $offset,       $expanded_facet,
 147         $branches, $query_type,       $scan
 148     ) = @_;
 149     my %options;
 150     $options{offset} = $offset;
 151     $options{expanded_facet} = $expanded_facet;
 152     my $results = $self->search($query, undef, $results_per_page, %options);
 153
 154     # Convert each result into a MARC::Record
 155     my (@records, $index);
 156     $index = $offset; # opac-search expects results to be put in the
 157         # right place in the array, according to $offset
 158     $results->each(sub {
 159             # The results come in an array for some reason
 160             my $marc_json = $_[0]->{record};
 161             my $marc = $self->json2marc($marc_json);
 162             $records[$index++] = $marc;
 163         });
 164     # consumers of this expect a name-spaced result, we provide the default
 165     # configuration.
 166     my %result;
 167     $result{biblioserver}{hits} = $results->total;
 168     $result{biblioserver}{RECORDS} = \@records;
 169     return (undef, \%result, $self->_convert_facets($results->{aggregations}, $expanded_facet));
 170 }
 171
 172 =head2 search_auth_compat
 173
 174     my ( $results, $total ) =
 175       $searcher->search_auth_compat( $query, $page, $count, %options );
 176
 177 This has a similar calling convention to L<search>, however it returns its
 178 results in a form the same as L<C4::AuthoritiesMarc::SearchAuthorities>.
 179
 180 =cut
 181
 182 sub search_auth_compat {
 183     my $self = shift;
 184
 185     # TODO handle paging
 186     my $database = Koha::Database->new();
 187     my $schema   = $database->schema();
 188     my $res      = $self->search(@_);
 189     my $bib_searcher = Koha::SearchEngine::Elasticsearch::Search->new({index => 'biblios'});
 190     my @records;
 191     $res->each(
 192         sub {
 193             my %result;
 194             my $record    = $_[0];
 195             my $marc_json = $record->{record};
 196
 197             # I wonder if these should be real values defined in the mapping
 198             # rather than hard-coded conversions.
 199             # Our results often come through as nested arrays, to fix this
 200             # requires changes in catmandu.
 201             my $authid = $record->{ 'Local-number' }[0][0];
 202             $result{authid} = $authid;
 203
 204             # TODO put all this info into the record at index time so we
 205             # don't have to go and sort it all out now.
 206             my $authtypecode = $record->{authtype};
 207             my $rs           = $schema->resultset('AuthType')
 208               ->search( { authtypecode => $authtypecode } );
 209
 210             # FIXME there's an assumption here that we will get a result.
 211             # the original code also makes an assumption that some provided
 212             # authtypecode may sometimes be used instead of the one stored
 213             # with the record. It's not documented why this is the case, so
 214             # it's not reproduced here yet.
 215             my $authtype           = $rs->single;
 216             my $auth_tag_to_report = $authtype->auth_tag_to_report;
 217             my $marc               = $self->json2marc($marc_json);
 218             my $mainentry          = $marc->field($auth_tag_to_report);
 219             my $reported_tag;
 220             if ($mainentry) {
 221                 foreach ( $mainentry->subfields() ) {
 222                     $reported_tag .= '$' . $_->[0] . $_->[1];
 223                 }
 224             }
 225             # Turn the resultset into a hash
 226             my %authtype_cols;
 227             foreach my $col ($authtype->result_source->columns) {
 228                 $authtype_cols{$col} = $authtype->get_column($col);
 229             }
 230             $result{authtype}     = $authtype->authtypetext;
 231             $result{reported_tag} = $reported_tag;
 232
 233             # Reimplementing BuildSummary is out of scope because it'll be hard
 234             $result{summary} =
 235               C4::AuthoritiesMarc::BuildSummary( $marc, $result{authid},
 236                 $authtypecode );
 237             $result{used} = $self->count_auth_use($bib_searcher, $authid);
 238             push @records, \%result;
 239         }
 240     );
 241     return ( \@records, $res->total );
 242 }
 243
 244 =head2 count_auth_use
 245
 246     my $count = $auth_searcher->count_auth_use($bib_searcher, $authid);
 247
 248 This runs a search to determine the number of records that reference the
 249 specified authid. C<$bib_searcher> must be something compatible with
 250 elasticsearch, as the query is built in this function.
 251
 252 =cut
 253
 254 sub count_auth_use {
 255     my ($self, $bib_searcher, $authid) = @_;
 256
 257     my $query = {
 258         query => {
 259             bool => {
 260 #                query  => { match_all => {} },
 261                 filter => { term      => { an => $authid } }
 262             }
 263         }
 264     };
 265     $bib_searcher->count($query);
 266 }
 267
 268 =head2 simple_search_compat
 269
 270     my ( $error, $marcresults, $total_hits ) =
 271       $searcher->simple_search( $query, $offset, $max_results );
 272
 273 This is a simpler interface to the searching, intended to be similar enough to
 274 L<C4::Search::SimpleSearch>.
 275
 276 Arguments:
 277
 278 =over 4
 279
 280 =item C<$query>
 281
 282 A thing to search for. It could be a simple string, or something constructed
 283 with the appropriate QueryBuilder module.
 284
 285 =item C<$offset>
 286
 287 How many results to skip from the start of the results.
 288
 289 =item C<$max_results>
 290
 291 The max number of results to return. The default is 100 (because unlimited
 292 is a pretty terrible thing to do.)
 293
 294 =back
 295
 296 Returns:
 297
 298 =over 4
 299
 300 =item C<$error>
 301
 302 if something went wrong, this'll contain some kind of error
 303 message.
 304
 305 =item C<$marcresults>
 306
 307 an arrayref of MARC::Records (note that this is different from the
 308 L<C4::Search> version which will return plain XML, but too bad.)
 309
 310 =item C<$total_hits>
 311
 312 the total number of results that this search could have returned.
 313
 314 =back
 315
 316 =cut
 317
 318 sub simple_search_compat {
 319     my ($self, $query, $offset, $max_results) = @_;
 320
 321     return ('No query entered', undef, undef) unless $query;
 322
 323     my %options;
 324     $options{offset} = $offset // 0;
 325     $max_results //= 100;
 326
 327     unless (ref $query) {
 328         # We'll push it through the query builder to sanitise everything.
 329         my $qb = Koha::SearchEngine::QueryBuilder->new({index => $self->index});
 330         (undef,$query) = $qb->build_query_compat(undef, [$query]);
 331     }
 332     my $results = $self->search($query, undef, $max_results, %options);
 333     my @records;
 334     $results->each(sub {
 335             # The results come in an array for some reason
 336             my $marc_json = $_[0]->{record};
 337             my $marc = $self->json2marc($marc_json);
 338             push @records, $marc;
 339         });
 340     return (undef, \@records, $results->total);
 341 }
 342
 343 =head2 json2marc
 344
 345     my $marc = $self->json2marc($marc_json);
 346
 347 Converts the form of marc (based on its JSON, but as a Perl structure) that
 348 Catmandu stores into a MARC::Record object.
 349
 350 =cut
 351
 352 sub json2marc {
 353     my ( $self, $marcjson ) = @_;
 354
 355     my $marc = MARC::Record->new();
 356     $marc->encoding('UTF-8');
 357
 358     # fields are like:
 359     # [ '245', '1', '2', 'a' => 'Title', 'b' => 'Subtitle' ]
 360     # or
 361     # [ '001', undef, undef, '_', 'a value' ]
 362     # conveniently, this is the form that MARC::Field->new() likes
 363     foreach my $field (@$marcjson) {
 364         next if @$field < 5;
 365         if ( $field->[0] eq 'LDR' ) {
 366             $marc->leader( $field->[4] );
 367         }
 368         else {
 369             my $tag = $field->[0];
 370             my $marc_field;
 371             if ( MARC::Field->is_controlfield_tag( $field->[0] ) ) {
 372                 $marc_field = MARC::Field->new($field->[0], $field->[4]);
 373             } else {
 374                 $marc_field = MARC::Field->new(@$field);
 375             }
 376             $marc->append_fields($marc_field);
 377         }
 378     }
 379     return $marc;
 380 }
 381
 382 =head2 _convert_facets
 383
 384     my $koha_facets = _convert_facets($es_facets, $expanded_facet);
 385
 386 Converts elasticsearch facets types to the form that Koha expects.
 387 It expects the ES facet name to match the Koha type, for example C<itype>,
 388 C<au>, C<su-to>, etc.
 389
 390 C<$expanded_facet> is the facet that we want to show FacetMaxCount entries for, rather
 391 than just 5 like normal.
 392
 393 =cut
 394
 395 sub _convert_facets {
 396     my ( $self, $es, $exp_facet ) = @_;
 397
 398     return if !$es;
 399
 400     # These should correspond to the ES field names, as opposed to the CCL
 401     # things that zebra uses.
 402     # TODO let the library define the order using the interface.
 403     my %type_to_label = (
 404         author   => { order => 1, label => 'Authors', },
 405         itype    => { order => 2, label => 'ItemTypes', },
 406         location => { order => 3, label => 'Location', },
 407         'su-geo' => { order => 4, label => 'Places', },
 408         se       => { order => 5, label => 'Series', },
 409         subject  => { order => 6, label => 'Topics', },
 410         ccode    => { order => 7, label => 'CollectionCodes',},
 411         holdingbranch => { order => 8, label => 'HoldingLibrary' },
 412         homebranch => { order => 9, label => 'HomeLibrary' }
 413     );
 414
 415     # We also have some special cases, e.g. itypes that need to show the
 416     # value rather than the code.
 417     my @itypes = Koha::ItemTypes->search;
 418     my @libraries = Koha::Libraries->search;
 419     my $library_names = { map { $_->branchcode => $_->branchname } @libraries };
 420     my @locations = Koha::AuthorisedValues->search( { category => 'LOC' } );
 421     my $opac = C4::Context->interface eq 'opac' ;
 422     my %special = (
 423         itype    => { map { $_->itemtype         => $_->description } @itypes },
 424         location => { map { $_->authorised_value => ( $opac ? ( $_->lib_opac || $_->lib ) : $_->lib ) } @locations },
 425         holdingbranch => $library_names,
 426         homebranch => $library_names
 427     );
 428     my @facets;
 429     $exp_facet //= '';
 430     while ( my ( $type, $data ) = each %$es ) {
 431         next if !exists( $type_to_label{$type} );
 432
 433         # We restrict to the most popular $limit !results
 434         my $limit = ( $type eq $exp_facet ) ? C4::Context->preference('FacetMaxCount') : 5;
 435         my $facet = {
 436             type_id    => $type . '_id',
 437             expand     => $type,
 438             expandable => ( $type ne $exp_facet )
 439               && ( @{ $data->{buckets} } > $limit ),
 440             "type_label_$type_to_label{$type}{label}" => 1,
 441             type_link_value                    => $type,
 442             order      => $type_to_label{$type}{order},
 443         };
 444         $limit = @{ $data->{buckets} } if ( $limit > @{ $data->{buckets} } );
 445         foreach my $term ( @{ $data->{buckets} }[ 0 .. $limit - 1 ] ) {
 446             my $t = $term->{key};
 447             my $c = $term->{doc_count};
 448             my $label;
 449             if ( exists( $special{$type} ) ) {
 450                 $label = $special{$type}->{$t} // $t;
 451             }
 452             else {
 453                 $label = $t;
 454             }
 455             push @{ $facet->{facets} }, {
 456                 facet_count       => $c,
 457                 facet_link_value  => $t,
 458                 facet_title_value => $t . " ($c)",
 459                 facet_label_value => $label,        # TODO either truncate this,
 460                      # or make the template do it like it should anyway
 461                 type_link_value => $type,
 462             };
 463         }
 464         push @facets, $facet if exists $facet->{facets};
 465     }
 466
 467     @facets = sort { $a->{order} cmp $b->{order} } @facets;
 468     return \@facets;
 469 }
 470
 471
 472 1;