Makefile.PL

   1 # Copyright 2007 MJ Ray
   2 #
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 2 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along with
  15 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  16 # Suite 330, Boston, MA  02111-1307 USA
  17 #
  18 # Current maintainer MJR http://mjr.towers.org.uk/
  19 # See http://www.koha.org/wiki/?page=KohaInstaller
  20 #
  21
  22 use strict;
  23 use warnings;
  24 use ExtUtils::MakeMaker;
  25 use POSIX;
  26 use File::Spec;
  27
  28 my $DEBUG = 0;
  29 die "perl 5.6.1 or later required" unless ($] >= 5.006001);
  30
  31 # Hash up directory structure & files beginning with the directory we were called from (should be the base of koha)...
  32
  33 my $dirtree = hashdir('.');
  34 my %result = ();
  35
  36 =head1 NAME
  37
  38 Makefile.PL - Koha packager and installer
  39
  40 =head1 SYNOPSIS
  41
  42 =head2 BASIC INSTALLATION
  43
  44         perl Makefile.PL
  45         make
  46         sudo make install
  47
  48 =head2 PACKAGING RELEASE TARBALLS
  49
  50         make manifest tardist
  51         make manifest zipdist
  52
  53 =head2 CLEANING UP
  54
  55         make clean
  56
  57 =head1 DESCRIPTION
  58
  59 This is a packager and installer that uses
  60 ExtUtils::MakeMaker, which is fairly common
  61 on perl systems.
  62 As well as building tar or zip files
  63 and installing with the above commands,
  64 it allows us to check pre-requisites
  65 and generate configuration files.
  66
  67 =head1 VARIABLES
  68
  69 =head2 NAME, VERSION_FROM, ABSTRACT, AUTHOR
  70
  71 Basic metadata about this software.
  72
  73 =head2 NO_META
  74
  75 Suppress generation of META.yml file.
  76
  77 =head2 PREREQ_PM
  78
  79 Hash of perl modules and versions required.
  80
  81 =head2 PM
  82
  83 Hash of file mappings
  84
  85 =head2 PL_FILES
  86
  87 This is a hash of PL scripts to run after installation and
  88 the files to ask them to generate.
  89 Maybe use the values from CONFIGURE
  90 to generate initial configuration files in future.
  91
  92 =cut
  93
  94 =head2 target_map
  95
  96 This is a hash mapping directories and files in the
  97 source tree to installation target directories.  The rules
  98 for this mapping are:
  99
 100 =over 4
 101
 102 =item If a directory or file is specified, it and its
 103 contents will be copied to the installation target directory.
 104
 105 =item If a subdirectory of a mapped directory is specified,
 106 its target overrides the parent's target for that subdirectory.
 107
 108 =item The value of each map entry may either be a scalar containing
 109 one target or a reference to a hash containing 'target' and 'trimdir'
 110 keys.
 111
 112 =item Any files at the top level of the source tree that are
 113 not included in the map will not be installed.
 114
 115 =item Any directories at the top level of the source tree
 116 that are not included in the map will be installed in
 117 INTRANET_CGI_DIR.  This is a sensible default given the
 118 current organization of the source tree, but (FIXME) it
 119 would be better to reorganize the source tree to better
 120 match the installation system, to allow adding new directories
 121 without having to adjust Makefile.PL each time.  The idea
 122 is to make the C<$target_map> hash as minimal as possible.
 123
 124 =back
 125
 126 The permitted installation targets are:
 127
 128 =over 4
 129
 130 =item INTRANET_CGI_DIR
 131
 132 CGI scripts for intranet (staff) interface.
 133
 134 =item INTRANET_TMPL_DIR
 135
 136 HTML templates for the intranet interface.
 137
 138 =item INTRANET_WWW_DIR
 139
 140 HTML files, images, etc. for DocumentRoot for the intranet interface.
 141
 142 =item OPAC_CGI_DIR
 143
 144 CGI scripts for OPAC (public) interface.
 145
 146 =item OPAC_TMPL_DIR
 147
 148 HTML templates for the OPAC interface.
 149
 150 =item OPAC_WWW_DIR
 151
 152 HTML files, images, etc. for DocumentRoot for the OPAC interface.
 153
 154 =item PERL_MODULE_DIR
 155
 156 Perl modules (at present just the C4 modules) that are intimately
 157 tied to Koha.  Depending on the installation options, these
 158 may or may not be installed one of the standard directories
 159 in Perl's default @LIB.
 160
 161 =item KOHA_CONF_DIR
 162
 163 Directory for Koha configuration files.
 164
 165 =item ZEBRA_CONF_DIR
 166
 167 Directory for Zebra configuration files.
 168
 169 =item ZEBRA_LOCK_DIR
 170
 171 Directory for Zebra's lock files.
 172
 173 =item ZEBRA_DATA_DIR
 174
 175 Directory for Zebra's data files.
 176
 177 =item ZEBRA_RUN_DIR
 178
 179 Directory for Zebra's UNIX-domain sockets.
 180
 181 =item MISC_DIR
 182
 183 Directory for for miscellaenous scripts, among other
 184 things the translation toolkit and RSS feed tools.
 185
 186 =item SCRIPT_DIR
 187
 188 Directory for command-line scripts and daemons.
 189
 190 =item MAN_DIR
 191
 192 Directory for man pages created from POD -- will mostly
 193 contain information of interest to Koha developers.
 194
 195 =item DOC_DIR
 196
 197 Directory for Koha documentation accessed from the
 198 command-line, e.g., READMEs.
 199
 200 =item LOG_DIR
 201
 202 Directory for Apache and Zebra logs produced by Koha.
 203
 204 =item NONE
 205
 206 This is a dummy target used to explicitly state
 207 that a given file or directory is not to be installed.
 208 This is used either for parts of the installer itself
 209 or for development tools that are not applicable to a
 210 production installation.
 211
 212 =back
 213
 214 =cut
 215
 216 my $target_map = {
 217   './about.pl'                  => 'INTRANET_CGI_DIR',
 218   './acqui'                     => 'INTRANET_CGI_DIR',
 219   './admin'                     => 'INTRANET_CGI_DIR',
 220   './authorities'               => 'INTRANET_CGI_DIR',
 221   './C4'                        => 'PERL_MODULE_DIR',
 222   './C4/SIP/t'                  => 'NONE',
 223   './C4/SIP/koha_test'          => 'NONE',
 224   './C4/tests'                  => 'NONE',
 225   './catalogue'                 => 'INTRANET_CGI_DIR',
 226   './cataloguing'               => 'INTRANET_CGI_DIR',
 227   './changelanguage.pl'         => 'INTRANET_CGI_DIR',
 228   './check_sysprefs.pl'         => 'NONE',
 229   './circ'                      => 'INTRANET_CGI_DIR',
 230   './edithelp.pl'               => 'INTRANET_CGI_DIR',
 231   './etc'                       => { target => 'KOHA_CONF_DIR', trimdir => -1 },
 232   './etc/zebradb'               => { target => 'ZEBRA_CONF_DIR', trimdir => -1 },
 233   './help.pl'                   => 'INTRANET_CGI_DIR',
 234   './installer-CPAN.pl'         => 'NONE',
 235   './installer'                 => 'INTRANET_CGI_DIR',
 236   './koha-tmpl/errors'          => {target => 'INTRANET_CGI_DIR', trimdir => 2},
 237   './koha-tmpl/intranet-tmpl'   => {target => 'INTRANET_TMPL_DIR', trimdir => -1},
 238   './koha-tmpl/opac-tmpl'       => {target => 'OPAC_TMPL_DIR', trimdir => -1},
 239   './kohaversion.pl'            => 'INTRANET_CGI_DIR',
 240   './labels'                    => 'INTRANET_CGI_DIR',
 241   './mainpage.pl'               => 'INTRANET_CGI_DIR',
 242   './Makefile.PL'               => 'NONE',
 243   './MANIFEST.SKIP'             => 'NONE',
 244   './members'                   => 'INTRANET_CGI_DIR',
 245   './misc'                      => { target => 'SCRIPT_DIR', trimdir => -1 },
 246   './misc/info'                 => { target => 'DOC_DIR', trimdir => 2 },
 247   './misc/release notes'        => { target => 'DOC_DIR', trimdir => 2 },
 248   './misc/translator'           => { target => 'MISC_DIR', trimdir => 2 },
 249   './misc/installer_devel_notes' => 'NONE',
 250   './opac'                      => 'OPAC_CGI_DIR',
 251   './README.txt'                => 'NONE',
 252   './reports'                   => 'INTRANET_CGI_DIR',
 253   './reserve'                   => 'INTRANET_CGI_DIR',
 254   './reviews'                   => 'INTRANET_CGI_DIR',
 255   './rewrite-config.PL'         => 'NONE',
 256   './reviews'                   => 'INTRANET_CGI_DIR',
 257   './rss'                       => 'MISC_DIR',
 258   './serials'                   => 'INTRANET_CGI_DIR',
 259   './skel'                      => 'NONE',
 260   './skel/var/log/koha'         => { target => 'LOG_DIR', trimdir => -1 },
 261   './skel/var/run/koha/zebradb' => { target => 'ZEBRA_RUN_DIR', trimdir => -1 },
 262   './skel/var/lock/koha/zebradb/authorities' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 263   './skel/var/lib/koha/zebradb/authorities/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 264   './skel/var/lib/koha/zebradb/authorities/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 265   './skel/var/lib/koha/zebradb/authorities/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 266   './skel/var/lib/koha/zebradb/authorities/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 267   './skel/var/lock/koha/zebradb/biblios' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 268   './skel/var/lib/koha/zebradb/biblios/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 269   './skel/var/lib/koha/zebradb/biblios/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 270   './skel/var/lib/koha/zebradb/biblios/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 271   './skel/var/lib/koha/zebradb/biblios/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 272   './sms'                       => 'INTRANET_CGI_DIR',
 273   './suggestion'                => 'INTRANET_CGI_DIR',
 274   './svc'                       => 'INTRANET_CGI_DIR',
 275   './t'                         => 'NONE',
 276   './tmp'                       => 'NONE', # FIXME need to determine whether
 277                                            # Koha generates any persistent temp files
 278                                            # that should go in /var/tmp/koha
 279   './tools'                     => 'INTRANET_CGI_DIR',
 280   './virtualshelves'            => 'INTRANET_CGI_DIR',
 281   # ignore files and directories created by the install itself
 282   './pm_to_blib'                => 'NONE',
 283   './blib'                      => 'NONE',
 284 };
 285
 286 =head1 CONFIGURATION OPTIONS
 287
 288 The following configuration options are used by the installer.
 289
 290 =over 4
 291
 292 =item INSTALL_MODE
 293
 294 Specifies whether installation will be FHS-compliant (default,
 295 assumes user has root), put everything under
 296 a single directory (for users installing on a web host
 297 that allows CGI scripts and a MySQL database but not root
 298 access), or development (for a developer who wants to run
 299 Koha from a git clone with no fuss).
 300
 301 =item INSTALL_BASE
 302
 303 Directory under which most components will go.  Default
 304 value will vary depending on INSTALL_MODE.
 305
 306 =item DB_TYPE
 307
 308 Type of DBMS (e.g., mysql or Pg).
 309
 310 =item DB_HOST
 311
 312 Name of DBMS server.
 313
 314 =item DB_PORT
 315
 316 Port that DBMS server is listening on.
 317
 318 =item DB_NAME
 319
 320 Name of the DBMS database for Koha.
 321
 322 =item DB_USER
 323
 324 Name of DBMS user account for Koha's database.
 325
 326 =item DB_PASS
 327
 328 Pasword of DMBS user account for Koha's database.
 329
 330 =item INSTALL_ZEBRA
 331
 332 Whether to install Zebra configuration files and data
 333 directories.
 334
 335 =item ZEBRA_MARC_FORMAT
 336
 337 Specifies format of MARC records to be indexed by Zebra.
 338
 339 =item ZEBRA_LANGUAGE
 340
 341 Specifies primary language of records that will be
 342 indexed by Zebra.
 343
 344 =item ZEBRA_USER
 345
 346 Internal Zebra user account for the index.
 347
 348 =item ZEBRA_PASS
 349
 350 Internal Zebra user account's password.
 351
 352 =item KOHA_USER
 353
 354 System user account that will own Koha's files.
 355
 356 =item KOHA_GROUP
 357
 358 System group that will own Koha's files.
 359
 360 =back
 361
 362 =cut
 363
 364 # default configuration options
 365 my %config_defaults = (
 366   'INSTALL_MODE'      => 'standard',
 367   'INSTALL_BASE'      => '/usr/share/koha',
 368   'DB_TYPE'           => 'mysql',
 369   'DB_HOST'           => 'localhost',
 370   'DB_NAME'           => 'koha',
 371   'DB_USER'           => 'kohaadmin',
 372   'DB_PASS'           => 'katikoan',
 373   'INSTALL_ZEBRA'     => 'yes',
 374   'ZEBRA_MARC_FORMAT' => 'marc21',
 375   'ZEBRA_LANGUAGE'    => 'en',
 376   'ZEBRA_USER'        => 'kohauser',
 377   'ZEBRA_PASS'        => 'zebrastripes',
 378   'KOHA_USER'         => 'koha',
 379   'KOHA_GROUP'        => 'koha',
 380 );
 381
 382 # valid values for certain configuration options
 383 my %valid_config_values = (
 384   'INSTALL_MODE'  => { 'standard' => 1, 'single' => 1, 'dev' => 1 },
 385   'DB_TYPE' => { 'mysql' => 1, 'Pg' => 1 },
 386   'INSTALL_ZEBRA' => { 'yes' => 1, 'no' => 1 },
 387   'ZEBRA_MARC_FORMAT' => { 'marc21' => 1, 'unimarc' => 1 }, # FIXME should generate from contents of distributation
 388   'ZEBRA_LANGUAGE'    => { 'en' => 1, 'fr' => 1 }, # FIXME should generate from contents of distribution
 389 );
 390
 391 my %config = get_configuration(\%config_defaults, \%valid_config_values);
 392 my ($target_directories, $skip_directories) = get_target_directories(\%config);
 393 display_configuration(\%config, $target_directories);
 394 my $file_map = {};
 395 get_file_map($target_map, $dirtree, $file_map, $config{'INSTALL_ZEBRA'} eq "yes" ? 1: 0);
 396
 397 my $pl_files = {
 398       'rewrite-config.PL' => [
 399          'blib/KOHA_CONF_DIR/koha-conf.xml',
 400          'blib/KOHA_CONF_DIR/koha-httpd.conf',
 401          ]
 402 };
 403
 404 if ($config{'INSTALL_ZEBRA'} eq "yes") {
 405     push @{ $pl_files->{'rewrite-config.PL'} }, (
 406         'blib/ZEBRA_CONF_DIR/etc/passwd',
 407         'blib/ZEBRA_CONF_DIR/zebra-biblios.cfg',
 408         'blib/ZEBRA_CONF_DIR/zebra-authorities.cfg'
 409     );
 410 }
 411
 412 if ($config{'INSTALL_MODE'} ne "dev") {
 413     push @{ $pl_files->{'rewrite-config.PL'} }, (
 414         'blib/PERL_MODULE_DIR/C4/Context.pm',
 415         'blib/SCRIPT_DIR/kohalib.pl'
 416     );
 417 }
 418
 419 WriteMakefile(
 420     NAME => 'koha',
 421     #VERSION => strftime('2.9.%Y%m%d%H',gmtime),
 422     VERSION_FROM => 'kohaversion.pl',
 423     ABSTRACT => 'Award-winning integrated library system (ILS) and Web OPAC',
 424     AUTHOR => 'Koha Developers <koha-devel@nongnu.org>',
 425     NO_META => 1,
 426     PREREQ_PM => {
 427 'Algorithm::CheckDigits' => 0.48,
 428 'Biblio::EndnoteStyle' => 0.05,
 429 'CGI' => 3.15,
 430 'CGI::Carp' => 1.29,
 431 'CGI::Session' => '4.10',
 432 'Class::Factory::Util' => 1.7,
 433 'Class::Accessor' => 0.30,
 434 'DBD::mysql' => 3.0008,
 435 'DBI' => 1.53,
 436 'Data::ICal' => 0.13,
 437 'Data::Dumper' => 2.121_08,
 438 'Date::Calc' => 5.4,
 439 'Date::ICal' => 1.72,
 440 'Date::Manip' => 5.44,
 441 'Digest::MD5' => 2.36,
 442 'File::Temp' => 0.16,
 443 'GD::Barcode::UPCE' => 1.1,
 444 'Getopt::Long' => 2.35,
 445 'Getopt::Std' => 1.05,
 446 'HTML::Template::Pro' => 0.65,
 447 'HTTP::Cookies' => 1.39,
 448 'HTTP::Request::Common' => 1.26,
 449 'LWP::Simple' => 1.41,
 450 'LWP::UserAgent' => 2.033,
 451 'Lingua::Stem' => 0.82,
 452 'List::Util' => 1.18,
 453 'List::MoreUtils' => 0.22,
 454 'Locale::Language' => 2.07,
 455 'MARC::Charset' => 0.98,
 456 'MARC::Crosswalk::DublinCore' => 0.02,
 457 'MARC::File::XML' => 0.88,
 458 'MARC::Record' => 2.00,
 459 'MIME::Base64' => 3.07,
 460 'MIME::QuotedPrint' => 3.07,
 461 'Mail::Sendmail' => 0.79,
 462 'Net::LDAP' => 0.34,
 463 'Net::LDAP::Filter' => 0.34,
 464 'Net::Z3950::ZOOM' => 1.16,
 465 'PDF::API2' => 2.000,
 466 'PDF::API2::Page' => 2.000,
 467 'PDF::API2::Util' => 2.000,
 468 'PDF::Reuse' => 0.33,
 469 'PDF::Reuse::Barcode' => 0.05,
 470 'POE' => 0.9999,
 471 'POSIX' => 1.09,
 472 'Schedule::At' => 1.06,
 473 'Term::ANSIColor' => 1.10,
 474 'Test' => 1.25,
 475 'Test::Harness' => 2.56,
 476 'Test::More' => 0.62,
 477 'Text::CSV' => 0.01,
 478 'Text::CSV_XS' => 0.32,
 479 'Text::Wrap' => 2005.082401,
 480 'Time::HiRes' => 1.86,
 481 'Time::localtime' => 1.02,
 482 'Unicode::Normalize' => 0.32,
 483 'XML::Dumper' => 0.81,
 484 'XML::LibXML' => 1.59,
 485 'XML::LibXSLT' => 1.63,
 486 'XML::SAX::ParserFactory' => 1.01,
 487 'XML::Simple' => 2.14,
 488 'XML::RSS' => 1.31,
 489         },
 490
 491         # File tree mapping
 492         PM => $file_map,
 493
 494     # Man pages generated from POD
 495     INSTALLMAN1DIR => File::Spec->catdir($target_directories->{'MAN_DIR'}, 'man1'),
 496     INSTALLMAN3DIR => File::Spec->catdir($target_directories->{'MAN_DIR'}, 'man3'),
 497
 498    PL_FILES => $pl_files,
 499
 500 );
 501
 502 =head1 FUNCTIONS
 503
 504 =head2 hashdir
 505
 506 This function recurses through the directory structure and builds
 507 a hash of hashes containing the structure with arrays holding filenames.
 508 This directory hashing routine was taken from BrowserUK @ http://www.perlmonks.org/?node_id=219919
 509
 510 =cut
 511
 512 sub hashdir{
 513     my $dir = shift;
 514     opendir my $dh, $dir or die $!;
 515     my $tree = {}->{$dir} = {};
 516     while( my $file = readdir($dh) ) {
 517         next if $file =~ m/^\.{1,2}/ and $file !~ /^\.htaccess/; # .htaccess is a special case
 518         my $path = $dir .'/' . $file;
 519         $tree->{$file} = hashdir($path), next if -d $path;
 520         push @{$tree->{'.'}}, $file;
 521     }
 522     return $tree;
 523 }
 524
 525 =head2 get_file_map
 526
 527 This function combines the target_map and file hash to
 528 map each source file to its destination relative to
 529 the set of installation targets.
 530
 531 Output will be a hash mapping from each source file
 532 to its destination value, like this:
 533
 534 'mainpage.pl' => '$(INTRANET_CGI_DIR)/mainpage.pl'
 535
 536 =cut
 537
 538 sub get_file_map {
 539     my $target_map = shift;
 540     my $dirtree = shift;
 541     my $file_map = shift;
 542     my $install_zebra = shift;
 543     my $curr_path = @_ ? shift : ['.'];
 544
 545     # Traverse the directory tree.
 546     # For each file or directory, identify the
 547     # most specific match in the target_map
 548     foreach my $dir (sort keys %{ $dirtree }) {
 549         if ($dir eq '.') {
 550             # deal with files in directory
 551             foreach my $file (sort @{ $dirtree->{$dir} }) {
 552                 my $targetdir = undef;
 553                 my $matchlevel = undef;
 554                 # first, see if there is a match on this specific
 555                 # file in the target map
 556                 my $filepath = join("/", @$curr_path, $file);
 557                 if (exists $target_map->{$filepath}) {
 558                     $targetdir = $target_map->{$filepath};
 559                     $matchlevel = scalar(@$curr_path) + 1;
 560                 } else {
 561                     # no match on the specific file; look for
 562                     # a directory match
 563                     for (my $i = scalar(@$curr_path) - 1; $i >= 0; $i--)  {
 564                         my $dirpath = join("/", @$curr_path[0..$i]);
 565                         if (exists $target_map->{$dirpath}) {
 566                             $targetdir = $target_map->{$dirpath};
 567                             $matchlevel = $i + 1;
 568                             last;
 569                         }
 570                     }
 571                 }
 572                 if (defined $targetdir) {
 573                      _add_to_file_map($file_map, $targetdir, $curr_path, $file, $matchlevel, $install_zebra);
 574                 } else {
 575                     my $path = join("/", @$curr_path);
 576                     print "failed to map: $path/$file\n" if $DEBUG;
 577                 }
 578             }
 579         } else {
 580             # dealing with subdirectory
 581             push @$curr_path, $dir;
 582             get_file_map($target_map, $dirtree->{$dir}, $file_map, $install_zebra, $curr_path);
 583             pop @$curr_path;
 584         }
 585     }
 586 }
 587
 588 sub _add_to_file_map {
 589     my $file_map = shift;
 590     my $targetdir = shift;
 591     my $curr_path = shift;
 592     my $file = shift;
 593     my $matchlevel = shift;
 594     my $install_zebra = shift;
 595     my $dest_path = @_ ? shift : $curr_path;
 596
 597     # The target can be one of the following:
 598     # 1. scalar representing target symbol
 599     # 2. hash ref containing target and trimdir keys
 600     #
 601     # Consequently, this routine traverses this structure,
 602     # calling itself recursively, until it deals with
 603     # all of the scalar target symbols.
 604     if (ref $targetdir eq 'HASH') {
 605         my $subtarget = $targetdir->{target};
 606         if (exists $targetdir->{trimdir}) {
 607             # if we get here, we've specified that
 608             # rather than installing the file to
 609             # $(TARGET)/matching/dirs/subdirs/file,
 610             # we want to install it to
 611             # $(TARGET)/subdirs/file
 612             #
 613             # Note that this the only place where
 614             # $matchlevel is used.
 615             my @new_dest_path = @$dest_path;
 616             if ($targetdir->{trimdir} == -1)  {
 617                 splice @new_dest_path, 0, $matchlevel;
 618             } else {
 619                 splice @new_dest_path, 0, $targetdir->{trimdir};
 620             }
 621             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel, $install_zebra, \@new_dest_path);
 622         } else {
 623             # actually getting here means that the
 624             # target was unnecessarily listed
 625             # as a hash, but we'll forgive that
 626             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel, $install_zebra);
 627         }
 628     } elsif ($targetdir ne 'NONE' and $targetdir ne '') {
 629         my $source = File::Spec->catfile(@$curr_path, $file);
 630         my $destination = File::Spec->catfile('blib', $targetdir, @$dest_path, $file);
 631         #print "$source => $destination\n"; # DEBUG
 632         # quote spaces in file names
 633         # FIXME: this is of questionable portability and
 634         # probably depends on user's make recognizing this
 635         # quoting syntax -- probably better to remove
 636         # spaces and shell metacharacters from all file names
 637         $source =~ s/ /\\ /g;
 638         $destination =~ s/ /\\ /g;
 639
 640         $file_map->{$source} = $destination unless (!$install_zebra and $targetdir =~ /ZEBRA/);
 641     }
 642 }
 643
 644 =head2 get_configuration_options
 645
 646 This prompts the user for various configuration options.
 647
 648 =cut
 649
 650 sub get_configuration {
 651   my $defaults = shift;
 652   my $valid_values = shift;
 653   my %config = ();
 654
 655   my $msg = q(
 656 By default, Koha can be installed in one of three ways:
 657
 658 standard: Install files in conformance with the Filesystem
 659           Hierarchy Standard (FHS).  This is the default mode
 660           and should be used when installing a production
 661           Koha system.  On Unix systems, root access is
 662           needed to complete a standard installation.
 663
 664 single:   Install files under a single directory.  This option
 665           is useful for installing Koha without root access, e.g.,
 666           on a web host that allows CGI scripts and MySQL databases
 667           but requires the user to keep all files under the user's
 668           HOME directory.
 669
 670 dev:      Create a set of symbolic links and configuration files to
 671           allow Koha to run directly from the source distribution.
 672           This mode is useful for developers who want to run
 673           Koha from a git clone.
 674
 675 Installation mode);
 676     $msg .= _add_valid_values_disp('INSTALL_MODE', $valid_values);
 677     $config{'INSTALL_MODE'} = _get_value('INSTALL_MODE', $msg, $defaults->{'INSTALL_MODE'}, $valid_values);
 678
 679     # set message and default value for INSTALL_BASE
 680     # depending on value of INSTALL_MODE
 681     my $install_base_default = $defaults->{'INSTALL_BASE'};
 682     if ($config{'INSTALL_MODE'} eq 'dev') {
 683         $msg = q(
 684 Please specify the directory in which to install Koha's
 685 active configuration files and (if applicable) the
 686 Zebra database.  Koha's CGI scripts and templates will
 687 be run from the current directory.
 688
 689 Configuration directory:);
 690         # FIXME - home directory portability consideration apply
 691         $install_base_default = (exists $ENV{'HOME'}) ? "$ENV{'HOME'}/koha-dev" : "/usr/share/koha-dev";
 692     } elsif ($config{'INSTALL_MODE'} eq 'single') {
 693         $msg = "\nPlease specify the directory in which to install Koha";
 694         # FIXME -- we're assuming under a 'single' mode install
 695         # that user will likely want to install under the home
 696         # directory.  This is OK in and of itself, but we should
 697         # use File::HomeDir to locate the home directory portably.
 698         # This is deferred for now because File::HomeDir is not yet
 699         # core.
 700         $install_base_default = (exists $ENV{'HOME'}) ? "$ENV{'HOME'}/koha" : "/usr/share/koha";
 701     } else {
 702         # must be standard
 703         $msg = q(
 704 Please specify the directory under which most Koha files
 705 will be installed.
 706
 707 Note that if you are planning in installing more than
 708 one instance of Koha, you may want to modify the last
 709 component of the directory path, which will be used
 710 as the package name in the FHS layout.
 711
 712 Base installation directory);
 713     }
 714     $config{'INSTALL_BASE'} = _get_value('INSTALL_BASE', $msg, $install_base_default, $valid_values);
 715     $config{'INSTALL_BASE'} = File::Spec->rel2abs($config{'INSTALL_BASE'});
 716
 717     if ($config{'INSTALL_MODE'} eq "standard") {
 718         $msg = q(
 719 Since you are using the 'standard' install
 720 mode, you should run 'make install' as root.
 721 However, it is recommended that a non-root
 722 user (on Unix and Linux platforms) have
 723 ownership of Koha's files, including the
 724 Zebra indexes if applicable.
 725
 726 Please specify a user account.  This
 727 user account does not need to exist
 728 right now, but it needs to exist
 729 before you run 'make install'.  Please
 730 note that for security reasons, this
 731 user should not be the same as the user
 732 account Apache runs under.
 733
 734 User account);
 735         $config{'KOHA_USER'} = _get_value('KOHA_USER', $msg, $defaults->{'KOHA_USER'}, $valid_values);
 736
 737         $msg = q(
 738 Please specify the group that should own
 739 Koha's files.  As above, this group need
 740 not exist right now, but should be created
 741 before you run 'make install'.
 742
 743 Group);
 744         $config{'KOHA_GROUP'} = _get_value('KOHA_GROUP', $msg, $defaults->{'KOHA_GROUP'}, $valid_values);
 745     }
 746
 747     $msg = q(
 748 Please specify which database engine you will use
 749 to store data in Koha.  The choices are MySQL and
 750 PostgreSQL; please note that at the moment
 751 PostgreSQL support is highly experimental.
 752
 753 DBMS to use);
 754     $msg .= _add_valid_values_disp('DB_TYPE', $valid_values);
 755     $config{'DB_TYPE'} = _get_value('DB_TYPE', $msg, $defaults->{'DB_TYPE'}, $valid_values);
 756
 757     $msg = q(
 758 Please specify the name or address of your
 759 database server.  Note that the database
 760 does not have to exist at this point, it
 761 can be created after running 'make install'
 762 and before you try using Koha for the first time.
 763
 764 Database server);
 765     $config{'DB_HOST'} = _get_value('DB_HOST', $msg, $defaults->{'DB_HOST'}, $valid_values);
 766
 767     $msg = q(
 768 Please specify the port used to connect to the
 769 DMBS);
 770     my $db_port_default = $config{'DB_TYPE'} eq 'mysql' ? '3306' : '5432';
 771     $config{'DB_PORT'} = _get_value('DB_PORT', $msg, $db_port_default, $valid_values);
 772
 773     $msg = q(
 774 Please specify the name of the database to be
 775 used by Koha);
 776     $config{'DB_NAME'} = _get_value('DB_NAME', $msg, $defaults->{'DB_NAME'}, $valid_values);
 777
 778     $msg = q(
 779 Please specify the user that owns the database to be
 780 used by Koha);
 781     $config{'DB_USER'} = _get_value('DB_USER', $msg, $defaults->{'DB_USER'}, $valid_values);
 782
 783     $msg = q(
 784 Please specify the password of the user that owns the
 785 database to be used by Koha);
 786     $config{'DB_PASS'} = _get_value('DB_PASS', $msg, $defaults->{'DB_PASS'}, $valid_values);
 787
 788     $msg = q(
 789 Koha can use the Zebra search engine for high-performance
 790 searching of bibliographic and authority records.  If you
 791 have installed the Zebra software and would like to use it,
 792 please answer 'yes' to the following question.  Otherwise,
 793 Koha will default to using its internal search engine.
 794
 795 Please note that if you choose *NOT* to install Zebra,
 796 koha-conf.xml will still contain some references to Zebra
 797 settings.  Those references will be ignored by Koha.
 798
 799 Install the Zebra configuration files?);
 800     $msg .= _add_valid_values_disp('INSTALL_ZEBRA', $valid_values);
 801     $config{'INSTALL_ZEBRA'} = _get_value('INSTALL_ZEBRA', $msg, $defaults->{'INSTALL_ZEBRA'}, $valid_values);
 802
 803     if ($config{'INSTALL_ZEBRA'} eq 'yes') {
 804         $msg = q(
 805 Since you've chosen to use Zebra with Koha,
 806 you must specify the primary MARC format of the
 807 records to be indexed by Zebra.
 808
 809 Koha provides Zebra configuration files for MARC 21
 810 and UNIMARC.
 811
 812 MARC format for Zebra indexing);
 813         $msg .= _add_valid_values_disp('ZEBRA_MARC_FORMAT', $valid_values);
 814         $config{'ZEBRA_MARC_FORMAT'} = _get_value('ZEBRA_MARC_FORMAT', $msg, $defaults->{'ZEBRA_MARC_FORMAT'}, $valid_values);
 815         $msg = q(
 816 Koha supplies Zebra configuration files tuned for
 817 searching either English (en) or French (fr) MARC
 818 records.
 819
 820 Primary language for Zebra indexing);
 821         $msg .= _add_valid_values_disp('ZEBRA_LANGUAGE', $valid_values);
 822         $config{'ZEBRA_LANGUAGE'} = _get_value('ZEBRA_LANGUAGE', $msg, $defaults->{'ZEBRA_LANGUAGE'}, $valid_values);
 823
 824         $msg = q(
 825 Please specify Zebra database user);
 826         $config{'ZEBRA_USER'} = _get_value('ZEBRA_USER', $msg, $defaults->{'ZEBRA_USER'}, $valid_values);
 827
 828         $msg = q(
 829 Please specify the Zebra database password);
 830         $config{'ZEBRA_PASS'} = _get_value('ZEBRA_PASS', $msg, $defaults->{'ZEBRA_PASS'}, $valid_values);
 831
 832     }
 833
 834     print "\n\n";
 835     return %config;
 836 }
 837
 838 sub _add_valid_values_disp {
 839     my $key = shift;
 840     my $valid_values = shift;
 841
 842     my $disp = "";
 843     if (exists $valid_values->{$key}) {
 844         $disp = " (" . join(", ", sort keys %{ $valid_values->{$key} }) . ")";
 845     }
 846     return $disp;
 847 }
 848
 849 sub _get_value {
 850     my $key = shift;
 851     my $msg = shift;
 852     my $default = shift;
 853     my $valid_values = shift;
 854
 855     # override default value from environment
 856     if (exists $ENV{$key}) {
 857         $default = $ENV{$key};
 858         $msg .= " (default from environment)";
 859     }
 860
 861     my $val = prompt($msg, $default);
 862
 863     while (exists $valid_values->{$key} and
 864            $val ne $default and
 865            not exists $valid_values->{$key}->{$val}) {
 866         my $retry_msg = "Value '$val' is not a valid option.\n";
 867         $retry_msg .= "Please enter a value";
 868         $retry_msg .= _add_valid_values_disp($key, $valid_values);
 869         $val = prompt($retry_msg, $default);
 870     }
 871     return $val;
 872 }
 873
 874 =head2 get_target_directories
 875
 876 Creates a hash mapping from symbols for installation target
 877 directories to actual directory paths.
 878
 879 Also returns a hash indicating targets for which
 880 files need not be copied -- this is used for the 'dev'
 881 mode installation, where some files are installed in place.
 882
 883 =cut
 884
 885 sub get_target_directories {
 886     my $config = shift;
 887
 888     my $base = $config->{'INSTALL_BASE'};
 889     my $mode = $config->{'INSTALL_MODE'};
 890
 891     # get last component of install base directory
 892     # to treat as package name
 893     my ($volume, $directories, $file) = File::Spec->splitpath($base, 1);
 894     my @basedir = File::Spec->splitdir($directories);
 895     my $package = pop @basedir;
 896
 897     my %dirmap = ();
 898     my %skipdirs = ();
 899     if ($mode eq 'single') {
 900         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
 901         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
 902         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
 903         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
 904         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
 905         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
 906         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
 907         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
 908         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
 909         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
 910         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
 911         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
 912         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
 913         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
 914         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
 915         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
 916         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
 917     } elsif ($mode eq 'dev') {
 918         my $curdir = File::Spec->rel2abs(File::Spec->curdir());
 919         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir($curdir);
 920         $skipdirs{'INTRANET_CGI_DIR'} = 1;
 921         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'intranet-tmpl');
 922         $skipdirs{'INTRANET_TMPL_DIR'} = 1;
 923         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl');
 924         $skipdirs{'INTRANET_WWW_DIR'} = 1;
 925         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir($curdir, 'opac');
 926         $skipdirs{'OPAC_CGI_DIR'} = 1;
 927         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'opac-tmpl');
 928         $skipdirs{'OPAC_TMPL_DIR'} = 1;
 929         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl');
 930         $skipdirs{'OPAC_WWW_DIR'} = 1;
 931         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir($curdir);
 932         $skipdirs{'PERL_MODULE_DIR'} = 1;
 933         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
 934         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
 935         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
 936         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
 937         $skipdirs{'SCRIPT_DIR'} = 1;
 938         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
 939         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
 940         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
 941         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
 942         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
 943         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
 944     } else {
 945         # mode is standard, i.e., 'fhs'
 946         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
 947         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
 948         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
 949         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
 950         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
 951         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
 952         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
 953         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package);
 954         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package, 'zebradb');
 955         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
 956         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
 957         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
 958         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
 959         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'var', 'lock', $package, 'zebradb');
 960         $dirmap{'LOG_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'log', $package);
 961         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'lib', $package, 'zebradb');
 962         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'run', $package, 'zebradb');
 963     }
 964
 965     _get_env_overrides(\%dirmap);
 966     _get_argv_overrides(\%dirmap);
 967
 968     return \%dirmap, \%skipdirs;
 969 }
 970
 971 sub _get_env_overrides {
 972     my $dirmap = shift;
 973
 974     foreach my $key (keys %$dirmap) {
 975         if (exists $ENV{$key}) {
 976             $dirmap->{$key} = $ENV{$key};
 977             print "Setting $key from environment\n";
 978         }
 979     }
 980 }
 981
 982 sub _get_argv_overrides {
 983     my $dirmap = shift;
 984
 985     my @new_argv = ();
 986     for (my $i = 0; $i <= $#ARGV; $i++) {
 987         if ($ARGV[$i] =~ /^([^=]+)=([^=]+)$/ and exists $dirmap->{$1}) {
 988             $dirmap->{$1} = $2;
 989         } else {
 990             push @new_argv, $ARGV[$i];
 991         }
 992     }
 993     @ARGV = @new_argv;
 994 }
 995
 996 sub display_configuration {
 997     my $config = shift;
 998     my $dirmap = shift;
 999     print "\n\nKoha will be installed with the following configuration parameters:\n\n";
1000     foreach my $key (sort keys %$config) {
1001         print sprintf("%-25.25s%s\n", $key, $config->{$key});
1002     }
1003
1004     print "\nand in the following directories:\n\n";
1005     foreach my $key (sort keys %$dirmap) {
1006         print sprintf("%-25.25s%s\n", $key, $dirmap->{$key});
1007     }
1008     print "\n\nTo change any configuration setting, please run\n";
1009     print "perl Makefile.PL again.  To override one of the target\n";
1010     print "directories, you can do so on the command line like this:\n";
1011     print "\nperl Makefile.PL PERL_MODULE_DIR=/usr/share/perl/5.8\n\n";
1012     print "You can also set different default values for parameters\n";
1013     print "or override directory locations by using environment variables.\n";
1014     print "\nFor example:\n\n";
1015     print "export DB_USER=my_koha\n";
1016     print "perl Makefile.PL\n";
1017     print "\nor\n\n";
1018     print "DB_USER=my_koha DOC_DIR=/usr/local/info perl Makefile.PL\n\n";
1019 }
1020
1021 package MY;
1022
1023 sub test {
1024     my $self = shift;
1025     my $test = $self->SUPER::test(@_);
1026     $test =~ s!\$\(INST_LIB\)!blib/PERL_MODULE_DIR!g;
1027     return $test;
1028 }
1029
1030 sub install {
1031     my $self = shift;
1032     my $install = "";
1033     # NOTE: we're *not* doing this: my $install = $self->SUPER::install(@_);
1034     # This means that we're completely overriding EU::MM's default
1035     # installation and uninstallation targets.
1036     foreach my $key (sort keys %$target_directories) {
1037         $install .= qq(
1038 KOHA_INST_$key = blib/$key
1039 KOHA_DEST_$key = $target_directories->{$key}
1040 ) unless ($config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/) or exists $skip_directories->{$key};
1041     }
1042
1043     $install .= qq(
1044 install :: all install_koha set_koha_ownership set_koha_permissions warn_koha_env_vars
1045 \t\$(NOECHO) \$(NOOP)
1046 );
1047     $install .= "install_koha ::\n";
1048     $install .= "\t\$(NOECHO) umask 022; \$(MOD_INSTALL) \\\n";
1049     foreach my $key (sort keys %$target_directories) {
1050         $install .= "\t\t\$(KOHA_INST_$key) \$(KOHA_DEST_$key) \\\n"
1051             unless ($config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/) or exists $skip_directories->{$key};
1052     }
1053     $install .= "\t\t\$(INST_MAN1DIR) \$(DESTINSTALLMAN1DIR) \\\n";
1054     $install .= "\t\t\$(INST_MAN3DIR) \$(DESTINSTALLMAN3DIR)\n";
1055
1056     $install .= "\n";
1057     $install .= "set_koha_ownership ::\n";
1058     if ($config{'INSTALL_MODE'} eq 'standard' and $config{'KOHA_USER'} ne "root") {
1059         foreach my $key (sort keys %$target_directories) {
1060             $install .= "\t\$(NOECHO) chown -R $config{'KOHA_USER'}:$config{'KOHA_GROUP'} \$(KOHA_DEST_$key)\n"
1061                 unless ($config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/) or exists $skip_directories->{$key};
1062         }
1063     } else {
1064         $install .= "\t\t\$(NOECHO) \$(NOOP)\n\n";
1065     }
1066
1067     $install .= "\n";
1068     $install .= "set_koha_permissions ::\n";
1069     # This is necessary because EU::MM installs files
1070     # as either 0444 or 0555, and we want the owner
1071     # of Koha's files to have write permission by default.
1072     foreach my $key (sort keys %$target_directories) {
1073         $install .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_$key)\n"
1074             unless ($config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/) or exists $skip_directories->{$key};
1075     }
1076     $install .= "\n";
1077
1078     $install .= "warn_koha_env_vars ::\n";
1079     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1080     $install .= "\t\$(NOECHO) \$(ECHO) Koha\\'s files have now been installed. \n";
1081     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1082     $install .= "\t\$(NOECHO) \$(ECHO) In order to use Koha\\'s command-line batch jobs,\n";
1083     $install .= "\t\$(NOECHO) \$(ECHO) you should set the following environment variables:\n";
1084     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1085     $install .= "\t\$(NOECHO) \$(ECHO) export KOHA_CONF=\$(KOHA_DEST_KOHA_CONF_DIR)/koha-conf.xml\n";
1086     $install .= "\t\$(NOECHO) \$(ECHO) export PERL5LIB=$target_directories->{'PERL_MODULE_DIR'}\n";
1087     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1088     $install .= "\t\$(NOECHO) \$(ECHO) For other post-installation tasks, please consult the README.\n";
1089     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1090
1091     return $install;
1092 }
1093
1094 sub postamble {
1095     # put directory mappings into Makefile
1096     # so that Make will export as environment
1097     # variables -- this is for the use of
1098     # rewrite-confg.PL
1099     my $env = join("\n", map { "export __${_}__ := $target_directories->{$_}" } keys %$target_directories);
1100     $env .= "\n\n";
1101
1102     # quote '$' in the two password parameters
1103     my %config = %config;
1104     $config{'DB_PASS'} =~ s/\$/\$\$/g;
1105     $config{'ZEBRA_PASS'} =~ s/\$/\$\$/g;
1106     $env .= join("\n", map { "export __${_}__ := $config{$_}" } keys %config);
1107     return "$env\n";
1108 }
1109
1110 __END__
1111
1112
1113 =head1 SEE ALSO
1114
1115 ExtUtils::MakeMaker(3)
1116
1117 =head1 AUTHORS
1118
1119 MJ Ray mjr at phonecoop.coop
1120 Galen Charlton galen.charlton at liblime.com
1121
1122 =cut
1123 FIXME: deal with .htaccess