Koha/SearchEngine/Elasticsearch/Search.pm

   1 package Koha::SearchEngine::Elasticsearch::Search;
   2
   3 # Copyright 2014 Catalyst IT
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 =head1 NAME
  21
  22 Koha::SearchEngine::Elasticsearch::Search - search functions for Elasticsearch
  23
  24 =head1 SYNOPSIS
  25
  26     my $searcher =
  27       Koha::SearchEngine::Elasticsearch::Search->new( { index => $index } );
  28     my $builder = Koha::SearchEngine::Elasticsearch::QueryBuilder->new(
  29         { index => $index } );
  30     my $query = $builder->build_query('perl');
  31     my $results = $searcher->search($query);
  32     print "There were " . $results->total . " results.\n";
  33     $results->each(sub {
  34         push @hits, @_[0];
  35     });
  36
  37 =head1 METHODS
  38
  39 =cut
  40
  41 use Modern::Perl;
  42
  43 use base qw(Koha::SearchEngine::Elasticsearch);
  44 use C4::Context;
  45 use Koha::ItemTypes;
  46 use Koha::AuthorisedValues;
  47 use Koha::SearchEngine::QueryBuilder;
  48 use Koha::SearchEngine::Search;
  49 use MARC::Record;
  50 use Catmandu::Store::ElasticSearch;
  51
  52 use Data::Dumper; #TODO remove
  53 use Carp qw(cluck);
  54
  55 Koha::SearchEngine::Elasticsearch::Search->mk_accessors(qw( store ));
  56
  57 =head2 search
  58
  59     my $results = $searcher->search($query, $page, $count, %options);
  60
  61 Run a search using the query. It'll return C<$count> results, starting at page
  62 C<$page> (C<$page> counts from 1, anything less that, or C<undef> becomes 1.)
  63 C<$count> is also the number of entries on a page.
  64
  65 C<%options> is a hash containing extra options:
  66
  67 =over 4
  68
  69 =item offset
  70
  71 If provided, this overrides the C<$page> value, and specifies the record as
  72 an offset (i.e. the number of the record to start with), rather than a page.
  73
  74 =back
  75
  76 Returns
  77
  78 =cut
  79
  80 sub search {
  81     my ($self, $query, $page, $count, %options) = @_;
  82
  83     my $params = $self->get_elasticsearch_params();
  84     my %paging;
  85     # 20 is the default number of results per page
  86     $paging{limit} = $count || 20;
  87     # ES/Catmandu doesn't want pages, it wants a record to start from.
  88     if (exists $options{offset}) {
  89         $paging{start} = $options{offset};
  90     } else {
  91         $page = (!defined($page) || ($page <= 0)) ? 0 : $page - 1;
  92         $paging{start} = $page * $paging{limit};
  93     }
  94     $self->store(
  95         Catmandu::Store::ElasticSearch->new(
  96             %$params,
  97         )
  98     ) unless $self->store;
  99     my $results = eval {
 100         $self->store->bag->search( %$query, %paging );
 101     };
 102     if ($@) {
 103         die $self->process_error($@);
 104     }
 105     return $results;
 106 }
 107
 108 =head2 count
 109
 110     my $count = $searcher->count($query);
 111
 112 This mimics a search request, but just gets the result count instead. That's
 113 faster than pulling all the data in, usually.
 114
 115 =cut
 116
 117 sub count {
 118     my ( $self, $query ) = @_;
 119
 120     my $params = $self->get_elasticsearch_params();
 121     $self->store(
 122         Catmandu::Store::ElasticSearch->new( %$params, trace_calls => 0, ) )
 123       unless $self->store;
 124
 125     my $search = $self->store->bag->search( %$query);
 126     my $count = $search->total() || 0;
 127     return $count;
 128 }
 129
 130 =head2 search_compat
 131
 132     my ( $error, $results, $facets ) = $search->search_compat(
 133         $query,            $simple_query, \@sort_by,       \@servers,
 134         $results_per_page, $offset,       $expanded_facet, $branches,
 135         $query_type,       $scan
 136       )
 137
 138 A search interface somewhat compatible with L<C4::Search->getRecords>. Anything
 139 that is returned in the query created by build_query_compat will probably
 140 get ignored here, along with some other things (like C<@servers>.)
 141
 142 =cut
 143
 144 sub search_compat {
 145     my (
 146         $self,     $query,            $simple_query, $sort_by,
 147         $servers,  $results_per_page, $offset,       $expanded_facet,
 148         $branches, $query_type,       $scan
 149     ) = @_;
 150     my %options;
 151     if ( !defined $offset or $offset < 0 ) {
 152         $offset = 0;
 153     }
 154     $options{offset} = $offset;
 155     $options{expanded_facet} = $expanded_facet;
 156     my $results = $self->search($query, undef, $results_per_page, %options);
 157
 158     # Convert each result into a MARC::Record
 159     my (@records, $index);
 160     $index = $offset; # opac-search expects results to be put in the
 161         # right place in the array, according to $offset
 162     $results->each(sub {
 163             # The results come in an array for some reason
 164             my $marc_json = $_[0]->{record};
 165             my $marc = $self->json2marc($marc_json);
 166             $records[$index++] = $marc;
 167         });
 168     # consumers of this expect a name-spaced result, we provide the default
 169     # configuration.
 170     my %result;
 171     $result{biblioserver}{hits} = $results->total;
 172     $result{biblioserver}{RECORDS} = \@records;
 173     return (undef, \%result, $self->_convert_facets($results->{aggregations}, $expanded_facet));
 174 }
 175
 176 =head2 search_auth_compat
 177
 178     my ( $results, $total ) =
 179       $searcher->search_auth_compat( $query, $page, $count, %options );
 180
 181 This has a similar calling convention to L<search>, however it returns its
 182 results in a form the same as L<C4::AuthoritiesMarc::SearchAuthorities>.
 183
 184 =cut
 185
 186 sub search_auth_compat {
 187     my $self = shift;
 188
 189     # TODO handle paging
 190     my $database = Koha::Database->new();
 191     my $schema   = $database->schema();
 192     my $res      = $self->search(@_);
 193     my $bib_searcher = Koha::SearchEngine::Elasticsearch::Search->new({index => 'biblios'});
 194     my @records;
 195     $res->each(
 196         sub {
 197             my %result;
 198             my $record    = $_[0];
 199             my $marc_json = $record->{record};
 200
 201             # I wonder if these should be real values defined in the mapping
 202             # rather than hard-coded conversions.
 203             # Handle legacy nested arrays indexed with splitting enabled.
 204             my $authid = $record->{ 'Local-number' }[0];
 205             $authid = @$authid[0] if (ref $authid eq 'ARRAY');
 206             $result{authid} = $authid;
 207
 208             # TODO put all this info into the record at index time so we
 209             # don't have to go and sort it all out now.
 210             my $authtypecode = $record->{authtype};
 211             my $rs           = $schema->resultset('AuthType')
 212               ->search( { authtypecode => $authtypecode } );
 213
 214             # FIXME there's an assumption here that we will get a result.
 215             # the original code also makes an assumption that some provided
 216             # authtypecode may sometimes be used instead of the one stored
 217             # with the record. It's not documented why this is the case, so
 218             # it's not reproduced here yet.
 219             my $authtype           = $rs->single;
 220             my $auth_tag_to_report = $authtype ? $authtype->auth_tag_to_report : "";
 221             my $marc               = $self->json2marc($marc_json);
 222             my $mainentry          = $marc->field($auth_tag_to_report);
 223             my $reported_tag;
 224             if ($mainentry) {
 225                 foreach ( $mainentry->subfields() ) {
 226                     $reported_tag .= '$' . $_->[0] . $_->[1];
 227                 }
 228             }
 229             # Turn the resultset into a hash
 230             $result{authtype}     = $authtype ? $authtype->authtypetext : $authtypecode;
 231             $result{reported_tag} = $reported_tag;
 232
 233             # Reimplementing BuildSummary is out of scope because it'll be hard
 234             $result{summary} =
 235               C4::AuthoritiesMarc::BuildSummary( $marc, $result{authid},
 236                 $authtypecode );
 237             $result{used} = $self->count_auth_use($bib_searcher, $authid);
 238             push @records, \%result;
 239         }
 240     );
 241     return ( \@records, $res->total );
 242 }
 243
 244 =head2 count_auth_use
 245
 246     my $count = $auth_searcher->count_auth_use($bib_searcher, $authid);
 247
 248 This runs a search to determine the number of records that reference the
 249 specified authid. C<$bib_searcher> must be something compatible with
 250 elasticsearch, as the query is built in this function.
 251
 252 =cut
 253
 254 sub count_auth_use {
 255     my ($self, $bib_searcher, $authid) = @_;
 256
 257     my $query = {
 258         query => {
 259             bool => {
 260 #                query  => { match_all => {} },
 261                 filter => { term      => { an => $authid } }
 262             }
 263         }
 264     };
 265     $bib_searcher->count($query);
 266 }
 267
 268 =head2 simple_search_compat
 269
 270     my ( $error, $marcresults, $total_hits ) =
 271       $searcher->simple_search( $query, $offset, $max_results, %options );
 272
 273 This is a simpler interface to the searching, intended to be similar enough to
 274 L<C4::Search::SimpleSearch>.
 275
 276 Arguments:
 277
 278 =over 4
 279
 280 =item C<$query>
 281
 282 A thing to search for. It could be a simple string, or something constructed
 283 with the appropriate QueryBuilder module.
 284
 285 =item C<$offset>
 286
 287 How many results to skip from the start of the results.
 288
 289 =item C<$max_results>
 290
 291 The max number of results to return. The default is 100 (because unlimited
 292 is a pretty terrible thing to do.)
 293
 294 =item C<%options>
 295
 296 These options are unused by Elasticsearch
 297
 298 =back
 299
 300 Returns:
 301
 302 =over 4
 303
 304 =item C<$error>
 305
 306 if something went wrong, this'll contain some kind of error
 307 message.
 308
 309 =item C<$marcresults>
 310
 311 an arrayref of MARC::Records (note that this is different from the
 312 L<C4::Search> version which will return plain XML, but too bad.)
 313
 314 =item C<$total_hits>
 315
 316 the total number of results that this search could have returned.
 317
 318 =back
 319
 320 =cut
 321
 322 sub simple_search_compat {
 323     my ($self, $query, $offset, $max_results) = @_;
 324
 325     return ('No query entered', undef, undef) unless $query;
 326
 327     my %options;
 328     $offset = 0 if not defined $offset or $offset < 0;
 329     $options{offset} = $offset;
 330     $max_results //= 100;
 331
 332     unless (ref $query) {
 333         # We'll push it through the query builder to sanitise everything.
 334         my $qb = Koha::SearchEngine::QueryBuilder->new({index => $self->index});
 335         (undef,$query) = $qb->build_query_compat(undef, [$query]);
 336     }
 337     my $results = $self->search($query, undef, $max_results, %options);
 338     my @records;
 339     $results->each(sub {
 340             # The results come in an array for some reason
 341             my $marc_json = $_[0]->{record};
 342             my $marc = $self->json2marc($marc_json);
 343             push @records, $marc;
 344         });
 345     return (undef, \@records, $results->total);
 346 }
 347
 348 =head2 extract_biblionumber
 349
 350     my $biblionumber = $searcher->extract_biblionumber( $searchresult );
 351
 352 $searchresult comes from simple_search_compat.
 353
 354 Returns the biblionumber from the search result record.
 355
 356 =cut
 357
 358 sub extract_biblionumber {
 359     my ( $self, $searchresultrecord ) = @_;
 360     return Koha::SearchEngine::Search::extract_biblionumber( $searchresultrecord );
 361 }
 362
 363 =head2 json2marc
 364
 365     my $marc = $self->json2marc($marc_json);
 366
 367 Converts the form of marc (based on its JSON, but as a Perl structure) that
 368 Catmandu stores into a MARC::Record object.
 369
 370 =cut
 371
 372 sub json2marc {
 373     my ( $self, $marcjson ) = @_;
 374
 375     my $marc = MARC::Record->new();
 376     $marc->encoding('UTF-8');
 377
 378     # fields are like:
 379     # [ '245', '1', '2', 'a' => 'Title', 'b' => 'Subtitle' ]
 380     # or
 381     # [ '001', undef, undef, '_', 'a value' ]
 382     # conveniently, this is the form that MARC::Field->new() likes
 383     foreach my $field (@$marcjson) {
 384         next if @$field < 5;
 385         if ( $field->[0] eq 'LDR' ) {
 386             $marc->leader( $field->[4] );
 387         }
 388         else {
 389             my $tag = $field->[0];
 390             my $marc_field;
 391             if ( MARC::Field->is_controlfield_tag( $field->[0] ) ) {
 392                 $marc_field = MARC::Field->new($field->[0], $field->[4]);
 393             } else {
 394                 $marc_field = MARC::Field->new(@$field);
 395             }
 396             $marc->append_fields($marc_field);
 397         }
 398     }
 399     return $marc;
 400 }
 401
 402 sub max_result_window {
 403     my ($self) = @_;
 404
 405     $self->store(
 406         Catmandu::Store::ElasticSearch->new(%{ $self->get_elasticsearch_params })
 407     ) unless $self->store;
 408
 409     my $index_name = $self->store->index_name;
 410     my $settings = $self->store->es->indices->get_settings(
 411         index  => $index_name,
 412         params => { include_defaults => 1, flat_settings => 1 },
 413     );
 414
 415     my $max_result_window = $settings->{$index_name}->{settings}->{'index.max_result_window'};
 416     $max_result_window //= $settings->{$index_name}->{defaults}->{'index.max_result_window'};
 417
 418     return $max_result_window;
 419 }
 420
 421 =head2 _convert_facets
 422
 423     my $koha_facets = _convert_facets($es_facets, $expanded_facet);
 424
 425 Converts elasticsearch facets types to the form that Koha expects.
 426 It expects the ES facet name to match the Koha type, for example C<itype>,
 427 C<au>, C<su-to>, etc.
 428
 429 C<$expanded_facet> is the facet that we want to show FacetMaxCount entries for, rather
 430 than just 5 like normal.
 431
 432 =cut
 433
 434 sub _convert_facets {
 435     my ( $self, $es, $exp_facet ) = @_;
 436
 437     return if !$es;
 438
 439     # These should correspond to the ES field names, as opposed to the CCL
 440     # things that zebra uses.
 441     # TODO let the library define the order using the interface.
 442     my %type_to_label = (
 443         author   => { order => 1, label => 'Authors', },
 444         itype    => { order => 2, label => 'ItemTypes', },
 445         location => { order => 3, label => 'Location', },
 446         'su-geo' => { order => 4, label => 'Places', },
 447         se       => { order => 5, label => 'Series', },
 448         subject  => { order => 6, label => 'Topics', },
 449         ccode    => { order => 7, label => 'CollectionCodes',},
 450         holdingbranch => { order => 8, label => 'HoldingLibrary' },
 451         homebranch => { order => 9, label => 'HomeLibrary' }
 452     );
 453
 454     # We also have some special cases, e.g. itypes that need to show the
 455     # value rather than the code.
 456     my @itypes = Koha::ItemTypes->search;
 457     my @libraries = Koha::Libraries->search;
 458     my $library_names = { map { $_->branchcode => $_->branchname } @libraries };
 459     my @locations = Koha::AuthorisedValues->search( { category => 'LOC' } );
 460     my $opac = C4::Context->interface eq 'opac' ;
 461     my %special = (
 462         itype    => { map { $_->itemtype         => $_->description } @itypes },
 463         location => { map { $_->authorised_value => ( $opac ? ( $_->lib_opac || $_->lib ) : $_->lib ) } @locations },
 464         holdingbranch => $library_names,
 465         homebranch => $library_names
 466     );
 467     my @facets;
 468     $exp_facet //= '';
 469     while ( my ( $type, $data ) = each %$es ) {
 470         next if !exists( $type_to_label{$type} );
 471
 472         # We restrict to the most popular $limit !results
 473         my $limit = ( $type eq $exp_facet ) ? C4::Context->preference('FacetMaxCount') : 5;
 474         my $facet = {
 475             type_id    => $type . '_id',
 476             expand     => $type,
 477             expandable => ( $type ne $exp_facet )
 478               && ( @{ $data->{buckets} } > $limit ),
 479             "type_label_$type_to_label{$type}{label}" => 1,
 480             type_link_value                    => $type,
 481             order      => $type_to_label{$type}{order},
 482         };
 483         $limit = @{ $data->{buckets} } if ( $limit > @{ $data->{buckets} } );
 484         foreach my $term ( @{ $data->{buckets} }[ 0 .. $limit - 1 ] ) {
 485             my $t = $term->{key};
 486             my $c = $term->{doc_count};
 487             my $label;
 488             if ( exists( $special{$type} ) ) {
 489                 $label = $special{$type}->{$t} // $t;
 490             }
 491             else {
 492                 $label = $t;
 493             }
 494             push @{ $facet->{facets} }, {
 495                 facet_count       => $c,
 496                 facet_link_value  => $t,
 497                 facet_title_value => $t . " ($c)",
 498                 facet_label_value => $label,        # TODO either truncate this,
 499                      # or make the template do it like it should anyway
 500                 type_link_value => $type,
 501             };
 502         }
 503         push @facets, $facet if exists $facet->{facets};
 504     }
 505
 506     @facets = sort { $a->{order} cmp $b->{order} } @facets;
 507     return \@facets;
 508 }
 509
 510
 511 1;