acqui/parcel.pl

   1 #!/usr/bin/perl
   2
   3 #script to recieve orders
   4
   5
   6 # Copyright 2000-2002 Katipo Communications
   7 # Copyright 2008-2009 BibLibre SARL
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it under the
  12 # terms of the GNU General Public License as published by the Free Software
  13 # Foundation; either version 2 of the License, or (at your option) any later
  14 # version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  17 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  18 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License along
  21 # with Koha; if not, write to the Free Software Foundation, Inc.,
  22 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  23
  24 =head1 NAME
  25
  26 parcel.pl
  27
  28 =head1 DESCRIPTION
  29
  30 This script shows all orders receipt or pending for a given supplier.
  31 It allows to write an order as 'received' when he arrives.
  32
  33 =head1 CGI PARAMETERS
  34
  35 =over 4
  36
  37 =item booksellerid
  38
  39 To know the supplier this script has to show orders.
  40
  41 =item code
  42
  43 is the bookseller invoice number.
  44
  45
  46 =item gst
  47
  48
  49 =item datereceived
  50
  51 To filter the results list on this given date.
  52
  53 =back
  54
  55 =cut
  56
  57 use strict;
  58 use warnings;
  59
  60 use C4::Auth;
  61 use C4::Acquisition;
  62 use C4::Budgets;
  63 use C4::Biblio;
  64 use C4::Items;
  65 use CGI qw ( -utf8 );
  66 use C4::Output;
  67 use C4::Dates qw/format_date format_date_in_iso/;
  68 use C4::Suggestions;
  69 use C4::Reserves qw/GetReservesFromBiblionumber/;
  70
  71 use Koha::Acquisition::Bookseller;
  72
  73 use JSON;
  74
  75 my $input=new CGI;
  76 my $sticky_filters = $input->param('sticky_filters') || 0;
  77
  78 my ($template, $loggedinuser, $cookie)
  79     = get_template_and_user({template_name => "acqui/parcel.tt",
  80                  query => $input,
  81                  type => "intranet",
  82                  authnotrequired => 0,
  83                  flagsrequired => {acquisition => 'order_receive'},
  84                  debug => 1,
  85 });
  86
  87 my $op = $input->param('op') // '';
  88
  89 # process cancellation first so that list of
  90 # orders to display is calculated after
  91 if ($op eq 'cancelreceipt') {
  92     my $ordernumber = $input->param('ordernumber');
  93     my $parent_ordernumber = CancelReceipt($ordernumber);
  94     unless($parent_ordernumber) {
  95         $template->param(error_cancelling_receipt => 1);
  96     }
  97 }
  98
  99 my $invoiceid = $input->param('invoiceid');
 100 my $invoice;
 101 $invoice = GetInvoiceDetails($invoiceid) if $invoiceid;
 102
 103 unless( $invoiceid and $invoice->{invoiceid} ) {
 104     $template->param(
 105         error_invoice_not_known => 1,
 106         no_orders_to_display    => 1
 107     );
 108     output_html_with_http_headers $input, $cookie, $template->output;
 109     exit;
 110 }
 111
 112 my $booksellerid = $invoice->{booksellerid};
 113 my $bookseller = Koha::Acquisition::Bookseller->fetch({ id => $booksellerid });
 114 my $gst = $bookseller->{gstrate} // C4::Context->preference("gist") // 0;
 115 my $datereceived = C4::Dates->new();
 116
 117 my @orders        = @{ $invoice->{orders} };
 118 my $countlines    = scalar @orders;
 119 my @loop_received = ();
 120 my @book_foot_loop;
 121 my %foot;
 122 my $total_gste = 0;
 123 my $total_gsti = 0;
 124
 125 for my $order ( @orders ) {
 126     $order = C4::Acquisition::populate_order_with_prices({ order => $order, booksellerid => $bookseller->{id}, receiving => 1, ordering => 1 });
 127     $order->{'unitprice'} += 0;
 128
 129     if ( $bookseller->{listincgst} and not $bookseller->{invoiceincgst} ) {
 130         $order->{ecost}     = $order->{ecostgste};
 131         $order->{unitprice} = $order->{unitpricegste};
 132     }
 133     elsif ( not $bookseller->{listinct} and $bookseller->{invoiceincgst} ) {
 134         $order->{ecost}     = $order->{ecostgsti};
 135         $order->{unitprice} = $order->{unitpricegsti};
 136     }
 137     $order->{total} = $order->{ecost} * $order->{quantity};
 138
 139     my %line = %{ $order };
 140     $line{invoice} = $invoice->{invoicenumber};
 141     $line{holds} = 0;
 142     my @itemnumbers = GetItemnumbersFromOrder( $order->{ordernumber} );
 143     for my $itemnumber ( @itemnumbers ) {
 144         my $holds = GetReservesFromBiblionumber({ biblionumber => $line{biblionumber}, itemnumber => $itemnumber });
 145         $line{holds} += scalar( @$holds );
 146     }
 147     $line{budget} = GetBudgetByOrderNumber( $line{ordernumber} );
 148     $foot{$line{gstrate}}{gstrate} = $line{gstrate};
 149     $foot{$line{gstrate}}{gstvalue} += $line{gstvalue};
 150     $total_gste += $line{totalgste};
 151     $total_gsti += $line{totalgsti};
 152
 153     my $suggestion   = GetSuggestionInfoFromBiblionumber($line{biblionumber});
 154     $line{suggestionid}         = $suggestion->{suggestionid};
 155     $line{surnamesuggestedby}   = $suggestion->{surnamesuggestedby};
 156     $line{firstnamesuggestedby} = $suggestion->{firstnamesuggestedby};
 157
 158     if ( $line{parent_ordernumber} != $line{ordernumber} ) {
 159         if ( grep { $_->{ordernumber} == $line{parent_ordernumber} }
 160             @orders
 161             )
 162         {
 163             $line{cannot_cancel} = 1;
 164         }
 165     }
 166
 167     my $budget = GetBudget( $line{budget_id} );
 168     $line{budget_name} = $budget->{'budget_name'};
 169
 170     push @loop_received, \%line;
 171 }
 172 push @book_foot_loop, map { $_ } values %foot;
 173
 174 my @loop_orders = ();
 175 unless( defined $invoice->{closedate} ) {
 176     my $pendingorders;
 177     if ( $op eq "search" or $sticky_filters ) {
 178         my ( $search, $ean, $basketname, $orderno, $basketgroupname );
 179         if ( $sticky_filters ) {
 180             $search = $input->cookie("filter_parcel_summary");
 181             $ean = $input->cookie("filter_parcel_ean");
 182             $basketname = $input->cookie("filter_parcel_basketname");
 183             $orderno = $input->cookie("filter_parcel_orderno");
 184             $basketgroupname = $input->cookie("filter_parcel_basketgroupname");
 185         } else {
 186             $search   = $input->param('summaryfilter') || '';
 187             $ean      = $input->param('eanfilter') || '';
 188             $basketname = $input->param('basketfilter') || '';
 189             $orderno  = $input->param('orderfilter') || '';
 190             $basketgroupname = $input->param('basketgroupnamefilter') || '';
 191         }
 192         $pendingorders = SearchOrders({
 193             booksellerid => $booksellerid,
 194             basketname => $basketname,
 195             ordernumber => $orderno,
 196             search => $search,
 197             ean => $ean,
 198             basketgroupname => $basketgroupname,
 199             pending => 1,
 200             ordered => 1,
 201         });
 202         $template->param(
 203             summaryfilter => $search,
 204             eanfilter => $ean,
 205             basketfilter => $basketname,
 206             orderfilter => $orderno,
 207             basketgroupnamefilter => $basketgroupname,
 208         );
 209     }else{
 210         $pendingorders = SearchOrders({
 211             booksellerid => $booksellerid,
 212             ordered => 1
 213         });
 214     }
 215     my $countpendings = scalar @$pendingorders;
 216
 217     for (my $i = 0 ; $i < $countpendings ; $i++) {
 218         my $order = $pendingorders->[$i];
 219         $order = C4::Acquisition::populate_order_with_prices({ order => $order, booksellerid => $bookseller->{id}, receiving => 1, ordering => 1 });
 220
 221         if ( $bookseller->{listincgst} and not $bookseller->{invoiceincgst} ) {
 222             $order->{ecost} = $order->{ecostgste};
 223         } elsif ( not $bookseller->{listinct} and $bookseller->{invoiceincgst} ) {
 224             $order->{ecost} = $order->{ecostgsti};
 225         }
 226         $order->{total} = $order->{ecost} * $order->{quantity};
 227
 228         my %line = %$order;
 229
 230         $line{invoice} = $invoice;
 231         $line{booksellerid} = $booksellerid;
 232
 233         my $biblionumber = $line{'biblionumber'};
 234         my $countbiblio = CountBiblioInOrders($biblionumber);
 235         my $ordernumber = $line{'ordernumber'};
 236         my @subscriptions = GetSubscriptionsId ($biblionumber);
 237         my $itemcount = GetItemsCount($biblionumber);
 238         my $holds  = GetHolds ($biblionumber);
 239         my @items = GetItemnumbersFromOrder( $ordernumber );
 240         my $itemholds;
 241         foreach my $item (@items){
 242             my $nb = GetItemHolds($biblionumber, $item);
 243             if ($nb){
 244                 $itemholds += $nb;
 245             }
 246         }
 247
 248         my $suggestion   = GetSuggestionInfoFromBiblionumber($line{biblionumber});
 249         $line{suggestionid}         = $suggestion->{suggestionid};
 250         $line{surnamesuggestedby}   = $suggestion->{surnamesuggestedby};
 251         $line{firstnamesuggestedby} = $suggestion->{firstnamesuggestedby};
 252
 253         # if the biblio is not in other orders and if there is no items elsewhere and no subscriptions and no holds we can then show the link "Delete order and Biblio" see bug 5680
 254         $line{can_del_bib}          = 1 if $countbiblio <= 1 && $itemcount == scalar @items && !(@subscriptions) && !($holds);
 255         $line{items}                = ($itemcount) - (scalar @items);
 256         $line{left_item}            = 1 if $line{items} >= 1;
 257         $line{left_biblio}          = 1 if $countbiblio > 1;
 258         $line{biblios}              = $countbiblio - 1;
 259         $line{left_subscription}    = 1 if scalar @subscriptions >= 1;
 260         $line{subscriptions}        = scalar @subscriptions;
 261         $line{left_holds}           = ($holds >= 1) ? 1 : 0;
 262         $line{left_holds_on_order}  = 1 if $line{left_holds}==1 && ($line{items} == 0 || $itemholds );
 263         $line{holds}                = $holds;
 264         $line{holds_on_order}       = $itemholds?$itemholds:$holds if $line{left_holds_on_order};
 265
 266         my $budget = GetBudget( $line{budget_id} );
 267         $line{budget_name} = $budget->{'budget_name'};
 268
 269         push @loop_orders, \%line;
 270     }
 271
 272     $template->param(
 273         loop_orders  => \@loop_orders,
 274     );
 275 }
 276
 277 $template->param(
 278     invoiceid             => $invoice->{invoiceid},
 279     invoice               => $invoice->{invoicenumber},
 280     invoiceclosedate      => $invoice->{closedate},
 281     datereceived          => $datereceived->output('iso'),
 282     invoicedatereceived   => $datereceived->output('iso'),
 283     formatteddatereceived => $datereceived->output(),
 284     name                  => $bookseller->{'name'},
 285     booksellerid          => $bookseller->{id},
 286     loop_received         => \@loop_received,
 287     loop_orders           => \@loop_orders,
 288     book_foot_loop        => \@book_foot_loop,
 289     (uc(C4::Context->preference("marcflavour"))) => 1,
 290     total_gste           => $total_gste,
 291     total_gsti           => $total_gsti,
 292     sticky_filters       => $sticky_filters,
 293 );
 294 output_html_with_http_headers $input, $cookie, $template->output;