acqui/basketgroup.pl

   1 #!/usr/bin/perl
   2
   3 #script to group (closed) baskets into basket groups for easier order management
   4 #written by john.soros@biblibre.com 01/10/2008
   5
   6 # Copyright 2008 - 2009 BibLibre SARL
   7 # Parts Copyright Catalyst 2010
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 3 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  19 # GNU General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU General Public License
  22 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  23
  24
  25 =head1 NAME
  26
  27 basketgroup.pl
  28
  29 =head1 DESCRIPTION
  30
  31  This script lets the user group (closed) baskets into basket groups for easier order management. Note that the grouped baskets have to be from the same bookseller and
  32  have to be closed to be printed or exported.
  33
  34 =head1 CGI PARAMETERS
  35
  36 =over 4
  37
  38 =item $booksellerid
  39
  40 The bookseller who we want to display the baskets (and basketgroups) of.
  41
  42 =back
  43
  44 =cut
  45
  46 use Modern::Perl;
  47 use Carp;
  48
  49 use C4::Auth;
  50 use C4::Output;
  51 use CGI qw ( -utf8 );
  52
  53 use C4::Acquisition qw/CloseBasketgroup ReOpenBasketgroup GetOrders GetBasketsByBasketgroup GetBasketsByBookseller ModBasketgroup NewBasketgroup DelBasketgroup GetBasketgroups ModBasket GetBasketgroup GetBasket GetBasketGroupAsCSV/;
  54 use Koha::EDI qw/create_edi_order get_edifact_ean/;
  55
  56 use Koha::Biblioitems;
  57 use Koha::Acquisition::Booksellers;
  58 use Koha::ItemTypes;
  59 use Koha::Patrons;
  60
  61 our $input=new CGI;
  62
  63 our ($template, $loggedinuser, $cookie)
  64     = get_template_and_user({template_name => "acqui/basketgroup.tt",
  65                              query => $input,
  66                              type => "intranet",
  67                              authnotrequired => 0,
  68                              flagsrequired => {acquisition => 'group_manage'},
  69                              debug => 1,
  70                 });
  71
  72 sub BasketTotal {
  73     my $basketno = shift;
  74     my $bookseller = shift;
  75     my $total = 0;
  76     my @orders = GetOrders($basketno);
  77     for my $order (@orders){
  78         # FIXME The following is wrong
  79         if ( $bookseller->listincgst ) {
  80             $total = $total + ( $order->{ecost_tax_included} * $order->{quantity} );
  81         } else {
  82             $total = $total + ( $order->{ecost_tax_excluded} * $order->{quantity} );
  83         }
  84     }
  85     return $total;
  86 }
  87
  88 #displays all basketgroups and all closed baskets (in their respective groups)
  89 sub displaybasketgroups {
  90     my $basketgroups = shift;
  91     my $bookseller = shift;
  92     my $baskets = shift;
  93     if (scalar @$basketgroups != 0) {
  94         foreach my $basketgroup (@$basketgroups){
  95             my $i = 0;
  96             my $basketsqty = 0;
  97             while($i < scalar(@$baskets)){
  98                 my $basket = @$baskets[$i];
  99                 if($basket->{'basketgroupid'} && $basket->{'basketgroupid'} == $basketgroup->{'id'}){
 100                     $basket->{total} = BasketTotal($basket->{basketno}, $bookseller);
 101                     push(@{$basketgroup->{'baskets'}}, $basket);
 102                     splice(@$baskets, $i, 1);
 103                     ++$basketsqty;
 104                     --$i;
 105                 }
 106                 ++$i;
 107             }
 108             $basketgroup -> {'basketsqty'} = $basketsqty;
 109         }
 110         $template->param(basketgroups => $basketgroups);
 111     }
 112     for(my $i=0; $i < scalar @$baskets; ++$i) {
 113         if( ! @$baskets[$i]->{'closedate'} ) {
 114             splice(@$baskets, $i, 1);
 115             --$i;
 116         }else{
 117             @$baskets[$i]->{total} = BasketTotal(@$baskets[$i]->{basketno}, $bookseller);
 118         }
 119     }
 120     $template->param(baskets => $baskets);
 121     $template->param( booksellername => $bookseller->name);
 122 }
 123
 124 sub printbasketgrouppdf{
 125     my ($basketgroupid) = @_;
 126
 127     my $pdfformat = C4::Context->preference("OrderPdfFormat");
 128     if ($pdfformat eq 'pdfformat::layout3pages' || $pdfformat eq 'pdfformat::layout2pages' || $pdfformat eq 'pdfformat::layout3pagesfr'
 129         || $pdfformat eq 'pdfformat::layout2pagesde'){
 130         eval {
 131         eval "require $pdfformat";
 132             import $pdfformat;
 133         };
 134         if ($@){
 135         }
 136     }
 137     else {
 138         print $input->header;
 139         print $input->start_html;  # FIXME Should do a nicer page
 140         print "<h1>Invalid PDF Format set</h1>";
 141         print "Please go to the systempreferences and set a valid pdfformat";
 142         exit;
 143     }
 144
 145     my $basketgroup = GetBasketgroup($basketgroupid);
 146     my $bookseller = Koha::Acquisition::Booksellers->find( $basketgroup->{booksellerid} );
 147     my $baskets = GetBasketsByBasketgroup($basketgroupid);
 148
 149     my %orders;
 150     for my $basket (@$baskets) {
 151         my @ba_orders;
 152         my @ords = &GetOrders($basket->{basketno});
 153         for my $ord (@ords) {
 154
 155             next unless ( $ord->{biblionumber} or $ord->{quantity}> 0 );
 156             eval {
 157                 require C4::Biblio;
 158                 import C4::Biblio;
 159             };
 160             if ($@){
 161                 croak $@;
 162             }
 163             eval {
 164                 require C4::Koha;
 165                 import C4::Koha;
 166             };
 167             if ($@){
 168                 croak $@;
 169             }
 170
 171             $ord->{tax_value} = $ord->{tax_value_on_ordering};
 172             $ord->{tax_rate} = $ord->{tax_rate_on_ordering};
 173             $ord->{total_tax_included} = $ord->{ecost_tax_included} * $ord->{quantity};
 174             $ord->{total_tax_excluded} = $ord->{ecost_tax_excluded} * $ord->{quantity};
 175
 176             my $biblioitem = Koha::Biblioitems->search({ biblionumber => $ord->{biblionumber} })->next;
 177
 178             #FIXME DELETE ME
 179             # 0      1        2        3         4            5         6       7      8        9
 180             #isbn, itemtype, author, title, publishercode, quantity, listprice ecost discount tax_rate
 181
 182             # Editor Number
 183             my $en;
 184             my $edition;
 185             $ord->{marcxml} = C4::Biblio::GetXmlBiblio( $ord->{biblionumber} );
 186             my $marcrecord=eval{MARC::Record::new_from_xml( $ord->{marcxml},'UTF-8' )};
 187             if ($marcrecord){
 188                 if ( C4::Context->preference("marcflavour") eq 'UNIMARC' ) {
 189                     $en = $marcrecord->subfield( '345', "b" );
 190                     $edition = $marcrecord->subfield( '205', 'a' );
 191                 } elsif ( C4::Context->preference("marcflavour") eq 'MARC21' ) {
 192                     $en = $marcrecord->subfield( '037', "a" );
 193                     $edition = $marcrecord->subfield( '250', 'a' );
 194                 }
 195             }
 196
 197             my $itemtype = ( $ord->{itemtype} and $biblioitem->itemtype )
 198                 ? Koha::ItemTypes->find( $biblioitem->itemtype )
 199                 : undef;
 200             $ord->{itemtype} = $itemtype ? $itemtype->description : undef;
 201
 202             $ord->{en} = $en ? $en : undef;
 203             $ord->{edition} = $edition ? $edition : undef;
 204
 205             push(@ba_orders, $ord);
 206         }
 207         $orders{$basket->{basketno}} = \@ba_orders;
 208     }
 209     print $input->header(
 210         -type       => 'application/pdf',
 211         -attachment => ( $basketgroup->{name} || $basketgroupid ) . '.pdf'
 212     );
 213     my $pdf = printpdf($basketgroup, $bookseller, $baskets, \%orders, $bookseller->tax_rate // C4::Context->preference("gist")) || die "pdf generation failed";
 214     print $pdf;
 215
 216 }
 217
 218 sub generate_edifact_orders {
 219     my $basketgroupid = shift;
 220     my $baskets       = GetBasketsByBasketgroup($basketgroupid);
 221     my $ean           = get_edifact_ean();
 222
 223     for my $basket ( @{$baskets} ) {
 224         create_edi_order( { ean => $ean, basketno => $basket->{basketno}, } );
 225     }
 226     return;
 227 }
 228
 229 my $op = $input->param('op') || 'display';
 230 # possible values of $op :
 231 # - add : adds a new basketgroup, or edit an open basketgroup, or display a closed basketgroup
 232 # - mod_basket : modify an individual basket of the basketgroup
 233 # - closeandprint : close and print an closed basketgroup in pdf. called by clicking on "Close and print" button in closed basketgroups list
 234 # - print : print a closed basketgroup. called by clicking on "Print" button in closed basketgroups list
 235 # - ediprint : generate edi order messages for the baskets in the group
 236 # - export : export in CSV a closed basketgroup. called by clicking on "Export" button in closed basketgroups list
 237 # - delete : delete an open basketgroup. called by clicking on "Delete" button in open basketgroups list
 238 # - reopen : reopen a closed basketgroup. called by clicking on "Reopen" button in closed basketgroup list
 239 # - attachbasket : save a modified basketgroup, or creates a new basketgroup when a basket is closed. called from basket page
 240 # - display : display the list of all basketgroups for a vendor
 241 my $booksellerid = $input->param('booksellerid');
 242 $template->param(booksellerid => $booksellerid);
 243
 244 if ( $op eq "add" ) {
 245 #
 246 # if no param('basketgroupid') is not defined, adds a new basketgroup
 247 # else, edit (if it is open) or display (if it is close) the basketgroup basketgroupid
 248 # the template will know if basketgroup must be displayed or edited, depending on the value of closed key
 249 #
 250     my $bookseller = Koha::Acquisition::Booksellers->find( $booksellerid );
 251     my $basketgroupid = $input->param('basketgroupid');
 252     my $billingplace;
 253     my $deliveryplace;
 254     my $freedeliveryplace;
 255     if ( $basketgroupid ) {
 256         # Get the selected baskets in the basketgroup to display them
 257         my $selecteds = GetBasketsByBasketgroup($basketgroupid);
 258         foreach my $basket(@{$selecteds}){
 259             $basket->{total} = BasketTotal($basket->{basketno}, $bookseller);
 260         }
 261         $template->param(basketgroupid => $basketgroupid,
 262                          selectedbaskets => $selecteds);
 263
 264         # Get general informations about the basket group to prefill the form
 265         my $basketgroup = GetBasketgroup($basketgroupid);
 266         $template->param(
 267             name            => $basketgroup->{name},
 268             deliverycomment => $basketgroup->{deliverycomment},
 269             freedeliveryplace => $basketgroup->{freedeliveryplace},
 270         );
 271         $billingplace  = $basketgroup->{billingplace};
 272         $deliveryplace = $basketgroup->{deliveryplace};
 273         $freedeliveryplace = $basketgroup->{freedeliveryplace};
 274         $template->param( closedbg => ($basketgroup ->{'closed'}) ? 1 : 0);
 275     } else {
 276         $template->param( closedbg => 0);
 277     }
 278     # determine default billing and delivery places depending on librarian homebranch and existing basketgroup data
 279     my $patron = Koha::Patrons->find( $loggedinuser ); # FIXME Not needed if billingplace and deliveryplace are set
 280     $billingplace  = $billingplace  || $patron->branchcode;
 281     $deliveryplace = $deliveryplace || $patron->branchcode;
 282
 283     $template->param( billingplace => $billingplace );
 284     $template->param( deliveryplace => $deliveryplace );
 285     $template->param( booksellerid => $booksellerid );
 286
 287     # the template will display a unique basketgroup
 288     $template->param(grouping => 1);
 289     my $basketgroups = &GetBasketgroups($booksellerid);
 290     my $baskets = &GetBasketsByBookseller($booksellerid);
 291     displaybasketgroups($basketgroups, $bookseller, $baskets);
 292 } elsif ($op eq 'mod_basket') {
 293 #
 294 # edit an individual basket contained in this basketgroup
 295 #
 296   my $basketno=$input->param('basketno');
 297   my $basketgroupid=$input->param('basketgroupid');
 298   ModBasket( { basketno => $basketno,
 299                          basketgroupid => $basketgroupid } );
 300   print $input->redirect("basket.pl?basketno=" . $basketno);
 301 } elsif ( $op eq 'closeandprint') {
 302 #
 303 # close an open basketgroup and generates a pdf
 304 #
 305     my $basketgroupid = $input->param('basketgroupid');
 306     CloseBasketgroup($basketgroupid);
 307     printbasketgrouppdf($basketgroupid);
 308     exit;
 309 }elsif ($op eq 'print'){
 310 #
 311 # print a closed basketgroup
 312 #
 313     my $basketgroupid = $input->param('basketgroupid');
 314     printbasketgrouppdf($basketgroupid);
 315     exit;
 316 }elsif ( $op eq "export" ) {
 317 #
 318 # export a closed basketgroup in csv
 319 #
 320     my $basketgroupid = $input->param('basketgroupid');
 321     print $input->header(
 322         -type       => 'text/csv',
 323         -attachment => 'basketgroup' . $basketgroupid . '.csv',
 324     );
 325     print GetBasketGroupAsCSV( $basketgroupid, $input );
 326     exit;
 327 }elsif( $op eq "delete"){
 328 #
 329 # delete an closed basketgroup
 330 #
 331     my $basketgroupid = $input->param('basketgroupid');
 332     DelBasketgroup($basketgroupid);
 333     print $input->redirect('/cgi-bin/koha/acqui/basketgroup.pl?booksellerid=' . $booksellerid.'&amp;listclosed=1');
 334 }elsif ( $op eq 'reopen'){
 335 #
 336 # reopen a closed basketgroup
 337 #
 338     my $basketgroupid   = $input->param('basketgroupid');
 339     my $booksellerid    = $input->param('booksellerid');
 340     ReOpenBasketgroup($basketgroupid);
 341     my $redirectpath = ((defined $input->param('mode'))&& ($input->param('mode') eq 'singlebg')) ?'/cgi-bin/koha/acqui/basketgroup.pl?op=add&amp;basketgroupid='.$basketgroupid.'&amp;booksellerid='.$booksellerid : '/cgi-bin/koha/acqui/basketgroup.pl?booksellerid=' .$booksellerid.'&amp;listclosed=1';
 342     print $input->redirect($redirectpath);
 343 } elsif ( $op eq 'attachbasket') {
 344 #
 345 # save a modified basketgroup, or creates a new basketgroup when a basket is closed. called from basket page
 346 #
 347     # Getting parameters
 348     my $basketgroup       = {};
 349     my @baskets           = $input->multi_param('basket');
 350     my $basketgroupid     = $input->param('basketgroupid');
 351     my $basketgroupname   = $input->param('basketgroupname');
 352     my $booksellerid      = $input->param('booksellerid');
 353     my $billingplace      = $input->param('billingplace');
 354     my $deliveryplace     = $input->param('deliveryplace');
 355     my $freedeliveryplace = $input->param('freedeliveryplace');
 356     my $deliverycomment   = $input->param('deliverycomment');
 357     my $closedbg          = $input->param('closedbg') ? 1 : 0;
 358     if ($basketgroupid) {
 359     # If we have a basketgroupid we edit the basketgroup
 360         $basketgroup = {
 361               name              => $basketgroupname,
 362               id                => $basketgroupid,
 363               basketlist        => \@baskets,
 364               billingplace      => $billingplace,
 365               deliveryplace     => $deliveryplace,
 366               freedeliveryplace => $freedeliveryplace,
 367               deliverycomment   => $deliverycomment,
 368               closed            => $closedbg,
 369         };
 370         ModBasketgroup($basketgroup);
 371         if($closedbg){
 372 # FIXME
 373         }
 374     }else{
 375     # we create a new basketgroup (with a closed basket)
 376         $basketgroup = {
 377             name              => $basketgroupname,
 378             booksellerid      => $booksellerid,
 379             basketlist        => \@baskets,
 380             billingplace      => $billingplace,
 381             deliveryplace     => $deliveryplace,
 382             freedeliveryplace => $freedeliveryplace,
 383             deliverycomment   => $deliverycomment,
 384             closed            => $closedbg,
 385         };
 386         $basketgroupid = NewBasketgroup($basketgroup);
 387     }
 388     my $redirectpath = ((defined $input->param('mode')) && ($input->param('mode') eq 'singlebg')) ?'/cgi-bin/koha/acqui/basketgroup.pl?op=add&amp;basketgroupid='.$basketgroupid.'&amp;booksellerid='.$booksellerid : '/cgi-bin/koha/acqui/basketgroup.pl?booksellerid=' . $booksellerid;
 389     $redirectpath .=  "&amp;listclosed=1" if $closedbg ;
 390     print $input->redirect($redirectpath );
 391
 392 } elsif ( $op eq 'ediprint') {
 393     my $basketgroupid = $input->param('basketgroupid');
 394     generate_edifact_orders( $basketgroupid );
 395     exit;
 396 }else{
 397 # no param : display the list of all basketgroups for a given vendor
 398     my $basketgroups = &GetBasketgroups($booksellerid);
 399     my $bookseller = Koha::Acquisition::Booksellers->find( $booksellerid );
 400     my $baskets = &GetBasketsByBookseller($booksellerid);
 401
 402     displaybasketgroups($basketgroups, $bookseller, $baskets);
 403 }
 404 $template->param(listclosed => ((defined $input->param('listclosed')) && ($input->param('listclosed') eq '1'))? 1:0 );
 405 #prolly won't use all these, maybe just use print, the rest can be done inside validate
 406 output_html_with_http_headers $input, $cookie, $template->output;